home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
HomeWare 14
/
HOMEWARE14.bin
/
comms
/
icom0425.arj
/
POSTTAG.SCR
< prev
next >
Wrap
Text File
|
1994-04-25
|
2KB
|
59 lines
;-----------------------------------------------------------------------
; POSTTAG.SCR This Intellicomm v2 script reads the NEWFILES catalog
; and executes POSTFILE.SCR on all Tagged files. It also copies the
; Tagged files into the FILELIST catalog.
;
; TO INSTALL:
;
; Copy the script into your Intellicomm Script Directory (\ICOM\SCR by
; default).
;
; TO USE:
;
; 1. Make sure that the files you intend to operate on are in your
; Intellicomm Download Directory (this is where POSTFILE.SCR
; will look for the file).
;
; 2. Select "Browse New BBS Files" from the Icom Main Menu, and Tag
; any files you want to operate POSTFILE.SCR on (perhaps files
; that you added manually, or that were imported from a text
; file or were scanned in using Import from Disk).
;
; 3. Press [Alt-U] to enter the Script Manager, hilight POSTTAG.SCR
; and select "Run".
;
;-----------------------------------------------------------------------
variable filename
variable extension
variable fullpath
variable tagged_record
copen "NEWFILES"
csetsort 1 0 ;sort by Tag Status/Location
while 1
cgetrec
if $ERRORLEVEL <> 0 break ;non-zero, at the end of the catalog
if $CTAG_FLD = "N" continue ;record is noted... skip it
if $CTAG_FLD <> "T" break ;record not tagged or noted; we're done
ctell tagged_record ;get the record #
fnstrip filename $CNAME_FLD 7 ;get the filename (no .EXT)
fnstrip extension $CNAME_FLD 15 ;get the .EXT (no filename)
assign fullpath $DL_DIR $CNAME_FLD
script "POSTFILE" filename extension fullpath
if $CNAME_FLD = "" ;this sucker had a virus...
cdelrec tagged_record ;kill it
continue
endif
assign $CTAG_FLD "U" ;untag
cputrec ;update with the FILE_ID.DIZ desc.
copen "FILELIST" ;close NEWFILES/open FILELIST
caddrec ;add the record to FILELIST
copen "NEWFILES"
csetsort 1 0 ;gotta do this again
cgetrec tagged_record ;get back to the record
endwhile
;--------------------------[End of script]------------------------------