home *** CD-ROM | disk | FTP | other *** search
/ Supremacy 2 / Supremacy-2.iso / Pompey / PP_031.MSA / AUTOMATI.ON / SOURCE / ULTRA.S < prev   
Text File  |  1985-11-20  |  11KB  |  645 lines
  1. *
  2. * Ultraload (Uni-load II)
  3. *
  4. * Written by Dack of The Un-Nameables
  5. * (Based on Uni-load by The Law)
  6. *
  7. * Includes depacker to/from odd addresses
  8. *
  9. * NOTE:-
  10. *
  11. * buff_len  = Max length of a PACKED file
  12. * max_files = No. of files open at once + 6
  13. *
  14. * only packed files are buffered, unpacked data
  15. * is treated as normal...
  16. *
  17. * gam = filename to $4b
  18. *
  19.  
  20.         opt c+,d-
  21.  
  22. buff_len    equ    $18c0a
  23. max_files    equ    32
  24.     bra    main
  25.  
  26. gam        dc.b "entvap",0
  27.         even
  28.  
  29. text    DC.B "Vapour presents . . ."
  30.     DC.B 00,00
  31.  
  32.     EVEN
  33.  
  34. ;SET TABS TO 10 FOR DISASSEMBLY
  35.  
  36.     
  37. main    MOVEA.L    4(A7),A5
  38.     move.l $c(a5),d0
  39.     add.l $14(a5),d0
  40.     add.l $1c(a5),d0
  41.     add.l #$200,d0
  42.     add.l #buff_len,d0    ;add buffer length
  43.     move.l d0,-(sp)
  44.     move.l a5,-(sp)
  45.     move.l #$4a0000,-(sp)
  46.     trap #1
  47.     lea $c(a7),a7
  48.  
  49.     dc.l $a000a00a
  50.     clr.w -(sp)
  51.     pea $ffffffff
  52.     move.l (a7),-(sp)
  53.     move.w #5,-(sp)
  54.     trap #14
  55.     lea $c(a7),a7
  56.     dc.w $a009
  57.  
  58.     pea    text
  59.     move.w    #9,-(a7)
  60.     trap    #1
  61.     addq.l    #6,a7
  62.  
  63. *
  64. * buffer address
  65. * (Can be absolute....)
  66. * 
  67.     move.l    #buff_start,buff_add    ;set buffer start address
  68.  
  69. CHEAT    CLR.L    -(A7)
  70.     MOVE.W    #$20,-(A7)
  71.     TRAP    #$01
  72.     ADDQ.L    #6,A7
  73.     LEA    SUPERLNG(PC),A6
  74.     MOVE.L    D0,(A6)
  75.     MOVE.L    $84,tr1
  76.     MOVE.L    #T1,$84
  77.     MOVE.L    SUPERLNG(PC),-(A7)
  78.     MOVE.W    #$20,-(A7)
  79.     TRAP    #$01
  80.     ADDQ.L    #6,A7
  81. stkk    clr.w    in_use
  82.     clr.l $60000
  83.     pea $60000
  84.     move.l (a7),-(sp)
  85.     move.l #gam,-(sp)
  86.     move.l #$4b0000,-(sp)
  87.     trap #1
  88.     lea $0c(a7),a7
  89.     clr.w -(sp)
  90.     trap #1
  91. SUPERLNG    DC.L    0
  92.  
  93.  
  94. ;multi file read 1st October 1989
  95. ;fix 11th October 1989 for decode from odd address
  96. ;bastard bug to find
  97.  
  98. T1        tst.w    inside
  99.         bne    bye
  100.         MOVEM.L a0-a6/d0-d7,reg
  101.         movea.l    a7,a1
  102.         addq.l     #6,a1
  103.         move.w     (a7),d0
  104.         btst     #$d,d0
  105.         bne.s     ok1
  106.         move.l     usp,a1
  107. ok1        cmpi.w  #0,(a1)
  108.         bne.s next1
  109.         move.l    tr1(pc),$84.w
  110.         bra.s    open
  111. next1        cmpi.w     #$3d,(a1)
  112.         beq    openup
  113.         cmpi.w    #$3f,(a1)
  114.         beq    read
  115.         cmpi.w    #$3e,(a1)
  116.         beq    close
  117.         cmpi.w    #$42,(a1)
  118.         beq    seek
  119.         cmpi.w    #$4e,(a1)
  120.         beq    ffirst
  121.         cmpi.w  #$3c,(a1)
  122.         beq     create
  123.         cmpi.w    #$40,(a1)
  124.         beq     write
  125. open        movem.l     reg(pc),a0-a6/d0-d7
  126. bye        dc.w     $4ef9
  127. tr1        dc.l     $0
  128.  
  129. openup        move.w    #1,inside    ;do normal traps
  130.         lea    f_names,a0
  131.         add.l    #300,a0
  132.         move.l    #5,d0
  133. s_loop        addq.l    #1,d0
  134.         add.l    #60,a0
  135.         tst.b    (a0)
  136.         bne.s    s_loop        ;search for empty slot
  137.  
  138. ;d0=my pretend file handle
  139.  
  140.         move.l    d0,d7
  141.  
  142. ****        
  143.         move.l d0,d6
  144.  
  145.         move.l    a0,a5
  146.         move.l    2(a1),a6    ;save file name address
  147.  
  148. ;open file
  149.         clr.w    -(a7)
  150.         move.l    a6,-(a7)
  151.         move.w    #$3d,-(a7)
  152.         trap    #1
  153.         addq.l    #8,a7
  154.  
  155.         tst.l    d0
  156.         bmi    error        ;in case file not there
  157.  
  158.         move.w    d0,d4
  159.         clr.l i_buff
  160.         pea i_buff
  161.         move.l #8,-(a7)
  162.         move.w d4,-(a7)
  163.         move.w #$3f,-(a7)
  164.         trap #1
  165.         lea 12(a7),a7
  166.         clr.w -(a7)
  167.         move.w d4,-(a7)
  168.         clr.l -(a7)
  169.         move.w #$42,-(a7)
  170.         trap #1
  171.         lea 10(a7),a7
  172.         cmp.l #"LSD!",i_buff
  173.         beq.s nermal    
  174.         lea real_hand,a0
  175.         lsl.l #2,d7
  176.         move.l d4,(a0,d7.w)
  177.         move.b #"0",(a5)
  178.         bra not_good
  179.  
  180. ;copy file name to storage
  181.  
  182. nermal        move.l    #59,d0
  183. c_loop        move.b    (a6)+,(a5)+
  184.         dbra    d0,c_loop
  185.  
  186.         move.l    i_len,d5
  187. not_com        lea    f_lengths,a0
  188.         lsl.l    #2,d7
  189.         move.l    d5,(a0,d7.w)        ;save file length in array
  190.         lea    so_read,a0
  191.         move.l #0,(a0,d7.w)
  192.         lea real_hand,a0
  193.         move.l #-1,(a0,d7.w)
  194.         
  195. ;close file as finished
  196.  
  197.         move.w    d4,-(a7)
  198.         move.w    #$3e,-(a7)
  199.         trap    #1
  200.         addq.l    #4,a7
  201.  
  202. not_good
  203.         clr.w    inside        ;my traps again
  204.         move.l d6,-(a7)
  205.         movem.l reg,a0-a6/d0-d7    
  206.         move.l    (a7)+,d0    ;give back my handle
  207.         rte
  208.  
  209. read        clr.l    d0
  210.         move.w    2(a1),d0    ;get handle
  211.         cmp.l    in_use,d0
  212.         beq    all_in        ;already loaded
  213.  
  214.         move.l d0,d1
  215.         lsl.l #2,d1
  216.         lea real_hand,a0
  217.         move.l (a0,d1.w),d2
  218.         cmp.l #-1,d2
  219.         beq.s cor_blimey
  220.  
  221.         move.l 4(a1),d0
  222.         move.l 8(a1),d1
  223.         move.w #1,inside
  224.         move.l d1,-(a7)
  225.         move.l d0,-(a7)
  226.         move.w d2,-(a7)
  227.         move.w #$3f,-(a7)
  228.         trap #1
  229.         lea 12(a7),a7
  230.         clr.w inside
  231.  
  232.         move.l d0,d4
  233.         bra titter
  234.  
  235. cor_blimey    move.l    a1,a5
  236.         move.w    #1,inside
  237.         move.l    d0,in_use
  238.         mulu     #60,d0
  239.         lea    f_names,a0
  240.         add.l    d0,a0        ;get correct filename
  241.         clr.w    -(a7)
  242.         move.l    a0,-(a7)
  243.         move.w    #$3d,-(a7)
  244.         trap    #1
  245.         addq.l    #8,a7
  246.         move.w    d0,d6
  247.         move.l    buff_add,-(a7)
  248.         move.l    #buff_len,-(a7)
  249.         move.w    d0,-(a7)
  250.         move.w    #$3f,-(a7)
  251.         trap    #1
  252.         lea    12(a7),a7
  253.         move.w    d6,-(a7)
  254.         move.w    #$3e,-(a7)
  255.         trap    #1
  256.         addq.l    #4,a7
  257.         clr.w    inside
  258.         move.l    buff_add,a0
  259.         move.l    a0,a1
  260.         add.l    #200,a1
  261.         move.l    4(a0),d7    ;length
  262.         bsr    DEPACK
  263.         move.l    buff_add,a0
  264.         move.l    a0,a1
  265.         add.l    #200,a1
  266. m2_back        move.b    (a1)+,(a0)+
  267.         subq.l    #1,d7
  268.         bne.s    m2_back
  269. read_in        move.l    a5,a1        ;put stack back in a1
  270. all_in        move.l    4(a1),d0    ;bytes to move
  271.         move.l    d0,d4
  272.         move.l    8(a1),a0    ;whereto
  273.         move.l    in_use,d1
  274.         lsl.l    #2,d1        ;*4
  275.         lea    so_read,a2
  276.         lea    f_lengths,a3
  277.         move.l    (a2,d1.w),d2    ;current offset
  278.         move.l    (a3,d1.w),d3    ;length of this file
  279.         move.l    buff_add,a1
  280.         add.l    d2,a1
  281. do_it        move.b    (a1)+,(a0)+
  282.         addq.l    #1,d2
  283.         cmp.l    d2,d3
  284.         blt.s    past_end
  285.         subq.l    #1,d0
  286.         bne.s    do_it
  287.         bra.s    wibble
  288. past_end    move.l    d3,d2        ;if past end then offset=end
  289. wibble        move.l    d2,(a2,d1.w)    ;save new offset
  290.         sub.l    d0,d4        ;get number of bytes read
  291. titter        move.l    d4,-(a7)
  292.         movem.l    reg,a0-a6/d0-d7
  293.         move.l    (a7)+,d0    ;return #bytes read
  294.         rte
  295.  
  296. close        clr.l    d0
  297.         move.w    2(a1),d0
  298.         cmp.l    in_use,d0    ;closing file currently loaded
  299.         bne.s    lucky
  300.         move.l    #-1,in_use
  301. lucky        move.l d0,d1
  302.         mulu    #60,d0
  303.         lea    f_names,a0
  304.         move.b    #0,(a0,d0.w)
  305.         lsl.l #2,d1
  306.         lea real_hand,a0
  307.         move.l (a0,d1.w),d0
  308.         cmp.l #-1,d0
  309.         beq.s standard
  310.         move.w #1,inside
  311.         move.w d0,-(a7)
  312.         move.w #$3e,-(a7)
  313.         trap #1
  314.         addq.w #4,a7
  315.         clr.w inside
  316. standard    movem.l    reg,a0-a6/d0-d7
  317.         clr.l    d0
  318.         rte
  319.  
  320. seek        lea    so_read,a2
  321.         lea    f_lengths,a3
  322.         clr.l    d0
  323.         move.w    6(a1),d0    ;file handle
  324.         lsl.l    #2,d0
  325.         clr.l    d1
  326.         move.w    8(a1),d1    ;type of seek
  327.         move.l    2(a1),d2    ;offset
  328.  
  329.         lea real_hand,a0
  330.         move.l (a0,d0.w),d3
  331.         cmp.l #-1,d3
  332.         beq.s com_seek
  333.         move.w #1,inside
  334.         move.w d1,-(a7)
  335.         move.w d3,-(a7)
  336.         move.l d2,-(a7)
  337.         move.w #$42,-(a7)
  338.         trap #1
  339.         lea 10(a7),a7
  340.  
  341.         move.l d0,d3
  342.         clr.w inside
  343.         bra com_out
  344.  
  345. com_seek    tst.w    d1        ;type 0?
  346.         bne.s    one_two
  347.  
  348. ;absolute move=type 0
  349.  
  350.         move.l    d2,d3
  351.         bra.s    same_end
  352. one_two        cmp.w    #1,d1
  353.         bne.s    mustbe2
  354.  
  355. ;type 1=from current place
  356.  
  357.         move.l    (a2,d0.w),d3
  358.         add.l    d2,d3
  359.         bra.s    same_end
  360. mustbe2        move.l    (a3,d0.w),d3
  361.         sub.l    d2,d3
  362.  
  363. ;type 2=from end
  364.  
  365. same_end    move.l    (a3,d0.w),d4    ;get length
  366.         cmp.l    d3,d4
  367.         bgt.s    ok_so_far    ;not past end
  368.         move.l    d4,d3
  369. ok_so_far    cmp.l    #0,d3
  370.         bgt.s    still_ok    ;not past start
  371.         clr.l    d3
  372. still_ok    move.l    d3,(a2,d0.w)    ;save new offset
  373. com_out        move.l    d3,-(a7)
  374.         movem.l    reg,a0-a6/d0-d7
  375.         move.l    (a7)+,d0    ;return new offset
  376.         rte
  377.  
  378. error        clr.w    inside
  379.         movem.l    reg,a0-a6/d0-d7
  380.         move.l    #-1,d0
  381.         rte    
  382.  
  383. create        move.w #1,inside
  384.         lea f_names,a0
  385.         add.l #300,a0
  386.         move.l #5,d0
  387. fcl        addq.l #1,d0
  388.         add.l #60,a0
  389.         tst.b (a0)
  390.         bne.s fcl
  391.  
  392.         move.l d0,d7
  393.         move.l a0,a5
  394.         move.w 6(a1),-(a7)
  395.         move.l 2(a1),-(a7)
  396.         move.w #$3c,-(a7)
  397.         trap #1
  398.         addq.l #8,a7
  399.  
  400.         tst.w d0
  401.         bmi nwc
  402.  
  403.         move.b #'i',(a5)
  404.         lea real_hand,a0
  405.         move.l d7,d6
  406.         lsl.l #2,d7
  407.         move.l d0,(a0,d7.w)
  408.         move.l d6,d0
  409. nwc        clr.w inside
  410.         move.l d0,-(a7)
  411.         movem.l reg,a0-a6/d0-d7
  412.         move.l (a7)+,d0
  413.         rte
  414.  
  415. write        clr.l d0
  416.         move.w 2(a1),d0
  417.         lsl.l #2,d0
  418.         lea real_hand,a0
  419.         move.l (a0,d0.w),d1
  420.         move.w d1,2(a1)
  421.         bra open
  422.  
  423. ffirst        move.l    2(a1),d0
  424.         move.l    d0,d5        ;preserve fname
  425.         move.w    6(a1),d1
  426.         move.w    #1,inside
  427.         move.w    d1,-(a7)
  428.         move.l    d0,-(a7)
  429.         move.w    #$4e,-(a7)
  430.         trap    #1
  431.         addq.l    #8,a7
  432.         tst.w    d0
  433.         bne    exit_route
  434.         move.w    #$2f,-(a7)
  435.         trap    #1
  436.         addq.l    #2,a7
  437.         move.l    d0,d7
  438.  
  439.         clr.w    -(a7)
  440.         move.l    d5,-(a7)
  441.         move.w    #$3d,-(a7)
  442.         trap    #1
  443.         addq.l    #8,a7
  444.  
  445.         move.w    d0,d6
  446.         clr.l tmp_read
  447.         pea    tmp_read
  448.         move.l    #8,-(a7)
  449.         move.w    d0,-(a7)
  450.         move.w    #$3f,-(a7)
  451.         trap    #1
  452.         lea    12(a7),a7
  453.         move.w    d6,-(a7)
  454.         move.w    #$3e,-(a7)
  455.         trap    #1
  456.         addq.l    #4,a7
  457.         lea    tmp_read,a0
  458.         cmp.l    #"LSD!",(a0)
  459.         bne.s    doont
  460.         move.l    d7,a1
  461.         move.l    4(a0),26(a1)
  462. doont        clr.l    d0
  463. exit_route    clr.w    inside
  464.         move.l    d0,-(a7)
  465.         movem.l    reg,a0-a6/d0-d7
  466.         move.l    (a7)+,d0
  467.         rte
  468.  
  469. reg        ds.l    16
  470. tmp_read    ds.l    4
  471. crunpos        dc.l 0
  472.  
  473. ;should now be capable of decoding from odd to odd addresses
  474. ;11th October 1989
  475.  
  476. DEPACK        adda.l #4,a0
  477.         move.w $ff8240,-(sp)
  478.         lea    crunpos(pc),a6
  479.         move.l a0,(a6)        ;save crunch position
  480.         move.b (a0)+,d5
  481.         lsl.w     #8,d5
  482.         move.b    (a0)+,d5
  483.         swap    d5
  484.         move.b    (a0)+,d5
  485.         lsl.w    #8,d5
  486.         move.b    (a0)+,d5
  487.         adda.l d5,a1
  488.         move.b    (a0),d0
  489.         lsl.w    #8,d0
  490.         move.b    1(a0),d0
  491.         swap    d0
  492.         move.b    2(a0),d0
  493.         lsl.w    #8,d0
  494.         move.b    3(a0),d0
  495.         adda.l     d0,a0
  496.         subq.l #4,a0
  497.         move.b    -2(a0),d0
  498.         lsl.w    #8,d0
  499.         move.b    -1(a0),d0
  500.         subq.l    #2,a0
  501.         tst.w    d0
  502.         bpl.s L_1
  503.         subq.l #1,a0
  504. L_1        move.b -(a0),d0
  505. L_2        lsl.b #1,d0
  506.         bne.s L_3
  507.         MOVE.B    -(A0),D0
  508.         ROXL.B    #1,D0
  509. L_3        BCC.S    L_10
  510.         CLR.W    D1
  511.         LSL.B    #1,D0
  512.         BNE.S    L_4
  513.         MOVE.B    -(A0),D0
  514.         ROXL.B    #1,D0
  515. L_4        BCC.S    L_9
  516.         LEA    NUMS(PC),A3
  517.         MOVEQ    #3,D3
  518. L_5        CLR.W    D1
  519.         MOVE.B    0(A3,D3.W),D2
  520.         EXT.W    D2
  521.         MOVEQ    #-1,D4
  522.         LSL.W    D2,D4
  523.         NOT.W    D4
  524.         SUBQ.W    #1,D2
  525. L_6        LSL.B    #1,D0
  526.         BNE.S    L_7
  527.         MOVE.B    -(A0),D0
  528.         ROXL.B    #1,D0
  529. L_7        ROXL.W    #1,D1
  530.         DBF    D2,L_6
  531.         TST.W    D3
  532.         BEQ.S    L_8
  533.         CMP.W    D1,D4
  534.         DBNE    D3,L_5
  535. L_8        MOVE.B    4(A3,D3.W),D2
  536.         EXT.W    D2
  537.         ADD.W    D2,D1
  538.         BRA    L_9
  539.  
  540. NUMS        DC.B    $0A,$03,$02,$02,$0E,$07,$04,$01
  541.  
  542. L_9        MOVE.B    -(A0),-(A1)
  543.         eor.w    #$5,$ff8240
  544.         DBF    D1,L_9
  545. L_10        MOVE.L    crunpos(pc),A3        ;get crunch position
  546.         ADDQ.L    #$8,A3
  547.         CMPA.L    A3,A0
  548.         BLE    BYENOW
  549.         LEA    NUMS2(PC),A3
  550.         MOVEQ    #3,D2
  551. L_11        LSL.B    #1,D0
  552.         BNE.S    L_12
  553.         MOVE.B    -(A0),D0
  554.         ROXL.B    #1,D0
  555. L_12        BCC.S    L_13
  556.         DBF    D2,L_11
  557. L_13        CLR.W    D1
  558.         ADDQ.W    #1,D2
  559.         MOVE.B    0(A3,D2.W),D3
  560.         BEQ.S    L_16
  561.         EXT.W    D3
  562.         SUBQ.W    #1,D3
  563. L_14        LSL.B    #1,D0
  564.         BNE.S    L_15
  565.         MOVE.B    -(A0),D0
  566.         ROXL.B    #1,D0
  567. L_15        ROXL.W    #1,D1
  568.         DBF    D3,L_14
  569. L_16        MOVE.B    5(A3,D2.W),D3
  570.         EXT.W    D3
  571.         ADD.W    D3,D1
  572.         BRA    L_161
  573.  
  574. NUMS2        DC.B    $0A,$02,$01,$00,$00,$0A,$06,$04,$03,$02
  575.  
  576. L_161        CMPI.W    #2,D1
  577.         BEQ.S    L_22
  578.         LEA    NUMS3(PC),A3
  579.         MOVEQ    #1,D3
  580. L_17        LSL.B    #1,D0
  581.         BNE.S    L_18
  582.         MOVE.B    -(A0),D0
  583.         ROXL.B    #1,D0
  584. L_18        BCC.S    L_19
  585.         DBF    D3,L_17
  586. L_19        ADDQ.W    #1,D3
  587.         CLR.W    D2
  588.         MOVE.B    0(A3,D3.W),D4
  589.         EXT.W    D4
  590. L_20        LSL.B    #1,D0
  591.         BNE.S    L_21
  592.         MOVE.B    -(A0),D0
  593.         ROXL.B    #1,D0
  594. L_21        ROXL.W    #1,D2
  595.         DBF    D4,L_20
  596.         LSL.W    #1,D3
  597.         ADD.W    4(A3,D3.W),D2
  598.         BRA.S    L_26
  599.  
  600. NUMS3        DC.B    $0B,$04,$07,$00,$01,$20,$00,$00
  601.         DC.B    $00,$20,$00,$00
  602.  
  603. L_22        CLR.W    D2
  604.         MOVEQ    #5,D3
  605.         CLR.W    D4
  606.         LSL.b    #1,D0
  607.         BNE.S    L_23
  608.         MOVE.B    -(A0),D0
  609.         ROXL.B    #1,D0
  610. L_23        BCC.S    L_24
  611.         MOVEQ    #8,D3
  612.         MOVEQ    #$40,D4
  613. L_24        LSL.B    #1,D0
  614.         BNE.S    L_25
  615.         MOVE.B    -(A0),D0
  616.         ROXL.B    #1,D0
  617. L_25        ROXL.W    #1,D2
  618.         DBF    D3,L_24
  619.         ADD.W    D4,D2
  620. L_26        LEA    0(A1,D2.W),A2
  621.         EXT.L    D1
  622.         ADDA.L    D1,A2
  623.         SUBQ.W    #1,D1
  624. L_27        MOVE.B    -(A2),-(A1)
  625.         DBF    D1,L_27
  626.         BRA    L_2
  627. BYENOW        move.w (a7)+,$ff8240
  628.         RTS
  629. stksav        dc.l 0
  630. in_use        ds.l    1
  631. inside        ds.l    1
  632. buff_add    ds.l    1
  633. whereto        ds.l    1
  634. so_read        dcb.l    0,max_files
  635. f_lengths    dcb.l    0,max_files
  636. f_names        rept    max_files
  637.         dcb.b    0,60
  638.         endr
  639. real_hand    dcb.l 0,max_files
  640. i_buff        ds.l     1
  641. i_len        ds.l     1
  642. buff_start    dc.l    0    ;start of buffer space
  643.  
  644.     
  645.