home *** CD-ROM | disk | FTP | other *** search
/ Amiga Format 91 / af091a.adf / af91a3.lzx / prgs / Sound / play.b next >
Text File  |  2018-01-21  |  4KB  |  208 lines
  1. { 
  2.   << play a sound file! >>
  3.  
  4.   Currently handles IFF 8SVX format.
  5.   If format is unknown, a default 
  6.   sampling rate is assumed. 
  7.  
  8.   USAGE 
  9.   -----
  10.   CLI/Shell:     Play [<file> [<sampling rate>]] | ?
  11.  
  12.   Author: David J Benn
  13.     Date: 6th,7th April,16th May,
  14.       30th June,
  15.       1st,3rd,4th,8th,28th July 1992,
  16.       6th,21st,25th January 1993,
  17.       3rd February 1993,
  18.       10th July 1993,
  19.       3rd January 1994,
  20.       20th March 1996
  21. }
  22.  
  23. declare function _Read&    library
  24.  
  25. longint offset&,samples_per_second&
  26. string  path$
  27.  
  28. SUB parse_sample(f$)
  29. shared offset&,samples_per_second&
  30. const default_rate=10000&
  31.  
  32.  { if IFF 8SVX sample, return
  33.    offset from start of file to
  34.    sample data and sampling rate in
  35.    samples per second. }
  36.  
  37.  open "I",1,f$
  38.  
  39.  '..skip FORM#### ?
  40.  dummy$=input$(8,#1)
  41.  
  42.  '..8SVX ?
  43.  x$=input$(4,#1)
  44.  if x$="8SVX" then
  45.    sample_format$="IFF 8SVX"
  46.  
  47.    '..skip VHDR###
  48.    dummy$=input$(8,#1)
  49.  
  50.    '..skip ULONGs x 3 
  51.    dummy$=input$(12,#1)
  52.  
  53.    '..get sampling rate bytes
  54.    hi%=asc(input$(1,#1))  '..high byte
  55.    lo%=asc(input$(1,#1))  '..low byte
  56.    samples_per_second&=hi%*256 + lo%
  57.  
  58.    '..find BODY
  59.  
  60.    '..skip rest of Voice8Header structure
  61.    dummy$=input$(6,#1)
  62.  
  63.    offset&=40  '..bytes up to this point
  64.    repeat 
  65.     repeat
  66.       x$=input$(1,#1)
  67.       offset&=offset&+1
  68.     until x$="B" and not eof(1)
  69.     if not eof(1) then
  70.       body$=input$(3,#1)
  71.       offset&=offset&+3
  72.     end if
  73.    until body$="ODY" and not eof(1) 
  74.  
  75.    if not eof(1) then
  76.      x$=input$(4,#1)  '..skip ####   
  77.      offset&=offset&+4
  78.    else
  79.      print "Error in file format!"
  80.      stop
  81.    end if
  82.    close 1
  83.  else
  84.    close 1
  85.    sample_format$="unknown"
  86.    offset&=0
  87.    if argcount<>2 then samples_per_second&=default_rate
  88.  end if
  89.  
  90.  '.. give info about sample
  91.  print "Sound file format is ";sample_format$;"."
  92.  
  93.  if sample_format$="unknown" then
  94.    if argcount<>2 then
  95.      print "Playback rate is";samples_per_second&;"Hz."
  96.    end if
  97.  else 
  98.    print "Sample was recorded at";samples_per_second&;"Hz."
  99.  end if
  100.  
  101. END SUB
  102.  
  103.  
  104. SUB play_sound(f$)
  105. shared offset&,samples_per_second&
  106. const maxsample=131070
  107. const channel=1
  108. const CHIP=0, MAXCHIP=2
  109.  
  110. dim   wave_ptr&(100)
  111.  
  112.  print 
  113.  print "*** ACE sound player ***"
  114.  
  115. '..file sample_size?
  116. open "I",1,f$
  117. sample_size&=lof(1)
  118. close 1
  119.  
  120. if sample_size&<>0 then
  121.   print f$;" contains";sample_size&;"bytes."
  122. else
  123.   print "Can't open ";f$;"."
  124.   stop
  125. end if
  126.  
  127. parse_sample(f$)
  128.  
  129. '..get the sample bytes
  130. buffer&=Alloc(sample_size&,CHIP) '...sample_size& bytes of CHIP RAM
  131. if buffer& = NULL then 
  132.   avail&=fre(MAXCHIP)  '..max. contiguous CHIP RAM
  133.   print "Largest contiguous CHIP RAM is";avail&;"bytes." 
  134.   stop
  135. end if
  136.  
  137. open "I",1,f$  
  138. fh&=handle(1)
  139. if fh&=0 then
  140.   print "Can't open ";f$;"."
  141.   stop 
  142. end if
  143. bytes&=_Read(fh&,buffer&,sample_size&)
  144. close 1
  145.  
  146. '..calculate period
  147. if argcount<>2 then 
  148.   per& = 3579546 \ samples_per_second&  
  149. else
  150.   sample_rate_requested&=clng(val(arg$(2)))
  151.   per& = 3579546 \ sample_rate_requested&
  152.   print "Requested sampling rate is";sample_rate_requested&;"Hz."
  153. end if
  154.   
  155. '...setup waveform table for voice 0
  156. sz&=sample_size&-offset&
  157.  
  158. if sz& <= maxsample then
  159.   '..play it in one go
  160.   wave channel,buffer&+offset&,sz&
  161.   dur&=.279365*per&*bytes&/1e6*18.2
  162.   sound per&,dur&,,channel
  163. else
  164.   segments&=sz&\maxsample
  165.   buf&=buffer&+offset&
  166.  
  167.   '..get the segment pointers
  168.   for i&=0 to segments&
  169.     wave_ptr&(i&)=buf&+maxsample*i&
  170.   next
  171.  
  172.   '..play sample in segments
  173.   for i&=0 to segments&
  174.     if sz& >= maxsample then 
  175.        wave channel,wave_ptr&(i&),maxsample 
  176.        bytes&=maxsample
  177.     else 
  178.        wave channel,wave_ptr&(i&),sz&
  179.        bytes&=sz&
  180.     end if
  181.     dur&=.279365*per&*bytes&/1e6*18.2
  182.     sound per&,dur&,,channel
  183.     sz&=sz&-maxsample
  184.   next   
  185. end if
  186.  
  187. END SUB
  188.  
  189.  
  190. { ** main ** }
  191.  
  192. if argcount=0 then
  193.   path$ = FileBox$("Choose a sound sample")
  194. else
  195.   if arg$(1)="?" then
  196.     print "usage: ";arg$(0);" [<file> [<sampling rate>]] | ?"
  197.     stop
  198.   else
  199.     path$ = arg$(1)
  200.   end if
  201. end if
  202.  
  203. if path$<>"" then 
  204.   play_sound(path$)
  205. else
  206.   dummy = MsgBox("No sound file selected.","OK")
  207. end if
  208.