home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
DOS/V Power Report 1997 May
/
VPR9705A.ISO
/
FWINDOWS
/
Padnv335
/
PADNV335.LZH
/
PADNAV1.SCR
< prev
next >
Wrap
Text File
|
1996-10-26
|
10KB
|
509 lines
; NIFTY-Serve用通信統合環境 PADNAV 通信カーネル1(秀Term用) Version 3.33
; Coded by Piyo / PFF01507
;
;********* 現在登録されているフォーラム一覧を取得するコマンド **********
GetFrmList:
#fname = #1+"\myforum.log"
chdir log
delfile #fname
restoredir
title "入会フォーラム一覧を取得中"
send "MYFORUM^M"
wait "ください。^M^J"
log #fname
wait "^M^J>"
log
return
;********* 掲示板のメニューを取得するコマンド **********
GetBbsList:
#fname = #1+"\bbs.frm"
chdir log
delfile #fname
restoredir
title "掲示板へ移動中"
send "GO BBS^M"
wait "として利用することはできませんのでご注意ください。^M^J"
log #fname
wait "^M^J>"
log
return
;********* 特設掲示板のメニューを取得するコマンド **********
GetTopicList:
#fname = #2+"\"+#1+".frm"
chdir log
delfile #fname
restoredir
title #1+"へ移動中"
send "GO "+#1+"^M"
log #fname
wait "^M^J>"
log
return
;********* 今週のお知らせを選択ダウンロードするコマンド **********
ReadWeekNews:
title "今週のお知らせを受信中"
send "GO NEW^M"
wait "^M^J>"
send #1+"^M"
log "nifnews."
loopswitch
case "^M^J続き (改行で次文書 E:終了)"
wait "^M^J>"
send "^M"
case "^M^J続き (改行で次頁 S:次文書 E:終了)"
wait "^M^J>"
send "^M"
case "^M^J表示終了"
wait "^M^J>"
log
breakloop
endloop
return
;********* 個人情報公開/非公開変更コマンド **********
ChgPrivate:
#cmd = "^M"
if( #1 == "*DISCLOSE" )
#cmd = "1^M"
title "個人情報を公開します"
endif
if( #1 == "*SECRET" )
#cmd = "2^M"
title "個人情報を非公開にします"
endif
send "GO MEMBER^M"
wait "^M^J>"
send "3^M"
wait "^M^J>"
send "1^M"
wait "^M^J:"
send #cmd
wait "^M^J>"
return
;********* Telnet接続コマンド **********
Telnet:
title "Telnet接続開始"
send "GO TELNET^M"
chdir script
delfile "TELNET.SCR"
copyfile #2, "TELNET.SCR"
restoredir
##count = 0
loopswitch
case "^M^J暫く時間をおいて再度アクセスしてください。"
wait "^M^J>"
##count = ##count+1
if( ##count > 20 )
timeoutmessage "只今、Telnetは混雑していますのでアクセスを中止します", 3
return
endif
send "2^M"
case "^M^J>"
send "2^M"
case "^M^JTELNET> "
breakloop
endloop
#cmd = "open "+#1+"^M"
if( length(#2) != 0 )
call TELNET.SCR #cmd
else
send #cmd
keyboard on
endif
loopswitch
case "No address associated with name"
wait "^M^JTELNET> "
send "quit^M"
case "Connection refused"
wait "^M^JTELNET> "
send "quit^M"
case "^M^J>"
breakloop
endloop
keyboard off
return
;************** 課金情報読込処理手順 ***************
ReadBill:
title "課金情報"
send "GO BILL^M"
wait "^M^J>"
log "BILL."
send "2^M"
wait "^M^J>"
log
return
;**************** 送信簿の読み取り ******************
SDL:
title "送信簿受信中"
send "GO MAIL^M"
wait "^M^JMAIL>"
log "SDL.LOG"
send "SDL^M"
wait "^M^JMAIL>"
log
send "COND SDL^M"
loopswitch
case "^M^JMAIL>"
breakloop
case "^M^J:"
send "1^M"
wait "^M^J:"
send "1^M"
wait "^M^JMAIL>"
breakloop
endloop
return
;********* プロフィール読みだしコマンド **********
Profile:
title "プロフィールを読込中"
#flag = "FALSE"
##i = length(#1)
#id = part(#1, 1, ##i-1)
send #id+"^M"
log "PROF."
loopswitch
case "-該当する利用者のプロフィールはありません-"
#flag = "TRUE"
case postmilliidle(500) "^M^J>", postmilliidle(500) "^M^JFORUM>", postmilliidle(500) "^M^JCCS(N)>", postmilliidle(500) "^M^JCCS(P)>", postmilliidle(500) "^M^JLIB>"
breakloop
case postmilliidle(500) "^M^JMAIL>", postmilliidle(500) "^M^JHP>", postmilliidle(500) "^M^JPATIO(N)>", postmilliidle(500) "^M^JPATIO(P)>"
breakloop
endloop
log
;if( #flag == "TRUE" )
send "GO MEMBERS^M"
wait "^M^J>"
send "1^M"
wait "^M^J:"
#id = part(#1, 6, ##i-6)
send #id+"^M"
log "PROF."
loopswitch
case "表示終了"
log
case "◆該当する利用者は公開されていません◆"
log
case postmilliidle(500) "^M^J>"
breakloop
case postmilliidle(500) "^M^J:"
send "^M"
endloop
;endif
return
;********* アクセスギフト送付コマンド **********
AccessGift:
readfile #1, #id
readfile #1, #money
readfile #1, #message
title "アクセスギフト送付作業中"
send "GO ACGIFT^M"
wait "^M^J>"
send "2^M"
wait "^M^J>"
if( #money == "3" )
send "2^M"
goto AccessGiftCancel
else
send "1^M"
endif
wait "^M^J:"
send #id+"^M"
loopswitch
case "^M^J:"
breakloop
case "◆"
wait "^M^J:"
send "^M"
wait "^M^J>"
call PADNAV.SCR:ErrorLog "アクセスギフト送付ミス "+#id
return
endloop
send "1^M"
wait "^M^J:"
send #money+"^M"
wait "^M^J:"
send "1^M"
loopswitch
case "^M^J:"
breakloop
case "^M^J本文 (10行まで 終了は行頭で/E)"
send #message+"^M"
send "/E^M"
wait "^M^J:"
send "2^M"
endloop
question "本当に送付してもいいですか?"
if( yes )
#cmd = "1^M"
else
#cmd = "2^M"
endif
send #cmd
wait "^M^J>"
return
AccessGiftCancel:
wait "^M^J>"
send "1^M"
wait "^M^J:"
send "1^M"
loopswitch
case "^M^J:"
breakloop
case "^M^J本文 (10行まで 終了は行頭で/E)"
send #message+"^M"
send "/E^M"
wait "^M^J:"
send "2^M"
endloop
send "1^M"
wait "^M^J>"
return
;********* アクセスギフト受領コマンド **********
ReceiveGift:
title "アクセスギフト受領作業中"
send "GO ACGIFT^M"
wait "^M^J>"
send "3^M"
loopswitch
case "^M^J>"
breakloop
case "◆"
wait "^M^J>"
call PADNAV.SCR:ErrorLog "受領可能なアクセスギフトはありませんでした"
return
endloop
send "1^M"
wait "^M^J:"
send "1^M"
wait "^M^J>"
return
;********* ファイルファインダー処理コマンド **********
FileFinder:
readfile #1, #base
title "ファイルファインダー実行中"
send "GO FILEFIND^M"
wait "^M^J>"
send #base+"^M"
wait "^M^J>"
send "1^M"
wait "):"
##i = 0
beginloop
readfile #1, #line
if( length(#line) == 0) breakloop
send #line+"^M"
wait "):", "^M^J>"
##i = ##i + 1
endloop
send "^M"
readfile #1, #logic
loopswitch
case "^M^J:"
if( ##i > 1 )
send #logic+"^M"
wait "^M^J:"
endif
send "1^M"
case "^M^J>"
breakloop
endloop
readfile #1, #data
if( length(#data) > 0 )
send "2^M"
wait "^M^J:"
send #data+"^M"
wait "^M^J>"
endif
readfile #1, #id
if( length(#id) > 0 )
send "4^M"
wait "^M^J:"
send #id+"^M"
wait "^M^J>"
endif
readfile #1, #date
if( length(#date) > 0 )
readfile #1, #direction
send "5^M"
wait "^M^J:"
send #date+"^M"
wait "^M^J:"
send #direction+"^M"
wait "^M^J>"
endif
readfile #1, #line
if( length(#line) > 0 )
send "6^M"
wait "^M^J:"
send #line+"^M"
wait "^M^J>"
endif
readfile #1, #line
if( length(#line) > 0 )
readfile #1, #direction
send "7^M"
wait "^M^J:"
send #line+"^M"
wait "^M^J:"
send #direction+"^M"
wait "^M^J>"
endif
readfile #1, #line
if( length(#line) > 0 )
if( #line != "2" )
send "C^M"
wait "^M^J:"
send #line+"^M"
wait "^M^J>"
endif
endif
readfile #1, #num
##num = value(#num)
readfile #1, #line
send "L^M"
log #2+"\hosoku\finder"
#found = "TRUE"
loopswitch
case "-該当するデータはありません-"
#found = "FALSE"
log
case "^M^J>"
breakloop
endloop
if( #found == "TRUE" )
send "all^M"
##i = 0
while( ##i < ##num )
#cmd = "NULL"
loopswitch
case postmilliidle(500) "^M^J>"
breakloop
case "^M^J処理 (1:ダウンロード S:次データ E:終了)"
#cmd = "READ"
case "^M^J処理 (1:ダウンロード E:終了)"
#cmd = "END"
endloop
if( #cmd = "END" ) breakloop
if( ##i >= ##num ) breakloop
send "S^M"
##i = ##i + 1
endwhile
log
endif
return
;************** シェアウェア入金確認 ***************
CheckShare:
title "シェアウェア入金確認"
send "GO SWREG^M"
wait "^M^J>"
send "3^M"
wait "^M^J>"
send "2^M"
wait "^M^J>"
send "5^M"
wait "^M^J>"
send #1+"^M"
wait "^M^J:"
send #2+"^M"
wait "^M^J:"
send #3+"^M"
chdir download
#log = "SW_"+#1+".ホソク"
log #log
wait "^M^J>"
log
restoredir
return
;********* 会議室タイトル読取コマンド **********
GetMesTitle:
send "RTN^M"
loopswitch
case "題名"
log #1
wait "^M^J>"
log
send "^M"
wait "^M^JCCS(N)>", "^M^JCCS(P)>"
send "RC MAX^M"
wait "^M^JCCS(N)>", "^M^JCCS(P)>"
breakloop
case "ありません◆"
wait "^M^JCCS(N)>", "^M^JCCS(P)>", "^M^J>"
call PADNAV.SCR:ErrorLog "会議室タイトル取得ミス "+#1
breakloop
case "^M^J現在、サービスは"
wait "^M^J>", "^M^JFORUM>", "^M^JCCS(N)>", "^M^JCCS(P)>", "^M^JLIB>"
call PADNAV.SCR:ErrorLog "会議室混雑("+#1+")"
breakloop
endloop
return
;********* ライブラリリスト読取コマンド **********
GetLibList:
appendfile #1
if( no )
#date = #3
else
#date = #2
endif
if( @libscan == "YES" ) #date = #3
closefile #1
loopswitch
case "^M^JLIB>"
send "SCAN DATE:"+#date+"^M"
wait "^M^J:"
send "^M"
loopswitch
case "データ名"
log #1
wait "^M^J>"
log
breakloop
case "ありません-"
wait "^M^J>"
breakloop
endloop
breakloop
case "^M^J-現在、公開ライブラリ"
wait "^M^J>", "^M^JFORUM>", "^M^JCCS(N)>", "^M^JCCS(P)>", "^M^JLIB>"
call PADNAV.SCR:ErrorLog "ライブラリが存在しない("+#1+")"
breakloop
case "このフォーラムでは利用できません"
wait "^M^J>", "^M^JFORUM>", "^M^JCCS(N)>", "^M^JCCS(P)>", "^M^JLIB>"
call PADNAV.SCR:ErrorLog "ライブラリ利用不可("+#1+")"
breakloop
case "^M^J現在、サービスは"
wait "^M^J>", "^M^JFORUM>", "^M^JCCS(N)>", "^M^JCCS(P)>", "^M^JLIB>"
call PADNAV.SCR:ErrorLog "ライブラリ混雑("+#1+")"
breakloop
case "^M^J>"
breakloop
case "^M^J◆該当するライブラリ"
wait "^M^J>", "^M^JFORUM>", "^M^JCCS(N)>", "^M^JCCS(P)>", "^M^JLIB>"
call PADNAV.SCR:ErrorLog "ライブラリが見つからない("+#1+")"
breakloop
endloop
send "E^M"
wait "^M^JLIB>", "^M^JFORUM>", "^M^J>"
return