home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DOS/V Power Report 1997 November
/
VPR9711A.ISO
/
VPR_DATA
/
Special
/
Okseik31
/
okseik31.lzh
/
SVSEIKEI.MAC
< prev
Wrap
Text File
|
1997-03-30
|
21KB
|
807 lines
// 電子メール・会議室発言用整形マクロ マクロサーバ対応版
// SVSEIKEI.MAC ver.3.1
// by JRくん(GFB03426) 1996.3.23
if (readonly) {
message "電子メール・会議室発言用整形:\n"
+ "「上書き禁止」なので実行を中止します。";
endmacro;
}
if (browsemode) {
message "電子メール・会議室発言用整形:\n"
+ "「閲覧モード」なので実行を中止します。";
endmacro;
}
title "起動の準備をしています:■□□";
// マクロサーバー起動
run "macserv.exe /h";
ddeinitiate "HideMacroServer", "DlgService";
if( !result ) {
message "ddeinitiate failed";
endmacro;
}
title "起動の準備をしています:■■□";
// 範囲選択しているかどうか調べる
if (rectselecting) {
// BOX 範囲選択している場合に範囲選択を変更
#x1 = seltopx; #y1 = seltopy;
#x2 = selendx; #y2 = selendy;
escape;
moveto #x2, #y2;
beginsel;
moveto #x1, #y1;
#selecting = yes;
} else {
#selecting = selecting;
}
#OptionChange = no;
$Mes[no] = "しない";
$Mes[yes] = "する";
// 引用符を取得
$inyoufuini = getinistr("HIDEMARU.INI", "Env", "RefMark");
$inyoufu = midstr($inyoufuini, 1, strlen($inyoufuini) - 2);
#inyoufuLen = strlen($inyoufu);
// INIファイルを取得
$INIdir = getinistr("HIDEMARU.INI", "Env", "MacroPath");
if ($INIdir == "") $INIdir = hidemarudir;
$INIfile = $INIdir+"\\OKSEIKEI.INI";
// 各種設定を取得
call GetEnv;
title "起動の準備をしています:■■■";
Menuoutput:
// 禁則処理・折り返し文字数値の変換処理
call ConvertKinsokuOrikaesi;
title 0;
// メニュー表示
if (#AutoRun) {
writeininum $INIfile,"Env","AutoRun", 0;
} else {
call Error;
if ($$return != "") {
message $Error;
call OptionMenuOutput;
goto Menuoutput;
}
if (#ConfigDlg) {
ConfigDlgMenu:
call OptionMenuOutput;
if (( $return == "202" ) || ( $return == "0" )) {
ddeexecute "exit";
endmacro;
}
call ConvertKinsokuOrikaesi;
call Error;
if ($$return != "") {
message $Error;
goto ConfigDlgMenu;
}
} else {
goto MainMenu;
MainMenuEnd:
}
}
// 整形開始
title "整形の準備をしています:■□□□□";
ddeexecute "exit";
disableinvert;
// 自動インデント を 一時的に 無し にする
#indentstate = indentstate;
if (#indentstate != 0) {
config "i0";
}
// 上書きモードの場合は、一時的に挿入モードにする
#overwrite = overwrite;
if( #overwrite ) overwriteswitch;
// 前処理:タブ -> スペース変換、範囲選択処理
if ((#selecting) && (#Part)) {
#x1 = seltopx; #y1 = seltopy;
#x2 = selendx; #y2 = selendy;
if (#ClipBoard) {
selectall;
copy;
moveto #x1, #y1;
beginsel;
moveto #x2, #y2;
}
if (#Tospace) tospace;
escape;
moveto selendx, selendy;
#count = lineno;
if (#x2 != 0) {
#count = #count + 1;
insertreturn;
}
moveto #x1, #y1;
#count = #count - lineno;
if (#x1 != 0) insertreturn;
} else {
selectall;
if (#ClipBoard) {
copy;
selectall;
}
if (#Tospace) tospace;
escape;
gofileend;
if (column != 0) insertreturn;
#x1 = 0; #y1 = 0;
#count = linecount + 1; // ←ダミーに適当に大きな値
gofiletop;
}
title "整形の準備をしています:■■□□□";
// ウィンドウを自動的に小さくする を 一時的に off にする
#AutoShrink = getininum("HIDEMARU.INI", "Env", "AutoShrink");
if (#AutoShrink) {
writeininum "HIDEMARU.INI", "Env", "AutoShrink", no;
envchanged;
}
// 折り返し文字数の設定
#prevwindowwidth = windowwidth;
#prevOrikaesiNum = width;
config "w" + str(#OrikaesiNum);
// 禁則処理の設定
#KinsokuChange = no;
if (#Kinsoku != -1) {
#prevKinsoku = kinsokustate;
if (#Kinsoku != #prevKinsoku) {
#KinsokuChange = yes;
if (#Kinsoku) {
config "k+";
} else {
config "k-";
}
}
}
if (#DisableDraw) disabledraw;
title "整形の準備をしています:■■■□□";
// ウィンドウを大きくする場合の処理
#Changewindowwidth = no;
#WindowNum = #OrikaesiNum;
if (linenostate) { // 行番号分の文字数を追加
call LineNoNum;
#WindowNum = #WindowNum + ##return + 1;
}
if (kinsokustate) { // 禁則処理分の文字数を追加
if (getininum("HIDEMARU.INI","Env","CRBurasage") == 1)
#WindowNum = #WindowNum + 1;
if (getininum("HIDEMARU.INI","Env","Burasage") > 0)
#WindowNum = #WindowNum + 2;
}
if (#WindowNum > windowwidth) {
#Changewindowwidth = yes;
setwindowsize #WindowNum, windowheight;
}
// 左余白文字列をつくる
$LeftMargin = "";
#a = #LeftMargin;
if ((#a > 0) && (#a < width)) {
while(#a > 0) {
$LeftMargin = $LeftMargin + " ";
#a = #a - 1;
}
}
$InyouMargin = "";
#a = #InyouMargin;
if ((#a > 0) && (#a < width)) {
while(#a > 0) {
$InyouMargin = $InyouMargin + " ";
#a = #a - 1;
}
}
// 引用行を区別しない場合のダミー処理
if (#INYOUlineProcess) {
#inyoufuLen = 0;
$inyoufu = "\n";
}
title "整形の準備をしています:■■■■□";
// 「埋め込みコマンド」の長さ、ふるい分け用文字列を取得
if (#CommandProcess) {
$CommandArray = "\n"; //←埋め込みコマンド処理しない時のダミー
} else {
#a = 1;
$CommandArray = "";
$CommandArray2 = "";
while (#a <= #NumberOfCommand) {
#Com[#a] = strlen($Com[#a]);
$ThisCommand = "\n" + leftstr($Com[#a] + " ",2);
$CommandArray = $CommandArray + $ThisCommand;
$CommandArray2= $ThisCommand + $CommandArray2;
#a = #a+ 1;
}
}
title "整形の準備をしています:■■■■■";
// 「顔文字」の長さ、ふるい分け用文字列を取得
if (#KAOMOJIwrap) {
#a = 1;
$KAOMOJIArray = "";
while (#a <= #NumberOfKAOMOJI) {
#KAO[#a] = strlen($KAO[#a]);
$KAOMOJIArray =$KAOMOJIArray + $KAO[#a];
#a = #a + 1;
}
if (kinsokustate) {
$TKin = getinistr("HIDEMARU.INI", "Env", "TKin");
} else {
$TKin = "\n";
}
} else {
$KAOMOJIArray = "\n"; //←顔文字ラップしないためのダミー
}
title "整形中...";
// メインループ
while (#count > 0) {
if (code == eof) break;
if (code == 0x0d) {
down;
golinetop2;
goto gogo;
}
// 引用行の処理
if (gettext(0, y, #inyoufuLen, y) == $inyoufu) {
title "整形中...("+str((y+1)*100/linecount)+"% 完了) [引用行 処理中]";
insert $InyouMargin;
golineend2;
if (code == eof) break;
down;
golinetop2;
goto gogo;
}
// 埋め込みコマンドの処理
#ComNo = strstr($CommandArray, "\n" + char(code));
if (#ComNo != -1) goto LineTopCommandProcess;
LineTopCommandProcessEnd:
// 普通行の処理
NormalLineLoop:
insert $LeftMargin;
golineend;
if (code == eof) {
break;
} else if (code == 0x0d) {
down;
golinetop2;
} else {
right;
if (strstr($KAOMOJIArray, char(code)) != -1) call KaoMojiWrap;
if (code == eof) {
break;
} else if (code == 0x0d) {
down;
golinetop2;
} else {
insertreturn;
goto NormalLineLoop;
}
}
title "整形中...("+str((y+1)*100/linecount)+"% 完了)";
gogo:
#count = #count - 1;
}
goto MacroEnd;
// 「埋め込みコマンド」処理
LineTopCommandProcess:
title "整形中...("+str((y+1)*100/linecount)+"% 完了) [埋め込みコマンド 処理中]";
$t = gettext(0, y, linelen, y);
#a = #ComNo / 3 + 1;
#ComNo2 = strstr($CommandArray2, "\n" + char(code));
#ComNo2 = #NumberOfCommand - (#ComNo2 / 3);
while (#a <= #ComNo2) {
if (leftstr($t,#Com[#a]) == $Com[#a]) {
golineend2;
if (code == eof) goto MacroEnd;
down;
golinetop2;
break;
}
#a = #a + 1;
}
if (#a <= #ComNo2) {
goto gogo;
}
goto LineTopCommandProcessEnd;
// サブルーチン
// 顔文字ラップ ←このルーチンはちょっと怪しいような気がする(^^;)
KaoMojiWrap:
title "整形中...("+str((y+1)*100/linecount)+"% 完了) [顔文字ラップ 処理中]";
#xx = column + 1; #yy = lineno;
#n = 1;
while (#n <= #NumberOfKAOMOJI) {
#xxx = #xx - #KAO[#n] + 1;
if (#xxx < 1) #xxx = 1;
movetolineno #xxx, #yy;
left;
#clm = column;
beginsel;
golineend2;
$LINE = gettext(seltopx, seltopy, selendx, selendy);
escape;
movetolineno #xx, #yy;
#KAOMOJIx = strstr($LINE, $KAO[#n]);
if ((#KAOMOJIx != -1) &&
((#clm + #KAOMOJIx) >= (#xx - #KAO[#n] )) &&
((#clm + #KAOMOJIx) <= (#xx + #KAO[#n] - 1))) {
#xend = #clm + 1 + #KAOMOJIx + #KAO[#n];
#wrapEndx = #OrikaesiNum + #KAOMOJIwrapMax + 1;
if (#xend <= #wrapEndx) {
movetolineno #xend, #yy;
if (strstr($TKin, char(code)) != -1) right;
break;
} else {
movetolineno #clm + 1 + #KAOMOJIx, #yy;
break;
}
}
#n = #n + 1;
}
return;
// メインダイアログの表示
MainMenu:
MainMenuLoop:
ddepoke "newdialog", "44,電子メール・会議室発言用 簡易整形 ver.3.1";
ddepoke "newcontrol","text,,現在の設定:";
ddepoke "newcontrol","text,,・折り返す文字数:" + $OrikaesiNum;
ddepoke "newcontrol","text,,・左余白の設定 普通行:" + str(#LeftMargin)
+ " 引用行:" + str(#InyouMargin);
ddepoke "newcontrol","text,,・引用行を区別:"
+ $Mes[1-#INYOUlineProcess];
ddepoke "newcontrol","text,,・埋め込みコマンド行を整形しない:"
+ $Mes[1-#CommandProcess];
ddepoke "newcontrol","text,,・顔文字ラップ:" + $Mes[#KAOMOJIwrap];
ddepoke "newcontrol","text,,・禁則処理:" + $Kinsoku;
ddepoke "newcontrol","text,,・シグネチャ:" + $SigName[#Signature];
ddepoke "newcontrol","text,,・タブ→スペース変換:" + $Mes[#Tospace];
if (#selecting) {
ddepoke "newcontrol","text,,・選択した範囲内のみ処理:" + $Mes[#Part];
} else {
ddepoke "newcontrol","text,, (全文対象)";
}
ddepoke "newcontrol", "button,,整形の実行(&E)";
ddepoke "notify", "101";
ddepoke "newcontrol", "button,,現在の設定の変更(&C)...";
ddepoke "notify", "102";
if (#OptionChange) {
ddepoke "newcontrol", "button,,終了(&Q)";
} else {
ddepoke "newcontrol", "button,,キャンセル(&Q)";
}
ddepoke "notify", "103";
ddepoke "part", "28";
ddepoke "newcontrol", "button,,ヘルプ(&H)";
ddepoke "notify", "104";
call MakeDialog;
if(( $$return == "103" ) || ( $$return == "0" )) { // 終了/キャンセル
ddeexecute "exit";
endmacro;
} else if( $$return == "102" ) { // 現在の設定の変更
call OptionMenuOutput;
goto Menuoutput;
} else if( $$return == "104" ) {
run "WINHELP.EXE " + $INIdir + "\\OKSEIKEI.HLP";
goto MainMenuLoop;
}
goto MainMenuEnd;
// 設定用ダイアログの表示
OptionMenuOutput:
ddepoke "newdialog", "38,電子メール・会議室発言用 簡易整形 ver.3.1 の 設定";
ddepoke "newcontrol", "check,INYOU,引用行を区別する(&I)";
ddepoke "default", str(1 - #INYOUlineProcess);
ddepoke "newcontrol","check,Command,埋め込みコマンド行/ヘッダ部を整形しない(&C)";
ddepoke "default", str(1 - #CommandProcess);
ddepoke "newcontrol","check,KAOMOJIwrap,顔文字ラップ(&W)";
ddepoke "default", str(#KAOMOJIwrap);
ddepoke "newcontrol", "text,, 右にはみ出す最大文字数(&R):";
ddepoke "part", "30";
ddepoke "newcontrol", "edit,KAOMOJIwrapMax," + str(#KAOMOJIwrapMax);
ddepoke "part", "5";
ddepoke "newcontrol", "text,,"; //(ダミー)
ddepoke "newcontrol", "radio,Kinsoku,禁則処理の設定(&K):";
ddepoke "item", "秀丸の設定に従う(" + $Mes[kinsokustate] + ")(&1)";
ddepoke "item", "しない(&2)";
ddepoke "item", "する(&3)";
ddepoke "default", str(#Kinsoku + 2);
ddepoke "part", "32";
ddepoke "newcontrol", "text,,"; //(ダミー)
ddepoke "newcontrol","check,Tospace,タブ→スペース変換(&T)";
ddepoke "default", str(#Tospace);
ddepoke "newcontrol","check,ClipBoard,整形前に全文をクリップボードにコピー(&B)";
ddepoke "default", str(#ClipBoard);
ddepoke "newcontrol","check,DisableDraw,整形途中を表示しない(&D)";
ddepoke "default", str(#DisableDraw);
ddepoke "newcolumn", "30";
ddepoke "newcontrol", "text,,・折り返す文字数(&M):";
ddepoke "part", "21";
ddepoke "newcontrol", "edit,OrikaesiNum," + str(#TmpOrikaesiNum);
ddepoke "part", "6";
ddepoke "newcontrol", "text,,"; //(ダミー)
ddepoke "newcontrol", "text,,・左余白";
ddepoke "part", "9";
ddepoke "newcontrol", "text,,普通行(&N):";
ddepoke "part", "12";
ddepoke "newcontrol", "edit,LeftMargin," + str(#LeftMargin);
ddepoke "part", "5";
ddepoke "newcontrol", "text,,"; //(ダミー)
ddepoke "newcontrol", "text,,";
ddepoke "part", "9";
ddepoke "newcontrol", "text,,引用行(&Y):";
ddepoke "part", "12";
ddepoke "newcontrol", "edit,InyouMargin," + str(#InyouMargin);
ddepoke "part", "5";
ddepoke "newcontrol", "text,,"; //(ダミー)
ddepoke "newcontrol", "text,,シグネチャ(&S):";
ddepoke "newcontrol","list,Signature,";
#n = 0;
while (#n <= #SignatureNum) {
ddepoke "item", $SigName[#n];
#n = #n + 1;
}
ddepoke "default", str(#Signature + 1);
ddepoke "height", "5";
ddepoke "newcontrol","text,,"; //←ダミー
if (#selecting) {
ddepoke "newcontrol","check,Part,選択した範囲内のみ(&L)";
ddepoke "default", str(#Part);
} else {
ddepoke "newcontrol","text,,(全文対象)";
}
if (#ConfigDlg) {
ddepoke "newcontrol", "button,,実行(&O)";
} else {
ddepoke "newcontrol", "button,,&Ok";
}
ddepoke "notify", "201";
ddepoke "part", "11";
ddepoke "newcontrol", "button,,キャンセル(&Q)";
ddepoke "notify", "202";
ddepoke "part", "11";
ddepoke "newcontrol", "button,,ヘルプ(&H)";
ddepoke "notify", "203";
call MakeDialog;
$return = $$return;
if( $return == "203" ) {
run "WINHELP.EXE " + $INIdir + "\\OKSEIKEI.HLP";
goto OptionMenuOutput;
}
if (($return != "0") && ($return != "202")) {
#TmpOrikaesiNum = val(dderequest("getstate OrikaesiNum"));
#CommandProcess = 1 - val(dderequest("getstate Command"));
#INYOUlineProcess = 1 - val(dderequest("getstate INYOU"));
#LeftMargin = val(dderequest("getstate LeftMargin"));
#InyouMargin = val(dderequest("getstate InyouMargin"));
#Kinsoku = val(dderequest("getstate Kinsoku")) - 2;
#KAOMOJIwrap = val(dderequest("getstate KAOMOJIwrap"));
#KAOMOJIwrapMax = val(dderequest("getstate KAOMOJIwrapMax"));
#Signature = val(dderequest("getstate Signature")) - 1;
if (#selecting) {
#Part = val(dderequest("getstate Part"));
}
#Tospace = val(dderequest("getstate Tospace"));
#ClipBoard = val(dderequest("getstate ClipBoard"));
#DisableDraw = val(dderequest("getstate DisableDraw"));
writeininum $INIfile,"Env","OrikaesiNum", #TmpOrikaesiNum;
writeininum $INIfile,"Env","CommandProcess", #CommandProcess;
writeininum $INIfile,"Env","INYOUlineProcess",#INYOUlineProcess;
writeininum $INIfile,"Env","LeftMargin", #LeftMargin;
writeininum $INIfile,"Env","InyouMargin", #InyouMargin;
writeininum $INIfile,"Env","Kinsoku", #Kinsoku;
writeininum $INIfile,"Env","KAOMOJIwrap", #KAOMOJIwrap;
writeininum $INIfile,"Env","KAOMOJIwrapMax", #KAOMOJIwrapMax;
writeininum $INIfile,"Env","Signature", #Signature;
if (#selecting) {
writeininum $INIfile,"Env","Part", #Part;
}
writeininum $INIfile,"Env","Tospace", #Tospace;
writeininum $INIfile,"Env","ClipBoard", #ClipBoard;
writeininum $INIfile,"Env","DisableDraw", #DisableDraw;
#OptionChange = yes;
}
return;
// マクロサーバでダイアログを作成
MakeDialog:
##hwnd = hidemaruhandle(0);
ddeexecute "dialog " + str(##hwnd);
$$a = "";
ddestartadvice "dlgresult", $$a;
while( strlen($$a) == 0 ) {
ddewaitadvice $$a, 100;
}
ddestopadvice "dlgresult";
ddeexecute "enddialog";
return $$a;
// 禁則処理・折り返し文字数値の変換処理
ConvertKinsokuOrikaesi:
// 禁則処理の設定
if (#Kinsoku == -1) {
$Kinsoku = "秀丸の設定に従う(" + $Mes[kinsokustate] + ")";
} else {
$Kinsoku = $Mes[#Kinsoku];
}
// 折り返し文字数の設定
if (#TmpOrikaesiNum == 0) {
$OrikaesiNum = "(折り返し文字数)";
#OrikaesiNum = width;
} else if (#TmpOrikaesiNum < 0) {
$OrikaesiNum = "(折り返し文字数)" + str(#TmpOrikaesiNum);
#OrikaesiNum = width + #TmpOrikaesiNum;
} else {
$OrikaesiNum = str(#TmpOrikaesiNum);
#OrikaesiNum = #TmpOrikaesiNum;
}
return;
// 行番号の表示されている桁数を返すサブルーチン
LineNoNum:
##LineCount = linecount;
##LineNoNumber = 4;
##mm = 10000;
while (1) {
if (##LineCount / ##mm < 1) break;
##LineNoNumber = ##LineNoNumber + 1;
##mm = ##mm * 10;
}
return ##LineNoNumber;
// 各種設定を取得
GetEnv:
// 折り返す文字数
#TmpOrikaesiNum =getininum($INIfile,"Env","OrikaesiNum");
// 普通行の左余白数
#LeftMargin =getininum($INIfile,"Env","LeftMargin");
// 引用行の左余白数
#InyouMargin =getininum($INIfile,"Env","InyouMargin");
// 引用符付きの行の右端を整形するかどうか
#INYOUlineProcess=getininum($INIfile,"Env","INYOUlineProcess");
// 埋め込みコマンド行を整形するかどうか
#CommandProcess =getininum($INIfile,"Env","CommandProcess");
// 禁則処理をするかどうか
#Kinsoku =getininum($INIfile,"Env","Kinsoku");
// 顔文字ラップをするかどうか
#KAOMOJIwrap =getininum($INIfile,"Env","KAOMOJIwrap");
// 選択した範囲内のみ処理するかどうか
#Part =getininum($INIfile,"Env","Part");
// シグネチャの指定
#Signature =getininum($INIfile,"Env","Signature");
// シグネチャ文字列の数
#SignatureNum =getininum($INIfile,"Signature_Name","SignatureNum");
// シグネチャ項目
$SigName[0] = "(なし)";
#n = 1;
while (#n <= #SignatureNum) {
$SigName[#n] = getinistr($INIfile,"Signature_Name",str(#n));
$SigFile[#n] = getinistr($INIfile,"Signature_File",str(#n));
#n = #n + 1;
}
// 「埋め込みコマンド」の項目数
#NumberOfCommand=getininum($INIfile,"IgnoreLineTop","NumberOfCommand");
// 「埋め込みコマンド」項目
#n = 1;
while (#n <= #NumberOfCommand) {
$Com[#n] = getinistr($INIfile,"IgnoreLineTop",str(#n));
#n = #n + 1;
}
// 「顔文字ラップ」の項目数
#NumberOfKAOMOJI =getininum($INIfile,"KAOMOJIwrap","NumberOfKAOMOJI");
// 「顔文字ラップ」項目
#n = 1;
while (#n <= #NumberOfKAOMOJI) {
$KAO[#n] = getinistr($INIfile,"KAOMOJIwrap",str(#n));
#n = #n + 1;
}
// 「顔文字ラップ」時の、右端をはみ出す最大文字数
#KAOMOJIwrapMax =getininum($INIfile,"Env","KAOMOJIwrapMax");
// タブ→スペース変換をするかどうか
#Tospace =getininum($INIfile,"Env","Tospace");
// 整形前に全文をクリップボードにコピーするかどうか
#ClipBoard =getininum($INIfile,"Env","ClipBoard");
// 整形途中を表示しないかどうか(1:表示しない, 0:表示する)
#DisableDraw =getininum($INIfile,"Env","DisableDraw");
// いきなり設定画面
#ConfigDlg =getininum($INIfile,"Env","ConfigDlg");
// 自動実行
#AutoRun =getininum($INIfile,"Env","AutoRun");
return;
// 終了処理
MacroEnd:
if (#KinsokuChange) {
if (#prevKinsoku) {
config "k+";
} else {
config "k-";
}
}
config "w" + str(#prevOrikaesiNum);
if (#Changewindowwidth) setwindowsize #prevwindowwidth, windowheight;
if (#AutoShrink) {
writeininum "HIDEMARU.INI", "Env", "AutoShrink", yes;
envchanged;
}
if (#indentstate == 1) {
config "i1";
} else if (#indentstate == 3) {
config "i2";
} else if (#indentstate == 5) {
config "i3";
} else if (#indentstate == 7) {
config "i4";
}
title 0;
if (#DisableDraw) enabledraw;
// シグネチャ挿入
if (#Signature) {
gofileend;
if (column != 0) insertreturn;
$SignatureFile = $SigFile[#Signature];
$Mac = rightstr($SignatureFile, 4);
if (($Mac == ".mac") || ($Mac == ".MAC")) {
execmacro $SignatureFile;
} else {
insertfile $INIdir + "\\" + $SignatureFile;
}
}
if( #overwrite ) overwriteswitch;
enableinvert;
endmacro;
Error:
// エラー処理
$Error = "";
if (#OrikaesiNum < 20) {
$Error = "・折り返す文字数の設定値が小さすぎます。\n"
+ " 20 から 250 までの間になるように\n"
+ " 設定値を確認・変更してください。\n\n";
} else if ((#OrikaesiNum < 20) || (#OrikaesiNum > 250)) {
$Error = "・折り返す文字数の設定値が大きすぎます。\n"
+ " 20 から 250 までの間になるように\n"
+ " 設定値を確認・変更してください。\n\n";
}
if (#LeftMargin < 0) {
$Error = $Error + "・普通行の左余白が小さすぎます。\n"
+ " 0または正の数を入力してください。\n\n";
} else if (#LeftMargin >= #OrikaesiNum) {
$Error = $Error + "・普通行の左余白が大きすぎます。\n"
+ " 折り返す文字数よりも小さい値を入力してください。\n\n";
}
if (#InyouMargin < 0) {
$Error = $Error + "・引用行の左余白が小さすぎます。\n"
+ " 0または正の数を入力してください。\n\n";
} else if (#InyouMargin >= #OrikaesiNum) {
$Error = $Error + "・引用行の左余白が大きすぎます。\n"
+ " 折り返す文字数よりも小さい値を入力してください。\n\n";
}
return $Error;