home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: Graphics / Graphics.zip / DKBOS2.ZOO / dkb212dt.zoo / tomb.dat < prev    next >
Text File  |  1991-04-23  |  18KB  |  740 lines
  1.  
  2. { Title-"Tomb" }
  3.  
  4. { -+ Compuserve Hall Of Fame award winner +- }
  5.  
  6. { A haunted tomb on a hill, gravestones, rusty fence, pumpkin patch. }
  7. { - Drew Wells CIS 73767,1244 }
  8. { 11/29/90 }
  9.  
  10.  
  11. { This file is for use with DKBTrace by David Buck
  12.   and is released into the public domain. }
  13.  
  14. INCLUDE "shapes.dat"
  15. INCLUDE "colors.dat"
  16. INCLUDE "textures.dat"
  17.  
  18.  
  19. { Camera }
  20. VIEW_POINT
  21.    DIRECTION <0.0 0.0  1.5>
  22.    UP  <0.0  1.0  0.0>
  23.    RIGHT <-1.333 0.0 0.0>
  24.    TRANSLATE < -15.0  5.0  120.0>
  25.    LOOK_AT <10.0 12.0 55.0>
  26. END_VIEW_POINT
  27.  
  28. DECLARE Yellow_Clouds = TEXTURE
  29.       0.05
  30.        BOZO
  31.        TURBULENCE 0.6
  32.        COLOUR_MAP
  33.           [0.0 0.5   COLOUR RED 0.9 GREEN 0.5  BLUE 0.3
  34.                      COLOUR RED 0.4 GREEN 0.4  BLUE 0.0]  
  35.           [0.5 0.6   COLOUR RED 1.0 GREEN 1.0  BLUE 1.0 ALPHA 1.0
  36.                      COLOUR RED 1.0 GREEN 1.0  BLUE 1.0 ALPHA 1.0 ]
  37.           [0.6 1.001 COLOUR RED 1.0 GREEN 1.0  BLUE 1.0 ALPHA 1.0
  38.                      COLOUR RED 1.0 GREEN 1.0  BLUE 1.0 ALPHA 1.0]
  39.        END_COLOUR_MAP
  40. END_TEXTURE
  41.  
  42. DECLARE Sunset_Sky = TEXTURE
  43.       0.05
  44.        GRADIENT <0.0 1.0 0.0>
  45.        
  46.        COLOUR_MAP
  47.           [0.0 0.4  {blue}
  48.                     COLOUR RED 0.8 GREEN 0.0 BLUE 0.0
  49.                     COLOUR RED 0.4 GREEN 0.0 BLUE 0.4]
  50.           
  51.           [0.4 0.6  COLOUR RED 0.4 GREEN 0.0 BLUE 0.4
  52.                     {white}
  53.                     COLOUR RED 0.0 GREEN 0.0 BLUE 0.2]
  54.           [0.6 1.001 COLOUR RED 0.0 GREEN 0.0 BLUE 0.2
  55.                     {grey}
  56.                     COLOUR RED 0.0 GREEN 0.0 BLUE 0.0]
  57.        END_COLOUR_MAP
  58.        SCALE <700.0 700.0 700.0>
  59. END_TEXTURE
  60.  
  61. DECLARE Moss = TEXTURE
  62.     MARBLE
  63.     TURBULENCE 0.62
  64.     COLOUR_MAP
  65.    [0.0 0.5  COLOUR RED 0.7 GREEN 0.7 BLUE 0.45
  66.     COLOUR RED 0.7 GREEN 0.65 BLUE 0.35]
  67.    [0.5 0.55 COLOUR RED 0.55 GREEN 0.7 BLUE 0.45
  68.     COLOUR RED 0.45 GREEN 0.60 BLUE 0.35]
  69.    [0.55 0.6 COLOUR RED 0.0 GREEN 0.50 BLUE 0.20
  70.     COLOUR RED 0.5 GREEN 0.6 BLUE 0.35]
  71.    [0.6 0.7  COLOUR RED 0.5 GREEN 0.6 BLUE 0.35
  72.     COLOUR RED 0.05 GREEN 0.35 BLUE 0.05]
  73.    [0.7 0.8  COLOUR RED 0.05 GREEN 0.35 BLUE 0.05
  74.     COLOUR RED 0.20 GREEN 0.30 BLUE 0.0]
  75.    [0.8 0.9  COLOUR RED 0.20 GREEN 0.30 BLUE 0.0
  76.     COLOUR RED 0.20 GREEN 0.50 BLUE 0.0]
  77.    [0.9 1.001  COLOUR RED 0.20 GREEN 0.50 BLUE 0.00
  78.     COLOUR RED 0.20 GREEN 0.30 BLUE 0.0]
  79.     END_COLOUR_MAP
  80.     SCALE <1.7 1.7 1.7>
  81. END_TEXTURE
  82.  
  83.  
  84. {***********************************************}
  85. { Define objects for use in scene               }
  86. {***********************************************}
  87.  
  88. DECLARE Cross =
  89.   OBJECT
  90.     UNION
  91.     { Tried to make celtic cross, but vga resolution is too coarse }
  92.     { INTERSECTION
  93.      QUADRIC Cylinder_Z
  94.         SCALE <0.4 0.4 0.4>
  95.         TRANSLATE <0.0 0.45 0.0>
  96.      END_QUADRIC
  97.      PLANE <0.0 0.0 -1.0>  0.02 END_PLANE
  98.      PLANE <0.0  0.0 1.0> 0.02 END_PLANE
  99.      END_INTERSECTION }
  100.  
  101.      {vertical part}
  102.      INTERSECTION
  103.       {top & bottom}
  104.       PLANE <0.0 1.0 0.0> 1.0 END_PLANE
  105.       PLANE <0.0 -1.0 0.0> 2.0 END_PLANE
  106.       {front & back}
  107.       PLANE <0.0 0.0 1.0> 0.12 END_PLANE
  108.       PLANE <0.0 0.0 -1.0> 0.12 END_PLANE
  109.       {left & right}
  110.       PLANE <1.0 0.0 0.0> 0.15 END_PLANE
  111.       PLANE <-1.0 0.0 0.0> 0.15 END_PLANE
  112.      END_INTERSECTION
  113.  
  114.      {horizontal part}
  115.      INTERSECTION
  116.       {top & bottom}
  117.       PLANE <0.0 1.0 0.0> 0.6 END_PLANE
  118.       PLANE <0.0 -1.0 0.0> -0.3 END_PLANE
  119.       {front & back}
  120.       PLANE <0.0 0.0 1.0> 0.12 END_PLANE
  121.       PLANE <0.0 0.0 -1.0> 0.12 END_PLANE
  122.       {left & right walls}
  123.       PLANE <1.0 0.0 0.0> 0.7 END_PLANE
  124.       PLANE <-1.0 0.0 0.0> 0.7 END_PLANE
  125.      END_INTERSECTION
  126.     END_UNION
  127.     BOUNDED_BY
  128.      INTERSECTION
  129.       PLANE <0.0 1.0 0.0> 1.1 END_PLANE
  130.       PLANE <0.0 -1.0 0.0> 2.1 END_PLANE
  131.       PLANE <0.0 0.0 1.0> 0.2 END_PLANE
  132.       PLANE <0.0 0.0 -1.0> 0.2 END_PLANE
  133.       PLANE <1.0 0.0 0.0> 0.8 END_PLANE
  134.       PLANE <-1.0 0.0 0.0> 0.8 END_PLANE
  135.      END_INTERSECTION
  136.     END_BOUND
  137.     TEXTURE
  138.       GRANITE
  139.       SCALE <0.1 0.1 0.1>
  140.       AMBIENT 0.1
  141.       DIFFUSE 0.9   
  142.     END_TEXTURE
  143.     COLOUR Blue
  144. END_OBJECT
  145.  
  146. DECLARE Headstone =
  147.   OBJECT
  148.     UNION
  149.      INTERSECTION      
  150.        QUADRIC Cylinder_Z END_QUADRIC
  151.        PLANE <0.0 0.0 -1.0>  0.1 END_PLANE
  152.        PLANE <0.0  0.0 1.0> 0.1 END_PLANE
  153.      END_INTERSECTION      
  154.      INTERSECTION
  155.        {top & bottom} 
  156.        PLANE <0.0 1.0 0.0> 0.0 END_PLANE
  157.        PLANE <0.0 -1.0 0.0> 2.0 END_PLANE
  158.        {front & back}
  159.        PLANE <0.0 0.0 1.0> 0.1 END_PLANE
  160.        PLANE <0.0 0.0 -1.0> 0.1 END_PLANE
  161.        {left & right }
  162.        PLANE <1.0 0.0 0.0> 1.0 END_PLANE
  163.        PLANE <-1.0 0.0 0.0> 1.0 END_PLANE
  164.      END_INTERSECTION
  165.     END_UNION
  166.     TEXTURE 
  167.       GRANITE 
  168.       SCALE<0.1 0.2 0.1>
  169.       AMBIENT 0.1
  170.       DIFFUSE 0.9   
  171.     END_TEXTURE
  172.    COLOUR Blue
  173. END_OBJECT
  174.  
  175. DECLARE Beam = QUADRIC Cylinder_Y
  176.     SCALE <1.0 1.0 1.0>
  177. END_QUADRIC
  178.  
  179. DECLARE Beam2 = QUADRIC Cylinder_Y
  180.      INVERSE
  181.      SCALE <0.5 1.0 0.5>
  182.     TRANSLATE <1.4 0.0 0.0>
  183. END_QUADRIC
  184.  
  185. DECLARE Beam3 =
  186.   OBJECT
  187.    INTERSECTION
  188.      QUADRIC Beam  SCALE <1.2 1.0 1.2> END_QUADRIC
  189.      QUADRIC Beam2 END_QUADRIC
  190.      QUADRIC Beam2 ROTATE <0.0  -45.0 0.0> END_QUADRIC
  191.      QUADRIC Beam2 ROTATE <0.0  -90.0 0.0> END_QUADRIC
  192.      QUADRIC Beam2 ROTATE <0.0 -135.0 0.0> END_QUADRIC
  193.      QUADRIC Beam2 ROTATE <0.0  180.0 0.0> END_QUADRIC
  194.      QUADRIC Beam2 ROTATE <0.0   45.0 0.0> END_QUADRIC
  195.      QUADRIC Beam2 ROTATE <0.0   90.0 0.0> END_QUADRIC
  196.      QUADRIC Beam2 ROTATE <0.0  135.0 0.0> END_QUADRIC
  197.      PLANE <0.0 1.0 0.0> 8.0 END_PLANE
  198.      PLANE <0.0 -1.0 0.0> 0.0 END_PLANE
  199.    END_INTERSECTION
  200.    { Blue marble was modified to look like green moss/mold }
  201.    TEXTURE
  202.      Moss
  203.      AMBIENT 0.1
  204.      DIFFUSE 0.99
  205.    END_TEXTURE
  206.    COLOUR RED 0.8 GREEN 0.0 BLUE 0.0
  207. END_OBJECT
  208.  
  209. DECLARE Pole = QUADRIC Cylinder_Y
  210.    SCALE <0.1 1.0 0.1>
  211. END_QUADRIC
  212.  
  213.      
  214. DECLARE Xpole = QUADRIC Cylinder_X
  215.    SCALE <0.1 0.1 0.1>
  216. END_QUADRIC
  217.  
  218. { Rusty iron gate & fence - object should have been composite to avoid the }
  219. {                           "carved from one piece" look. }
  220. DECLARE Gate = OBJECT
  221.   UNION
  222.    INTERSECTION
  223.      QUADRIC Xpole  END_QUADRIC
  224.      PLANE <1.0 0.0 0.0> 8.0 END_PLANE
  225.      PLANE <-1.0 0.0 0.0> 2.0 END_PLANE
  226.      TRANSLATE <0.0 6.5 0.0>
  227.    END_INTERSECTION
  228.    INTERSECTION
  229.      QUADRIC Xpole  END_QUADRIC
  230.      PLANE <1.0 0.0 0.0> 8.0 END_PLANE
  231.      PLANE <-1.0 0.0 0.0> 2.0 END_PLANE
  232.      TRANSLATE <0.0 1.9 0.0>
  233.    END_INTERSECTION
  234.    INTERSECTION
  235.      QUADRIC Pole  END_QUADRIC
  236.      PLANE <0.0 1.0 0.0> 7.5 END_PLANE
  237.      PLANE <0.0 -1.0 0.0> 0.0 END_PLANE
  238.      TRANSLATE <1.0 0.0 0.2>
  239.    END_INTERSECTION
  240.    SPHERE <1.0 7.5 0.0> 0.3 END_SPHERE
  241.    INTERSECTION
  242.      QUADRIC Pole END_QUADRIC
  243.      PLANE <0.0 1.0 0.0> 7.75 END_PLANE
  244.      PLANE <0.0 -1.0 0.0> 0.2 END_PLANE
  245.      TRANSLATE <2.5 0.0 0.0>
  246.    END_INTERSECTION
  247.    SPHERE <2.5 7.75 0.0> 0.3 END_SPHERE
  248.    INTERSECTION
  249.      QUADRIC Pole END_QUADRIC
  250.      PLANE <0.0 1.0 0.0> 8.0 END_PLANE
  251.      PLANE <0.0 -1.0 0.0> 0.2 END_PLANE
  252.      TRANSLATE <4.0 0.0 0.0>
  253.    END_INTERSECTION
  254.    SPHERE <4.0 8.0 0.0> 0.3 END_SPHERE
  255.    INTERSECTION
  256.      QUADRIC Pole  END_QUADRIC
  257.      PLANE <0.0 1.0 0.0> 7.75 END_PLANE
  258.      PLANE <0.0 -1.0 0.0> 0.2 END_PLANE
  259.      TRANSLATE<5.5 0.0 0.0>
  260.    END_INTERSECTION
  261.    SPHERE <5.5 7.75 0.0> 0.3 END_SPHERE
  262.    INTERSECTION
  263.      QUADRIC Pole END_QUADRIC
  264.      PLANE <0.0 1.0 0.0> 7.5 END_PLANE
  265.      PLANE <0.0 -1.0 0.0> 0.2 END_PLANE
  266.      TRANSLATE <7.0 0.0 0.0>
  267.    END_INTERSECTION
  268.    SPHERE <7.0 7.5 0.0> 0.3 END_SPHERE
  269.   END_UNION
  270.   BOUNDED_BY
  271.    INTERSECTION
  272.       PLANE <0.0 1.0 0.0> 9.0 END_PLANE
  273.       PLANE <0.0 -1.0 0.0> 0.0 END_PLANE
  274.       PLANE <0.0 0.0 1.0> 1.0 END_PLANE
  275.       PLANE <0.0 0.0 -1.0> 1.0 END_PLANE
  276.       PLANE <1.0 0.0 0.0> 8.0 END_PLANE
  277.       PLANE <-1.0 0.0 0.0> 0.0 END_PLANE
  278.    END_INTERSECTION
  279.   END_BOUND
  280.   TEXTURE 
  281.     0.05
  282.     Iron 
  283.     AMBIENT 0.4
  284.     DIFFUSE 0.99   
  285.   END_TEXTURE 
  286.   COLOUR Blue
  287. END_OBJECT
  288.  
  289. { A rectangular pad to serve as a footing for the column }
  290. DECLARE BasePad =
  291.    OBJECT
  292.    INTERSECTION
  293.       PLANE <0.0 1.0 0.0> 0.25 END_PLANE
  294.       PLANE <0.0 -1.0 0.0> 0.25 END_PLANE
  295.       PLANE <0.0 0.0 1.0> 1.2 END_PLANE
  296.       PLANE <0.0 0.0 -1.0> 1.2 END_PLANE
  297.       PLANE <1.0 0.0 0.0> 1.2 END_PLANE
  298.       PLANE <-1.0 0.0 0.0> 1.2 END_PLANE
  299.    END_INTERSECTION
  300.  
  301.    TEXTURE
  302.      Moss
  303.      SCALE <0.8 0.3 1.0>
  304.      AMBIENT 0.1
  305.      DIFFUSE 0.9
  306.    END_TEXTURE
  307.    COLOUR RED 0.6 GREEN 0.6 BLUE 0.4
  308. END_OBJECT
  309.  
  310. DECLARE Column = COMPOSITE
  311.    OBJECT Beam3   TRANSLATE <0.0 0.0 0.0> END_OBJECT
  312.    OBJECT BasePad TRANSLATE <0.0 1.0 0.0> END_OBJECT
  313.    OBJECT BasePad TRANSLATE <0.0 8.0 0.0> END_OBJECT
  314. END_COMPOSITE
  315.  
  316. DECLARE Tomb = OBJECT
  317.   UNION
  318.    { Main structure }
  319.    INTERSECTION
  320.       {ceiling and floor}
  321.       PLANE <0.0 1.0 0.0> 10.0 END_PLANE
  322.       PLANE <0.0 -1.0 0.0> 6.0 END_PLANE
  323.       {front and back walls}
  324.       PLANE <0.0 0.0 1.0> 7.5 END_PLANE
  325.       PLANE <0.0 0.0 -1.0> 7.5 END_PLANE
  326.       {left & right walls}
  327.       PLANE <1.0 0.0 0.0> 10.0 END_PLANE
  328.       PLANE <-1.0 0.0 0.0> 10.0 END_PLANE
  329.       {doorway}
  330.       INTERSECTION
  331.         {ceiling and floor} 
  332.         PLANE <0.0 1.0 0.0> 7.0 END_PLANE
  333.         PLANE <0.0 -1.0 0.0> 6.0 END_PLANE
  334.         {front and back walls}
  335.         PLANE <0.0 0.0 1.0> 17.5 END_PLANE
  336.         PLANE <0.0 0.0 -1.0> 7.0 END_PLANE
  337.         {left & right walls}
  338.         PLANE <1.0 0.0 0.0> 3.0 END_PLANE
  339.         PLANE <-1.0 0.0 0.0> 3.0 END_PLANE
  340.         INVERSE 
  341.       END_INTERSECTION
  342.    END_INTERSECTION
  343.    { Foundation }
  344.    INTERSECTION
  345.       {top & bottom}
  346.       PLANE <0.0 1.0 0.0> -1.0 END_PLANE
  347.       PLANE <0.0 -1.0 0.0> 5.0 END_PLANE
  348.       {front & back}
  349.       PLANE <0.0 0.0 1.0> 8.5 END_PLANE
  350.       PLANE <0.0 0.0 -1.0> 8.5 END_PLANE
  351.       {left & right}
  352.       PLANE <1.0 0.0 0.0> 11.0 END_PLANE
  353.       PLANE <-1.0 0.0 0.0> 11.0 END_PLANE
  354.    END_INTERSECTION
  355.   END_UNION
  356.   BOUNDED_BY
  357.    SPHERE <0.0 0.0 0.0> 18.0 END_SPHERE
  358.   END_BOUND
  359.   TEXTURE
  360.        GRANITE
  361.        BUMPS 0.8
  362.        SCALE < 0.5 0.1 1.0>
  363.        AMBIENT 0.1
  364.        DIFFUSE 0.9
  365.   END_TEXTURE
  366.   COLOUR Blue
  367. END_OBJECT
  368.  
  369. DECLARE InnerBeams = OBJECT
  370.    UNION
  371.     INTERSECTION
  372.      QUADRIC Beam END_QUADRIC
  373.      PLANE <0.0 1.0 0.0> 8.0 END_PLANE
  374.      PLANE <0.0 -1.0 0.0> 2.0 END_PLANE
  375.      TRANSLATE < 5.0 0.0 7.5>
  376.     END_INTERSECTION
  377.     INTERSECTION
  378.      QUADRIC Beam END_QUADRIC
  379.      PLANE <0.0 1.0 0.0> 8.0 END_PLANE
  380.      PLANE <0.0 -1.0 0.0> 2.0 END_PLANE
  381.      TRANSLATE < -5.0 0.0 7.5>
  382.     END_INTERSECTION
  383.    END_UNION
  384.    TEXTURE
  385.       GRANITE
  386.       BUMPS 0.5
  387.       SCALE < 0.5 0.6 1.0>
  388.       AMBIENT 0.10
  389.       DIFFUSE 0.9
  390.    END_TEXTURE
  391.    COLOUR Blue
  392. END_OBJECT
  393.  
  394. DECLARE Pointy = OBJECT
  395.    UNION
  396.     {pointy part}
  397.     INTERSECTION
  398.       PLANE <0.0 -1.0 0.0> 1.0 END_PLANE
  399.       PLANE <0.0 0.0 1.0> 0.5 END_PLANE
  400.       PLANE <0.0 0.0 -1.0> 0.5 END_PLANE
  401.       PLANE <1.0 0.0 0.0> 0.0 ROTATE <0.0 0.0 70.0> END_PLANE
  402.       PLANE <-1.0 0.0 0.0> 0.0 ROTATE <0.0 0.0 -70.0> END_PLANE
  403.       SCALE <3.0 4.0 1.0>
  404.       TRANSLATE < 0.0 12.0 7.5>
  405.     END_INTERSECTION
  406.    END_UNION
  407.    TEXTURE
  408.       GRANITE
  409.       BUMPS 0.5
  410.       SCALE < 0.7 0.5 0.33>
  411.       AMBIENT 0.10
  412.       DIFFUSE 0.9
  413.    END_TEXTURE
  414.    COLOUR Blue
  415. END_OBJECT
  416.  
  417. DECLARE CornerBeams = OBJECT
  418.   UNION
  419.     INTERSECTION
  420.       QUADRIC Beam SCALE <1.5 1.0 1.5>END_QUADRIC
  421.       PLANE <0.0 1.0 0.0> 10.0 END_PLANE
  422.       PLANE <0.0 -1.0 0.0> 2.0 END_PLANE
  423.       TRANSLATE < 10.0 0.0 7.5>
  424.     END_INTERSECTION
  425.     INTERSECTION      
  426.       QUADRIC Beam SCALE <1.5 1.0 1.5> END_QUADRIC
  427.       PLANE <0.0 1.0 0.0> 10.0 END_PLANE
  428.       PLANE <0.0 -1.0 0.0> 2.0 END_PLANE
  429.       TRANSLATE < -10.0 0.0 7.5>
  430.     END_INTERSECTION
  431.     SPHERE < -10.0 10.0 7.5> 1.5 END_SPHERE
  432.     SPHERE <  10.0 10.0 7.5> 1.5 END_SPHERE
  433.   END_UNION
  434.   TEXTURE
  435.       GRANITE
  436.       BUMPS 0.5
  437.       SCALE < 0.3 0.1 1.0>
  438.       AMBIENT 0.10
  439.       DIFFUSE 0.9
  440.   END_TEXTURE
  441.   COLOUR Blue
  442. END_OBJECT
  443.  
  444. { Ghost in tomb doorway }
  445. DECLARE Figure = OBJECT
  446.   INTERSECTION
  447.      QUADRIC Beam SCALE <2.3 1.0 2.3> END_QUADRIC
  448.      PLANE <0.0 1.0 0.0> 8.0 END_PLANE
  449.      PLANE <0.0 -1.0 0.0> 2.0 END_PLANE
  450.      TRANSLATE < 0.0 0.0 4.3>
  451.   END_INTERSECTION
  452.   TEXTURE
  453.      GRANITE
  454.      { Use any ghost image you like for the tomb doorway or comment }
  455.      { out the Figure in TombAll }
  456.      {IMAGEMAP <-1.0 1.0 0.0> GIF "ghost.gif" ONCE}
  457.      SCALE < 6.5 8.0 6.5 >
  458.      TRANSLATE < -1.0 7.5 4.3 >
  459.      AMBIENT 0.10
  460.      DIFFUSE 0.3
  461.    END_TEXTURE
  462.    COLOUR Blue
  463. END_OBJECT
  464.  
  465. { TombAll is the completed tomb }
  466. DECLARE TombAll = COMPOSITE
  467.    OBJECT Tomb END_OBJECT
  468.    OBJECT InnerBeams END_OBJECT
  469.    OBJECT Pointy END_OBJECT
  470.    OBJECT CornerBeams END_OBJECT
  471.    OBJECT Figure END_OBJECT
  472. END_COMPOSITE
  473.  
  474. { Pumpkin parts }
  475. DECLARE Stem = OBJECT
  476.   INTERSECTION
  477.     QUADRIC Pole  END_QUADRIC
  478.     PLANE <0.0 1.0 0.0> 0.04 ROTATE <0.0 -10.0 -10.0> END_PLANE
  479.     PLANE <0.0 -1.0 0.0> 1.0 END_PLANE
  480.     TRANSLATE<0.0 0.3 0.0>
  481.   END_INTERSECTION
  482.   TEXTURE
  483.     BUMPS 0.5
  484.     COLOR RED 0.04 GREEN 0.33 BLUE 0.05
  485.     SCALE < 0.2 0.2 0.2>
  486.     AMBIENT 0.1
  487.     DIFFUSE 0.9   
  488.   END_TEXTURE
  489.   COLOR RED 0.04 GREEN 0.33 BLUE 0.05
  490. END_OBJECT
  491.  
  492. DECLARE Slice = QUADRIC
  493.   Sphere
  494.   TRANSLATE <0.0 0.0 0.5>
  495.   SCALE <0.28 0.30 0.40>
  496. END_QUADRIC
  497.  
  498. DECLARE Pumpkin = OBJECT
  499.   UNION
  500.     QUADRIC Slice END_QUADRIC
  501.     QUADRIC Slice ROTATE <0.0 -20.0  0.0> END_QUADRIC
  502.     QUADRIC Slice ROTATE <0.0 -40.0  0.0> END_QUADRIC
  503.     QUADRIC Slice ROTATE <0.0 -60.0  0.0> END_QUADRIC
  504.     QUADRIC Slice ROTATE <0.0 -80.0  0.0> END_QUADRIC
  505.     QUADRIC Slice ROTATE <0.0 -100.0 0.0> END_QUADRIC
  506.     QUADRIC Slice ROTATE <0.0 -120.0 0.0> END_QUADRIC
  507.     QUADRIC Slice ROTATE <0.0 -140.0 0.0> END_QUADRIC
  508.     QUADRIC Slice ROTATE <0.0 -160.0 0.0> END_QUADRIC
  509.     QUADRIC Slice ROTATE <0.0 -180.0 0.0> END_QUADRIC
  510.     QUADRIC Slice ROTATE <0.0 -200.0 0.0> END_QUADRIC
  511.     QUADRIC Slice ROTATE <0.0 -220.0 0.0> END_QUADRIC
  512.     QUADRIC Slice ROTATE <0.0 -240.0 0.0> END_QUADRIC
  513.     QUADRIC Slice ROTATE <0.0 -260.0 0.0> END_QUADRIC
  514.     QUADRIC Slice ROTATE <0.0 -280.0 0.0> END_QUADRIC
  515.     QUADRIC Slice ROTATE <0.0 -300.0 0.0> END_QUADRIC
  516.     QUADRIC Slice ROTATE <0.0 -320.0 0.0> END_QUADRIC
  517.     QUADRIC Slice ROTATE <0.0 -340.0 0.0> END_QUADRIC
  518.   END_UNION
  519.   BOUNDED_BY
  520.       QUADRIC Sphere SCALE <1.5 1.5 1.5> END_QUADRIC
  521.   END_BOUND
  522.   TEXTURE
  523.     BUMPS 0.3
  524.     COLOR RED 0.5 GREEN 0.22 BLUE 0.1
  525.     SCALE < 0.1 0.1 0.1>
  526.     AMBIENT 0.1
  527.     DIFFUSE 0.9
  528.     PHONG 0.75
  529.     PHONGSIZE 30.0
  530.   END_TEXTURE
  531.   COLOR RED 0.5 GREEN 0.22 BLUE 0.1
  532. END_OBJECT
  533.  
  534.  
  535. {*****************************************}
  536. { Scene description     }
  537. {*****************************************}
  538.  
  539. OBJECT
  540.    Cross
  541.    SCALE <1.7 2.0 1.0>
  542.    ROTATE <-15.0 0.0 0.0>
  543.    TRANSLATE <-16.0 7.7 61.5>    
  544. END_OBJECT
  545.  
  546. OBJECT
  547.    Headstone
  548.    SCALE <1.0 1.0 1.0>
  549.    ROTATE <15.0 0.0 0.0>
  550.    TRANSLATE <-14.0 4.0 76.0>
  551. END_OBJECT
  552.  
  553. OBJECT
  554.    Headstone
  555.    SCALE <1.0 1.0 1.0>
  556.    TRANSLATE <12.0 4.0 74.0>
  557. END_OBJECT
  558.  
  559. OBJECT
  560.    Headstone
  561.    SCALE <1.0 1.0 1.0>
  562.    ROTATE <-10.0 0.0 0.0>
  563.    TRANSLATE <18.0 8.0 70.0>
  564. END_OBJECT
  565.  
  566. OBJECT
  567.    Cross
  568.    SCALE <1.5 2.0 1.0>
  569.    ROTATE <-15.0 0.0 0.0>
  570.    TRANSLATE <17.0 10.0 60.0>
  571. END_OBJECT
  572.  
  573. OBJECT
  574.    Cross
  575.    SCALE <1.5 2.0 1.0>
  576.    ROTATE <-15.0 0.0 20.0>
  577.    TRANSLATE <26.0 10.0 70.0>
  578. END_OBJECT
  579.  
  580. OBJECT
  581.    Cross
  582.    SCALE <1.5 2.0 1.0>
  583.    ROTATE <-15.0 0.0 -10.0>
  584.    TRANSLATE <31.0 10.0 78.0>
  585. END_OBJECT
  586.  
  587.  
  588. { Little Pumpkin Patch }
  589. OBJECT
  590.    Pumpkin
  591.    SCALE <1.5 2.0 1.5>
  592.    TRANSLATE < 5.0 1.55 95.0>
  593. END_OBJECT
  594. OBJECT
  595.    Stem
  596.    SCALE <1.5 2.5 1.5>
  597.    TRANSLATE < 5.0 1.55 95.0>
  598. END_OBJECT
  599. OBJECT
  600.    Pumpkin
  601.    SCALE <1.5 2.5 1.5>
  602.    TRANSLATE < 11.0 1.6 90.0>
  603. END_OBJECT
  604. OBJECT
  605.    Stem
  606.    SCALE <1.5 2.5 1.5>
  607.    TRANSLATE < 11.0 1.6 90.0>
  608. END_OBJECT
  609.  
  610.  
  611. { Ghastly Tomb!}
  612. COMPOSITE
  613.    TombAll
  614.    ROTATE <15.0 15.0 0.0>
  615.    TRANSLATE <0.0 10.0 58.0>
  616. END_COMPOSITE
  617.  
  618. {left entry gate}
  619. OBJECT
  620.    Gate
  621.    TRANSLATE <-9.0 0.0 88.0>
  622. END_OBJECT
  623.  
  624. {right entry gate}
  625. OBJECT
  626.    Gate
  627.    ROTATE <-10.0 -160.0 0.0>
  628.    TRANSLATE <7.0 0.0 87.5>
  629. END_OBJECT
  630.  
  631. {Use gate object to make left & right fence}
  632. OBJECT
  633.    Gate
  634.    TRANSLATE <-19.0 0.0 88.0>
  635. END_OBJECT
  636. OBJECT
  637.    Gate
  638.    TRANSLATE <-31.0 0.0 88.0>
  639. END_OBJECT
  640. OBJECT
  641.    Gate
  642.    TRANSLATE <9.0 0.0 88.0>
  643. END_OBJECT
  644. OBJECT
  645.    Gate
  646.    TRANSLATE <19.0 0.0 88.0>
  647. END_OBJECT
  648.  
  649. { Columns to hold the fence and gates up }
  650. COMPOSITE Column TRANSLATE <-20.0 0.0 88.0> END_COMPOSITE
  651. COMPOSITE Column TRANSLATE <-10.0 0.0 88.0> END_COMPOSITE
  652. COMPOSITE Column TRANSLATE < 8.0 0.0 88.0> END_COMPOSITE
  653. COMPOSITE Column TRANSLATE < 18.0 0.0 88.0> END_COMPOSITE
  654.  
  655. {hill under tomb}
  656. OBJECT
  657.     QUADRIC Paraboloid_Y
  658.       SCALE<40.0 10.0 77.0>
  659.     END_QUADRIC
  660.     ROTATE <0.0 0.0 180.0>
  661.     TRANSLATE <0.0 21.0 -28.0>
  662.     TEXTURE
  663.       BUMPS 0.8
  664.       COLOR RED 0.5 GREEN 0.6 BLUE 0.2
  665.       SCALE < 5.0 5.0 5.0>
  666.       AMBIENT 0.1
  667.       DIFFUSE 0.7    
  668.     END_TEXTURE                                      
  669.     COLOR RED 0.5 GREEN 0.6 BLUE 0.2
  670. END_OBJECT
  671.  
  672. {hill to right of tomb}
  673. OBJECT
  674.     QUADRIC Paraboloid_Y
  675.       SCALE<30.0 10.0 40.0>
  676.     END_QUADRIC
  677.     ROTATE <0.0 0.0 180.0>
  678.     TRANSLATE <40.0 14.0 50.0>
  679.     TEXTURE
  680.       BUMPS 0.8
  681.       COLOR RED 0.6 GREEN 0.6 BLUE 0.1
  682.       SCALE < 7.0 5.0 5.0>
  683.       AMBIENT 0.1
  684.       DIFFUSE 0.7
  685.     END_TEXTURE
  686.     COLOR RED 0.6 GREEN 0.6 BLUE 0.1
  687. END_OBJECT
  688.  
  689. { Ground }
  690. OBJECT
  691.     PLANE <0.0 1.0 0.0> 1.0 END_PLANE
  692.     TEXTURE
  693.       BUMPS 0.7
  694.       COLOR RED 0.6 GREEN 0.6 BLUE 0.1
  695.       SCALE < 1.0 1.0 1.0>
  696.       AMBIENT 0.1
  697.       DIFFUSE 0.7
  698.     END_TEXTURE
  699.     COLOR RED 0.6 GREEN 0.6 BLUE 0.1
  700. END_OBJECT
  701.  
  702. {The Sun}
  703. OBJECT
  704.   SPHERE <0.0 0.0 0.0> 150.0 END_SPHERE
  705.   TRANSLATE <150.0 30.0 1200.0>
  706.   TEXTURE
  707.     COLOR White
  708.     AMBIENT 1.0
  709.     DIFFUSE 0.0
  710.   END_TEXTURE
  711.   LIGHT_SOURCE
  712.   COLOR White
  713. END_OBJECT
  714.  
  715. { Sky - gradient sunset}
  716. OBJECT
  717.   SPHERE <0.0 0.0 0.0> 2000.0 INVERSE END_SPHERE
  718.    TEXTURE
  719.      Sunset_Sky
  720.      TRANSLATE <0.0 200.0 0.0>
  721.      SCALE <1.2 1.2 1.2>
  722.      AMBIENT 0.6
  723.      DIFFUSE 0.0
  724.    END_TEXTURE
  725.    COLOR Green
  726. END_OBJECT
  727.  
  728. { Clouds - uses a sky texture with the sky portion defined as transparent }
  729. {          so the gradient behind it is visible  }
  730. OBJECT
  731.    SPHERE <0.0 0.0 0.0> 1997.0 INVERSE END_SPHERE
  732.    TEXTURE
  733.     Yellow_Clouds
  734.     SCALE <1000.0 30.0 100.0>
  735.     AMBIENT 0.6
  736.     DIFFUSE 0.0
  737.    END_TEXTURE
  738.    COLOR Green
  739. END_OBJECT
  740.