home *** CD-ROM | disk | FTP | other *** search
/ PC-Online 1996 May / PCOnline_05_1996.bin / linux / source / kernel-s / v1.1 / scsi / 274x / aha274x / aha274x.seq < prev    next >
Text File  |  1995-10-10  |  29KB  |  1,014 lines
  1. # @(#)aha274x.seq 1.26 94/09/06 jda
  2. #
  3. # Adaptec 274x device driver for Linux.
  4. # Copyright (c) 1994 The University of Calgary Department of Computer Science.
  5. # 
  6. # This program is free software; you can redistribute it and/or modify
  7. # it under the terms of the GNU General Public License as published by
  8. # the Free Software Foundation; either version 2 of the License, or
  9. # (at your option) any later version.
  10. # 
  11. # This program is distributed in the hope that it will be useful,
  12. # but WITHOUT ANY WARRANTY; without even the implied warranty of
  13. # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  14. # GNU General Public License for more details.
  15. # 
  16. # You should have received a copy of the GNU General Public License
  17. # along with this program; if not, write to the Free Software
  18. # Foundation, Inc., 675 Mass Ave, Cambridge, MA 02139, USA.
  19.  
  20. VERSION AHA274X_SEQ_VERSION 1.26
  21.  
  22. MAXSCB        = 4
  23.  
  24. SCSISEQ        = 0x00
  25. SXFRCTL0    = 0x01
  26. SXFRCTL1    = 0x02
  27. SCSISIGI    = 0x03
  28. SCSISIGO    = 0x03
  29. SCSIRATE    = 0x04
  30. SCSIID        = 0x05
  31. SCSIDATL    = 0x06
  32. STCNT        = 0x08
  33. STCNT+0        = 0x08
  34. STCNT+1        = 0x09
  35. STCNT+2        = 0x0a
  36. SSTAT0        = 0x0b
  37. CLRSINT1    = 0x0c
  38. SSTAT1        = 0x0c
  39. SIMODE1        = 0x11
  40. SCSIBUSL    = 0x12
  41. SHADDR        = 0x14
  42. SELID        = 0x19
  43. SBLKCTL        = 0x1f
  44. SEQCTL        = 0x60
  45. A        = 0x64                # == ACCUM
  46. SINDEX        = 0x65
  47. DINDEX        = 0x66
  48. ALLZEROS    = 0x6a
  49. NONE        = 0x6a
  50. SINDIR        = 0x6c
  51. DINDIR        = 0x6d
  52. FUNCTION1    = 0x6e
  53. HADDR        = 0x88
  54. HCNT        = 0x8c
  55. HCNT+0        = 0x8c
  56. HCNT+1        = 0x8d
  57. HCNT+2        = 0x8e
  58. SCBPTR        = 0x90
  59. INTSTAT        = 0x91
  60. DFCNTRL        = 0x93
  61. DFSTATUS    = 0x94
  62. DFDAT        = 0x99
  63. QINFIFO        = 0x9b
  64. QINCNT        = 0x9c
  65. QOUTFIFO    = 0x9d
  66.  
  67. SCSICONF    = 0x5a
  68.  
  69. #  The two reserved bytes at SCBARRAY+1[23] are expected to be set to
  70. #  zero, and the reserved bit in SCBARRAY+0 is used as an internal flag
  71. #  to indicate whether or not to reload scatter-gather parameters after
  72. #  a disconnect.
  73. #
  74. SCBARRAY+0    = 0xa0
  75. SCBARRAY+1    = 0xa1
  76. SCBARRAY+2    = 0xa2
  77. SCBARRAY+3    = 0xa3
  78. SCBARRAY+7    = 0xa7
  79. SCBARRAY+11    = 0xab
  80. SCBARRAY+14    = 0xae
  81. SCBARRAY+15    = 0xaf
  82. SCBARRAY+16    = 0xb0
  83. SCBARRAY+17    = 0xb1
  84. SCBARRAY+18    = 0xb2
  85. SCBARRAY+19    = 0xb3
  86. SCBARRAY+20    = 0xb4
  87. SCBARRAY+21    = 0xb5
  88. SCBARRAY+22    = 0xb6
  89. SCBARRAY+23    = 0xb7
  90. SCBARRAY+24    = 0xb8
  91. SCBARRAY+25    = 0xb9
  92.  
  93. SIGNAL_0    = 0x01                # unknown scsi bus phase
  94. SIGNAL_1    = 0x11                # message reject
  95. SIGNAL_2    = 0x21                # no IDENTIFY after reconnect
  96. SIGNAL_3    = 0x31                # no cmd match for reconnect
  97. SIGNAL_4    = 0x41                # SDTR -> SCSIRATE conversion
  98.  
  99. #  The host adapter card (at least the BIOS) uses 20-2f for SCSI
  100. #  device information, 32-33 and 5a-5f as well.  Since we don't support
  101. #  wide or twin-bus SCSI, 28-2f can be reclaimed.  As it turns out, the
  102. #  BIOS trashes 20-27 anyway, writing the synchronous negotiation results
  103. #  on top of the BIOS values, so we re-use those for our per-target
  104. #  scratchspace (actually a value that can be copied directly into
  105. #  SCSIRATE).  This implies, since we can't get the BIOS config values,
  106. #  that all targets will be negotiated with for synchronous transfer.
  107. #  NEEDSDTR has one bit per target indicating if an SDTR message is
  108. #  needed for that device - this will be set initially, as well as
  109. #  after a bus reset condition.
  110. #
  111. #  The high bit of DROPATN is set if ATN should be dropped before the ACK
  112. #  when outb is called.  REJBYTE contains the first byte of a MESSAGE IN
  113. #  message, so the driver can report an intelligible error if a message is
  114. #  rejected.
  115. #
  116. #  RESELECT's high bit is true if we are currently handling a reselect;
  117. #  its next-highest bit is true ONLY IF we've seen an IDENTIFY message
  118. #  from the reselecting target.  If we haven't had IDENTIFY, then we have
  119. #  no idea what the lun is, and we can't select the right SCB register
  120. #  bank, so force a kernel panic if the target attempts a data in/out or
  121. #  command phase instead of corrupting something.
  122. #
  123. #  Note that LAST_SHADDR and SG_NEXT occupy four bytes each.
  124. #
  125. SYNCNEG        = 0x20
  126. DISC_DSB_A    = 0x32
  127.  
  128. DROPATN        = 0x30
  129. REJBYTE        = 0x31
  130. RESELECT    = 0x34
  131.  
  132. MSG_FLAGS    = 0x35
  133. MSG_LEN        = 0x36
  134. MSG_START+0    = 0x37
  135. MSG_START+1    = 0x38
  136. MSG_START+2    = 0x39
  137. MSG_START+3    = 0x3a
  138. MSG_START+4    = 0x3b
  139. MSG_START+5    = 0x3c
  140. -MSG_START+0    = 0xc9                # 2's complement of MSG_START+0
  141.  
  142. ARG_1        = 0x4c                # sdtr conversion args & return
  143. ARG_2        = 0x4d
  144. RETURN_1    = 0x4c
  145.  
  146. SIGSTATE    = 0x4e                # value written to SCSISIGO
  147. NEEDSDTR    = 0x4f                # send SDTR message, 1 bit/trgt
  148. LAST_SHADDR    = 0x50                # value after last dma transfer
  149.  
  150. SG_SIZEOF    = 12                # sizeof(struct scatterlist)
  151. SG_NOLOAD    = 0x54                # load SG pointer/length?
  152. SG_COUNT    = 0x55                # working value of SG count
  153. SG_NEXT        = 0x56                # working value of SG pointer
  154. SG_NEXT+0    = 0x56
  155. SG_NEXT+1    = 0x57
  156. SG_NEXT+2    = 0x58
  157. SG_NEXT+3    = 0x59
  158.  
  159. #  Poll QINCNT for work - the lower three bits contain
  160. #  the number of entries in the Queue In FIFO.
  161. #
  162. start:
  163.     test    SCSISIGI,0x4    jnz reselect    # BSYI
  164.     test    QINCNT,0x7    jz start
  165.  
  166. #  We have at least one queued SCB now.  Set the SCB pointer
  167. #  from the FIFO so we see the right bank of SCB registers,
  168. #  then set SCSI options and set the initiator and target
  169. #  SCSI IDs.
  170. #
  171.     mov    SCBPTR,QINFIFO
  172.     mov    SCBARRAY+1    call initialize
  173.     clr    SG_NOLOAD
  174.     clr    RESELECT
  175.  
  176. #  As soon as we get a successful selection, the target should go
  177. #  into the message out phase since we have ATN asserted.  Prepare
  178. #  the message to send, locking out the device driver.  If the device
  179. #  driver hasn't beaten us with an ABORT or RESET message, then tack
  180. #  on a SDTR negotation if required.
  181. #
  182. #  Messages are stored in scratch RAM starting with a flag byte (high bit
  183. #  set means active message), one length byte, and then the message itself.
  184. #
  185.     mov    SCBARRAY+1    call disconnect    # disconnect ok?
  186.  
  187.     and    SINDEX,0x7,SCBARRAY+1        # lun
  188.     or    SINDEX,A            # return value from disconnect
  189.     or    SINDEX,0x80    call mk_mesg    # IDENTIFY message
  190.  
  191.     mov    A,SINDEX
  192.     cmp    MSG_START+0,A    jne !message    # did driver beat us?
  193.     mvi    MSG_START+1    call mk_sdtr    # build SDTR message if needed
  194.  
  195. !message:
  196.  
  197. #  Enable selection phase as an initiator, and do automatic ATN
  198. #  after the selection.
  199. #
  200.     mvi    SCSISEQ,0x48            # ENSELO|ENAUTOATNO
  201.  
  202. #  Wait for successful arbitration.  The AIC-7770 documentation says
  203. #  that SELINGO indicates successful arbitration, and that it should
  204. #  be used to look for SELDO.  However, if the sequencer is paused at
  205. #  just the right time - a parallel fsck(8) on two drives did it for
  206. #  me - then SELINGO can flip back to false before we've seen it.  This
  207. #  makes the sequencer sit in the arbitration loop forever.  This is
  208. #  Not Good.
  209. #
  210. #  Therefore, I've added a check in the arbitration loop for SELDO
  211. #  too.  This could arguably be made a critical section by disabling
  212. #  pauses, but I don't want to make a potentially infinite loop a CS.
  213. #  I suppose you could fold it into the select loop, too, but since
  214. #  I've been hunting this bug for four days it's kinda like a trophy.
  215. #
  216. arbitrate:
  217.     test    SSTAT0,0x40    jnz *select    # SELDO
  218.     test    SSTAT0,0x10    jz arbitrate    # SELINGO
  219.  
  220. #  Wait for a successful selection.  If the hardware selection
  221. #  timer goes off, then the driver gets the interrupt, so we don't
  222. #  need to worry about it.
  223. #
  224. select:
  225.     test    SSTAT0,0x40    jz select    # SELDO
  226.     jmp    *select
  227.  
  228. #  Reselection is being initiated by a target - we've seen the BSY
  229. #  line driven active, and we didn't do it!  Enable the reselection
  230. #  hardware, and wait for it to finish.  Make a note that we've been
  231. #  reselected, but haven't seen an IDENTIFY message from the target
  232. #  yet.
  233. #
  234. reselect:
  235.     mvi    SCSISEQ,0x10            # ENRSELI
  236.  
  237. reselect1:
  238.     test    SSTAT0,0x20    jz reselect1    # SELDI
  239.     mov    SELID        call initialize
  240.  
  241.     mvi    RESELECT,0x80            # reselected, no IDENTIFY
  242.  
  243. #  After the [re]selection, make sure that the [re]selection enable
  244. #  bit is off.  This chip is flaky enough without extra things
  245. #  turned on.  Also clear the BUSFREE bit in SSTAT1 since we'll be
  246. #  using it shortly.
  247. #
  248. *select:
  249.     clr    SCSISEQ
  250.     mvi    CLRSINT1,0x8            # CLRBUSFREE
  251.  
  252. #  Main loop for information transfer phases.  If BSY is false, then
  253. #  we have a bus free condition, expected or not.  Otherwise, wait
  254. #  for the target to assert REQ before checking MSG, C/D and I/O
  255. #  for the bus phase.
  256. #
  257. #  We can't simply look at the values of SCSISIGI here (if we want
  258. #  to do synchronous data transfer), because the target won't assert
  259. #  REQ if it's already sent us some data that we haven't acknowledged
  260. #  yet.
  261. #
  262. ITloop:
  263.     test    SSTAT1,0x8    jnz p_busfree    # BUSFREE
  264.     test    SSTAT1,0x1    jz ITloop    # REQINIT
  265.  
  266.     and    A,0xe0,SCSISIGI            # CDI|IOI|MSGI
  267.  
  268.     cmp    ALLZEROS,A    je p_dataout
  269.     cmp    A,0x40        je p_datain
  270.     cmp    A,0x80        je p_command
  271.     cmp    A,0xc0        je p_status
  272.     cmp    A,0xa0        je p_mesgout
  273.     cmp    A,0xe0        je p_mesgin
  274.  
  275.     mvi    INTSTAT,SIGNAL_0        # unknown - signal driver
  276.  
  277. p_dataout:
  278.     mvi    0        call scsisig    # !CDO|!IOO|!MSGO
  279.     call    assert
  280.     call    sg_load
  281.  
  282.     mvi    A,3
  283.     mvi    DINDEX,HCNT
  284.     mvi    SCBARRAY+23    call bcopy
  285.  
  286.     mvi    A,3
  287.     mvi    DINDEX,STCNT
  288.     mvi    SCBARRAY+23    call bcopy
  289.  
  290.     mvi    A,4
  291.     mvi    DINDEX,HADDR
  292.     mvi    SCBARRAY+19    call bcopy
  293.  
  294.     mvi    0x3d        call dma    # SCSIEN|SDMAEN|HDMAEN|
  295.                         #   DIRECTION|FIFORESET
  296.  
  297.     call    sg_advance
  298.     mov    SCBARRAY+18,SG_COUNT        # residual S/G count
  299.  
  300.     jmp    ITloop
  301.  
  302. p_datain:
  303.     mvi    0x40        call scsisig    # !CDO|IOO|!MSGO
  304.     call    assert
  305.     call    sg_load
  306.  
  307.     mvi    A,3
  308.     mvi    DINDEX,HCNT
  309.     mvi    SCBARRAY+23    call bcopy
  310.  
  311.     mvi    A,3
  312.     mvi    DINDEX,STCNT
  313.     mvi    SCBARRAY+23    call bcopy
  314.  
  315.     mvi    A,4
  316.     mvi    DINDEX,HADDR
  317.     mvi    SCBARRAY+19    call bcopy
  318.  
  319.     mvi    0x39        call dma    # SCSIEN|SDMAEN|HDMAEN|
  320.                         #   !DIRECTION|FIFORESET
  321.     call    sg_advance
  322.     mov    SCBARRAY+18,SG_COUNT        # residual S/G count
  323.  
  324.     jmp    ITloop
  325.  
  326. #  Command phase.  Set up the DMA registers and let 'er rip - the
  327. #  two bytes after the SCB SCSI_cmd_length are zeroed by the driver,
  328. #  so we can copy those three bytes directly into HCNT.
  329. #
  330. p_command:
  331.     mvi    0x80        call scsisig    # CDO|!IOO|!MSGO
  332.     call    assert
  333.  
  334.     mvi    A,3
  335.     mvi    DINDEX,HCNT
  336.     mvi    SCBARRAY+11    call bcopy
  337.  
  338.     mvi    A,3
  339.     mvi    DINDEX,STCNT
  340.     mvi    SCBARRAY+11    call bcopy
  341.  
  342.     mvi    A,4
  343.     mvi    DINDEX,HADDR
  344.     mvi    SCBARRAY+7    call bcopy
  345.  
  346.     mvi    0x3d        call dma    # SCSIEN|SDMAEN|HDMAEN|
  347.                         #   DIRECTION|FIFORESET
  348.     jmp    ITloop
  349.  
  350. #  Status phase.  Wait for the data byte to appear, then read it
  351. #  and store it into the SCB.
  352. #
  353. p_status:
  354.     mvi    0xc0        call scsisig    # CDO|IOO|!MSGO
  355.  
  356.     mvi    SCBARRAY+14    call inb
  357.     jmp    ITloop
  358.  
  359. #  Message out phase.  If there is no active message, but the target
  360. #  took us into this phase anyway, build a no-op message and send it.
  361. #
  362. p_mesgout:
  363.     mvi    0xa0        call scsisig    # CDO|!IOO|MSGO
  364.     mvi    0x8        call mk_mesg    # build NOP message
  365.  
  366. #  Set up automatic PIO transfer from MSG_START.  Bit 3 in
  367. #  SXFRCTL0 (SPIOEN) is already on.
  368. #
  369.     mvi    SINDEX,MSG_START+0
  370.     mov    DINDEX,MSG_LEN
  371.     clr    A
  372.  
  373. #  When target asks for a byte, drop ATN if it's the last one in
  374. #  the message.  Otherwise, keep going until the message is exhausted.
  375. #  (We can't use outb for this since it wants the input in SINDEX.)
  376. #
  377. p_mesgout2:
  378.     test    SSTAT0,0x2    jz p_mesgout2    # SPIORDY
  379.  
  380.     cmp    DINDEX,1    jne p_mesgout3    # last byte?
  381.     mvi    CLRSINT1,0x40            # CLRATNO - drop ATN
  382.  
  383. #  Write a byte to the SCSI bus.  The AIC-7770 refuses to automatically
  384. #  send ACKs in automatic PIO or DMA mode unless you make sure that the
  385. #  "expected" bus phase in SCSISIGO matches the actual bus phase.  This
  386. #  behaviour is completely undocumented and caused me several days of
  387. #  grief.
  388. #
  389. #  After plugging in different drives to test with and using a longer
  390. #  SCSI cable, I found that I/O in Automatic PIO mode ceased to function,
  391. #  especially when transferring >1 byte.  It seems to be much more stable
  392. #  if STCNT is set to one before the transfer, and SDONE (in SSTAT0) is
  393. #  polled for transfer completion - for both output _and_ input.  The
  394. #  only theory I have is that SPIORDY doesn't drop right away when SCSIDATL
  395. #  is accessed (like the documentation says it does), and that on a longer
  396. #  cable run, the sequencer code was fast enough to loop back and see
  397. #  an SPIORDY that hadn't dropped yet.
  398. #
  399. p_mesgout3:
  400.     call    one_stcnt
  401.     mov    SCSIDATL,SINDIR
  402.  
  403. p_mesgout4:
  404.     test    SSTAT0,0x4    jz p_mesgout4    # SDONE
  405.     dec    DINDEX
  406.     inc    A
  407.     cmp    MSG_LEN,A    jne p_mesgout2
  408.  
  409. #  If the next bus phase after ATN drops is a message out, it means
  410. #  that the target is requesting that the last message(s) be resent.
  411. #
  412. p_mesgout5:
  413.     test    SSTAT1,0x8    jnz p_mesgout6    # BUSFREE
  414.     test    SSTAT1,0x1    jz p_mesgout5    # REQINIT
  415.  
  416.     and    A,0xe0,SCSISIGI            # CDI|IOI|MSGI
  417.     cmp    A,0xa0        jne p_mesgout6
  418.     mvi    0x10        call scsisig    # ATNO - re-assert ATN
  419.  
  420.     jmp    ITloop
  421.  
  422. p_mesgout6:
  423.     clr    MSG_FLAGS            # no active msg
  424.     jmp    ITloop
  425.  
  426. #  Message in phase.  Bytes are read using Automatic PIO mode, but not
  427. #  using inb.  This alleviates a race condition, namely that if ATN had
  428. #  to be asserted under Automatic PIO mode, it had to beat the SCSI
  429. #  circuitry sending an ACK to the target.  This showed up under heavy
  430. #  loads and really confused things, since ABORT commands wouldn't be
  431. #  seen by the drive after an IDENTIFY message in until it had changed
  432. #  to a data I/O phase.
  433. #
  434. p_mesgin:
  435.     mvi    0xe0        call scsisig    # CDO|IOO|MSGO
  436.     mvi    A        call inb_first    # read the 1st message byte
  437.     mvi    REJBYTE,A            # save it for the driver
  438.  
  439.     cmp    ALLZEROS,A    jne p_mesgin1
  440.  
  441. #  We got a "command complete" message, so put the SCB pointer
  442. #  into the Queue Out, and trigger a completion interrupt.
  443. #
  444.     mov    QOUTFIFO,SCBPTR
  445.     mvi    INTSTAT,0x2            # CMDCMPLT
  446.     jmp    p_mesgin_done
  447.  
  448. #  Is it an extended message?  We only support the synchronous data
  449. #  transfer request message, which will probably be in response to
  450. #  an SDTR message out from us.  If it's not an SDTR, reject it -
  451. #  apparently this can be done after any message in byte, according
  452. #  to the SCSI-2 spec.
  453. #
  454. #  XXX - we should really reject this if we didn't initiate the SDTR
  455. #     negotiation; this may cause problems with unusual devices.
  456. #
  457. p_mesgin1:
  458.     cmp    A,1        jne p_mesgin2    # extended message code?
  459.     
  460.     mvi    A        call inb_next
  461.     cmp    A,3        jne p_mesginN    # extended mesg length = 3
  462.     mvi    A        call inb_next
  463.     cmp    A,1        jne p_mesginN    # SDTR code
  464.  
  465.     mvi    ARG_1        call inb_next    # xfer period
  466.     mvi    ARG_2        call inb_next    # REQ/ACK offset
  467.     mvi    INTSTAT,SIGNAL_4        # call driver to convert
  468.  
  469.     call    ndx_sdtr            # index sync config for target
  470.     mov    DINDEX,SINDEX
  471.     mov    DINDIR,RETURN_1            # save returned value
  472.  
  473.     not    A                # turn off "need sdtr" flag
  474.     and    NEEDSDTR,A
  475.  
  476. #  Even though the SCSI-2 specification says that a device responding
  477. #  to our SDTR message should honor our parameters for transmitting
  478. #  to us, it doesn't seem to work too well in real life.  In particular,
  479. #  a lot of CD-ROM and tape units don't function: try using the SDTR
  480. #  parameters the device sent us for both transmitting and receiving.
  481. #
  482.     mov    SCSIRATE,RETURN_1
  483.     jmp    p_mesgin_done
  484.  
  485. #  Is it a disconnect message?  Set a flag in the SCB to remind us
  486. #  and await the bus going free.
  487. #
  488. p_mesgin2:
  489.     cmp    A,4        jne p_mesgin3    # disconnect code?
  490.  
  491.     or    SCBARRAY+0,0x4            # set "disconnected" bit
  492.     jmp    p_mesgin_done
  493.  
  494. #  Save data pointers message?  Use SHADDR and STCNT instead of HADDR
  495. #  and HCNT, since it's a reflection of how many bytes were transferred
  496. #  on the SCSI (as opposed to the host) bus.  Make sure to use the values
  497. #  saved after the last DMA transfer - reading the message in byte changes
  498. #  the values in them.
  499. #
  500. p_mesgin3:
  501.     cmp    A,2        jne p_mesgin4    # save data pointers code?
  502.  
  503.     mvi    A,4
  504.     mvi    DINDEX,SCBARRAY+19
  505.     mvi    LAST_SHADDR    call bcopy
  506.  
  507.     mvi    A,3
  508.     mvi    DINDEX,SCBARRAY+23
  509.     mvi    SCBARRAY+15    call bcopy    # residual data count (stcnt)
  510.  
  511.     call    sg_ram2scb
  512.  
  513.     jmp    p_mesgin_done
  514.  
  515. #  Restore pointers message?  Data pointers are recopied from the
  516. #  SCB anyway at the start of any DMA operation, so the only thing
  517. #  to copy is the scatter-gather values.
  518. #
  519. p_mesgin4:
  520.     cmp    A,3        jne p_mesgin5    # restore pointers code?
  521.  
  522.     call    sg_scb2ram
  523.     jmp    p_mesgin_done
  524.  
  525. #  Identify message?  For a reconnecting target, this tells us the lun
  526. #  that the reconnection is for - find the correct SCB and switch to it,
  527. #  clearing the "disconnected" bit so we don't "find" it by accident later.
  528. #
  529. p_mesgin5:
  530.     test    A,0x80        jz p_mesgin6    # identify message?
  531.  
  532.     test    A,0x78        jnz p_mesginN    # !DiscPriv|!LUNTAR|!Reserved
  533.  
  534.     mov    A        call findSCB    # switch to correct SCB
  535.  
  536. #  If a active message is present after calling findSCB, then either it
  537. #  or the driver is trying to abort the command.  Either way, something
  538. #  untoward has happened and we should just leave it alone.
  539. #
  540.     test    MSG_FLAGS,0x80    jnz p_mesgin_done
  541.  
  542.     xor    SCBARRAY+0,0x4            # clear disconnect bit in SCB
  543.     mvi    RESELECT,0xc0            # make note of IDENTIFY
  544.  
  545.     call    sg_scb2ram            # implied restore pointers
  546.                         #   required on reselect
  547.     jmp    p_mesgin_done
  548.  
  549. #  Message reject?  If we have an outstanding SDTR negotiation, assume
  550. #  that it's a response from the target selecting asynchronous transfer,
  551. #  otherwise just ignore it since we have no clue what it pertains to.
  552. #
  553. #  XXX - I don't have a device that responds this way.  Does this code
  554. #     actually work?
  555. #
  556. p_mesgin6:
  557.     cmp    A,7        jne p_mesgin7    # message reject code?
  558.  
  559.     and    FUNCTION1,0x70,SCSIID        # outstanding SDTR message?
  560.     mov    A,FUNCTION1
  561.     test    NEEDSDTR,A    jz p_mesgin_done  # no - ignore rejection
  562.  
  563.     call    ndx_sdtr            # note use of asynch xfer
  564.     mov    DINDEX,SINDEX
  565.     clr    DINDIR
  566.  
  567.     not    A                # turn off "active sdtr" flag
  568.     and    NEEDSDTR,A
  569.  
  570.     clr    SCSIRATE            # select asynch xfer
  571.     jmp    p_mesgin_done
  572.  
  573. #  [ ADD MORE MESSAGE HANDLING HERE ]
  574. #
  575. p_mesgin7:
  576.  
  577. #  We have no idea what this message in is, and there's no way
  578. #  to pass it up to the kernel, so we issue a message reject and
  579. #  hope for the best.  Since we're now using manual PIO mode to
  580. #  read in the message, there should no longer be a race condition
  581. #  present when we assert ATN.  In any case, rejection should be a
  582. #  rare occurrence - signal the driver when it happens.
  583. #
  584. p_mesginN:
  585.     or    SINDEX,0x10,SIGSTATE        # turn on ATNO
  586.     call    scsisig
  587.     mvi    INTSTAT,SIGNAL_1        # let driver know
  588.  
  589.     mvi    0x7        call mk_mesg    # MESSAGE REJECT message
  590.  
  591. p_mesgin_done:
  592.     call    inb_last            # ack & turn auto PIO back on
  593.     jmp    ITloop
  594.  
  595. #  Bus free phase.  It might be useful to interrupt the device
  596. #  driver if we aren't expecting this.  For now, make sure that
  597. #  ATN isn't being asserted and look for a new command.
  598. #
  599. p_busfree:
  600.     mvi    CLRSINT1,0x40            # CLRATNO
  601.     clr    SIGSTATE
  602.     jmp    start
  603.  
  604. #  Bcopy: number of bytes to transfer should be in A, DINDEX should
  605. #  contain the destination address, and SINDEX should contain the
  606. #  source address.  All input parameters are trashed on return.
  607. #
  608. bcopy:
  609.     mov    DINDIR,SINDIR
  610.     dec    A
  611.     cmp    ALLZEROS,A    jne bcopy
  612.     ret
  613.  
  614. #  Locking the driver out, build a one-byte message passed in SINDEX
  615. #  if there is no active message already.  SINDEX is returned intact.
  616. #
  617. mk_mesg:
  618.     mvi    SEQCTL,0x40            # PAUSEDIS
  619.     test    MSG_FLAGS,0x80    jnz mk_mesg1    # active message?
  620.  
  621.     mvi    MSG_FLAGS,0x80            # if not, there is now
  622.     mvi    MSG_LEN,1            # length = 1
  623.     mov    MSG_START+0,SINDEX        # 1-byte message
  624.  
  625. mk_mesg1:
  626.     clr    SEQCTL                # !PAUSEDIS
  627.     ret
  628.  
  629. #  Input byte in Automatic PIO mode.  The address to store the byte
  630. #  in should be in SINDEX.  DINDEX will be used by this routine.
  631. #
  632. inb:
  633.     test    SSTAT0,0x2    jz inb        # SPIORDY
  634.     mov    DINDEX,SINDEX
  635.     call    one_stcnt            # xfer one byte
  636.     mov    DINDIR,SCSIDATL
  637. inb1:
  638.     test    SSTAT0,0x4    jz inb1        # SDONE - wait to "finish"
  639.     ret
  640.  
  641. #  Carefully read data in Automatic PIO mode.  I first tried this using
  642. #  Manual PIO mode, but it gave me continual underrun errors, probably
  643. #  indicating that I did something wrong, but I feel more secure leaving
  644. #  Automatic PIO on all the time.
  645. #
  646. #  According to Adaptec's documentation, an ACK is not sent on input from
  647. #  the target until SCSIDATL is read from.  So we wait until SCSIDATL is
  648. #  latched (the usual way), then read the data byte directly off the bus
  649. #  using SCSIBUSL.  When we have pulled the ATN line, or we just want to
  650. #  acknowledge the byte, then we do a dummy read from SCISDATL.  The SCSI
  651. #  spec guarantees that the target will hold the data byte on the bus until
  652. #  we send our ACK.
  653. #
  654. #  The assumption here is that these are called in a particular sequence,
  655. #  and that REQ is already set when inb_first is called.  inb_{first,next}
  656. #  use the same calling convention as inb.
  657. #
  658. inb_first:
  659.     mov    DINDEX,SINDEX
  660.     mov    DINDIR,SCSIBUSL    ret        # read byte directly from bus
  661.  
  662. inb_next:
  663.     mov    DINDEX,SINDEX            # save SINDEX
  664.  
  665.     call    one_stcnt            # xfer one byte
  666.     mov    NONE,SCSIDATL            # dummy read from latch to ACK
  667. inb_next1:
  668.     test    SSTAT0,0x4    jz inb_next1    # SDONE
  669. inb_next2:
  670.     test    SSTAT0,0x2    jz inb_next2    # SPIORDY - wait for next byte
  671.     mov    DINDIR,SCSIBUSL    ret        # read byte directly from bus
  672.  
  673. inb_last:
  674.     call    one_stcnt            # ACK with dummy read
  675.     mov    NONE,SCSIDATL
  676. inb_last1:
  677.     test    SSTAT0,0x4    jz inb_last1    # wait for completion
  678.     ret
  679.  
  680. #  Output byte in Automatic PIO mode.  The byte to output should be
  681. #  in SINDEX.  If DROPATN's high bit is set, then ATN will be dropped
  682. #  before the byte is output.
  683. #
  684. outb:
  685.     test    SSTAT0,0x2    jz outb        # SPIORDY
  686.     call    one_stcnt            # xfer one byte
  687.  
  688.     test    DROPATN,0x80    jz outb1
  689.     mvi    CLRSINT1,0x40            # CLRATNO
  690.     clr    DROPATN
  691. outb1:
  692.     mov    SCSIDATL,SINDEX
  693. outb2:
  694.     test    SSTAT0,0x4    jz outb2    # SDONE
  695.     ret
  696.  
  697. #  Write the value "1" into the STCNT registers, for Automatic PIO
  698. #  transfers.
  699. #
  700. one_stcnt:
  701.     clr    STCNT+2
  702.     clr    STCNT+1
  703.     mvi    STCNT+0,1    ret
  704.  
  705. #  DMA data transfer.  HADDR and HCNT must be loaded first, and
  706. #  SINDEX should contain the value to load DFCNTRL with - 0x3d for
  707. #  host->scsi, or 0x39 for scsi->host.  The SCSI channel is cleared
  708. #  during initialization.
  709. #
  710. dma:
  711.     mov    DFCNTRL,SINDEX
  712. dma1:
  713. dma2:
  714.     test    SSTAT0,0x1    jnz dma3    # DMADONE
  715.     test    SSTAT1,0x10    jz dma1        # PHASEMIS, ie. underrun
  716.  
  717. #  We will be "done" DMAing when the transfer count goes to zero, or
  718. #  the target changes the phase (in light of this, it makes sense that
  719. #  the DMA circuitry doesn't ACK when PHASEMIS is active).  If we are
  720. #  doing a SCSI->Host transfer, flush the data FIFO.
  721. #
  722. dma3:
  723.     test    SINDEX,0x4    jnz dma5    # DIRECTION
  724.     and    SINDEX,0xfe            # mask out FIFORESET
  725.     or    DFCNTRL,0x2,SINDEX        # FIFOFLUSH
  726. dma4:
  727.     test    DFCNTRL,0x2    jnz dma4    # FIFOFLUSHACK
  728.  
  729. #  Now shut the DMA enables off, and copy STCNT (ie. the underrun
  730. #  amount, if any) to the SCB registers; SG_COUNT will get copied to
  731. #  the SCB's residual S/G count field after sg_advance is called.  Make
  732. #  sure that the DMA enables are actually off first lest we get an ILLSADDR.
  733. #  Save the value of SHADDR into scratch RAM in case we need to save data
  734. #  pointers.
  735. #
  736. dma5:
  737.     clr    DFCNTRL                # disable DMA
  738. dma6:
  739.     test    DFCNTRL,0x38    jnz dma6    # SCSIENACK|SDMAENACK|HDMAENACK
  740.  
  741.     mvi    A,4
  742.     mvi    DINDEX,LAST_SHADDR
  743.     mvi    SHADDR        call bcopy
  744.  
  745.     mvi    A,3
  746.     mvi    DINDEX,SCBARRAY+15
  747.     mvi    STCNT        call bcopy
  748.  
  749.     ret
  750.  
  751. #  Common SCSI initialization for selection and reselection.  Expects
  752. #  the target SCSI ID to be in the upper four bits of SINDEX, and A's
  753. #  contents are stomped on return.
  754. #
  755. initialize:
  756.     clr    SBLKCTL                # channel A, !wide
  757.     and    SCSIID,0xf0,SINDEX        # target ID
  758.     and    A,0x7,SCSICONF            # SCSI_ID_A[210]
  759.     or    SCSIID,A
  760.  
  761. #  Esundry initialization.
  762. #
  763.     clr    DROPATN
  764.     clr    SIGSTATE
  765.  
  766. #  Turn on Automatic PIO mode now, before we expect to see an REQ
  767. #  from the target.  It shouldn't hurt anything to leave it on.  Set
  768. #  CLRCHN here before the target has entered a data transfer mode -
  769. #  with synchronous SCSI, if you do it later, you blow away some
  770. #  data in the SCSI FIFO that the target has already sent to you.
  771. #
  772.     mvi    SXFRCTL0,0xa            # SPIOEN|CLRCHN
  773.  
  774. #  Set SCSI bus parity checking and the selection timeout value,
  775. #  and enable the hardware selection timer.  Set the SELTO interrupt
  776. #  to signal the driver.
  777. #
  778.     and    A,0x38,SCSICONF            # PARITY_ENB_A|SEL_TIM_A[10]
  779.     or    SXFRCTL1,0x4,A            # ENSTIMER
  780.     mvi    SIMODE1,0x84            # ENSELTIMO|ENSCSIPERR
  781.     
  782. #  Initialize scatter-gather pointers by setting up the working copy
  783. #  in scratch RAM.
  784. #
  785.     call    sg_scb2ram
  786.  
  787. #  Initialize SCSIRATE with the appropriate value for this target.
  788. #
  789.     call    ndx_sdtr
  790.     mov    SCSIRATE,SINDIR
  791.     ret
  792.  
  793. #  Assert that if we've been reselected, then we've seen an IDENTIFY
  794. #  message.
  795. #
  796. assert:
  797.     test    RESELECT,0x80    jz assert1    # reselected?
  798.     test    RESELECT,0x40    jnz assert1    # seen IDENTIFY?
  799.  
  800.     mvi    INTSTAT,SIGNAL_2        # no - cause a kernel panic
  801.  
  802. assert1:
  803.     ret
  804.  
  805. #  Find out if disconnection is ok from the information the BIOS has left
  806. #  us.  The target ID should be in the upper four bits of SINDEX; A will
  807. #  contain either 0x40 (disconnection ok) or 0x00 (diconnection not ok)
  808. #  on exit.
  809. #
  810. #  This is the only place the target ID is limited to three bits, so we
  811. #  can use the FUNCTION1 register.
  812. #
  813. disconnect:
  814.     and    FUNCTION1,0x70,SINDEX        # strip off extra just in case
  815.     mov    A,FUNCTION1
  816.     test    DISC_DSB_A,A    jz disconnect1    # bit nonzero if DISabled
  817.  
  818.     clr    A        ret
  819. disconnect1:
  820.     mvi    A,0x40        ret
  821.  
  822. #  Locate the SCB matching the target ID in SELID and the lun in the lower
  823. #  three bits of SINDEX, and switch the SCB to it.  Have the kernel print
  824. #  a warning message if it can't be found - this seems to happen occasionally
  825. #  under high loads.  Also, if not found, generate an ABORT message to the
  826. #  target.
  827. #
  828. findSCB:
  829.     and    A,0x7,SINDEX            # lun in lower three bits
  830.     or    A,A,SELID            # can I do this?
  831.     and    A,0xf7                # only channel A implemented
  832.  
  833.     clr    SINDEX
  834.  
  835. findSCB1:
  836.     mov    SCBPTR,SINDEX            # switch to new SCB
  837.     cmp    SCBARRAY+1,A    jne findSCB2    # target ID/channel/lun match?
  838.     test    SCBARRAY+0,0x4    jz findSCB2    # should be disconnected
  839.  
  840.     ret
  841.  
  842. findSCB2:
  843.     inc    SINDEX
  844.     cmp    SINDEX,MAXSCB    jne findSCB1
  845.  
  846.     mvi    INTSTAT,SIGNAL_3        # not found - signal kernel
  847.     mvi    0x6        call mk_mesg    # ABORT message
  848.  
  849.     or    SINDEX,0x10,SIGSTATE        # assert ATNO
  850.     call    scsisig
  851.     ret
  852.  
  853. #  Make a working copy of the scatter-gather parameters in the SCB.
  854. #
  855. sg_scb2ram:
  856.     mov    SG_COUNT,SCBARRAY+2
  857.  
  858.     mvi    A,4
  859.     mvi    DINDEX,SG_NEXT
  860.     mvi    SCBARRAY+3    call bcopy
  861.  
  862.     mvi    SG_NOLOAD,0x80
  863.     test    SCBARRAY+0,0x10    jnz sg_scb2ram1    # don't reload s/g?
  864.     clr    SG_NOLOAD
  865.  
  866. sg_scb2ram1:
  867.     ret
  868.  
  869. #  Copying RAM values back to SCB, for Save Data Pointers message.
  870. #
  871. sg_ram2scb:
  872.     mov    SCBARRAY+2,SG_COUNT
  873.  
  874.     mvi    A,4
  875.     mvi    DINDEX,SCBARRAY+3
  876.     mvi    SG_NEXT        call bcopy
  877.  
  878.     and    SCBARRAY+0,0xef,SCBARRAY+0
  879.     test    SG_NOLOAD,0x80    jz sg_ram2scb1    # reload s/g?
  880.     or    SCBARRAY+0,0x10
  881.  
  882. sg_ram2scb1:
  883.     ret
  884.  
  885. #  Load a struct scatter if needed and set up the data address and
  886. #  length.  If the working value of the SG count is nonzero, then
  887. #  we need to load a new set of values.
  888. #
  889. #  This, like the above DMA, assumes a little-endian host data storage.
  890. #
  891. sg_load:
  892.     test    SG_COUNT,0xff    jz sg_load3    # SG being used?
  893.     test    SG_NOLOAD,0x80    jnz sg_load3    # don't reload s/g?
  894.  
  895.     clr    HCNT+2
  896.     clr    HCNT+1
  897.     mvi    HCNT+0,SG_SIZEOF
  898.  
  899.     mvi    A,4
  900.     mvi    DINDEX,HADDR
  901.     mvi    SG_NEXT        call bcopy
  902.  
  903.     mvi    DFCNTRL,0xd            # HDMAEN|DIRECTION|FIFORESET
  904.  
  905. #  Wait for DMA from host memory to data FIFO to complete, then disable
  906. #  DMA and wait for it to acknowledge that it's off.
  907. #
  908. sg_load1:
  909.     test    DFSTATUS,0x8    jz sg_load1    # HDONE
  910.  
  911.     clr    DFCNTRL                # disable DMA
  912. sg_load2:
  913.     test    DFCNTRL,0x8    jnz sg_load2    # HDMAENACK
  914.  
  915. #  Copy data from FIFO into SCB data pointer and data count.  This assumes
  916. #  that the struct scatterlist has this structure (this and sizeof(struct
  917. #  scatterlist) == 12 are asserted in aha274x.c):
  918. #
  919. #    struct scatterlist {
  920. #        char *address;        /* four bytes, little-endian order */
  921. #        ...            /* four bytes, ignored */
  922. #        unsigned short length;    /* two bytes, little-endian order */
  923. #    }
  924. #
  925.     mov    SCBARRAY+19,DFDAT        # new data address
  926.     mov    SCBARRAY+20,DFDAT
  927.     mov    SCBARRAY+21,DFDAT
  928.     mov    SCBARRAY+22,DFDAT
  929.  
  930.     mov    NONE,DFDAT            # throw away four bytes
  931.     mov    NONE,DFDAT
  932.     mov    NONE,DFDAT
  933.     mov    NONE,DFDAT
  934.  
  935.     mov    SCBARRAY+23,DFDAT
  936.     mov    SCBARRAY+24,DFDAT
  937.     clr    SCBARRAY+25
  938.  
  939. sg_load3:
  940.     ret
  941.  
  942. #  Advance the scatter-gather pointers only IF NEEDED.  If SG is enabled,
  943. #  and the SCSI transfer count is zero (note that this should be called
  944. #  right after a DMA finishes), then move the working copies of the SG
  945. #  pointer/length along.  If the SCSI transfer count is not zero, then
  946. #  presumably the target is disconnecting - do not reload the SG values
  947. #  next time.
  948. #
  949. sg_advance:
  950.     test    SG_COUNT,0xff    jz sg_advance2    # s/g enabled?
  951.  
  952.     test    STCNT+0,0xff    jnz sg_advance1    # SCSI transfer count nonzero?
  953.     test    STCNT+1,0xff    jnz sg_advance1
  954.     test    STCNT+2,0xff    jnz sg_advance1
  955.  
  956.     clr    SG_NOLOAD            # reload s/g next time
  957.     dec    SG_COUNT            # one less segment to go
  958.  
  959.     clr    A                # add sizeof(struct scatter)
  960.     add    SG_NEXT+0,SG_SIZEOF,SG_NEXT+0
  961.     adc    SG_NEXT+1,A,SG_NEXT+1
  962.     adc    SG_NEXT+2,A,SG_NEXT+2
  963.     adc    SG_NEXT+3,A,SG_NEXT+3
  964.  
  965.     ret
  966.  
  967. sg_advance1:
  968.     mvi    SG_NOLOAD,0x80            # don't reload s/g next time
  969. sg_advance2:
  970.     ret
  971.  
  972. #  Add the array base SYNCNEG to the target offset (the target address
  973. #  is in SCSIID), and return the result in SINDEX.  The accumulator
  974. #  contains the 3->8 decoding of the target ID on return.
  975. #
  976. ndx_sdtr:
  977.     shr    A,SCSIID,4
  978.     and    A,0x7
  979.     add    SINDEX,SYNCNEG,A
  980.  
  981.     and    FUNCTION1,0x70,SCSIID        # 3-bit target address decode
  982.     mov    A,FUNCTION1    ret
  983.  
  984. #  If we need to negotiate transfer parameters, build the SDTR message
  985. #  starting at the address passed in SINDEX.  DINDEX is modified on return.
  986. #
  987. mk_sdtr:
  988.     mov    DINDEX,SINDEX            # save SINDEX
  989.  
  990.     call    ndx_sdtr
  991.     test    NEEDSDTR,A    jnz mk_sdtr1    # do we need negotiation?
  992.     ret
  993.  
  994. mk_sdtr1:
  995.     mvi    DINDIR,1            # extended message
  996.     mvi    DINDIR,3            # extended message length = 3
  997.     mvi    DINDIR,1            # SDTR code
  998.     mvi    DINDIR,25            # REQ/ACK transfer period
  999.     mvi    DINDIR,15            # REQ/ACK offset
  1000.  
  1001.     add    MSG_LEN,-MSG_START+0,DINDEX    # update message length
  1002.     ret
  1003.  
  1004. #  Set SCSI bus control signal state.  This also saves the last-written
  1005. #  value into a location where the higher-level driver can read it - if
  1006. #  it has to send an ABORT or RESET message, then it needs to know this
  1007. #  so it can assert ATN without upsetting SCSISIGO.  The new value is
  1008. #  expected in SINDEX.  Change the actual state last to avoid contention
  1009. #  from the driver.
  1010. #
  1011. scsisig:
  1012.     mov    SIGSTATE,SINDEX
  1013.     mov    SCSISIGO,SINDEX    ret
  1014.