OS/2 Shareware BBS: 18 REXX/18-REXX.zip/MKESLN.ZIP/MKESLAN.CMD

OS/2 REXX Batch file | 1992-09-02 | 12KB | 190 lines

/****************************************************************/
/* MKESLAN.CMD                  Version 1.2; September 2, 1992  */
/*                                                              */
/* Function:                                                    */
/*      Build the WPS entries for the following products:       */
/*              Extended Services:                              */
/*                      Communications Manager                  */
/*                      Database Manager                        */
/*              LAN Requester                                   */
/* Parameters:                                                  */
/*      None                                                    */
/*                                                              */
/* Programmed by:                                               */
/*      Georg Haschek (61804212 at VIEVMA)                      */
/*                                                              */
/* Change history:                                              */
/*      1.0  92/07/31 ... First release to OS2TOOLS             */
/*      1.1  92/08/11 ... Fix lowercase problem in PATH         */
/*                        processing                            */
/*      1.2  92/09/02 ... Make UPM Programs PM                  */
/*                    ... Add "Program Group" icon              */
/*                                                              */
/****************************************************************/
Trace 'O'
Address CMD
'@ECHO OFF'
Signal On Halt
Signal On Syntax

/**************/
/* Initialize */
/**************/
Call rxfuncadd sysloadfuncs, rexxutil, sysloadfuncs
Call sysloadfuncs

Parse Version v
v = Translate(Word(v,5)||Right(Wordpos(Word(v,4),'Jan Feb Mar Apr May Jun Jul Aug Sep Oct Nov Dec'),2)||Right(Word(v,3),2),'0',' ')
If v < 19920708 Then Do
  Say "The version of REXX on your system is backlevel."
  Say " "
  Say "Please get the latest version from OS2TOOLS (REXX20 PACKAGE), or from"
  Say "the OS2CSD disk. The success of MKESLAN is not guaranteed!"
  'PAUSE'
End

landrive = ''
cmdrive = ''
dbdrive = ''
upmdrive = ''
bootdrive = Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\OS2\SYSTEM',Value('PATH',,'OS2ENVIRONMENT'))-2,2)
If Pos('\IBMLAN',Translate(Value('PATH',,'OS2ENVIRONMENT'))) > 0 Then landrive = Translate(Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\IBMLAN',Translate(Value('PATH',,'OS2ENVIRONMENT')))-2,2))
If Pos('\CMLIB',Translate(Value('PATH',,'OS2ENVIRONMENT'))) > 0 Then cmdrive = Translate(Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\CMLIB',Translate(Value('PATH',,'OS2ENVIRONMENT')))-2,2))
If Pos('\SQLLIB',Translate(Value('PATH',,'OS2ENVIRONMENT'))) > 0 Then dbdrive = Translate(Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\SQLLIB',Translate(Value('PATH',,'OS2ENVIRONMENT')))-2,2))
If Pos('\MUGLIB',Translate(Value('PATH',,'OS2ENVIRONMENT'))) > 0 Then upmdrive = Translate(Substr(Value('PATH',,'OS2ENVIRONMENT'),Pos('\MUGLIB',Translate(Value('PATH',,'OS2ENVIRONMENT')))-2,2))
If landrive = '' & cmdrive = '' & dbdrive = '' Then Do
  Say "No Extended Services or LAN Requester found, terminating."
  Call Endit
End

iconfile = 'GROUP.ICO'
iconparm = ''
If Stream(iconfile,'C','QUERY EXISTS') = '' Then Do
  Parse Source . . myname .
  mydir = Filespec('D',myname)||Filespec('P',myname)
  If Stream(mydir||iconfile,'C','QUERY EXISTS') = '' Then Do
    If SysSearchPath('PATH',iconfile) = '' Then Do
      If SysSearchPath('DPATH',iconfile) <> '' Then Do
        iconparm = 'ICONFILE='||SysSearchPath('DPATH',iconfile)||';'
      End
    End
    Else Do
      iconparm = 'ICONFILE='||SysSearchPath('PATH',iconfile)||';'
    End
  End
  Else Do
    iconparm = 'ICONFILE='||mydir||iconfile||';'
  End
End
Else Do
  iconparm = 'ICONFILE='||Directory()||'\'||iconfile||';'
End

'CLS'
Say "Your system is installed on the" bootdrive "drive."
Say " "
Say "The following components have been found:"
Say " "
If landrive <> '' Then Say "     LAN Requester on drive" landrive
If cmdrive <> '' Then Say "     Communications Manager on drive" cmdrive
If dbdrive <> '' Then Say "     Database Manager on drive" dbdrive
If upmdrive <> '' Then Say "     User Profile Management on drive" upmdrive
Say " "
Say "This program will now create a folder for each identified product on your"
Say "desktop, which will contain the standard WPS entries."
Say " "
Say "Do you want to continue (Y/N)?"
Parse Upper Pull yesno .
If Substr(yesno,1,1) <> 'Y' Then Call Endit

If landrive <> '' Then Do
  Call SysCreateObject 'WPFolder','LAN Services','<WP_DESKTOP>','OBJECTID=<LAN_FOLDER>;'||iconparm,'R'
  Call SysCreateObject 'WPProgram','OS/2 LAN Services Installation/Configuration','<LAN_FOLDER>','EXENAME='||landrive||'\IBMLAN\INSTALL\LANINST.EXE;PROGTYPE=WINDOWABLEVIO;STARTUPDIR='||landrive||'\IBMLAN\INSTALL;','R'
  Call SysCreateObject 'WPProgram','LAN Messaging','<LAN_FOLDER>','EXENAME='||landrive||'\IBMLAN\NETPROG\NETSEND.CMD;PROGTYPE=FULLSCREEN;STARTUPDIR='||landrive||'\IBMLAN\NETPROG;','R'
  Call SysCreateObject 'WPProgram','LAN Requester','<LAN_FOLDER>','EXENAME='||landrive||'\IBMLAN\NETPROG\NET.EXE;PROGTYPE=FULLSCREEN;STARTUPDIR='||landrive||'\IBMLAN\NETPROG;','R'
  Call SysCreateObject 'WPProgram','OS/2 LAN Command Reference','<LAN_FOLDER>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS='||landrive||'\IBMLAN\BOOK\A3ALANCR.INF;STARTUPDIR='||bootdrive||'\OS2;','R'
  Call SysCreateObject 'WPProgram','OS/2 LAN Online Reference','<LAN_FOLDER>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS='||landrive||'\IBMLAN\BOOK\A3ALANOR.INF;STARTUPDIR='||bootdrive||'\OS2;','R'
End

If cmdrive <> '' | dbdrive <> '' Then Do
  Call SysCreateObject 'WPFolder','Extended Services','<WP_DESKTOP>','OBJECTID=<ES_FOLDER>;'||iconparm,'R'
  Call SysCreateObject 'WPProgram','View Install History File','<ES_FOLDER>','EXENAME='||bootdrive||'\OS2\INSTALL\VIEWLOG.CMD;PROGTYPE=FULLSCREEN;STARTUPDIR='||bootdrive||'\OS2\INSTALL;','R'
  Call SysCreateObject 'WPProgram','Add or Remove Features','<ES_FOLDER>','EXENAME='||bootdrive||'\OS2\INSTALL\REINST.CMD;PROGTYPE=FULLSCREEN;STARTUPDIR='||bootdrive||'\OS2\INSTALL;','R'
  Call SysCreateObject 'WPProgram','Basic Configuration and Installation','<ES_FOLDER>','EXENAME='||bootdrive||'\OS2\INSTALL\ESCFG.CMD;PROGTYPE=FULLSCREEN;STARTUPDIR='||bootdrive||'\OS2\INSTALL;','R'
  Call SysCreateObject 'WPProgram','Extended Services Command Reference','<ES_FOLDER>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS=ESCMDREF.INF;STARTUPDIR='||bootdrive||'\OS2\BOOK;','R'
  Call SysCreateObject 'WPProgram','View Custom Build History File','<ES_FOLDER>','EXENAME='||bootdrive||'\OS2\INSTALL\VIEWBLOG.CMD;PROGTYPE=FULLSCREEN;STARTUPDIR='||bootdrive||'\OS2\INSTALL;','R'
  Call SysCreateObject 'WPProgram','Create Custom Install Diskette','<ES_FOLDER>','EXENAME='||bootdrive||'\OS2\INSTALL\CUSTBLD.CMD;PROGTYPE=FULLSCREEN;STARTUPDIR='||bootdrive||'\OS2\INSTALL;','R'
End

Call SysCreateObject 'WPFolder','User Profile Management Services','<WP_DESKTOP>','OBJECTID=<UPM_FOLDER>;'||iconparm,'R'
Call SysCreateObject 'WPProgram','Logoff','<UPM_FOLDER>','EXENAME='||upmdrive||'\MUGLIB\LOGOFF.EXE;PARAMETER=/L;STARTUPDIR='||upmdrive||'\OS2\INSTALL;PROGTYPE=PM;','R'
Call SysCreateObject 'WPProgram','User Profile Management','<UPM_FOLDER>','EXENAME='||upmdrive||'\MUGLIB\UPMACCTS.EXE;STARTUPDIR='||upmdrive||'\OS2\INSTALL;PROGTYPE=PM;','R'
Call SysCreateObject 'WPProgram','Logon','<UPM_FOLDER>','EXENAME='||upmdrive||'\MUGLIB\LOGON.EXE;STARTUPDIR='||upmdrive||'\OS2\INSTALL;PROGTYPE=PM;','R'

If dbdrive <> '' Then Do
  Call SysCreateObject 'WPFolder','Database Manager','<WP_DESKTOP>','OBJECTID=<DBM_FOLDER>;'||iconparm,'R'
  Call SysCreateObject 'WPProgram','Directory Tool','<DBM_FOLDER>','EXENAME='||dbdrive||'\SQLLIB\DIRECT.EXE;PROGTYPE=PM;STARTUPDIR='||dbdrive||'\SQLLIB;','R'
  Call SysCreateObject 'WPProgram','Database Manager Messages','<DBM_FOLDER>','EXENAME='||bootdrive||'\OS2\VIEW.EXE;PROGTYPE=PM;PARAMETERS='||dbdrive||'\SQLLIB\BOOK\DBMSG.INF;STARTUPDIR='||dbdrive||'\SQLLIB;','R'
  Call SysCreateObject 'WPProgram','DBM Command Line Interface','<DBM_FOLDER>','EXENAME=CMD.EXE;PROGTYPE=WINDOWABLEVIO;PARAMETERS=/K DBM.CMD -S & STARTDBM.EXE;STARTUPDIR='||ldbdrive||'\SQLLIB;','R'
  Call SysCreateObject 'WPProgram','Query Manager','<DBM_FOLDER>','EXENAME='||dbdrive||'\SQLLIB\QUERYMGR.EXE;PROGTYPE=PM;STARTUPDIR='||dbdrive||'\SQLLIB;','R'
  Call SysCreateObject 'WPProgram','Configuration Tool','<DBM_FOLDER>','EXENAME='||dbdrive||'\SQLLIB\CONFIG.EXE;PROGTYPE=PM;STARTUPDIR='||dbdrive||'\SQLLIB;','R'
  Call SysCreateObject 'WPProgram','Recovery Tool','<DBM_FOLDER>','EXENAME='||dbdrive||'\SQLLIB\RECOVERY.EXE;PROGTYPE=PM;STARTUPDIR='||dbdrive||'\SQLLIB;','R'
End

If cmdrive <> '' Then Do
  Call SysCreateObject 'WPFolder','Communications Manager','<WP_DESKTOP>','OBJECTID=<CM_FOLDER>;'||iconparm,'R'
  Call SysCreateObject 'WPProgram','Display SNA Configuration Log','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\APPN\APPNLOG2.EXE;PROGTYPE=PM;PARAMETERS=[Enter configuration log (.LOG) file name];STARTUPDIR='||cmdrive||'\CMLIB;','R'
  Call SysCreateObject 'WPProgram','Display Active SNA Configuration','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\APPN\PMDSPLAY.EXE;PROGTYPE=PM;STARTUPDIR='||cmdrive||'\CMLIB\APPN;','R'
  Call SysCreateObject 'WPProgram','Manage SNA Logical Links','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\APPN\APPNLINK.EXE;PROGTYPE=PM;STARTUPDIR='||cmdrive||'\CMLIB\APPN;','R'
  Call SysCreateObject 'WPProgram','Verify SNA Network Definitions','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\APPN\VERIFYNS.CMD;PROGTYPE=WINDOWABLEVIO;PARAMETERS=[Enter node definitions (.NDF) file name];STARTUPDIR='||cmdrive||'\CMLIB\APPN;','R'
  Call SysCreateObject 'WPProgram','SNA Network Definitions Configuration','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\APPN\APPNC2.EXE;PROGTYPE=PM;PARAMETERS=[Enter node definitions (.NDF) file name];STARTUPDIR='||cmdrive||'\CMLIB;','R'
  Call SysCreateObject 'WPProgram','Communications Manager','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\STARTCM.CMD;PROGTYPE=FULLSCREEN;STARTUPDIR='||cmdrive||'\CMLIB;','R'
  Call SysCreateObject 'WPProgram','Configuration File Manager','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\COPYCFG.EXE;PROGTYPE=PM;STARTUPDIR='||cmdrive||'\CMLIB;','R'
  Call SysCreateObject 'WPProgram','Start/Stop CM Trace','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\APPN\CMTRACE.EXE;PROGTYPE=WINDOWABLEVIO;PARAMETERS=[Enter trace options];STARTUPDIR='||cmdrive||'\CMLIB\APPN;','R'
  Call SysCreateObject 'WPProgram','Format SNA Trace Information','<CM_FOLDER>','EXENAME='||cmdrive||'\CMLIB\APPN\FMTTRACE.EXE;PROGTYPE=WINDOWABLEVIO;PARAMETERS=[Enter optional flags and trace (.TRC) file name];STARTUPDIR='||cmdrive||'\CMLIB\APPN;','R'
End

/****************/
/* Exit program */
/****************/
Endit:
Exit 0

/********************************/
/* Notify user in case of error */
/********************************/
Telluser: Procedure
Parse source . . tell_name .
tell_name = Filespec('name',tell_name)
Parse Upper Var tell_name tell_name '.' .
If Arg(2,'e') = 0 Then Do
  Say tell_name||':' Date('U') Time() Arg(1)
End
Else Do
  If Arg(2) = 0 Then Do
    Say tell_name||':' Date('U') Time() Arg(1)
  End
  Else Do
    Say Copies(' ',15+Length(tell_name)) Arg(1)
  End
End
Return 0

/*************************/
/* Handle SIGNAL ON HALT */
/*************************/
Halt:
Call Telluser 'Halt signalled in line' SIGL'.'
Call Endit

/***************************/
/* Handle SIGNAL ON SYNTAX */
/***************************/
Syntax:
myrc = rc
errormsg ='REXX error' myrc 'in line' SIGL':' Errortext(myrc)
errormsg2 = Substr('     ',1,6-Length(SIGL))(SIGL)' *-*   'Sourceline(sigl)
Call Telluser errormsg
Call Telluser errormsg2,1
Call Endit