PC Direct 1995 September/PCD0995.ISO/files/gallery.dir/00001.ls

Text File | 1994-12-18 | 13.3 KB | 348 lines

global demoQTstate, cDemoQT, gSectionPressed, gGalleryList, gFirstGoRound, gProductList, gReturnFromDemo, gProductSelect, gSectionSelect, cAudioLevel, gPauseSprite, gPlaySprite, gStopSprite, gRewindSprite, gFforwardSprite, gDemoButtonSprite, gPictureList, gNumOPics, gCurrentPicture, gFirstProductButton, gLastProductButton, gPictureSprite, gCurrentSection, gLeftFromQT, gMacIDSprite, gWindowsIDSprite, gLaunchQTButton, gMyPath, gPTimerSet, gPresentationTime, gPresentationLight, gYellowSet, gRedSet, gLightColor

on startMovie
  sound stop 1
  sound stop 2
  set gFirstProductButton to 3
  set gLastProductButton to 10
  set gDemoButtonSprite to 11
  set gRewindSprite to 12
  set gFforwardSprite to 13
  set gStopSprite to 14
  set gPauseSprite to 15
  set gPlaySprite to 16
  set gMacIDSprite to 17
  set gWindowsIDSprite to 18
  set cDemoQT to 31
  set gPictureSprite to 34
  set gLaunchQTButton to 37
  set cAudioLevel to 46
  set the preLoadEventAbort to 1
  if gReturnFromDemo = 1 then
    set gReturnFromDemo to 0
    if gLeftFromQT = 1 then
      set the movieRate of sprite cDemoQT to 0
      set the movieTime of sprite cDemoQT to 0
      set demoQTstate to #stop
    else
      puppetSprite(gLaunchQTButton, 1)
      puppetSprite(gPictureSprite, 1)
      set the castNum of sprite gLaunchQTButton to the number of cast "PlayQT"
      set the castNum of sprite gPictureSprite to the number of cast (string(gCurrentSection) & string(gCurrentPicture))
    end if
    puppetSprite(gMacIDSprite, 1)
    puppetSprite(gWindowsIDSprite, 1)
    puppetSprite(gDemoButtonSprite, 1)
    if gProductSelect <> #null then
      set sectionFlags to getProp(gProductList, gProductSelect)
      if getAt(sectionFlags, 1) then
        set the castNum of sprite gMacIDSprite to the number of cast "macID lit"
      else
        set the castNum of sprite gMacIDSprite to the number of cast "macID"
      end if
      if getAt(sectionFlags, 2) then
        set the castNum of sprite gWindowsIDSprite to the number of cast "windowsID lit"
      else
        set the castNum of sprite gWindowsIDSprite to the number of cast "windowsID"
      end if
      if the machineType <> 256 then
        if getAt(sectionFlags, 3) then
          set the castNum of sprite gDemoButtonSprite to the number of cast "GoDemo"
        else
          set the castNum of sprite gDemoButtonSprite to the number of cast "GoDemo lit"
        end if
      else
        if getAt(sectionFlags, 4) then
          set the castNum of sprite gDemoButtonSprite to the number of cast "GoDemo"
        else
          set the castNum of sprite gDemoButtonSprite to the number of cast "GoDemo lit"
        end if
      end if
      puppetSprite(gSectionPressed, 1)
      puppetSprite(gDemoButtonSprite, 1)
      set the castNum of sprite gDemoButtonSprite to the number of cast "GoDemo"
      set whichCast to string(gSectionSelect)
      set the castNum of sprite gSectionPressed to the number of cast (whichCast && "lit")
    end if
  end if
  if gPTimerSet then
    puppetSprite(gPresentationLight, 1)
    set the castNum of sprite gPresentationLight to the number of cast gLightColor
    updateStage()
  end if
end

on initGallery
  global soundLevel, gProductSelect, gSectionSelect, gProductPressed, gSectionPressed, gReturnFromDemo, cDemoQT, demoQTstate, gGalleryList, gProductList
  set gFirstGoRound to 0
  set gProductSelect to #null
  set gSectionSelect to EMPTY
  set gProductPressed to 0
  set gSectionPressed to 0
  set demoQTstate to #stop
  set gGalleryList to [#presentations: [#jobseek, #longevity, #sancwoods], #sales: [#virtualdrive, #intershop, #elliott, #cmddemo], #courseware: [#nasa, #connect, #lite], #consumer: [#startrek, #helix, #strad, #keroppi], #kiosks: [#telefono, #napa], #graphics: [#dreamlight, #freakshow, #medicine], #custom: [#imps, #mediaband], #macromedia: [#macromedia]]
  set gProductList to [#jobseek: [1, 1, 1, 1], #longevity: [1, 1, 0, 0], #sancwoods: [1, 1, 1, 1], #virtualdrive: [1, 1, 0, 0], #intershop: [1, 1, 0, 0], #elliott: [1, 1, 1, 1], #cmddemo: [1, 1, 0, 0], #nasa: [1, 1, 0, 0], #connect: [1, 1, 0, 0], #lite: [1, 1, 0, 0], #startrek: [1, 1, 0, 0], #helix: [1, 1, 0, 0], #strad: [1, 1, 0, 0], #keroppi: [1, 1, 1, 1], #telefono: [1, 1, 1, 1], #napa: [1, 0, 0, 0], #dreamlight: [1, 1, 0, 0], #freakshow: [1, 1, 0, 0], #medicine: [1, 1, 0, 0], #imps: [1, 1, 1, 0], #mediaband: [1, 1, 1, 1]]
  set gPictureList to [#presentations: 4, #sales: 5, #courseware: 4, #consumer: 5, #kiosks: 3, #graphics: 4, #custom: 3, #macromedia: 1]
end

on playGalleryDemo whichOne
  set gReturnFromDemo to 1
  if whichOne = #sancwoods then
    if the machineType = 256 then
      play movie gMyPath & "DEMOS\SANCWOOD\SANCWOOD.DIR"
    else
      play movie gMyPath & "DEMOS:SANCWOOD:SANCWOOD.DIR"
    end if
    exit
  end if
  if whichOne = #jobseek then
    if the machineType = 256 then
      play movie gMyPath & "DEMOS\JOBSWIN\JOBSEEK.DIR"
    else
      play movie gMyPath & "DEMOS:JOBSEEK:JOBSEEK.DIR"
    end if
    exit
  end if
  if whichOne = #elliott then
    if the machineType = 256 then
      play movie gMyPath & "DEMOS\ELLIOTTD\ELLIOTTD.DIR"
    else
      play movie gMyPath & "DEMOS:ELLIOTTD:ELLIOTTD.DIR"
    end if
    exit
  end if
  if whichOne = #keroppi then
    if the machineType = 256 then
      play movie gMyPath & "DEMOS\KEROPPIW\KP_INTRO.DIR"
    else
      play movie gMyPath & "DEMOS:KEROPPI:KP_INTRO.DIR"
    end if
    exit
  end if
  if whichOne = #telefono then
    if the machineType = 256 then
      play movie gMyPath & "DEMOS\ELTELDEM\ETDEMO.DIR"
    else
      play movie gMyPath & "DEMOS:ELTELDEM:ETDEMO.DIR"
    end if
    exit
  end if
  if whichOne = #imps then
    if the machineType = 256 then
      play movie gMyPath & "DEMOS\WOODSTOK\WOODSTOK"
    else
      play movie gMyPath & "DEMOS:WOODSTOK:WOODSTOK"
    end if
    exit
  end if
  if whichOne = #mediaband then
    if the machineType = 256 then
      play movie gMyPath & "DEMOS\MEDIABAN\HOUSEJAM"
    else
      play movie gMyPath & "DEMOS:MEDIABAN:HOUSEJAM"
    end if
    exit
  end if
end

on galleryQTplay
  set WhichSprite to the clickOn
  puppetSprite(WhichSprite, 1)
  set the castNum of sprite gPlaySprite to the number of cast "playGallery lit"
  set the movieRate of sprite cDemoQT to 1
  set demoQTstate to #play
  set the castNum of sprite gStopSprite to the number of cast "stopGallery"
  set the castNum of sprite gPauseSprite to the number of cast "pauseGallery"
  updateStage()
end

on galleryQTpause
  set WhichSprite to the clickOn
  puppetSprite(WhichSprite, 1)
  set the castNum of sprite gPauseSprite to the number of cast "pauseGallery lit"
  if demoQTstate = #play then
    set the movieRate of sprite cDemoQT to 0
    set demoQTstate to #pause
    set the castNum of sprite gPlaySprite to the number of cast "playGallery"
    updateStage()
  else
    if demoQTstate = #pause then
      set the movieRate of sprite cDemoQT to 1
      set demoQTstate to #play
      set the castNum of sprite gPauseSprite to the number of cast "pauseGallery"
      set the castNum of sprite gPlaySprite to the number of cast "playGallery lit"
      updateStage()
    end if
  end if
end

on galleryQTstop
  set WhichSprite to the clickOn
  puppetSprite(WhichSprite, 1)
  set the movieTime of sprite cDemoQT to 0
  set the movieRate of sprite cDemoQT to 0
  returnToSection()
  set the castNum of sprite gStopSprite to the number of cast "stopGallery"
  set the castNum of sprite gPauseSprite to the number of cast "pauseGallery"
  set the castNum of sprite gPlaySprite to the number of cast "playGallery"
  updateStage()
end

on galleryQTfforward
  set WhichSprite to the clickOn
  puppetSprite(WhichSprite, 1)
  set the castNum of sprite gFforwardSprite to the number of cast "fforwardGallery lit"
  set the movieRate of sprite cDemoQT to 2
  repeat while the stillDown
    updateStage()
  end repeat
  if the movieTime of sprite cDemoQT = the stopTime of sprite cDemoQT then
    set the movieTime of sprite cDemoQT to 0
    set the movieRate of sprite cDemoQT to 0
    returnToSection()
    exit
  end if
  if (demoQTstate = #pause) or (demoQTstate = #stop) then
    set the movieRate of sprite cDemoQT to 0
  else
    set the movieRate of sprite cDemoQT to 1
  end if
end

on galleryQTrewind
  set WhichSprite to the clickOn
  puppetSprite(WhichSprite, 1)
  set the castNum of sprite gRewindSprite to the number of cast "rewindGallery lit"
  set the movieRate of sprite cDemoQT to -2
  repeat while the stillDown
    updateStage()
  end repeat
  if (demoQTstate = #pause) or (demoQTstate = #stop) then
    set the movieRate of sprite cDemoQT to 0
  else
    set the movieRate of sprite cDemoQT to 1
  end if
  exit
end

on resetVideoButt
  set the castNum of sprite gPlaySprite to the number of cast "playGallery"
  set the castNum of sprite gStopSprite to the number of cast "stopGallery"
  set the castNum of sprite gPauseSprite to the number of cast "pauseGallery"
  set the castNum of sprite gFforwardSprite to the number of cast "fforwardGallery"
  set the castNum of sprite gRewindSprite to the number of cast "rewindGallery"
end

on gallerySelect whichSection
  global gProductPressed, gSectionPressed, gProductSelect, gSectionSelect, gReturnFromDemo, gCompColor, gGalleryList, cDemoQT, gMacIDSprite, gWindowsIDSprite, gDemoButtonSprite
  puppetSound("click")
  set gProductSelect to #null
  puppetSprite(cDemoQT, 0)
  resetVideoButt()
  set WhichSprite to the clickOn
  puppetSprite(WhichSprite, 1)
  set whichCast to the name of cast the castNum of sprite WhichSprite
  set gSectionPressed to WhichSprite
  set gSectionSelect to whichSection
  set the castNum of sprite WhichSprite to the number of cast (whichCast && "lit")
  repeat with x = gFirstProductButton to gLastProductButton
    if x <> gSectionPressed then
      puppetSprite(x, 0)
    end if
  end repeat
  set the castNum of sprite gMacIDSprite to the number of cast "macID"
  set the castNum of sprite gWindowsIDSprite to the number of cast "windowsID"
  set the castNum of sprite gDemoButtonSprite to the number of cast "GoDemo lit"
  updateStage()
  go(string(getPropAt(gGalleryList, WhichSprite - 2)))
  set gNumOPics to getProp(gPictureList, whichSection)
  set gCurrentSection to whichSection
  set gCurrentPicture to 1
end

on returnToSection
  global gProductPressed, gSectionPressed, gProductSelect, gSectionSelect, gGalleryList, cDemoQT
  puppetSprite(cDemoQT, 0)
  repeat with n = gStopSprite to gPlaySprite
    set offcast to word 1 of the name of cast the castNum of sprite n
    set the castNum of sprite n to the number of cast offcast
  end repeat
  go(string(getPropAt(gGalleryList, gSectionPressed - 2)))
end

on galleryProductSelect whichSection
  global gProductPressed, gSectionPressed, gProductSelect, gSectionSelect, gReturnFromDemo, gCompColor, gGalleryList
  if whichSection = #null then
    set the castNum of sprite gMacIDSprite to the number of cast "macID"
    set the castNum of sprite gMacIDSprite to the number of cast "windowsID"
    exit
  else
    if the machineType <> 256 then
      puppetSound("click")
    end if
    puppetSprite(gPlaySprite, 1)
    puppetSprite(gLaunchQTButton, 0)
    set the castNum of sprite gPlaySprite to the number of cast "playGallery lit"
    set WhichSprite to the clickOn
    set whichCast to the name of cast the castNum of sprite WhichSprite
    set gProductPressed to WhichSprite
    set gProductSelect to whichSection
    go(string(whichSection))
    set sectionFlags to getProp(gProductList, gProductSelect)
    if getAt(sectionFlags, 1) then
      set the castNum of sprite gMacIDSprite to the number of cast "macID lit"
    end if
    if getAt(sectionFlags, 2) then
      set the castNum of sprite gWindowsIDSprite to the number of cast "windowsID lit"
    end if
    if (the machineType <> 256) and getAt(sectionFlags, 3) then
      set the castNum of sprite gDemoButtonSprite to the number of cast "GoDemo"
    end if
    if (the machineType = 256) and getAt(sectionFlags, 4) then
      set the castNum of sprite gDemoButtonSprite to the number of cast "GoDemo"
    end if
    updateStage()
    galleryQTstart()
  end if
end

on galleryQTstart
  global demoQTstate, cDemoQT, gSoundlevel
  set the movieRate of sprite cDemoQT to 1
  set the volume of sprite cDemoQT to 256
  set demoQTstate to #play
  updateStage()
end

on memoryman1
  preLoadCast(the number of cast "Gallery blur", the number of cast "QuickDraw Box")
end

on mrUnloader1
  put "Before unloading: The freebytes =" && string(the freeBytes) && "and the FreeBlock =" && string(the freeBlock)
  unLoadCast(the number of cast "up tooth.pict", the number of cast "Gallery blur")
  put "After unloading the freebytes =" && the freeBytes && "and the FreeBlock =" && the freeBlock
end

on mrUnLoader2
  unLoadCast(the number of cast "Binder Snap", the number of cast "Startup Loop 2.AIFF")
  unLoadCast(the number of cast "PowerUp1", the number of cast "PowerUp12")
  unLoadCast(the number of cast "GALLERY pic", the number of cast "RightHand 3")
end

on enterFrame
  if gPTimerSet then
    if (the timer > (gPresentationTime * 3600)) and not gRedSet then
      set gLightColor to "Red timer light lit"
      set the castNum of sprite gPresentationLight to the number of cast gLightColor
      set gRedSet to 1
      exit
    end if
    if (the timer > ((gPresentationTime * 3600) - 7200)) and not gYellowSet then
      set gLightColor to "Yellow timer light lit"
      set the castNum of sprite gPresentationLight to the number of cast gLightColor
      set gYellowSet to 1
    end if
  end if
end