home *** CD-ROM | disk | FTP | other *** search
/ PC-Online 1996 May / PCOnline_05_1996.bin / linux / source / n / tcpip / nntp-1.5 / nntp-1 / nntp.1.5.11t / xmit / nntpsend.csh < prev    next >
Encoding:
Linux/UNIX/POSIX Shell Script  |  1993-10-17  |  1.5 KB  |  54 lines
  1. #!/bin/csh -f
  2. #
  3. # What we have here is a csh script for sending netnews to NNTP sites.
  4. #
  5. set batchdir=/usr/spool/news/batch libdir=/usr/spool/news/lib
  6. set path=( $libdir /usr/ucb /usr/bin /bin $path )
  7. set pname=$0
  8. set pname=$pname:t
  9. echo ${pname}: "[$$]" begin `date`
  10. #
  11. # Go to where the action is
  12. #
  13. cd $batchdir
  14. umask 022
  15. #
  16. #    For NNTP
  17. #
  18. #    Here "foo", "bar", and "zot" are the Internet names of
  19. #    the machines to which to send.  We make the supposition
  20. #    that the batch files will be a host's internet name.
  21. #    So, for example "nike"'s internet name is "ames-titan.arpa".
  22. #    Because of this, your sys file must have "ames-titan.arpa"
  23. #    as the batch file output for the machine "nike".
  24. #
  25. foreach host ( {cad,zen,jade,cartan}.berkeley.edu decvax.dec.com cgl.ucsf.edu ucdavis.edu 128.54.0.1 )
  26.     set lock=NNTP_LOCK.${host} tmp=${host}.tmp send=${host}.nntp
  27.     shlock -p $$ -f ${lock}
  28.     if ($status == 0) then
  29.         if ( -e ${tmp} ) then
  30.             cat ${tmp} >> ${send}
  31.             rm ${tmp}
  32.         endif
  33.         if ( -e ${host} ) then
  34. # if there's already other work to do, let the tmp file cool off.
  35. # we'll pick it up again during the next iteration to make sure that
  36. # we don't miss anything that inews is adding to it now.
  37.             if ( -e ${send} ) then
  38.                 mv ${host} ${tmp}
  39.             else
  40.                 mv ${host} ${send}
  41.             endif
  42.         endif
  43.         if ( -e ${send} ) then
  44.             echo ${pname}: "[$$]" begin ${host}
  45.             time nntpxmit ${host}:${send}
  46.             echo ${pname}: "[$$]" end ${host}
  47.         endif
  48.         rm -f ${lock}
  49.     else
  50.         echo ${pname}: "[$$]" ${host} locked by "[`cat ${lock}`]"
  51.     endif
  52. end
  53. echo ${pname}: "[$$]" end `date`
  54.