home *** CD-ROM | disk | FTP | other *** search
/ DOS/V Power Report 1997 March / VPR9703A.ISO / OLS / Win95 / HT315 / HT315.LZH / RIMNET.SCR < prev    next >
Text File  |  1996-05-05  |  6KB  |  191 lines
  1. ; ＲＩＭＮＥＴ用自動ログインスクリプト V 0.2
  2. ;
  3. ; （１）概要
  4. ;       RIMNET用ﾊﾟｿｺﾝ通信ﾛｸﾞｲﾝ処理をｻﾎﾟｰﾄします。
  5. ;       telnet兼用です。
  6. ;
  7. ; （２）秀TERMホスト設定。
  8. ;       秀TERMのホスト設定は、以下の設定をして下さい。
  9. ;         新JIS。
  10. ;         
  11. ;
  12. ; （３）ユーザＩＤ、パスワードの設定。
  13. ;       一番最初に接続した時に聞いてきます。
  14. ;       又は、秀TERMのスクリプトの実行でも設定できます。
  15. ;       入力したユーザＩＤ、パスワードは、
  16. ;       永久的変数に記憶されるので２回目以降は、自動ログインになります。
  17. ;       書き換えたい場合は、「スクリプト・変数一覧」で、
  18. ;       %RIMUSERIDと%%RIMPasswordを削除してください。
  19. ;
  20. ; （４）ログオフ処理。
  21. ;       ログオフ処理が必要な場合は、コメントを外して下さい。
  22. ;
  23. ; （５）ログ処理。
  24. ;       ログは、秀TERMのホストプロパティのログ設定で行います。
  25. ;       スクリプトでログ処理したい場合は、コメントを外して下さい。
  26. ;       その場合、ログオフ処理もコメントを外してください。
  27. ;       ログ形式は、RIMmmdd.LOGです。必要ならスクリプトを修正して下さい。
  28. ;
  29. ; （６）修正履歴
  30. ;       96/04/28 新規作成。
  31. ;       96/05/05 ﾀｲﾄﾙ削除。ﾛｸﾞ処理ｺﾒﾝﾄ変更。
  32. ;       
  33. ;
  34. ;      何かあればメールなりFWINCOM MES10で連絡して下さい。
  35. ;      竹島和夫    NIFTY：BYJ00102  e-mail：takeshima@jsn.justnet.or.jp
  36.  
  37.  
  38.         gethostname #HostName
  39.         if( #HostName == "" )
  40.                 question "スクリプトのセットアップをしますか？"
  41.                 if( yes )
  42.                         goto ScriptSetup
  43.                 endif
  44.         endif
  45.  
  46.  
  47. ;---------------------------------------------------------------------------
  48. ;ログ処理。RIMmmdd.LOGで取ります。必要な場合、コメントを外して下さい。
  49. ;
  50. ;                getdate #date
  51. ;                log "RIM" + part( #date, 2, 4 ) + ".LOG"
  52. ;
  53. ;---------------------------------------------------------------------------
  54.  
  55.         afterhangup Atoshimatsu
  56.         #frag = "0"
  57.  
  58. ;ログイン処理。
  59.  
  60.         timeout 40                               ;タイムオーバー時、修正。
  61.         loopswitch
  62.  
  63.                 case "login: " 
  64.  
  65. EnterUserID:
  66.                         if( %RIMUSERID == "" )
  67.                           input "ユーザＩＤを入力してください。", %RIMUSERID
  68.                                 if( cancel )
  69.                                         hangup
  70.                                 endif
  71.                         endif
  72.  
  73.                        if( #frag == "2" )
  74.                                 goto USERIDEND
  75.                         endif
  76.  
  77.                         send %RIMUSERID + "^M"
  78. USERIDEND:
  79.                         #frag = "1"
  80.  
  81.                 case "Password:"
  82. EnterPassword:
  83.                         #mes = "パスワードを入力してください。"
  84.                         if( %%RIMPassword == "" )
  85.                                 secretinput #mes, %%RIMPassword
  86.                                 if( cancel )
  87.                                         hangup
  88.                                 endif
  89.                         endif
  90.                         #temp = %%RIMPassword
  91.                         if( #temp == "毎回入力する" )
  92.                                 secretinput #mes, #temp
  93.                                 if( cancel )
  94.                                         hangup
  95.                                 endif
  96.                         endif
  97.                         send #temp + "^M"
  98.                         #frag = "2"
  99.  
  100.  
  101.                 case "Login incorrect"
  102.                         if( #frag == "1" )
  103.                                 %RIMUSERID = ""
  104.                             else
  105.                                 if( %%RIMPassword != "毎回入力する" )
  106.                                        %%RIMPassword = ""
  107.                                 endif                                
  108.                         endif
  109.                         #frag = "0"
  110.                         goto EnterUserID
  111.  
  112.                 case "MAIN MENU (main menu)"
  113.                         breakloop
  114.                 case timeout
  115.                         goto ErrorExit                
  116.         endloop
  117.  
  118. ;--------------------------------------------------------------------------
  119. ;ログオフ処理。必要な場合、コメントを外してして下さい。
  120. ;
  121. ;WaitLogoff:
  122. ;        timeout 0
  123. ;        wait "Connection closed.^M^J"
  124. ;        timeout 10
  125. ;        wait "logging off ^M^J"
  126. ;        if( timeout ) goto WaitLogOff
  127. ;        hangup
  128. ;
  129. ;ここまで
  130. ;--------------------------------------------------------------------------
  131.         exit
  132.  
  133.  
  134. ErrorExit:
  135.         message "ログインタイムオーバー。「timeout XXX」の値（秒）変更して試して下さい。"
  136.         message "このあと手動運転してください。"
  137.         exit
  138.  
  139. ;******************
  140. ;通話時間表示処理。
  141.  
  142. Atoshimatsu:
  143.         savebuffer
  144.         #hour = part( #1, 0, 2 )
  145.         #minute = part( #1, 2, 2 )
  146.         #second = part( #1, 4, 2 )
  147.         #mes = "通話時間は"
  148.         if( #hour != "00" )
  149.                 #mes = #mes + #hour + "時間"
  150.         endif
  151.           #mes = #mes + #minute + "分" + #second + "秒でした"
  152.           message #mes
  153. ;----------------------------------------------------------------
  154. ;秀Termを自動終了させる場合は、コメントを外して下さい。
  155.  
  156. ;        closehideterm
  157.  
  158. ;ここまで
  159. ;----------------------------------------------------------------
  160.         return
  161.  
  162. ;******************
  163.  
  164. ;スクリプトセットアップ。
  165.  
  166. ScriptSetup:
  167.         menu "RIMNET.SCRセットアップメニュー(Escで終了)", 0, "ユーザＩＤの変更", "パスワードの変更"
  168.         switch result
  169.                 case 0
  170.                         goto ScriptSetup
  171.  
  172.                 case 1
  173.                         input "新しいユーザＩＤを入力して下さい。", %RIMUSERID
  174.                         if( cancel ) goto ScriptSetup
  175.                         input "新しいパスワードを入力して下さい。ログイン毎に入力したい場合は何も入力せずにＯＫして下さい。", %%RIMPassword
  176.                         if( %%TCPassword == "" )
  177.                                 %%RIMPassword = "毎回入力する"
  178.                         endif
  179.                         goto ScriptSetup
  180.  
  181.                 case 2
  182.                         input "新しいパスワードを入力して下さい。ログイン毎に入力したい場合は何も入力せずにＯＫして下さい。", %%RIMPassword
  183.                         if( %%RIMPassword == "" )
  184.                                 %%RIMPassword = "毎回入力する"
  185.                         endif
  186.                         goto ScriptSetup
  187.  
  188.         endswitch
  189.         exit
  190.  
  191.