OS/2 Shareware BBS: 35 Internet/35-Internet.zip/shackos2.zip/blamspam.cmd

OS/2 REXX Batch file | 1997-05-21 | 11KB | 304 lines

/* To blow the spam right off the POP3 server before the mailer retrieves it */
/* Copyright (c)1997 Kari Jackson for InnoVal Systems Solutions, Inc. */
program="BlamSpam"
infile=program||".T~$"
cfgfile=program||".Cfg"
interval=900 /* re-checks every 15 minutes */
if stream(cfgfile,"c","query exists")="" then do
   say
   say "Configuration file ("cfgfile") not found."
   exit
end
call RxFuncAdd "SysLoadFuncs", "RexxUtil", "SysLoadFuncs"
signal on syntax name NoREXX
call SysLoadFuncs
signal on syntax name Syntax
signal on halt name Halt
"@ECHO OFF"
parse arg args
if translate(left(args,3))="/F:" then do
   if pos('"',args)=4 then parse var args . '"' savefile '"' hackargs
   else parse var args . ":" savefile hackargs
   if stream(savefile,"c","query exists")="" then newfile=1
   if lineout(savefile) then do
      say
      say "Cannot write to file" savefile"."
      exit
   end
   if newfile=1 then call sysfiledelete savefile
end
else hackargs=args
hackargs=strip(hackargs)
again=0
do forever
   if again then do
      parse value syscurpos() with row column
      call syscurpos row, 0
      say "Process complete....sleeping for" interval/60 "minutes...."
      say "or press Ctrl-C to exit...."
      call syssleep interval
   end
   else again=1
   "hacksaw email get localfile("infile")" hackargs
   if rc<0 then do
      call TellUser CENTER 80 "HACKSAW returned error code" rc "when trying to retrieve mail. Will keep trying...."
      iterate
   end
   if rc=0 then iterate
   total=rc
   headerlines="NOBODY" /* will check all header lines but not the message body */
   z=0
   do while lines(cfgfile)
      line=translate(strip(linein(cfgfile)))
      if line="" then iterate
      if left(line,2)="/*" then iterate
      if left(line,13)="<HEADERLINES>" then do
         parse var line . "=" headerlines
         iterate
      end
      z=z+1
      parse upper var line spammer "09"x headers
      if strip(headers)="" then headers=headerlines
      headers=translate(headers," ",",")
      spammers.z=strip(spammer)||"09"x||space(headers,1)
   end
   if z>0 then spammers.0=z
   call lineout cfgfile
   if spammers.0=0 then do
      say ""
      say "Configuration file ("cfgfile") does not seem to contain any entries."
      exit
   end
   message=0
   messagenumbers=""
   killit=0
   say ""
   do while lines(infile)
      origline=linein(infile)
      first=1
      line=translate(strip(origline))
      select
         when left(line,13)="-=-=-=-=-=-= " & pos(" MESSAGE [",line)>27 & ,
            /* .... */ right(line,14)="] =-=-=-=-=-=-" then do
            message=message+1
            parse value syscurpos() with row column
            call syscurpos row, 0
            call charout ,"Processing message" message "of" total"...."
            if savefile<>"SAVEFILE" then do
               if killit then do
                  call lineout savefile,"Message killed for presence of string:" reason
                  do u=1 to temp.0
                     call lineout savefile,temp.u
                  end
               end
               temp.0=1
               temp.1=origline
            end
            killit=0
            r=0
            do while lines(infile)
               hdrline=linein(infile)
               if savefile<>"SAVEFILE" then do
                  temp.0=temp.0+1
                  u=temp.0
                  temp.u=hdrline
               end
               hdrline=translate(translate(hdrline," ","09"x))
               select
                  when left(hdrline,1)=" " then do
                     msghdrs.r=msghdrs.r space(hdrline)
                  end
                  when strip(hdrline)="" then nop
                  otherwise do
                     r=r+1
                     msghdrs.r=space(hdrline)
                  end
               end
               if strip(hdrline)="" then leave
            end
            msghdrs.0=r
            do i=1 to spammers.0
               parse var spammers.i spammer "09"x headers
               if headers<>oldheaders & headers<>"NOBODY" & headers<>"ENTIRE" then do
                  tags.0=0
                  parsethem=headers
                  do until parsethem=""
                     parse var parsethem this parsethem
                     tags.0=tags.0+1
                     q=tags.0
                     if right(this,1)<>":" then this=this||":"
                     tags.q=this
                  end
                  oldheaders=headers
               end
               do n=1 to msghdrs.0
                  parse var msghdrs.n tag content
                  hit=0
                  if headers<>"ENTIRE" & headers<>"NOBODY" then do
                     do j=1 to tags.0
                        if tag<>tags.j then iterate
                        hit=1
                        leave
                     end
                  end
                  if (hit | headers="NOBODY" | headers="ENTIRE") & ,
                     pos(spammer,content)>0 then do
                     killit=1
                     messagenumbers=strip(messagenumbers||" "||message)
                     parse value syscurpos() with row column
                     call syscurpos row, 0
                     string="Message #"||message||":" spammer
                     say string||copies(" ",79-length(string))
                     reason=spammer
                  end
                  if killit then leave
               end
               if killit then leave
            end
         end
         when killit=0 then do i=1 to spammers.0
            if first & savefile<>"SAVEFILE" then do
               temp.0=temp.0+1
               u=temp.0
               temp.u=origline
               first=0
            end
            parse var spammers.i spammer "09"x headers
            if headers="NOBODY" then iterate
            if wordpos("MSGTEXT",headers)=0 & headers<>"ENTIRE" then iterate
            if pos(spammer,line)>0 then do
               killit=1
               messagenumbers=strip(messagenumbers||" "||message)
               parse value syscurpos() with row column
               call syscurpos row, 0
               string="Message #"||message||":" spammer
               say string||copies(" ",79-length(string))
               reason=spammer
            end
            if killit then leave
         end
         otherwise if savefile<>"SAVEFILE" then do
            temp.0=temp.0+1
            u=temp.0
            temp.u=origline
         end
      end
   end
   if killit & savefile<>"SAVEFILE" then do
      call lineout savefile,"Message killed for presence of string:" reason
      do u=1 to temp.0
         call lineout savefile,temp.u
      end
      call lineout savefile,origline
   end
   if messagenumbers<>"" then do until rc=0
      "hacksaw email mw" hackargs
      if rc<0 then do
         call TellUser CENTER 80 "HACKSAW returned error code" rc "when checking the number of messages on the server before deleting message(s)" messagenumbers".  Will keep trying...."
         iterate
      end
      if rc<message then do
         longline=program "wants to delete message number(s)" messagenumbers", but the POP3 server says there are fewer messages present now than there were a moment ago. "
         longline=longline||"This must mean that some other program has deleted some messages from the server. Therefore," program "cannot delete these messages since there's no "
         longline=longline||"way of knowing that the old message numbers still refer to the same messages!"
         call TellUser CENTER 80 longline
         rc=0
         iterate
      end
      nospace=translate(messagenumbers,","," ")
      "hacksaw email del mn("nospace")" hackargs
      if rc=200 then do
         call TellUser CENTER 80 "POP3 server says there are no messages present.  User must have deleted them before" program "could, using some other program."
         rc=0
      end
      else if rc<>0 then do
         call TellUser CENTER 80 "HACKSAW returned error code" rc "when trying to delete message number(s)" messagenumbers".  Will keep trying...."
      end
   end
   else do
      parse value syscurpos() with row column
      call syscurpos row, 0
      say "No messages matched the search strings.                                        "
   end
   call lineout infile
   call sysfiledelete infile
   if words(hackargs)>1 | (translate(left(hackargs,5))<>"PORT(" & hackargs<>"") then leave
end
exit
Syntax:
  say ""
  say "Error" rc "in line" sigl":" errortext(rc)
  say sigl":" sourceline(sigl)
  exit
return
Halt:
   say ""
   say Program "interrupted by Ctrl-C, ShutDown, or closing of WorkArea."
   exit
return
NoREXX:
   call TellUser CENTER 80 "Unable to load the REXXUtil functions.  Either the REXXUTIL.DLL file is not on the LIBPATH or REXX support is not installed on this system."
   exit
return
TellUser: procedure
/* Copyright (c)1995 Kari Jackson */
   parse arg format width message
   if wordpos(format,"CENTER center LEFT left LINES lines")=0 then return "ERROR1"
   if datatype(width,"W")=0 then return "ERROR2"
   if width>80 then return "ERROR3"
   if width=80 then width=79
   if message="" then return "ERROR4"
   width=width-4
   if wordpos(format,"LINES lines")=0 then do
      testing=message
      testlen1=0
      do until testing=""
         parse var testing test testing
         testlen2=length(test)
         if testlen2>testlen1 then testlen1=testlen2
      end
      if testlen1>width then width=testlen1
      if width>75 then return "ERROR5"
      do q=1 until message=""
         if msg.q="MSG."q then parse var message msg.q message
         do until message=""
            parse var message nextword message
            if length(msg.q nextword) > width then do
               message=nextword message
               iterate q
            end
            else msg.q=msg.q nextword
         end
      end
   end
   else do
      parse var message delimiter 2 message
      do q=1 until message=""
         parse var message msg.q (delimiter) message
      end
      testlen4=0
      do c=1 to q
         testlen5=length(msg.c)
         if testlen5>testlen4 then testlen4=testlen5
      end
      if testlen4>width then width=testlen4
   end
   if format="left"|format="LEFT" then do
      width=0
      do c=1 to q
         width2=length(msg.c)
         if width2>width then width=width2
      end
   end
   say
   say "┌"copies("─",width+2)"┐"
   if format="LEFT"|format="left" then do b=1 to q
      say "│ "msg.b||copies(" ",width-length(msg.b))" │"
   end
   else do b=1 to q
      say "│ "center(msg.b,width)" │"
   end
   say "└"copies("─",width+2)"┘"
   say
return "SUCCESS"