home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
OS/2 Shareware BBS: 35 Internet
/
35-Internet.zip
/
michnet.zip
/
michnet.cmd
next >
Wrap
OS/2 REXX Batch file
|
1995-01-13
|
12KB
|
275 lines
/****************************************************************************/
/* */
/* OS/2 2.x / WARP REXX Driver for IBM TCP/IP version 2.0 / IAK */
/* */
/* MICHNET.CMD */
/* */
/* .................................................. */
/* */
/* Sample attachment script for dialing into MichNet server in order to */
/* establish a SLIP connection. This script should be specified on page 1 */
/* in the Login Script field for connections via SlipPM or using the */
/* -connect option if executing slip directly. */
/* */
/* For example, the following might be used in SlipPM: */
/* Login Script: michnet.cmd atdt998-1300 uniqname@umich.edu kerberospwd */
/* */
/* which would then feed the "atdt998-1300" command to the modem, followed */
/* by the login id and password once the connection is established. */
/* */
/* From slip directly the script supports: */
/* -connect "michnet.cmd atdt998-1300 loginid *" */
/* */
/* which would cause michnet.trm to initially prompt for the password. It */
/* would then feed the "atdt998-1300" command to the modem, and when */
/* MichNet answers, it would use "loginid" as a username and the password */
/* specified. */
/* */
/* Make sure you have these settings in your Dialup dialog box */
/* for University of Michigan NAS info. Your University mileage */
/* may vary: */
/* */
/* *Phone Number: <blank> */
/* Login Script: michnet.cmd atdt9981300 uniqname@umich.edu kerberos */
/* *MTU Size: 1006 */
/* *Domain Nameserver: 141.211.144.15 */
/* *Your Domain Name: umich.edu */
/* News Server: news.itd.umich.edu */
/* Gopher Server: gopher.itd.umich.edu */
/* WWW Server: www.umich.edu */
/* POP Mail Server: pop.itd.umich.edu (questionable) */
/* Replay Domain: umich.edu */
/* Reply (Mail) ID: <uniqname>@umich.edu */
/* POP Login ID: <uniqname> */
/* POP Password: <kerberos> */
/* */
/* This has been tested to work only with SLIP as of 10-JAN-95. The Gamma */
/* PPP driver is out but not yet tested. (I'm working on it.) */
/* */
/* Enjoy! (Brian Shensky, shensky@umich.edu, 14 January 1995) */
/* */
/****************************************************************************/
parse arg interface , dialcmd username password
/*--------------------------------------------------------------------------*/
/* Initialization and Main Script Code */
/*--------------------------------------------------------------------------*/
/* Set some definitions for easier COM strings */
cr='0d'x
crlf='0d0a'x
say ''
say 'MICHNET - SLIP Connection Script for MichNet',
'(interface' interface')'
/* Prompt for missing information */
if dialcmd = '' then do
call charout , 'Dial Command: '
parse pull dialcmd
end
if username = '' | username = '*' then do
call charout , 'User Name: '
parse pull username
end
else do
say 'User:' username
end
if password = '' | password = '*' then do
call charout , 'Password: '
password = readpass()
end
/* Flush any stuff left over from previous COM activity */
call flush_receive
/* Reset the modem here */
/* You may need to customize this for your modem make and model */
call lineout , 'Reset modem...'
call send 'AT&F"H3\N3' || cr
call waitfor 'OK', 5 ; call flush_receive 'echo'
if RC = 1 then do
call lineout , 'Modem not resetting... Trying again'
call send '+++'
call waitfor 'OK'
call send 'ATHZ' || cr
call waitfor 'OK', 3
end
/* Dial the remote server */
call charout , 'Now Dialing...'
/* Wait for connection */
call send dialcmd || cr
call waitfor 'CONNECT' ; call waitfor crlf
/* Handle login. We wait for standard strings, and then flush anything */
/* else to take care of trailing spaces, etc.. */
/* call send cr */
call waitfor 'host:' ; call flush_receive 'echo'
call send 'slip' || cr
call waitfor 'login:' ; call flush_receive 'echo'
call send username || cr
call waitfor 'Password:' ; call flush_receive 'echo'
call send password || cr
/* Parse the results of the SLIP command to determine our address. */
/* We use the "waitfor_buffer" variable from the waitfor routine */
/* to parse the stuff we get from the MichNet after waiting for an */
/* appropriate point in the data stream. */
/* SL/IP session from (141.211.7.10) to 141.211.7.11 beginning.... */
call waitfor ')'
say '!!!' waitfor_buffer '!!!'
parse var waitfor_buffer 'SL/IP session from (' a '.' b '.' c '.' d ')' .
call waitfor 'beginning....'
parse var waitfor_buffer . e '.' f '.' g '.' h .
annex_address = a||'.'||b||'.'||c||'.'||d
/* parse var waitfor_buffer a '.' b '.' c '.' d '.' . */
os2_address = e||'.'||f||'.'||g||'.'||h
/* Flush anything else */
call flush_receive 'echo'
/* Now configure this host for the appropriate address, */
/* and for a default route through the Annex. */
say crlf crlf 'HEY!! SLIP Connection Established'
say 'Configuring local address =' os2_address
say 'MichNet =' annex_address
'ifconfig sl0' os2_address annex_address 'netmask 255.255.255.0'
'route add default' annex_address '1'
/* All done */
exit 0
/*--------------------------------------------------------------------------*/
/* send ( sendstring) */
/*..........................................................................*/
/* */
/* Routine to send a character string off to the modem. */
/* */
/*--------------------------------------------------------------------------*/
send:
parse arg sendstring
call slip_com_output interface , sendstring
return
/*--------------------------------------------------------------------------*/
/* waitfor ( waitstring , [timeout] ) */
/*..........................................................................*/
/* */
/* Waits for the supplied string to show up in the COM input. All input */
/* from the time this function is called until the string shows up in the */
/* input is accumulated in the "waitfor_buffer" variable. */
/* */
/* If timeout is specified, it says how long to wait if data stops showing */
/* up on the COM port (in seconds). */
/* */
/*--------------------------------------------------------------------------*/
waitfor:
parse arg waitstring , timeout
if timeout = '' then
timeout = 5000 /* L O N G delay if not specified */
waitfor_buffer = '' ; done = -1; curpos = 1
ORI_TIME=TIME('E')
if (remain_buffer = 'REMAIN_BUFFER') then do
remain_buffer = ''
end
do while (done = -1)
if (remain_buffer \= '') then do
line = remain_buffer
remain_buffer = ''
end
else do
line = slip_com_input(interface,,10)
end
waitfor_buffer = waitfor_buffer || line
index = pos(waitstring,waitfor_buffer)
if (index > 0) then do
remain_buffer = substr(waitfor_buffer,index+length(waitstring))
waitfor_buffer = delstr(waitfor_buffer,index+length(waitstring))
done = 0
end
call charout , substr(waitfor_buffer,curpos)
curpos = length(waitfor_buffer)+1
if ((done \= 0) & (TIME('E')>timeout)) then do
call lineout , ' WAITFOR: timed out '
done = 1
end
end
timeout=0
RC=done
return RC
/*--------------------------------------------------------------------------*/
/* readpass () */
/*..........................................................................*/
/* */
/* Routine used to read a password from the user without echoing the */
/* password to the screen. */
/* */
/*--------------------------------------------------------------------------*/
readpass:
answer = ''
do until key = cr
key = slip_getch()
if key \= cr then do
answer = answer || key
end
end
say ''
return answer
/*--------------------------------------------------------------------------*/
/* flush_receive () */
/*..........................................................................*/
/* */
/* Routine to flush any pending characters to be read from the COM port. */
/* Reads everything it can until nothing new shows up for 100ms, at which */
/* point it returns. */
/* */
/* The optional echo argument, if 1, says to echo flushed information. */
/* */
/*--------------------------------------------------------------------------*/
flush_receive:
parse arg echo
/* If echoing the flush - take care of waitfor remaining buffer */
if (echo \= '') & (length(remain_buffer) > 0) then do
call charout , remain_buffer
remain_buffer = ''
end
/* Eat anything left in the modem or COM buffers */
/* Stop when nothing new appears for 100ms. */
do until line = ''
line = slip_com_input(interface,,100)
if echo \= '' then
call charout , line
end
return