home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Wizard Games 2
/
W_GAMES2.ISO
/
german
/
wkslist.cmd
< prev
Wrap
OS/2 REXX Batch file
|
1995-03-02
|
4KB
|
106 lines
/*
WKSLIST.CMD
REXX-Programm zum Betrachten von Dateien.
Abhängig von der Dateierweiterung wird dann ein passender
Betrachter aufgerufen.
***************************************************************
* Die Liste der benutzten Betrachtungsprogramme kann beliebig *
* erweitert werden.Zu jeder Erweiterung muss ein passender Be-*
* trachter definiert werden (siehe unten). Wichtig ist, in der*
* Zeile *
* Erweiterung.0 = 9 *
* immer die aktuelle Größe der Liste anzupassen. *
***************************************************************
* Modus /U "UNZIP" : Datei im ZIP-Archiv. Die Datei wird zuerst
aus dem ZIP ins TEMP-Verzeichnis geholt.
%1 = d:\path\unzip.exe The UNZIP-Program
%2 = d:\path\archive.zip The ZIP-Archive
%3 = path/path/filename.ext The file to be unzipped and viewed (with PATH)
%4 = d:\temppath\WKS0001.TMP The TEMPPath-Filename-destination
* Modus /L "LIST" : Datei ist bereits vorhanden. Direkt listen !
%1 = d:\path\filename.ext
(C) 1994 Wolfram Körner, Friedenstraße 5a, 97072 Würzburg.
*/
call RxFuncAdd 'SysLoadFuncs', 'RexxUtil', 'SysLoadFuncs'
call SysLoadFuncs
parse arg cmdline /* Kommandozeilen-Parameter holen */
parse var cmdline Mode cmdline /* welchen Modus ? /U oder /L */
Mode = TRANSLATE(Mode)
if Mode = "/U" then do
parse var cmdline UnzipExe ZIP ZIPFile TEMPFile Rest /* zerlegen */
end
if Mode = "/L" then do
parse var cmdline TEMPFile Rest /* oder so zerlegen */
ZIPFile=TEMPFile
end
/* ------ Die Liste der Erweiterungen und der passenden Betrachter ----------*/
Betrachter = "e.exe" /* Im Zweifel wird dieser Betrachter genommen*/
Erweiterung.0 = 14 /* Größe der folgenden Liste */
Erweiterung.1=".INF" /* *.INF wird mit VIEW.EXE betrachtet */
Lister.1= "view.exe"
Erweiterung.2=".ICO" /* *.ICO wird mit ICONEDIT.EXE betrachtet */
Lister.2= "iconedit.exe"
Erweiterung.3=".BMP" /* und-so-weiter... */
Lister.3= "iconedit.exe"
Erweiterung.4=".MID"
Lister.4= "mppm.exe"
Erweiterung.5=".WAV"
Lister.5= "mppm.exe"
Erweiterung.6=".AVI"
Lister.6= "mppm.exe"
Erweiterung.7=".MET"
Lister.7= "picview.exe"
Erweiterung.8=".PIF"
Lister.8= "picview.exe"
Erweiterung.9=".SPL"
Lister.9= "picview.exe"
Erweiterung.10=".MOD"
Lister.10= "dmplayer"
Erweiterung.11=".GIF"
Lister.11= "pmjpeg"
Erweiterung.12=".PCX"
Lister.12= "pmjpeg"
Erweiterung.13=".TIF"
Lister.13= "pmjpeg"
Erweiterung.14=".JPG"
Lister.14= "pmjpeg"
/* -------------- Datei aus dem Archiv holen (nur Modus /U )----------- */
/* UNZIP-Options:
-j "Junk Pathnames"
-o "overwrite"
-p "extract to pipe"
*/
if Mode = "/U" then
UnzipExe "-pjo" ZIP ZIPFile " > " TEMPFile
/* -------------- Suchroutine für den passenden Betrachter ------------ */
ZIPFile = Translate(ZIPFile) /* In GROSSBUCHSTABEN umwandeln */
do i=1 to Erweiterung.0
if Erweiterung.i = right(ZIPFile, 4) then
Betrachter=Lister.i
end /* do */
/* --------------- Aufruf des Betrachters mit der Datei --------------- */
'start /f' Betrachter TEMPFile