home *** CD-ROM | disk | FTP | other *** search
/ Falcon 030 Power 2 / F030_POWER2.iso / ST_STE / MAGS / ICTARI08.ARJ / ictari.08 / ASSEMBLY / LAYOUT.S next >
Text File  |  1994-02-15  |  14KB  |  470 lines
  1. *
  2. * Written with DevpacST 2, Medium rez, tabs set to 8.
  3. *
  4. * By, Mike Barnard, December 1st to 4th 1993. 
  5. *
  6. * This program is not about 'how to display a picture on-screen', although
  7. * that's what it does. It's about how I like to write and comment my
  8. * source code so a stranger can read and understand it. So many listings
  9. * I've seen have been continuous. Line after line of mnemonics, operands
  10. * and data. No breaks, separations or logical structure. Trying to find
  11. * out how the author was thinking takes hours of reading each line,
  12. * deciding what it does, commenting it myself, finding where the routines
  13. * start and end, inserting blank lines for clarity... what a time waste.
  14. *
  15. * I'm nowhere near good, I'm a learner. This is just MY idea of how code
  16. * CAN be commented. Except for one thing. A neighbour of mine once told
  17. * me about the 'Rule of Seven'. It basically means that when writing code,
  18. * no single chunk of code should be longer than 7 lines if you can help
  19. * it. It's not absolute! In programming, what's right is what works. But
  20. * it's true that the human brain finds it difficult to digest more than
  21. * that amount of information at a time. (If you can read a whole 
  22. * listing at a glance then lucky you, but I can't, and I don't know of
  23. * anyone else who can...).
  24. *
  25. * So anyway. This little program loads a Degas picture file from disk
  26. * and displays it to the standard screen memory. Then it looks for the
  27. * escape key to be pressed and returns to the desktop. Remember, It's not
  28. * WHAT it does, just how I've listed the source. Adding comments may
  29. * swell the source file, but the end program won't be hurt for it. I'm
  30. * just learning how to make this machine do what I want it to, and I TRY
  31. * to understand other peoples listings when they release them. Please try
  32. * to make them readable. For others, and for yourself. Thanks.
  33. *
  34. * Oh, you'll have to supply a degas low res picture yourself. I don't
  35. * want to waste too much disk space.
  36. *
  37. * Any comments, good, bad or indifferent...
  38. *
  39. * Mike Barnard
  40. * 52 Westbourne Avenue
  41. * Worthing
  42. * West Sussex
  43. * BN14 8DF
  44. *
  45. * (NO CALLING AT THE DOOR! Please.)
  46. *
  47. * I hope my ideas are useful.
  48. * 
  49. *************************************************************************
  50. *                                    *
  51. *                LAYOUT.S                *
  52. *                                    *
  53. *************************************************************************
  54.  
  55.         TEXT
  56.         
  57. start        jsr    init    goto the initialise routine
  58.         jsr    loadit    get the picture from the disk
  59. keyloop        jsr    getkey    if key pressed, get it's scancode
  60.         jsr    whatkey    find if it's <esc>
  61.         bra    keyloop    if not go back and look again...            
  62.  
  63. *************************************************************************
  64.  
  65. * IS THE SCANCODE THE <ESC> KEY?
  66.  
  67. whatkey
  68.  
  69.     move.w    scancode,d0    put current code into d0
  70.     cmpi.w    #1,d0        is it 1? (<ESCAPE> key)
  71.     beq    exit        yes, branch
  72.     
  73.     rts            no, go back
  74.     
  75. *************************************************************************
  76.  
  77. * RESTORE AND RETURN TO DESKTOP
  78.  
  79. exit
  80.  
  81. * restore screen resolution
  82.     
  83.     move.w    oldrez,-(sp)    screen rez required. (0=low, 1=med.)
  84.     move.l    #-1,-(sp)    negative number, no change to addresses
  85.     move.l    #-1,-(sp)    negative number, no change to addresses
  86.     move.w    #5,-(sp)    function number
  87.     trap    #14        XBIOS 14 - SETSCREEN
  88.     add.l    #12,sp        tidy
  89.  
  90. * restore palette
  91.  
  92.     move.l    #oldpal,-(sp)        palette to load
  93.     move.w    #6,-(sp)        function number
  94.     trap    #14            XBIOS 14 - SETPALETTE
  95.     addq.l    #6,sp             tidy
  96.     
  97. * exit to desktop
  98.  
  99.     move.w    #0,-(sp)    function number
  100.     trap    #1        byeeeeeeee.....
  101.  
  102. *************************************************************************
  103.  
  104. * HAS A KEY BEEN PRESSED?
  105.  
  106. getkey
  107.  
  108.     movem.l    d0-d7/a0-a6,-(sp)    Save registers
  109.     move.w    #0,scancode        Ensure null return unless key found
  110.     
  111. * has a key been pressed?
  112.  
  113.     move.w    #$0b,-(sp)    GEMDOS $0B - KEYBOARD BUFFER STATUS?
  114.     trap    #1        Result returned in d0.
  115.     addq.l    #2,sp        tidy
  116.  
  117.     tst.w    d0        d0.w=0, no keys pressed, -1 = yes
  118.     beq    .end        no keypresses in buffer, so return
  119.     
  120. * yes, found a keypress. Now get it's scancode
  121.  
  122.     move.w    #$08,-(sp)    GEMDOS 8 - GET A KEYPRESS
  123.     trap    #1
  124.     addq.l    #2,sp
  125.  
  126.     swap    d0        put scancode into low word
  127.     move.w    d0,scancode    save the scancode for later
  128.  
  129. .end    
  130.     movem.l    (sp)+,d0-d7/a0-a6    restore registers
  131.  
  132.     rts
  133.  
  134. *************************************************************************
  135.  
  136. * LOAD A DEGAS PICTURE FROM A DISK AND DISPLAY
  137.  
  138. loadit
  139.  
  140. * open the file, store the handle
  141.  
  142.     move.w    #0,-(sp)    file attribute (0=nornal, read\write)
  143.     move.l    #filename,-(sp)    address of file name string
  144.     move.w    #61,-(sp)    function number
  145.     trap    #1        GEMDOS 61 - OPEN A FILE
  146.     addq.l    #8,sp        tidy
  147.     
  148.     tst    d0        check for error
  149.     bmi    file_error    yes, branch
  150.  
  151.     move.w    d0,handle    store the file handle
  152.  
  153. * read the picture header to a buffer
  154.  
  155.     move.l    #headbuf,-(sp)    where to put the data
  156.     move.l    #34,-(sp)    how many bytes to read
  157.     move.w    handle,-(sp)    file handle
  158.     move.w    #63,-(sp)    function number
  159.     trap    #1        GEMDOS 63 - READ BYTES
  160.     add.l    #12,sp        tidy
  161.     
  162. * set the palette from the header
  163.  
  164.     move.l    #headbuf+2,-(sp)    palette starts 2 bytes into header
  165.     move.w    #6,-(sp)        function number
  166.     trap    #14            XBIOS 14 - SETPALETTE
  167.     addq.l    #6,sp             tidy
  168.  
  169. * read the picture data
  170.  
  171.     move.l    scrnp,-(sp)    where to put the data
  172.     move.l    #32000,-(sp)    how many bytes to read
  173.     move.w    handle,-(sp)    file handle
  174.     move.w    #63,-(sp)    function number
  175.     trap    #1        GEMDOS 63 - READ BYTES
  176.     add.l    #12,sp        tidy
  177.  
  178. * close the file
  179.  
  180.     move.w    handle,-(sp)    file handle
  181.     move.w    #62,-(sp)    function number
  182.     trap    #1        GEMDOS 62 - CLOSE A FILE
  183.     addq.l    #4,sp        tidy
  184.     
  185.     rts
  186.  
  187. *************************************************************************
  188.  
  189. * INITIALISE THE PROGRAM
  190.  
  191. init
  192.     
  193. * find current rez. Returned in d0
  194.  
  195.     move.w    #4,-(sp)    function number
  196.     trap    #14        XBIOS 4 - GETREZ
  197.     addq.l    #2,sp        tidy
  198.     
  199.     move.w    d0,oldrez    save it
  200.     
  201. * is it low? If not set it to low. 
  202.  
  203. * (If you are intending to trace this program from within MONST to watch
  204. * it at work, you may get screen corruption when you attempt to run a
  205. * trace through this bit, changing the screen resolution. It took me ages
  206. * to find out how to cure it but a good read of the manual (page 107 for
  207. * version 2 users) shows the reason, and how to cure it. You haven't got
  208. * the manual? I hope you're not one of the thieves who have helped to ruin
  209. * the ST market!).
  210.  
  211.     cmpi.w    #0,d0        is d0 = 0? (low rez?)
  212.     beq    getpal        Yes, branch
  213.     
  214.     move.w    #0,-(sp)    screen rez required. (0=low)
  215.     move.l    #-1,-(sp)    negative number, no change to addresses
  216.     move.l    #-1,-(sp)    negative number, no change to addresses
  217.     move.w    #5,-(sp)    function number
  218.     trap    #14        XBIOS 14 - SETSCREEN
  219.     add.l    #12,sp        tidy
  220.     
  221. * get current palette and store it
  222.  
  223. getpal    
  224.  
  225.     move.l    #oldpal,a3    address of palette save buffer into a3
  226.     move.w    #0,d3        counter for 16 colour registers
  227.     
  228. .loop    move.w    #-1,-(sp)    negative means read not write
  229.     move.w    d3,-(sp)    the colour register to read
  230.     move.w    #7,-(sp)    function number
  231.     trap    #14        XBIOS 7 - SETCOLOR
  232.     addq.l    #6,sp        tidy
  233.     
  234.     move.w    d0,(a3)+    put the colour data into the buffer.
  235.     addq.w    #1,d3        point d3 to the next colour register
  236.     cmpi.w    #16,d3        is d3 pointing to colour register 16 yet?
  237.     blt    .loop        No, branch
  238.     
  239. * get screen start address and store it
  240.  
  241.     move.w    #2,-(sp)    function number
  242.     trap    #14        XBIOS 2 - PHYSBASE
  243.     addq.l    #2,sp        tidy
  244.     
  245.     move.l    d0,scrnp    save the physical screen address
  246.     
  247.     rts
  248.     
  249. *************************************************************************
  250.  
  251. * DEAL WITH FILE ERRORS
  252.  
  253. file_error
  254.     
  255. * set the character colour to blue. (I found the error messages were
  256. * being printed in yellow, difficult to read, so this allows them to be
  257. * read).
  258.  
  259.     move.l    d0,errnumf    save the error code
  260.  
  261.     move.l    #setbl,-(sp)    address of string to set character colour
  262.     move.w    #9,-(sp)    function number
  263.     trap    #1        GEMDOS 9 - PRINT A STRING
  264.     addq.l    #6,sp        tidy
  265.  
  266.     move.l    errnumf,d0    return the error code
  267.  
  268. * is the error 'file not found'?
  269.  
  270.     cmpi.l    #-33,d0        is the error code -33?
  271.     bne    .1        no, branch
  272.     
  273. * if so, say so
  274.  
  275.     move.b    #9,cursx    select the x cursor position
  276.     move.b    #5,cursy    select the Y cursor position
  277.     jsr    setcurs        set the cursor
  278.  
  279.     move.l    #ermes01,-(sp)    address of message (file not found)
  280.     move.w    #9,-(sp)    function number
  281.     trap    #1        GEMDOS 9 - PRINT A STRING
  282.     addq.l    #6,sp        tidy
  283.     
  284.     bra    .2        goto next message
  285.  
  286. * else say general file error
  287.     
  288. .1    move.b    #8,cursx    select the x cursor position
  289.     move.b    #5,cursy    select the Y cursor position
  290.     jsr    setcurs        set the cursor
  291.  
  292.     move.l    #ermes02,-(sp)    address of message (file error)
  293.     move.w    #9,-(sp)    function number
  294.     trap    #1        GEMDOS 9 - PRINT A STRING
  295.     addq.l    #6,sp        tidy
  296.     
  297. * and print the error code number
  298.  
  299.     move.b    #8,cursx    select the x cursor position
  300.     move.b    #7,cursy    select the Y cursor position
  301.     jsr    setcurs        set the cursor
  302.  
  303.     move.l    #ermes04,-(sp)    address of message (error code is :)
  304.     move.w    #9,-(sp)    function number
  305.     trap    #1        GEMDOS 9 - PRINT A STRING
  306.     addq.l    #6,sp        tidy
  307.     
  308.     clr.l    d0        ensure d0 has no stray data
  309.     move.w    errnumf+2,d0    put the (word) error code into d0
  310.     move.l    #bidebuf,a0    load address of the binary/decimal buffer
  311.     jsr    bins2dec    convert signed bin. num to decimal string
  312.     
  313.     move.l    #bidebuf+1,-(sp)    address of ascii error code string
  314.     move.w    #9,-(sp)    function number
  315.     trap    #1        GEMDOS 9 - PRINT A STRING
  316.     addq.l    #6,sp        tidy
  317.  
  318. * say 'press escape'
  319.  
  320. .2    move.b    #8,cursx    select the x cursor position
  321.     move.b    #9,cursy    select the Y cursor position
  322.     jsr    setcurs        set the cursor
  323.  
  324.     move.l    #ermes03,-(sp)    address of message (press escape)
  325.     move.w    #9,-(sp)    function number
  326.     trap    #1        GEMDOS 9 - PRINT A STRING
  327.     addq.l    #6,sp        tidy
  328.     
  329. * go to exit routine
  330.  
  331.     bra    keyloop
  332.  
  333. *************************************************************************
  334.  
  335. * PRINT A SIGNED, WORD-SIZED, NUMBER TO THE SCREEN, IN DECIMAL.
  336.  
  337. * requires a 7 byte buffer
  338. * byte 1 - header, number of digits in the string
  339. * byte 2 to 7 - space for a 6 digit string. (A minus sign if needed, and
  340. *         up to five numeric digits).
  341.  
  342. * put the number to be printed into the low word of d0
  343. * put the address of the 7 byte buffer into a0
  344.  
  345. bins2dec
  346.  
  347. * set up the registers
  348.  
  349.     movem.l    a0-a1/d0-d4,-(sp)    save registers
  350.     
  351.     lea    1(a0),a1    point a1 to where the neg sign is to go
  352.     clr.l    d1        counter - number of decimal digits
  353.     clr.l    d2        flag - no leading nonzero digit found d2=0
  354.     
  355. * is the number negative?
  356.     
  357.     tst.w    d0        is d0 negative?
  358.     bpl    calcdg        no, branch
  359.  
  360. * if so, negate d0 & put a minus sign first on the string
  361.  
  362.     neg.w    d0        take d0 from 0. result in d0.
  363.     move.b    #"-",(a1)+    put the ascii for a minus sign in buffer
  364.     addq.b    #1,d1        inc number of digits counter
  365.     
  366. * now calculate the separate digits
  367.     
  368. calcdg    move.w    #10000,d3    d3 = the divisor
  369.     bsr    divs16        divide d0 by d3 and save ascii in buffer
  370.  
  371.     move.w    #1000,d3
  372.     bsr    divs16
  373.  
  374.     move.w    #100,d3
  375.     bsr    divs16    
  376.  
  377.     move.w    #10,d3
  378.     bsr    divs16    
  379.     
  380.     add.b    #'0',d0        convert the units digit to ascii
  381.     move.b    d0,(a1)+    always save the units digit
  382.     addq.b    #1,d1        inc number of digits
  383.     move.b    d1,(a0)        put the number of digits at the front of buffer
  384.  
  385.     movem.l    (sp)+,a0-a1/d0-d4    restore registers
  386.     
  387.     rts    
  388.  
  389. * divide a (long) number in d0 by a (word) number in d3 low word
  390.     
  391. divs16    divu    d3,d0        unsigned division
  392.     move.w    d0,d4        save the answer to d4
  393.     clr.w    d0        set low word of d0 to 0
  394.     swap    d0        put the remainder into low word of d0
  395.     
  396.     tst.b    d2        test the leading zero flag
  397.     bne    svdig        branch if the flag is not zero
  398.     
  399.     tst.b    d4        it is, so test this digit for zero
  400.     beq    enddiv        it is. No numbers left, so branch
  401.     addq.b    #1,d2        d4 not zero, so set the flag to say so
  402.  
  403. * save the number in d4 to the buffer as ascii
  404.  
  405. svdig    add.b    #'0',d4        make into ascii
  406.     addq.b    #1,d1        inc number of digits
  407.     move.b    d4,(a1)+    save ascii digit in buffer
  408.     
  409. enddiv    rts    
  410.     
  411. *************************************************************************
  412.  
  413. * SET THE CURSOR POSITION
  414.  
  415. * ALWAYS set BOTH 'cursx' & 'cursy' values before calling.  Note that if 
  416. * one of them is left from a previous call to this subroutine, it will have
  417. * #31 added to it AGAIN!
  418.  
  419. setcurs
  420.  
  421.     movem.l    d0-d7/a0-a6,-(sp)    save registers
  422.  
  423. * ascii the cursor references
  424.  
  425.     add.b    #31,cursx    adding #31 makes it an ascii code
  426.     add.b    #31,cursy    adding #31 makes it an ascii code
  427.  
  428. * print the cursor string, setting the screen cursor
  429.  
  430.     move.l    #curspos,-(sp)    address of string onto stack
  431.     move.w    #9,-(sp)    GEMDOS 9 - PRINT A STRING
  432.     trap    #1
  433.     addq.l    #6,sp
  434.     
  435.     movem.l    (sp)+,d0-d7/a0-a6    restore registers
  436.  
  437.     rts
  438.  
  439. *************************************************************************
  440.  
  441. * RESERVED MEMORY
  442.  
  443.         DATA
  444.  
  445. ermes01        dc.b    "Can't find the file...",0
  446. ermes02        dc.b    "File problem... oh dear!",0
  447. ermes03        dc.b    "Press <ESCAPE> to exit...",0
  448. ermes04        dc.b    "The error code is : ",0
  449. errnumf        dc.l    0,0        error code store and printing string
  450. filename    dc.b    "PIC.PI1",0
  451. setbl        dc.b    27,"b",8,0    set character print to colour blue
  452.  
  453. curspos        dc.b    27,"Y"        print this string to place the
  454. cursy        dc.b    32        cursor where you want it.
  455. cursx        dc.b    32
  456.         dc.b    0
  457.         
  458.         BSS
  459.  
  460.         even
  461. bidebuf        ds.b    8    buffer for printing signed numbers in dec
  462. handle        ds.w    1    file handle
  463. headbuf        ds.w    17    picture header
  464. oldrez        ds.w    1    original screen rez
  465. oldpal        ds.w    16    original colour palette
  466. scancode    ds.w    1    code from a keypress
  467. scrnp        ds.l    1    physical screen address
  468.  
  469. ****************************** T H E   E N D ******************************
  470.