DOS/V Power Report 1996 February/VPR9602A.ISO/office95/shared.dir/01000_Script_1000

Text File | 1995-10-16 | 4KB | 163 lines

on startmovie
  global autoMode,pauseSprite,previousSprite,nextSprite,menuSprite,quitSprite
  put 45 into menuSprite
  put 47 into pauseSprite
  put 46 into previousSprite
  put 48 into nextSprite
  put 44 into quitSprite -- not used in this demo
  put true into autoMode
end

on initSprites
  global pauseSprite,previousSprite,nextSprite,menuSprite,quitSprite
  puppetSprite pauseSprite,true
  puppetSprite previousSprite,true
  puppetSprite nextSprite,true
  puppetSprite quitSprite,true
  puppetSprite menuSprite,true
end

on turnOffSprites
  global pauseSprite,previousSprite,nextSprite,menuSprite,quitSprite
  puppetSprite pauseSprite,false
  puppetSprite previousSprite,false
  puppetSprite nextSprite,false
  puppetSprite quitSprite,false
  puppetSprite menuSprite,false
end

on pauseMode
  global autoMode,pauseSprite,nextSprite

  if autoMode then
    sound stop 2
    put false into autoMode
    set the castNum of sprite pauseSprite to the castNum of sprite pauseSprite + 1
    updateStage
    pause
  else
    put true into autoMode
    set the castNum of sprite pauseSprite to the castNum of sprite pauseSprite - 1
    updateStage
    go frame marker(0)
  end if
end

on goNext
  global nextSprite,pauseSprite,autoMode
  sound stop 2
  set autoMode to true
  set the castNum of sprite pauseSprite to the number of cast "pause"
  depress nextSprite
  go marker (1)

end

on goPrevious
  global previousSprite,pauseSprite,autoMode
  sound stop 2
  set autoMode to true
  set the castNum of sprite pauseSprite to the number of cast "pause"
  depress previousSprite
  go marker(-1)
end

on goMenu
  global menuSprite
  sound stop 1
  sound stop 2
  depress menuSprite
  turnOffSprites
  put the moviename into theMovie
  if theMovie = "ACCESS.DIR" then
    put "ACMENU.DIR" into menuName
  else if theMovie contains "ex" then
    put "EXMENU.DIR" into menuName
  else if theMovie contains "pp" then
    put "PPMENU.DIR" into menuName
  else if theMovie = "SCHED.DIR" then
    put "SCMENU.DIR" into menuName
  else if theMovie contains "wd" then
    put "WDMENU.DIR" into menuName
  else if theMovie contains "BUCKET" then
    put "BUCMENU.DIR" into menuName
  else if "NEW.DIR,CUP.DIR,VUP.DIR" contains theMovie then
    put "INTRO.DIR" into menuName
  end if
  go frame "Menu" of movie menuName
end

on goIntroMenu
  global menuSprite
  sound stop 2
  depress menuSprite
  turnOffSprites
  go frame "Menu" of movie "intro.dir"
end

on goCredits
  sound stop 2
  turnOffSprites
end

on creditsQuit
  global quitSprite
  sound stop 2
  depress quitSprite
  turnOffSprites
  go frame "exit"
end

on depress whichSprite
  put the ticks into startTime
  set the castNum of sprite whichSprite to the castNum of sprite whichSprite + 1
  repeat while the mouseDown or the ticks < startTime + 20
    updatestage
  end repeat
  set the castNum of sprite whichSprite to the castNum of sprite whichSprite - 1
  updateStage
end

on playSound theSound
  --cursor 4
  --unLoadCast
  --preload marker(1)

  if the machineType = 256 then
    sound playFile 2, the pathname & "AUDIO\" & theSound
  else
    sound playFile 2, the pathname & "AUDIO:" & theSound
  end if

  --puppetSound 2, cast theSound

  --cursor 0
end playSound

on loadEmUp
  cursor 4
  --preload marker(1)
  cursor 0
end loadEmUp

on doPause length
  if length > 10 then
    set endPause = the ticks + length
  else
    set endPause = the ticks + (length*60) -- converts length from seconds to ticks
  end if
  repeat while the ticks < endPause
    if the commandDown then
      exit repeat
    else if the mouseDown then
      exit repeat
    end if
    go the frame
  end repeat
  go the frame + 1
end doPause

on waitSound
  if soundBusy(2) then go to the frame
end waitSound