home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
OS/2 Shareware BBS: 29 Fixes_o
/
29-Fixes_o.zip
/
updwebsu.exe
/
rsuwp.cmd
< prev
next >
Wrap
OS/2 REXX Batch file
|
1996-11-08
|
2KB
|
63 lines
/**********************************************************/
/* Create Desktop object to connect to SOFTUPD html page. */
/* Build for IBM Web Explorer or Netscape Navigator. */
/**********************************************************/
call RxFuncAdd 'SysLoadFuncs', 'RexxUtil', 'SysLoadFuncs'
call SysLoadFuncs
found=0
Arg which .
Select
When which='WEBX' then
Do
expl=SysSearchPath('PATH','EXPLORE.EXE')
If expl='' then
Do
Say 'EXPLORE.EXE not found anywhere in your PATH, cannot continue.'
Signal Done
End
found=1
title='Software Updates^via IBM Web Explorer'
objid='<WP_SRVUPW>'
End
When which='NETSCAPE' then
Do
x=SysIni('USER','ALL:','apps.')
Do j=1 to apps.0
If translate(apps.j)='NETSCAPE' then
Do
x=SysIni('USER',apps.j,'ALL:','key.')
expl=SysIni('USER',apps.j,key.1)||'\NETSCAPE.EXE'
title='Software Updates^via Netscape Navigator'
objid='<WP_SRVUPN>'
found=1
Leave j
End
End
End
Otherwise
Do
Say 'Invalid request ('which').'
Signal Done
End
End
/**********************************/
/* Create object if browser found */
/**********************************/
If found then
Do
classname = 'WPProgram'
title =title
location ='<WP_DESKTOP>'
setup ='OBJECTID='objid';'||,
'PARAMETERS=http://ps.boulder.ibm.com/softupd.html;'||,
'PROGTYPE=PM;'||,
'EXENAME='expl';'
If SysCreateObject(classname,title,location,setup, 'UPDATE')=1 then
Say 'Created "'title'" program object on your desktop.'
Else
Say 'Unable to create "'title'" program object on your desktop.'
End
Done:
Exit