home *** CD-ROM | disk | FTP | other *** search
/ OS/2 Shareware BBS: 22 gnu / 22-gnu.zip / gnuawk.zip / awklib / eg / prog / tee.awk < prev    next >
Text File  |  1997-03-15  |  688b  |  39 lines
  1. # tee.awk --- tee in awk
  2. # Arnold Robbins, arnold@gnu.ai.mit.edu, Public Domain
  3. # May 1993
  4. # Revised December 1995
  5.  
  6. BEGIN    \
  7. {
  8.     for (i = 1; i < ARGC; i++)
  9.         copy[i] = ARGV[i]
  10.  
  11.     if (ARGV[1] == "-a") {
  12.         append = 1
  13.         delete ARGV[1]
  14.         delete copy[1]
  15.         ARGC--
  16.     }
  17.     if (ARGC < 2) {
  18.         print "usage: tee [-a] file ..." > "/dev/stderr"
  19.         exit 1
  20.     }
  21.     ARGV[1] = "-"
  22.     ARGC = 2
  23. }
  24. {
  25.     # moving the if outside the loop makes it run faster
  26.     if (append)
  27.         for (i in copy)
  28.             print >> copy[i]
  29.     else
  30.         for (i in copy)
  31.             print > copy[i]
  32.     print
  33. }
  34. END    \
  35. {
  36.     for (i in copy)
  37.         close(copy[i])
  38. }
  39.