home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
FreeWare Collection 3
/
FreeSoftwareCollection3pd199x-jp.img
/
mop_data
/
moppilot
/
login.plt
< prev
next >
Wrap
Text File
|
1980-01-02
|
7KB
|
208 lines
/************************************************************************
* *
* Auto login program for NIFTY copy left (c) Fox labo. *
* ~~~~~~~~~ *
*=======================================================================*
* *
* Ver./Level=0.0 at 1990 12/15 make by H.Ishihara *
* for crate from FULLAUTO.PLT *
* *
*=======================================================================*
* *
* 未読メールのダウン部分はサンプル(モップ氏作成チビゴリラ氏/モップ *
* 氏修正版)を参考にしました。 *
* *
*************************************************************************/
/************************************************************************
*
* ID, PassWord, Dial type, Telephon number 及び会議室の設定
*/
/************************************************/
%ID{********}; /* ID番号の設定 */
%PassWord{********}; /* パス・ワードの設定 */
%Telephone /* 電話番号と接続種別の設定および呼出し順 *
* を設定する。 *
*==============================================*
* 接続種別 *
*----------------------------------------------*
* Link0:直通経由(10/17日以降はISDN用の予備) *
* Link1:FENICS ROAD 1 経由 *
* Link2:FENICS ROAD 2 経由 *
************************************************/
{ flyingx({Yes}); /* フライングに設定 */
/* (MNPでない場合、削除) */
display({\n東京 ROAD 2 (2400/MNP) にダイアル中です。\n\n});
dialone({ATDP 5703-0222},Link2,); /* 東京 ROAD2 2400/MNP 1回目 */
dialone({ATDP 5703-0222},Link2,); /* 東京 ROAD2 2400/MNP 2回目 */
dialone({ATDP 5703-0222},Link2,); /* 東京 ROAD2 2400/MNP 3回目 */
display({\n東京 ROAD 1 (2400/MNP) にダイアル中です。\n\n});
dialone({ATDP 3739-9120},Link1,); /* 東京 ROAD1 2400/MNP 1回目 */
dialone({ATDP 3739-9120},Link1,); /* 東京 ROAD1 2400/MNP 2回目 */
flyingx({No}); /* フライング禁止に設定 */
/* (MNPの場合、削除) */
display({東京 ROAD 1 (1200) にダイアル中です。\n});
dialone({ATDP 3739-9241D},Link1,); /* 東京 ROAD1 1200 */
display({\n接続出来なかったので1分間休憩します。\n\n})
wait({60},);
Telephone;
};
/************************************************************************
*
* 初期設定
*/
%InitTerm /* 本体の初期化処理 */
{ display({\n本体の初期化を開始しました\n});
nattou({No}); /* 納豆スクロールをOFFに設定する */
sendtype({Line}); /* 入力をライン単位に設定する */
rscs({Yes}); /* フロー制御を RS/CS に設定する */
baud({9600}); /* 転送速度を 9600 [bps] に設定する */
xon({No}); /* Xフロー制御を行わないに設定する */
flyline({2}); /* メモ送信のフライング数を2に設定する */
ctrl({Yes}); /* 制御文字を有効とする */
esc({Yes}); /* ANSIエスケープを有効とする */
setoak({JZRH}); /* OAKの設定(漢字,全角,ローマ字…) */
};
%InitModem /* モデムの初期化処理 */
{ display({\nモデムの初期化を開始しました\n\n});
type({ATZ\n});
wait
( {5},{Abort({\nモデムが動作して無いよぉ~(;_;))\n})},
{\nOK},
{ display({\n});
/************************************************
* モデムの初期設定 *
*==============================================*
* X3 :ビジィ・トーン検出+CONNECT/xxxx 表示 *
* \N3:オート・リアイアブルで接続 *
* \V2:接続時の MNP (9999/REL9) 表示 *
* \Q2:MNP 時のフロー制御を RS/CS とする *
* %C0:MNP 時の圧縮を使用しない *
* &E0:モデム・ポートのスピードを表示 *
* \J0:端末固定モードに設定する *
************************************************/
wait({1},{type({ATX3\\N3\\V2\\Q2%C0&E0\\J0\n})});
}
);
wait
( {10},{Abort({\nモデムからの応答が無いよぉ~(;_;)\n})},
{OK},{wait({1},)},
{ERROR},{Abort({\nコマンドに誤りがあるよぉ~(;_;)\n})}
);
};
/************************************************************************
*
* 共通処理
*/
%WaitChar
{ [Waitchr,WaitcmdC]
wait
( {60},{AbortOff({\nホストの反応が鈍いよぉ~(;_;)\n})},
Waitchr,WaitcmdC
)
};
/************************************************************************
*
* 終了処理
*/
%Abort /* 異常を検出した場合の処理 */
{ [CommentA]
display(CommentA);
display({\n正常に処理できなかったので終了します。(;_;)\n});
discon;
stop;
};
%ModemOff
{ wait({2},{type({+++})});
wait
( {10},{Abort({\nコマンド・モードに切り替わらないよぉ~(;_;)\n})},
{OK},{wait({2},{type({ATH0\n})})}
);
};
%AbortOff /* 異常切断処理 */
{ [CommentB]
display(CommentB);
display({\nうんがぁ~、モデムを直接切断します。(^_^;)\n});
ModemOff;
wait
( {10},{Abort({\nありゃ?_?、モデムからの応答が無いよぉ~(^_^;)\n})},
{OK},{display({\nモデムを直接切断しました(^_^;)\n})},
);
discon;
stop;
};
/************************************************************************
*
* 接続処理
*/
%Connect
{ type({SVC\n});
wait
( {60},{AbortOff({\nホストの反応が可笑しいよぉ~(;_;)\n})},
{User-ID --->},{type(ID)},
{\n INPUT Error},{AbortOff({\nあれぇ?_?『SVC』受け付けてくれない\n})}
);
type({\n});
wait
( {60},{AbortOff({\nホストの反応が鈍いよぉ~(;_;)\n})},
{Password --->},{type(PassWord)},
{\n User-ID Error},{AbortOff({\nID間違ってない?(^_^;)\n})}
);
type({\n});
wait
( {60},{AbortOff({\nホストの反応が鈍いよぉ~(;_;)\n})},
{\n Password ERROR},{AbortOff({\nパス・ワードが可笑しいよぉ(^_^;)\n})},
{\n>}
);
display({\n自動接続を完了しました。\n});
stop;
};
%Link0
{ wait
( {60},{AbortOff({\nホストの反応が鈍いよぉ~(;_;)\n})},
{Connection-ID --->},{Connect},
{\n*},
{ type({C NIF\n});
Link0;
},
{\n46+},{Link1},
{\n00+},{Link1},
{NO CARRIER},{wait({1},)}
);
};
%Link1
{ wait({3},{type({.00+})});
Link0;
};
%Link2
{ wait({3},{type({@P\n})});
Link0;
};
/************************************************************************
*
* 主処理
*/
display({\nNIFTY-Serveへの接続を開始しました。\n});
wait({1},); /* イニシャライズ待機 */
InitTerm; /* 端末の初期処理 */
wait({1},); /* イニシャライズ待機 */
InitModem; /* モデムの初期化処理 */
Telephone; /* 接続処理 */