home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
OS/2 Shareware BBS: 18 REXX
/
18-REXX.zip
/
instpa.zip
/
INSTPA.CMD
Wrap
OS/2 REXX Batch file
|
1993-08-01
|
5KB
|
120 lines
/* INSTPATH.CMD - Change the install path for OS/2 */
/* REXX program to review and modify installation paths */
/* for OS/2 2.1 GA. */
/* This program is needed if you wish to install OS/2 drivers or components */
/* from a drive other than the one used for the initial installation. This is the */
/* case when you have installed from CID or CDROM and the drive mappings have */
/* changed. */
/* Disclaimer: use this software at your own risk. I have gone */
/* through the INI files on different machines and have determined */
/* these settings are the ones used for reinstallation and driver */
/* installation. There is no public documentation on these settings */
/* as far as I can tell. But the good news is that it seems to work! */
/* Written by Philip Lieberman */
/* Lieberman and Associates Design and Engineering Group */
/* 221 N. Robertson Blvd. Suite C - Beverly Hills, CA 90211 */
/* Compuserve: 76426,363 - Prodigy: PKFJ82A - IBMLINK: DEV2203 */
/* First release: 7/3/93 */
call rxfuncadd sysloadfuncs, rexxutil, sysloadfuncs
call sysloadfuncs
/* Path to Selective Installation INI file */
/* The rest of the installation stuff is in the OS2.INI file */
INSTALLER='C:\OS2\INSTALL\REINSTAL.INI'
Call Syscls
DO FOREVER
say 'Change OS/2 2.1 GA Installation path/devices'
say ' Version 1.0 - by Philip Lieberman'
say ''
say 'Options:'
say '(R)eview current settings'
say '(C)hange settings'
say '(E)xit'
say
say 'Your selection: (R,C,E):'
parse upper pull response_menu
if response_menu = 'R' then do 1
Say '******** Entries in REINSTAL.INI - Used for Selective Install ****'
Call SysIni INSTALLER, 'All:', 'Apps.'
if Result \= 'ERROR:' then
do i = 1 to Apps.0
call SysIni INSTALLER, Apps.i, 'All:', 'Keys'
if Result \= 'ERROR:' then
do j=1 to Keys.0
val = SysIni(INSTALLER, Apps.i, Keys.j)
if length(val) <= 2 then
say left(Apps.i, 20) left(Keys.j, 20) C2X(val)
else
say left(Apps.i, 20) left(Keys.j, 20),
'Len=x'''Left(d2x(length(val)),4) left(val, 20)
end
end
Say ''
Say '******** Entries in OS2.INI - Used for Printer/Display Install ****'
call SysIni 'USER', 'PM_INSTALL', 'All:', 'Keys'
if Result \= 'ERROR:' then
do j=1 to Keys.0
val = SysIni('USER', 'PM_INSTALL', Keys.j)
if length(val)<=2 then
say left('PM_INSTALL', 20) left(Keys.j, 20) C2X(val)
else
say left('PM_INSTALL', 20) left(Keys.j, 20),
'Len=x'''Left(d2x(length(val)),4) left(val, 20)
end
Say ''
end
if response_menu = 'C' then do 1
Say ' Caution: changing the installation path requires that you understand'
Say ' the structure of the installation disks. If you are installing from'
Say ' a network or CDROM, the path is usually: X:\OS2SE21 where X: is'
Say ' the drive letter and path of the network NET USE drive or the drive '
Say ' letter and path of the CDROM.'
Say ''
Say ' When you select diskette installation, the installation program will'
Say ' assume that installation will be done exclusively from diskettes in'
Say ' the A: drive.'
Say''
Say ' Do you want to continue? (Y/N)'
parse upper pull confirm
if confirm \= 'Y' then EXIT
Say ' Do you want installation from diskette (D) or CDROM/Network (C)'
parse upper pull response
if response = 'D' then Do 1
say 'Now modifying Installation for diskette operation'
val = SysIni(INSTALLER,'InstallWindow','SOURCEPATH','A:\')
val = SysIni(INSTALLER,'InstallWindow','FDISKETTESOURCE',X2C('0100'))
val = SysIni('USER','PM_INSTALL','MEDIA','DISKETTE')
val = SysIni('USER','PM_INSTALL','PDR_DIR','A:\')
end
else
Do 1
say 'Now modifying Installation for Network/CDROM operation'
say ' What is the path to use to get to the Network or CDROM?'
parse upper pull SOURCE_PATH
Say 'Source path for installation/reinstallation will be: 'SOURCE_PATH
val = SysIni(INSTALLER,'InstallWindow','SOURCEPATH',SOURCE_PATH)
val = SysIni(INSTALLER,'InstallWindow','FDISKETTESOURCE',X2C('0000'))
val = SysIni('USER','PM_INSTALL','MEDIA','REMOVABLE')
val = SysIni('USER','PM_INSTALL','PDR_DIR',SOURCE_PATH)
end
end
if response_menu = 'E' then EXIT
say '---- Press ENTER to continue ----'
pull pause_step
end