CD-ROM Magazin 1995 July/August/CDROMMAG.ISO/asym/prg/mtb30/advanced.ats

Text File | 1994-10-03 | 64.3 KB | 2,036 lines

ACTION    "╓ffnen einer Datei mit dem Standard-Dialogfeld ╓ffnen"
BEHAVIOR    "╓ffnet eine vom Benutzer ausgewΣhlte Datei."
CATEGORY    Dateien
HANDLERS    buttonClick, buttonUp, buttonDown, buttonDoubleClick, rightButtonDown, rightButtonUp, rightButtonDoubleClick
ARG    Beschrift    is    "╓ffnen"
ARG    Hilfetext    is    "Zu ÷ffnende Datei auswΣhlen"
ARG    Erweit    is    "*.txt"
ARG    Verzeich    is    "."
{
    linkDll sysToolBookDirectory & "tb30dlg.dll"
        string openDlg(string,string,string,string)
    end    linkDLL

    get openDlg("$$Verzeich","$$Erweit","$$Hilfetext","$$Beschrift")
    if it <> null
        clear sysError
        openfile it
        if sysError <> null
            request "Die Datei "&&it&&"konnte nicht ge÷ffnet werden"
        end if
    end if
    unlinkDLL sysToolBookDirectory & "tb30dlg.dll"
}

SCRIPT "Einfⁿgen einer Textzeile"
BEHAVIOR "Fⁿgt eine einzelne Textzeile ein und behΣlt die Sortierreihenfolge des Felds bei."
CATEGORY Text
{
to get ZeileEinfⁿgen txt,neueZeile
    if txt is null
        return neueZeile
    end
    set Anfang to 1  -- erste Textzeile
    set tlc to textlinecount(txt)
    set Ende to tlc -- letzte Textzeile
    local Einfⁿgestelle
    while Anfang <= Ende
        set Mittelpunkt to (Anfang+Ende) div 2
        set ZeileMitte to textline Mittelpunkt of txt
        conditions
            when neueZeile < ZeileMitte as text
                -- untersucht Werte, die niedriger als der aktuelle Mittelpunkt
                --sind
                set Ende to Mittelpunkt-1
                set Einfⁿgestelle to Mittelpunkt
            when neueZeile > ZeileMitte as text
                -- untersucht Werte, die gr÷▀er als der aktuelle Mittelpunkt
                --sind
                set Anfang to Mittelpunkt+1
                set Einfⁿgestelle to Mittelpunkt+1
            else
                -- das Element existiert bereits
                set Einfⁿgestelle to Mittelpunkt
                break while
        end
    end
    if Einfⁿgestelle > tlc
        put neueZeile before textline Einfⁿgestelle of txt
    else
        put neueZeile&crlf before textline Einfⁿgestelle of txt
    end
    return txt
end
}

SCRIPT "Abrufen einer zuletzt verwendeten Datei"
BEHAVIOR "Ruft den Namen einer zuletzt verwendeten Datei. Diese Dateien werden unten im Menⁿ Datei auf Autorenebene aufgelistet."
CATEGORIES Dateien
{
to handle loadFile mAlias      -- evtl. benutzerdefinierte Botschaft
-- mAlias wird von menuItemSelected ⁿbergeben.
-- Siehe Kapitel 13 des ToolBook-Benutzerhandbuchs fⁿr ein Beispiel
        linkDLL sysToolBookDirectory & "tb30WIN.DLL"
            STRING     getIniVar(STRING,STRING,STRING)
                           -- Abschnitt, Element, Datei
        end linkDLL

        get getIniVar("files", mAlias, "toolbook.ini")
        request it
--        go to page 1 of book it    -- Standardverhalten
        unlinkDLL sysToolBookDirectory & "tb30WIN.DLL"
end loadFile
}

ACTION    "Anzeigen oder Verbergen von Objekten mit ▄bergang"
BEHAVIOR    "Zeigt ein Objekt mit einem ▄bergangseffekt an"
CATEGORIES    Effekte
ARG Geschw  oneOf  "slow,normal,fast" is "normal"
ARG Effekt oneOf     "blinds,dissolve,drip,fade,iris,push,puzzle,rain,slide,spiral,split,tear,turnPage,wipe,zoom"  is "fade"
ARG myObjekte is     "objects of this page"     help "Legt eine Referenz ($$myObjekte) auf ein Objekt oder Objekte fest."
ARG Show oneOf "show,hide" is "show"    help "Zeigt verborgene Objekte an oder verbirgt angezeigte Objekte."

{
-- Dieses Skript funktioniert einwandfrei, es gibt aber so viele Variationen, vielleicht wollen Sie ein bi▀chen experimentieren.
      set sysSuspendMessages to TRUE
    linkDLL "USER"
        int LockWindowUpdate(WORD)
    end    linkDLL
    set pObjListe to $$myObjekte
    if pObjListe is Null and object of self is not in "page,background,book"
        set pObjListe to self
    end if
    set sysLockScreen to true
    while (pObjListe is not NULL)
        pop pObjListe
        $$Show it
    end

 -- Setzt sysLockScreen zurⁿck, Windows Paint-Botschaft ausschalten:
     get LockWindowUpdate(sysClientHandle)
    sysLockScreen = false
    get lockWindowUpdate(0)

    transition "$$Effekt $$Geschw" to this page
    unlinkDLL "USER"
}

SCRIPT    "Umwandeln von Textzeilen in eine Liste"
BEHAVIOR    "Diese Behandlungsroutine wandelt eine durch CRLF-getrennte Zeichenfolge in eine durch Kommas getrennte Liste."
CATEGORIES    Text
{
to get TextzeilenInListe txt
    local STACK Lst
    step i from textlinecount(txt) to 1 by - 1
        push textline i of txt onto Lst
    end
    return Lst
end TextzeilenInListe
}

SCRIPT "Anzeigen von Werten aus einer 1D-Matrix"
BEHAVIOR "Zeigt den Inhalt einer eindimensionalen Matrix an."
CATEGORY Daten
{
to handle Abfragen1DMatrix x[]
    local RⁿckWert
    set d to dimensions(x)
    step i from 1 to d
        put x[i] after RⁿckWert
        if i < d
            put crlf after RⁿckWert
        end    if
    end    step
    request RⁿckWert
end    Abfragen1DMatrix
}

SCRIPT "Anzeigen von Werten aus einer 2D-Matrix"
BEHAVIOR "Zeigt den Inhalt einer zweidimensionalen Matrix an."
CATEGORY Daten
{
  to handle Abfragen2DMatrix x[][]
    local RⁿckWert
    set d to dimensions(x)
    step i from 1 to item 1 of d
        step j from 1 to item 2 of d
            put x[i][j] after RⁿckWert
            if j < item 2 of d
                put tab after RⁿckWert
            end    if
        end    step
        if i < item 1 of d
            put crlf after RⁿckWert
        end    if
    end    step
    request RⁿckWert
 end Abfragen2DMatrix
}

SCRIPT "Sortieren einer 1D-Matrix"
BEHAVIOR "Dies ist die OpenScript-Version der standarmΣ▀igen QuickSort-Operation."
CATEGORIES Daten
{
-- Die nΣchsten drei Behandlungsroutinen
-- fⁿhren eine standardmΣ▀igen QuickSort-
-- Operation durch.
to handle QuickSort fMatrix[] by reference
    system s_nichtVertauschen
    set s_nichtVertauschen to 0
    send Quicksrt fMatrix, 1, dimensions ( fMatrix )
end    QuickSort

to handle Quicksrt fMatrix[] by reference, Min, Max
    system  s_nichtVertauschen
    if Max > Min
        send Vertauschen  fMatrix, Min, ((Min+Max) div 2)
        set Lst to Min
        step i from (Min+1) to Max
            if fMatrix[i] < fMatrix[Min] as text
                increment Lst
                send Vertauschen fMatrix, Lst, i
            else
                increment s_nichtVertauschen
            end
        end
        send Vertauschen fMatrix,Min,Lst
           send Quicksrt fMatrix, Min, Lst-1
        send Quicksrt fMatrix, Lst+1,Max
       end
end    Quicksrt

to handle Vertauschen fMatrix[] by reference, x, y
    local Temp
    set Temp to fMatrix[x]
    set fMatrix[x] to fMatrix[y]
    set fMatrix[y] to Temp
end    Vertauschen
}

SCRIPT "Sortieren einer 2D-Matrix"
BEHAVIOR "Dies OpenScript-Version der standardmΣ▀igen QuickSort-Operation wurde fⁿr zwei Dimensionen angepa▀t."
CATEGORIES Daten
{
-- Nicht vergessen, da▀ Matrizen nach Referenz nicht nach Wert ⁿbergeben werden
--
to handle QuickSort2D fMatrix[][] by reference,SortSpalte,DTyp
    system stbk_nichtVertauschen

    set stbk_nichtVertauschen to 0
    send QuickSrt2D fMatrix, 1, item 1 of dimensions(fMatrix),SortSpalte,DTyp
end

to handle QuickSrt2D fMatrix[][] by reference, Min, Max,SortSpalte,DTyp
    system  stbk_nichtVertauschen
    if Max > Min
        send Vertauschen  fMatrix, Min, ((Min+Max) div 2)
        set Lst to Min
        step i from (Min+1) to Max
            conditions
                when DTyp is "text"
                    set test to fMatrix[i][SortSpalte] < fMatrix[Min][SortSpalte] as text
                when DTyp is "date"
                    set Test to fMatrix[i][SortSpalte] < fMatrix[Min][SortSpalte] as date
                else
                    set Test to fMatrix[i][SortSpalte] < fMatrix[Min][SortSpalte] as number
            end
            if Test
                increment Lst
                send Vertauschen fMatrix, Lst, i
            else
                increment stbk_nichtVertauschen
            end if
        end step
        send Vertauschen fMatrix,Min,Lst

           send QuickSrt2D fMatrix, Min, Lst-1,SortSpalte,DTyp
        send QuickSrt2D fMatrix, Lst+1,Max,SortSpalte,DTyp
       end
end

to handle Vertauschen fMatrix[][] by reference, a, b
    local Temp
    step i from 1 to item 2 of dimensions (fMatrix)
        set Temp to fMatrix[a][i]
        set fMatrix[a][i] to fMatrix[b][i]
        set fMatrix[b][i] to Temp
    end
end
}

SCRIPT "Verwenden einer RECT-Struktur"
BEHAVIOR  "Die nachfolgenden Funktionen sind nⁿtzlich zum Arbeiten mit Windows-Funktionen, die eine RECT-Struktur erfordern oder liefern."
CATEGORIES Daten
{
-- Lst ist eine Liste von 4 ganzen Zahlen
-- pRect ist ein gesperrter Zeiger auf 8 Byte
to handle setRect Lst,pRect
    step i from 0 to 6 by 2
        pop Lst
        get pointerInt(i,pRect,it)
    end
end

-- pRect ist ein gesperrter Zeiger auf 8 Byte
to get getRect pRect
    local RⁿckWert
    step i from 6 to 0 by -2
        push pointerInt(i,pRect) onto RⁿckWert
    end
    return RⁿckWert
end
}

SCRIPT "Verwenden von Windows-Zeigern"
BEHAVIOR "Die folgenden Funktionen sind nutzlich, wenn Sie einen Zeiger zum Aufrufen einer Windows-Funktion zuordnen mⁿssen."
CATEGORIES Windows
{
-- die link-Anwendungen fⁿr die nachfolgenden Funktionen
to handle linkMemFunctions
    linkDLL "KERNEL"
        WORD     GlobalAlloc(WORD,DWORD)
        WORD     GlobalFree(WORD)
        WORD     GlobalHandle(WORD)
        POINTER GlobalLock(WORD)
        WORD     GlobalUnlock(WORD)
    end linkDLL
end    linkMemFunctions

to get getWinPointer nGr÷▀e
    local word hMem
    local RⁿckWert
    hMem = GlobalAlloc(66,nGr÷▀e)
    return GlobalLock(hMem)
end getWinPointer

to get freeWinPointer pMem
    local word hMem, RⁿckWert
    hMem = GlobalHandle(item 1 of pMem)
    RⁿckWert = GlobalUnlock(hMem)
    return GlobalFree(hMem)
end    freeWinPointer
}

ACTION    "Erstellen einer Matrix und Mischen der Werte"
BEHAVIOR    "Erstellt eine Matrix, deren Elemente 1 bis $$Num (Num) per Zufall gemischt werden."
CATEGORIES     Daten
ARG    Num is    "52"    help    "Anzahl der zu mischenden Elemente angeben."
{
    local INT Ergebnis[$$Num]
    local LOGICAL Tabelle[$$Num]

    set i to 1
    while i <= $$Num
        set x to random($$Num)
        if Tabelle[x] is not true
            set Tabelle[x] to true
            set Ergebnis[i] to x
            increment i
        end    if
    end while
}

ACTION    "Suchen nach Text in einem Listenfeld"
BEHAVIOR    "Durchsucht ein Listenfeld (Einzel- oder Mehrfachauswahl) nach einem angegebenen Suchtext und wΣhlt die Zeile mit dem Suchtext aus."
CATEGORIES    Text
ARG    Suchtext    is "Nach welchem Text soll gesucht werden?" help "Geben Sie den Text hier an oder Σndern Sie das Skript entsprechend."
ARG Feldname is "searchField" help "Name des zu durchsuchenden Listenfelds angegeben."
{
    set Suchtext to "$$Suchtext"
--     Alternative:
--     ask "Nach welchem Text soll gesucht werden" with \
--    "$$Suchtext"
--     if it is null or it is "cancel"
--        break
--    else
--         set Suchtext to it
--    end if
    set sysLockScreen to TRUE
    set AltFT to fieldType of field "$$Feldname"
    set fieldType of field "$$Feldname" to wordWrap
    search for Suchtext
    get item 3 of selectedTextState
    set fieldType of field "$$Feldname" to AltFT
     if it <> NULL
        set selectedTextLines of field "$$Feldname" to it
        set scroll of field "$$Feldname" to it - 1
    else
        request QUOTE & Suchtext & QUOTE && "wurde nicht gefunden."
    end if
}

SCRIPT "BeschrΣnken der LΣnge einer Eingabe"
BEHAVIOR "Beim Drⁿcken einer Taste bestΣtigt diese Routine, da▀ die charCount des Feldtexts innerhalb der im Skript angegebenen Grenzen liegt."
CATEGORY Daten
{
-- unterbindet die Eingabe einer Zeichenanzahl, die ⁿber das
-- Maximum liegt. Legen Sie diese Routine im Feld ab.
to handle keyChar Taste
    local INT MaxZeichenanzahl
    local INT aktuelleAnzahl
    MaxZeichenanzahl = 10
    aktuelleAnzahl = charCount(my text)
    if (aktuelleAnzahl >= MaxZeichenanzahl) \
     or (keyPressed = keyEnter and aktuelleAnzahl >= \
     MaxZeichenanzahl - 1)
        beep 1
    else
        forward
    end    if
end    keyChar
}


SCRIPT "Aktivieren des ▄berschreibmodus fⁿr Feldtext"
BEHAVIOR "Aktiviert das Umschalten zwischen Einfⁿge- und ▄berschreibmodus, wie bei vielen Textverarbeitungsprogrammen."
CATEGORY Text
{
to handle keyDown Taste
    system LOGICAL ▄berschreibFlag
    if key is keyInsert
        set ▄berschreibFlag to not ▄berschreibFlag
    end if
    forward
end    keyDown

to handle keyChar Taste
    system LOGICAL ▄berschreibFlag
    set sysLockScreen to true

    if ▄berschreibFlag and (key <> keyBack)
        send clear
    end if
    forward
end    keyChar
}

ACTION    "Summe der Textzeilen in einem Textfeld"
BEHAVIOR    "Dieses Skript addiert die Zahlen auf jeder Zeile im Textfeld $$Zahlen und legt das Ergebnis im Feld $$Summe ab."
CATEGORIES    Mathe
ARG    Zahlen    is    "Zahlen"    help "Der Name des Felds mit den zu addierenden Zahlen."
ARG    Summe    is    "Summe"    help "Der Name des Felds, in dem die Summe angezeigt wird."
{
    set Summe to 0
    step i from 1 to textLineCount(text of field "$$Zahlen")
        set Temp to (textline i of text of field "$$Zahlen")
        set Summe to Summe + Temp
    end
    put Summe into text of field "$$Summe"
}

SCRIPT "Berechnen des Sinus anhand von Punkten"
BEHAVIOR "Berechnet den Sinus eines Winkels anhand von zwei Punkten und dem Standard-Koordinatensystem."
CATEGORY Mathe
{
to get SinusVonPunkten x1,x2,y1,y2
    x = abs(x2 - x1)
    y = abs(y2 - y1)
    conditions
    when x = 0
        r = 1
    when y = 0
        r = 0
    else
    -- Formel fⁿr Sinus
        r = y/sqrt(x^2 + y^2)
    end conditions
    if y2 < y1
        r = -r
    end if
    return r
end SinusVonPunkten
}

SCRIPT "Berechnen den Kosinus anhand von Punkten"
BEHAVIOR "Berechnet den Kosinus eines Winkels anhand von zwei Punkten und dem Standard-Koordinatensystem."
CATEGORY Mathe
{
to get KosinusVonPunkten x1,x2,y1,y2
    x = abs(x2 - x1)
    y = abs(y2 - y1)
    conditions
    when x = 0
        r = 0
    when y = 0
        r = 1
    else
    -- Formel fⁿr Kosinus
        r = x/sqrt(x^2 + y^2)
    end conditions
    if x2 < x1
        r = -r
    end if
    return r
end KosinusVonPunkten
}

SCRIPT "Berechnen des Winkels zwischen Punkten"
BEHAVIOR "Liefert den Winkel zwischen einen Punkt eines Vektors (z.B. in einer Animation) und einem anderen Punkt (z.B. einem Mausklick)."
CATEGORY  Mathe
{
to get Winkel Pos, Obj, Vektor
    -- Pos ist evtl. die Position des Mausklicks
    -- Obj ist eine Objektreferenz auf einen Punkt eines Vektors (z.B. ein sich
    -- bewegendes Objekt), d.h. eine durch einen Punkt definierte Richtung

    -- . Vektor
    --  \      . Pos
     --   \    /
    --    \  /
    --       . Obj

    -- Liefert den Winkel im Bogenma▀
    system s_2PI,s_PIdiv2
    -- nur einmal berechnen
    if s_2PI is null
        set s_2PI to 2 * PI
    end if

    if s_PIdiv2 is null
        set s_PIdiv2 to PI/2
    end if

    -- siehe "Ermitteln des Mittelpunkts eines Objekts"
    set yMitte to objectCenter (Obj)
    pop yMitte into xMitte
    set yOffset to Pos
    pop yOffset into xOffset
    -- Die nΣchsten zwei als Systemvariablen, weil
    -- sie wahrscheinlich geΣndert werden
    set yVek to Vektor
    pop yVek into xVek
    --     siehe  "Berechnen des Kosinus von Punkten" und
    --     "Berechnen des Sinus von Punkten"
    set MausSin to (SinusVonPunkten(xMitte,yMitte,xOffset,yOffset))
    set MausKos to (KosinusVonPunkten(xMitte,yMitte,xOffset,yOffset))
    set vecSin to (SinusVonPunkten(xMitte,yMitte,xVek,yVek))
    set vecCos to (KosinusVonPunkten(xMitte,yMitte,xVek,yVek))

--    angle between them is: arctan(x2/y2) - arctan(x1/y1)
    set Winkel to ((aTan2(vecCos,vecSin)) - (aTan2(MausKos,MausSin)) + s_PIdiv2) -- adjust quadrant

 -- Quadrant ermitteln
    if Winkel > PI
        if Winkel > s_2PI
            set Winkel to Winkel mod s_2PI
        else
            set Winkel to (Winkel mod PI) - PI
        end if
    end if
    return Winkel
end Winkel
}

SCRIPT "Suchen und Ersetzen von Text"
BEHAVIOR "Durchsucht 'txt' nach 'Suchtext und ersetzt es durch 'Ersatztext'."
CATEGORIES Werkzeuge
{
-- Durchsucht 'txt' nach 'Suchtext und ersetzt es durch 'Ersatztext'.
-- Wenn asWord den Wert true hat, wird Suchtext nur durch Ersatztext
-- ersetzt, wenn er als ganzes Wort vorkommt.
-- (Ein Wort ist eine Zeichenfolge, der entweder ein im "Trennzeichen"
-- aufgefⁿhrtes Zeichen oder der Anfang oder das Ende von 'txt'
-- voransteht und nachsteht. Die Trennzeichen-Zeichenfolge enthΣlt
-- space, tab, crlf und allgemeine Interpunktionszeichen und
-- mathematische Operatoren.)

to get SuchenErsetzen txt,SuchenNach,ErsetzenDurch,asWord
    if asWord is null
        set asWord to "false"
    end if
    Laufsumme = 1
    ZeichenGesamt=charcount(txt)
    SuchLΣnge=charcount(SuchenNach)
    ErsetzLΣnge=charcount(ErsetzenDurch)
    -- diese Zeichenfolge enthΣlt alle Zeichen, die neben einem
    -- Wort stehen k÷nnen, ohne es von der benachbarten
    -- Zeichenfolge zu trennen.
    WortTrennen = " " & tab & crlf & "-+*/<>,()[];^=&.?':" & quote
    while Laufsumme <= ZeichenGesamt
        set AktText to chars Laufsumme to ZeichenGesamt of txt
        AktOffset = offset(SuchenNach,AktText)
        if AktOffset = 0
            break while
        else
            PosAnfang = (Laufsumme+AktOffset-1)
            PosEnde = (Laufsumme+AktOffset+SuchLΣnge-2)
            if asWord is true
                -- Prⁿft, ob es sich um ein einzelnes Wort handelt:
                if not ((PosAnfang = 1 or char (PosAnfang - 1) \
                 of txt is in WortTrennen) and\
                 (PosEnde = ZeichenGesamt or char PosEnde + 1 \
                 of txt is in WortTrennen))
                     increment Laufsumme by AktOffset+SuchLΣnge-1
                    continue while
                end if
            end    if
            set chars PosAnfang to PosEnde of txt to ErsetzenDurch
            increment Laufsumme by AktOffset+ErsetzLΣnge-1
            increment ZeichenGesamt by ErsetzLΣnge - SuchLΣnge
        end    if
    end    while
    return txt
end    SuchenErsetzen
}

SCRIPT "─ndert das Verhalten des back-Befehls"
BEHAVIOR "Bietet eine Alternative zum Standardverhalten des back-Befehls in ToolBook"
CATEGORY Seitenwechsel
{
to handle enterApplication
    system s_backBotschaft
    -- initialize system variable
    s_backBotschaft = false
    -- schaltet syshistory aus
    syshistoryrecord = false
    clear syshistory
    forward
end enterApplication

to handle leavePage
    system s_backBotschaft
    -- fⁿgt die Seite in syshistory ein, nur wenn der
    -- Seitenwechsel *nicht* mit BACK eingeleitet wurde
    if targetWindow is mainWindow
        if s_backBotschaft is false
            push this page onto syshistory
        else
            s_backBotschaft = false
        end
    end if
    forward
end leavePage

to handle back
    system s_backBotschaft
    if itemcount(syshistory) > 0
        s_backBotschaft = true
        pop syshistory
        in mainwindow
            go to it
        end in
    else
        request "Es ist nicht m÷glich, weiter zurⁿckzugehen."
    end if
end back
}

SCRIPT "Erweitern der Auswahl in einem Mehrfachauswahl-Feld"
BEHAVIOR "Dieses Skript erweitert die FunktionalitΣt eines Mehrfachauswahl-Felds auf Einzelauswahl und Auswahlerweiterung"
CATEGORIES Werkzeuge
{
to handle buttonDown Pos,istUmschalt,istStrg
    -- Script in field to be ExtendSelect
    -- Klicken ohne Umschalt, dann mit Umschalt,
    -- um die Auswahl zu erweitern
    -- Strg gedrⁿckt halten fⁿr normale Mehrfahrauswahl
    -- Ohne Umschalt oder Strg fⁿr normale Einfachauswahl
    system WORD s_UmschaltStart
     -- funktioniert nur mit multiSelect-Feldern
    if fieldType of self <> "multiSelect"
        fieldType of self = multiSelect
    end if
     sysLockScreen = TRUE
    conditions
    when istUmschalt
        if s_UmschaltStart is not null
            UmschaltEnde = item 1 of textFromPoint(Pos)
            if UmschaltEnde < s_UmschaltStart
                ZΣhler = -1
            else
                ZΣhler = 1
            end if
            clear my selectedTextlines
            step i from s_UmschaltStart to UmschaltEnde by ZΣhler
                push i onto my selectedTextlines
            end step
        end if
        break buttonDown
    when not istStrg
        clear my selectedTextlines
        my selectedTextlines = item 1 of textFromPoint(Pos)
        sysLockScreen = FALSE
    end conditions
    s_UmschaltStart = item 1 of textFromPoint(Pos)
    forward
end buttonDown
}

SCRIPT "Ziehen von Objekten"
BEHAVIOR "Leichte Methode zum Ziehen von Objekten auf Leserebene."
CATEGORY Werkzeuge
{
to handle buttonDown Pos
    local STACK bnds,MausOffset
    linkDLL "user"
        int getsystemmetrics(int)
    end    linkDLL

    -- Prⁿft, ob der Benutzer die Maustasten vertauscht hat
    if getsystemmetrics(23) >0
        set leftMouseButton to keyRightButton
    else
        set leftMouseButton to keyLeftButton
    end    if

    unlinkDLL "user"
    set bnds to bounds of target
    set MausOffset to item 1 of Pos - item 1 of Bnds,\
      item 2 of Pos - item 2 of Bnds

    while keystate(leftMouseButton)is down
        neuePos = sysMousePosition
        if neuePos <> Pos
            set position of target to \
              item 1 of neuePos-item 1 of MausOffset,\
              item 2 of neuePos-item 2 of MausOffset
            set Pos to neuePos
        end    if
    end while
end    buttonDown
}

SCRIPT    "Zeichnen eines Auswahlrechtecks"
BEHAVIOR    "Zeichnet ein Auswahlrechteck zum AuswΣhlen und L÷schen von Objekten auf Leserebene."
CATEGORIES    Zeichnen
{
to handle buttonDown Pos
    system xy
    set myObj to objectFromPoint (Pos)
    if myObj = NULL or object of parent of myObj = background
        draw rectangle from Pos to Pos
        set name of selection to "selectionRectangle"
        set transparent of selection to TRUE
        set lineStyle of selection to dotted
        set xy to position of selection
    end if

end buttonDown


to handle buttonStillDown
    send AuswahlrechteckZeichnen
end buttonStillDown

to handle buttonUp
    if AuswahlrechteckGezeichnet of this page <> TRUE
        break
    end if
    set x to item 1 of bounds of selection
    set y to item 2 of bounds of selection
    set MitX to item 3 of bounds of selection
    set MitY to item 4 of bounds of selection
    step i from 1 to itemCount (objects of this page)
        if x < item 1 of bounds of item i of objects of this page and \
            y < item 2 of bounds of item i of objects of this page and \
            MitX > item 3 of bounds of item i of objects of this page and \
            MitY > item 4 of bounds of item i of objects of this page

            extend select item i of objects of this page
        end if
    end step
    if itemCount (selection) >= 2 -- 1 = selectionRectangle
        -- diesen Abschnitt Σndern, um das Verhalten anzupassen
        request "Alle eingeschlossenen Objekte l÷schen?" with "Ja" or "Nein"
        if it = "Ja"
            send clear
        else
            set selection to rectangle "selectionRectangle"
            send clear
        end if
    else
        set selection to rectangle "selectionRectangle"
        send clear
    end if
end buttonUp

to handle AuswahlrechteckZeichnen
    system xy
    set AuswahlrechteckGezeichnet of this page to TRUE
    if item 1 of sysMousePosition < item 1 of xy and \
        item 2 of sysMousePosition > item 2 of xy
        set Quadrant3 to TRUE
    else
        set Quadrant3 to FALSE
    end if

    if item 1 of sysMousePosition > item 1 of xy and \
        item 2 of sysMousePosition < item 2 of xy
        set Quadrant1 to TRUE
    else
        set Quadrant1 to FALSE
    end if

    conditions
      when not Quadrant3 and not Quadrant1
          set Temp to xy
         set item 3 of Temp to item 1 of sysMousePosition
         set item 4 of Temp to item 2 of sysMousePosition

      when Quadrant3 and not Quadrant1
          set Temp to sysMousePosition
          set item 2 of Temp to item 2 of xy
          set item 3 of Temp to item 1 of xy
          set item 4 of Temp to item 2 of sysMousePosition

     when not Quadrant3 and Quadrant1
         set Temp to sysMousePosition
         set item 1 of Temp to item 1 of xy
         set item 3 of Temp to item 1 of sysMousePosition
         set item 4 of Temp to item 2 of xy

    end conditions
    set bounds of selection to Temp
end AuswahlrechteckZeichnen
}

SCRIPT    "─ndern der Gr÷▀e eines Objekts mit mehreren Scheitelpunkten"
BEHAVIOR    "Diese Behandlungsroutine Σndert die Gr÷▀e der folgenden Objekttypen:polygon, irregularPolygon, line, angledLine oder curve."
CATEGORIES    Zeichnen
{
-- ─ndert die Gr÷▀e des aktuellen Objekts proportional nach Prozent:
-- Beispiel: Um ein Vieleck auf 90% seiner Originalgr÷▀e zu bringen,
-- rufen Sie diese Funktion wie folgt auf:
-- send Gr÷▀e─ndern polygon "foo",.9

to handle Gr÷▀e─ndern AktObj,Betrag
    set b to bounds of AktObj
    -- ermittelt den Mittelpunkt des Objekts
    set MitX to item 1 of b + (item 3 of b - item 1 of b) /2
    set MitY to item 2 of b + (item 4 of b - item 2 of b) /2
    -- prⁿft, ob die Scheitelpunkte geΣndert werden k÷nnen
    set AktObjTyp to object of AktObj
    if AktObjTyp is not in \
     "polygon,irregularPolygon,line,angledLine,curve"
        break
    end    if
    set v to vertices of AktObj
    -- Scheitelpunkte durchlaufen, in Polma▀e umwandeln, Vektoren anpassen,
    -- dann in x,y zurⁿckΣndern
    step i from 1 to itemCount(v) by 2
        set x to item i of v
        set y to item i+1 of v
        -- x,y Abstand der Punkte vom Mittelpunkt
        set dx to x-MitX
        set dy to y-MitY
        -- LΣnge und Winkel von Vektor ermitteln:
        -- atan2 ist bei x=0,y=0 nicht definiert:
        if dx=0 and dy=0
            set radians to 0
            set h to 0
        else
            -- Gr÷▀e wird hier geΣndert
            set h to hypotenuse(dx,dy)*Betrag
            set radians to atan2(dy,dx)
        end    if
        set item i of v to MitX+cos(radians)*h
        set item i+1 of v to MitY+sin(radians)*h
    end    step
    set vertices of AktObj to v
end Gr÷▀e─ndern
}

SCRIPT    "Suchen und Ersetzen in allen Skripten eines Buchs"
BEHAVIOR    "Durchsucht alle Skripten eines Buchs nach einer Zeichenfolge und ersetzt sie."
CATEGORIES    Testen
{
to handle SuchenUErsetzen
    set sysTimeFormat to "seconds"
    local szHintergrundname
    clear sysError
    ask "Geben Sie den zu ersetzenden Text ein:"
    if sysError <> "cancel" and it is not null
        set Suchtext to it
    else
        break buttonUp
    end    if
    ask "Geben Sie den Text, durch den " && Suchtext && "ersetzt werden soll:"
    if sysError <> "cancel" and it is not null
        set Ersatztext to it
    else
        break buttonUp
    end    if
    set Startzeit to sysTime
    set sysCursor to 4
    if script of this book contains Suchtext
        step i from 1 to wordCount(script of this book)
            if word i of script of this book = Suchtext as text
                put Ersatztext into word i of script of this book
            end    if
        end    step
    end    if
    step n from 1 to pageCount of this book
        go to page n
        step i from 1 to itemCount(objects of this page)
            if script of item i of objects of this page contains Suchtext
                step j from 1 to wordCount(script of item i of objects of this page)
                    if word j of script of item i of objects of this page = Suchtext as text
                        put Ersatztext into word j of script of item i of objects of this page
                    end    if
                end    step
            end if
            if object of item i of objects of this page is group
                get GruppeErsetzen(item i of objects of this page, \
                        Suchtext,Ersatztext)
            end    if
        end    step
        if uniqueName of this background <> szHintergrundname as text
            set szHintergrundname to uniqueName of this background
            step i from 1 to itemCount(objects of this background)
                if script of item i of objects of this background contains Suchtext
                    step j from 1 to wordCount(script of item i of objects of this background)
                        if word j of script of item i of objects of this background = Suchtext as text
                            put Ersatztext into word j of script of item i of objects of this background
                        end    if
                    end    step
                end if
                if object of item i of objects of this background is group
                    get GruppeErsetzen(item i of objects of this background, \
                            Suchtext,Ersatztext)
                end    if
            end
            if script of this background contains Suchtext
                step i from 1 to wordCount(script of this background)
                    if word i of script of this background = Suchtext as text
                        put Ersatztext into word i of script of this background
                    end    if
                end    step
            end    if
        end    if
        if script of this page contains Suchtext
            step i from 1 to wordCount(script of this page)
                if word i of script of this page = Suchtext as text
                    put Ersatztext into word i of script of this page
                end    if
            end    step
        end    if
    end    step
    request "Verstrichene Zeit: " && sysTime - Startzeit && "Sekunden."
    set sysCursor to default
end    SuchenUErsetzen

to get GruppeErsetzen groupID,Suchtext,Ersatztext
    step i from 1 to itemCount(objects of groupID)
        if script of item i of objects of groupID contains Suchtext
            step n from 1 to wordCount(script of item i of objects of groupID)
                if word n of script of item i of objects of groupID = Suchtext as text
                    put Ersatztext into word n of script of item i of objects \
                            of groupID
                end    if
            end    step
        end    if
        if object of item i of objects of groupID is group
            get GruppeErsetzen(item i of objects of groupID,Suchtext, \
                    Ersatztext)
        end    if
    end    step
    return true
end    GruppeErsetzen
}

SCRIPT "Packen einer ToolBook-Datei"
BEHAVIOR "Automatisiert das Entfernen von ⁿberflⁿssigen Informationen aus einem Buch."
CATEGORY Testen
{
-- Aus dem Skript-Album
to handle BuchPacken
    LOCAL lpMem, TempDatei
    LOCAL INT status

    send linkDlls
    lpMem = getWinPointer(192)
    if lpMem = NULL
        break to system
    end

    sysCursor = 4
    status = GetTempFileName(0,"tbk",0,lpMem)
    TempDatei = pointerString(0,lpMem)
    fileName = name of this book
    save as TempDatei,TRUE
    save as fileName,TRUE
    get freeWinPointer(lpMem)
    get DateiEntfernen(TempDatei)
    syscursor = default
end    BuchPacken


to handle linkDlls
    linkDLL "kernel"
        WORD    globalAlloc         (WORD,DWORD)
        WORD    globalFree           (WORD)
        POINTER globalLock           (WORD)
        WORD    globalUnlock         (WORD)
        WORD    globalReAlloc       (WORD,DWORD,WORD)
        WORD     globalHandle        (INT)
        INT     getTempFileName        (INT,STRING,WORD,POINTER)
    end    linkDLL

    linkDLL sysToolBookDirectory & "tb30dos.dll"
        INT     DateiEntfernen             (STRING)
    end linkDLL
end    linkDLLs


to get getWinPointer memChunk
    LOCAL memHandle, lPointer

    memHandle = globalAlloc(66, MemChunk)    -- FIXED,ZEROINIT
    if memHandle = NULL
        return NULL
    end    if

    lPointer = globalLock(memHandle)
    if lPointer = NULL
        return NULL
    end    if

    return lPointer
end    getWinPointer


to get freeWinPointer lPointer
    LOCAL WORD memHandle
    LOCAL INT status
    LOCAL LOGICAL passFlag

    passFlag = TRUE

    if lPointer = NULL or item 1 of lPointer < 0
        return FALSE
    end    if

    memHandle = globalHandle(item 1 of lPointer)

    status = globalUnlock(memHandle)
    if status <> 0
        passFlag = FALSE
    else
        status = globalFree(memHandle)
        if status <> 0
            passFlag = FALSE
        end    if
    end    if
    return passFlag
end    freeWinPointer
}

SCRIPT "Entpacken eines DWord auf drei Byte"
BEHAVIOR    "Entpackt ein DWord auf drei Byte. Nⁿtzlich zum Abrufen von Farben und MIDI-Botschaften von Windows."
CATEGORIES    Werkzeuge
{
to get ExplizitByte gepacktDWord
    r = (gepacktDWord mod 256)
    g = (gepacktDWord mod 65536) bitShiftRight 8
    b = gepacktDWord bitShiftRight 16
    push b onto it
    push g onto it
    push r onto it
    return it
end    ExplizitByte
}

SCRIPT "Packen von drei Byte in ein DWord"
BEHAVIOR    "Packt drei Byte in ein DWort. Nⁿtzlich zum Senden von Farben und MIDI-Botschaften an Windows."
CATEGORIES    Werkzeuge
{
to get packenDWord rgb
    set r to item 1 of rgb
    set g to item 2 of rgb
    set b to item 3 of rgb
    set it to r + (g bitShiftLeft 8) + (b bitshiftLeft 16)
    return it
end    packenDWord
}
ACTION    "Verknⁿpfen mit timeGetTime()"
BEHAVIOR    "Stellt eine Verknⁿpfung mit timeGetTime() fⁿr Zeitereignisse. Dies ist ein besserer Zeitgeber als getTickCount."
CATEGORY    Windows
{
    linkdll "mmSystem"
        DWORD timeGetTime()
    end
}

ACTION    "Bildschirm aufleuchten lassen"
BEHAVIOR    "Veranla▀t das ToolBook-Fenster, $$mal bei einer Rate von ca. $$Geschw/Sekunde."
CATEGORIES    Effekte
ARG mal is "5"  help "Wie viele Male der Bildschirm aufleuchten soll."
ARG    Geschw is "100"    help "Je h÷her die Zahl, desto schneller das Blinken."
{
--to handle Blinken  -- empfohlene benutzerdefinierte Botschaft
    linkDLL "kernel"
          word     globalAlloc(word,dword)
        pointer globalLock(word)
        word     globalUnlock(word)
        word     globalFree(word)
    end    linkDLL

   linkDLL "user"
        word     invertRect(word,pointer)
        word     getClientRect(word,pointer)
        word     getDC(word)
        int     releaseDC(word,word)
    end    linkDLL

    set vHmem to globalAlloc(66, 8)
    set vPtrMem to globalLock(vHmem)
    get getClientRect(sysClientHandle,vPtrMem)
    set vHDC to getDC(sysClientHandle)
    set neueGeschw to 1000/$$Geschw

    step i from 1 to $$mal
        get invertRect(vHDC,vPtrMem)
        pause neueGeschw ticks
        get invertRect(vHDC,vPtrMem)
        pause neueGeschw ticks
    end step

    get releaseDC (sysClientHandle,vHDC)
    get GlobalUnlock(vHmem)
    get GlobalFree(vHmem)
    unlinkDLL "kernel"
    unlinkDLL "user"
--end
}

SCRIPT    "Ermitten der Ausfⁿhrungszeit"
BEHAVIOR    "Mit diesen zwei Behandlungsroutinen k÷nnen Sie Zeit-Tests durchfⁿhren. Sie vergleichen automatisch zwei Tests, die nacheinander durchgefⁿhrt werden."
CATEGORIES    Testen
{
to handle Startzeit
    system s_TestZeit
    linkDLL "mmSystem"
        DWORD timeGetTime()
    end    linkDLL
    set s_TestZeit to timeGetTime()
end    Startzeit

to handle showElapsedTime
    system s_TestZeit, s_LetzteTestZeit

    set AktTestZeit to (timeGetTime() - s_TestZeit) / 1000
    format number AktTestZeit as "#.0"

    set Hilfetext to "Dieser Test hat" && AktTestZeit && "Sekunden gedauert."
    if s_LetzteTestZeit <> 0 and s_LetzteTestZeit is not null
        get (AktTestZeit - s_LetzteTestZeit)
        set DeltaZeit to (it / Min(s_LetzteTestZeit,AktTestZeit)) * 100
        format number DeltaZeit as "#.0"
        if DeltaZeit <> 0

            conditions
            when DeltaZeit < 0
                set Relation to "schneller"
            when DeltaZeit > 0
                set Relation to "langsamer"
            end    conditions

            get abs(DeltaZeit)
            format number it as "#.0"
            put " Er war" && it & "%" && Relation &&\
              "als der vorherige Test." after Hilfetext
        end    if
    end    if
    request Hilfetext
    set s_LetzteTestZeit to AktTestZeit
    unlinkDLL "mmSystem" -- refCount dekrementieren
end    showElapsedTime
}

SCRIPT "Initialisieren eines Excel-GesprΣchs"
BEHAVIOR "Diese Funktion startet Excel, falls es noch nicht ausgefⁿhrt wird. Bei ▄bergabe eines Dateinamens wird Excel veranla▀t, die Datei zu laden, falls sie noch nicht ge÷ffnet ist."
CATEGORY Windows
{
to get ExcelInitialisieren Dateiname

    -- Ermitteln den aktuellen Status von Excel
    getRemote "Status" application "Excel" topic "System"

    -- Falls fehlgeschlagen, weil kein Server vorhanden ist,
    -- wird Excel gestartet
    if item 1 of sysError = "Fehlgeschlagen: Kein Server"
        linkDLL sysToolBookDirectory & "tb30win.dll"
            INT yieldApp()
        end linkDLL
        run "excel.exe" && Dateiname
        -- Deaktiviert Excel
        get yieldApp()
        getRemote "Status" application "Excel" topic "System"
        unlinkDLL sysToolBookDirectory & "tb30win.dll"
      end    if

      -- getRemote-Status soll Bereit liefern
    if it <> "Bereit"
        return FALSE
    end if

       -- Stellt sicher, da▀ Excel nicht minimiert ist
    executeRemote "[App.Restore()]" application "excel"

    -- Falls keine Datei angegeben wurde, wird TRUE geleifert
    if Dateiname = NULL
        return TRUE
    end if

    -- Prⁿft, ob fDateiname ge÷ffnet ist, falls ja, wird
    -- die Datei aktiviert
    executeRemote "[Activate(""" & Dateiname & """)]" \
     application "excel" topic Dateiname

    -- Falls fehlgeschlagen, weil kein Server vorhanden ist,
    -- wird versucht, die Datei zu ÷ffnen
    if item 1 of sysError = "Fehlgeschlaten: Kein Server"
        executeRemote "[Open(""" & Dateiname & """)]" \
         application "excel"
    end if

    -- Falls sysError OK ist, ist die Operation erfolgreich
    if item 1 of sysError = "OK"
        return TRUE
    end if
    return FALSE
end    ExcelInitialisieren
}

SCRIPT "Anzeigen eines ToolBook-Fensters im Desktop-Vordergrund"
BEHAVIOR "Bringt ein ToolBook-Fenster dynamisch in den Desktop-Vordergrund. Dies ist nⁿtzlich, wenn Sie verschiedene ToolBook-Anwendungen von einem Hauptbuch ausfⁿhren."
CATEGORY Windows
{
to handle FensterInVordergrund Anwendung

    linkDLL "user"
        --bringWindowToTop ist eine Windows-Funktion, die
        --das Fenster, dessen Zugriffsnummer ⁿbergeben wird,
        --vor allen anderen Fenstern anzeigt.
        INT bringWindowToTop(WORD)
    end linkDLL

    --getRemote liefert 9 separate Elemente in sysError
    --item 1 ist der Status der Fernanfrage
       getRemote "sysWindowHandle" application  toolBook topic Anwendung
    if (item 1 of sysError) is "OK"
        get bringWindowToTop(it)
        --bringWindowToTop pa▀t die Seitengr÷▀e nicht an
        --und stellt das Fenster nicht wiederher
        executeRemote "send SizeToPage" application toolbook \
         topic Anwendung
    else
        --die Anwendung lΣuft nicht, also wird sie gestartet
        run Anwendung
    end if

    unlinkDLL "user"
end FensterInVordergrund
}

SCRIPT    "Ermittelt die Bildschirmaufl÷sung"
BEHAVIOR    "Legt die Variable Bildschirmaufl÷sung auf die aktuelle Bildschirmaufl÷sung fest."
CATEGORY    Windows
{
to get Aufl÷sung
    local hAufl, vAufl, Bildschirmaufl÷sung

    linkDLL sysToolBookDirectory & "tb30win.dll"
        INT horizontalAnzeigeAufl()
        INT verticalAnzeigeAufl()
    end    linkDLL
    set hAufl to horizontalAnzeigeAufl()
    set vAufl to verticalAnzeigeAufl()

    push vAufl onto Bildschirmaufl÷sung  -- item 2 ist die vertikale Aufl÷sung
    push hAufl onto Bildschirmaufl÷sung  -- item 1 ist die horizontale Aufl÷sung

    unlinkDLL sysToolBookDirectory & "tb30win.dll"
    return Bildschirmaufl÷sung
end Aufl÷sung
}

SCRIPT "Ermitteln der Druckeraufl÷sung"
BEHAVIOR "Liefert die Druckaufl÷sung des Druckers in dpi (Punkte pro Zoll)"
CATEGORY Windows
{
to get DruckerAufl
    linkDll "GDI"
        WORD     createIC    (STRING,STRING,STRING,STRING)
        INT    getDeviceCaps    (WORD,INT)
        INT     deleteDC     (WORD)
    end linkDLL

    linkDLL sysToolBookDirectory & "tb30win.dll"
        STRING GetWinIniVar     (STRING, STRING)
    end linkDLL

    LOGPIXELSX = 88 -- Windows-Konstanten
    LOGPIXELSY = 90

    TreiberInfo = getWinIniVar("windows", "device")
    GerΣteInfo = item 1 of TreiberInfo

    if GerΣteInfo is NULL
        set sysError to "Es ist kein Drucker angeschlossen."
        unlinkDLL "GDI"
        unlinkDLL sysToolBookDirectory & "tb30win.dll"
        return NULL
    end if

    GerΣteDatei = item 2 of TreiberInfo
    GerΣteAnschlu▀ = item 3 of TreiberInfo

    hDC = createIC(GerΣteDatei,GerΣteInfo,GerΣteAnschlu▀,NULL)
    DrXAufl = getDeviceCaps(hDC,LOGPIXELSX)
    DrYAufl = getDeviceCaps(hDC,LOGPIXELSY)
    get deleteDC(hDC)

    unlinkDLL "GDI"
    unlinkDLL sysToolBookDirectory & "tb30win.dll"
    return DrXAufl & "," & DrYAufl
end DruckerAufl
}

SCRIPT "Ermitteln der Anzeigeaufl÷sung"
BEHAVIOR "Ermittelt die Aufl÷sung des Monitors in Pixeln pro Zoll"
CATEGORY Windows
{
to get AnzeigeAufl

    linkDLL sysToolBookDirectory & "tb30win.dll"
        INT    displayLogPixelsX()
        INT displayLogPixelsY()
    end linkDLL

    AnzeigePixX = displayLogPixelsX()
    AnzeigePixY = displayLogPixelsY()

    unlinkDLL sysToolBookDirectory & "tb30win.dll"
    return AnzeigePixX & "," & AnzeigePixY
end AnzeigeAufl
}

SCRIPT    "Ermittelt die Farben der Anzeige"
BEHAVIOR    "Liefert die Farbanzahl der Anzeige"
CATEGORIES    Windows
{
to get AnzahlFarben
    linkDLL "gdi"
        INT getDeviceCaps(WORD,INT)
    end linkDLL

    linkDLL "user"
        WORD getDC(WORD)
        INT  releaseDC(WORD,WORD)
    end linkDLL

    hDC = getDC(windowHandle of mainWindow)
    RⁿckWert = getDeviceCaps(hDC,24) -- 24 ist die Zauberzahl fⁿr Farben
    get ReleaseDC(windowHandle of mainWindow, hDC)
    unlinkDLL "gdi"
    unlinkDLL "user"
    return RⁿckWert
end    AnzahlFarben
}

SCRIPT    "Ermitteln der Farbe eines Pixels"
BEHAVIOR    "Ermittelt die Farbe eines beliebigen Pixels auf dem Bildschirm."
CATEGORIES    Windows
{
to handle buttonClick Pos
    linkDLL "user"
        WORD getDC(WORD)
        INT releaseDC(WORD,WORD)
    end    linkDLL

    linkDLL "gdi"
        DWORD getPixel(WORD,INT,INT)
    end    linkDLL

    linkDLL sysToolBookDirectory & "tb30WIN.DLL"
        STRING RGBtoHLS(DOUBLE,DOUBLE,DOUBLE)
     end    linkDLL

    get pageUnitsToClient(Pos)
    set XKoord to item 1 of it
    set YKoord to item 2 of it
    set hDC to getDC(sysClientHandle)
    get getPixel(hDC, XKoord, YKoord)
    if it <> -1     -- unwahrscheinlich
        Rotwert = it mod 256 -- holt das lobyte im loword
        it = it bitShiftRight 8
        Grⁿnwert = it mod 256 -- holt das lobyte im loword
        Blauwert = it bitShiftRight 8

        set HLSWert to RGBtoHLS(Rotwert, Grⁿnwert, Blauwert)
        if HLSWert = -20     -- sehr unwahrscheinlich
            request "Umwandlung von RGB in HLS ist fehlgeschlagen."
            unlinkDLL "gdi"
            unlinkDLL "user"
            unlinkDLL sysToolBookDirectory & "tb30win.dll"
            break buttonUp
        end    if

--        set text of field "RGB" to Rotwert&","&Grⁿnwert&","&Blauwert
--        set text of field "HLS" to HLSWert
--        set fillColor of rectangle "color" to HLSWert
        request "RGB ist" && Rotwert&","&Grⁿnwert&","&Blauwert
        request "HLS ist" && HLSWert
    else
        request "Fehler beim Abrufen der Pixelfarbe."
    end    if
    get ReleaseDC(sysWindowHandle, hDC)
    unlinkDLL "gdi"
    unlinkDLL "user"
    unlinkDLL sysToolBookDirectory & "tb30win.dll"
end buttonClick
}

SCRIPT    "Get the running version of Windows"
BEHAVIOR    "Returns the running version of Windows."
CATEGORIES    Windows
{
to get winVersion
    linkDLL "kernel"
        DWORD GetVersion()
    end
    set verNum to GetVersion()
    set WverNum to verNum mod 65536
    set majorNumber to WverNum mod 256
    set minorNumber to WverNum div 256
    unlinkDLL "kernel"
    return majorNumber &"." & minorNumber
 end winVersion
}

SCRIPT    "Ermitteln der aktuellen DOS-Version"
BEHAVIOR    "Liefert die laufende DOS-Version"
CATEGORIES    DOS
{
to get DOSVersion
    linkDLL "kernel"
        DWORD GetVersion()
    end
    set verNum to GetVersion()
    set DverNum to verNum div 65536
     set dNummer1 to DverNum div 256
    set dNummer2 to DverNum mod 256
    unlinkDLL "kernel"
    return dNummer1 & "." & dNummer2
end DOSVersion
}

SCRIPT "Beenden und Neustart von Windows"
BEHAVIOR "Diese Behandlungsroutine demonstriert eine Methode zu Beenden und Neustarten von Windows."
CATEGORY Windows
{
--Wenn Neustart true ist, wird Windows beendet und erneut gestartet.
--Wenn Neustart null oder false ist, wird Windows nur beendet.
to handle exitWindows Neustart
    linkDLL "user"
        INT ExitWindows (DWORD, INT)
    end linkDLL
    if Neustart is true
        get ExitWindows (66, 0)
    else
        get ExitWindows (0, 0)
    end if
    -- Abtrennen der Verknⁿpfung nicht n÷tig.
end    exitWindows
}

ACTION "Abrufen von Systeminformationen"
BEHAVIOR "Liefert Informationen ⁿber die auf dem System installierten Multimedia-Treiber"
CATEGORIES    Multimedia
ARG MediaTyp oneOf "all,animation,bitmap,cdAudio,digitalVideo,overlay,sequencer,vcr,videodisc,waveAudio" is "all" help "Choose a device type."
ARG Info oneOf "installname, quantity, quantity open, name 1, name 1 open" is "installname" help "Ermittelt Informationen ⁿber das GerΣt."
{
      sMS = sysMediaSuspend
    sysMediaSuspend = FALSE
    clear sysError
    GerΣtetyp = "$$MediaTyp"
    Info = "$$Info"

    get callMCI("sysInfo" && GerΣtetyp && Info)
    if sysError is NULL
        request it
    else
        if sMS = TRUE -- Fehlerbehandlung, falls der Benutzer dies erwartet
            request "Wird vom GerΣt" && QUOTE & GerΣtetyp & QUOTE && "nicht erkannt:" \
                && QUOTE & Info & QUOTE & ":" & CRLF & CRLF & sysError
        end if
    end if
    sysMediaSuspend = sMS
}

ACTION "Abrufen von GerΣteinformationen"
BEHAVIOR "Liefert Informationen ⁿber die FΣhigkeiten des Multimedia-Treibers"
CATEGORIES    Multimedia
ARG MediaTyp oneOf "all,animation,bitmap,cdAudio,digitalVideo,overlay,sequencer,vcr,videodisc,waveAudio" is "all" help "WΣhlen Sie einen GerΣtetyp aus."
ARG Info oneOf "can eject,can freeze,can play,can record,can reverse,can save,can stretch,compound device,device type,fast play rate,has audio,has video,inputs,normal play rate,outputs,slow play rate,uses files,uses palettes,windows" is "device type" help "Angegebene Info zum GerΣt abrufen."
{
    -- Wenn das Verhalten nicht vom Treiber unterstⁿtzt
    -- wird, jedoch in der Spezifikation unterstⁿtzt wird,
    -- liefert diese Funktion FALSE. Wenn das Verhalten
    -- nicht in der Spezifikation unterstⁿtzt wird, wird NULL
    --geliefert und einen Bericht eingerichtet, der angezeigt
    -- wird, wenn sysMediaSuspend TRUE ist.
    sMS = sysMediaSuspend
    sysMediaSuspend = FALSE
    clear sysError
    GerΣtetyp = "$$MediaTyp"
    cap = "$$Info"
    get callMCI("capability" && GerΣtetyp && cap)
    if sysError is NULL
        request it
    else
        if sMS = TRUE -- Fehlerbehandlung, falls der Benutzer dies erwartet
            request "Wird vom GerΣt nicht erkannt:" && QUOTE & GerΣtetyp & QUOTE && "" \
                && QUOTE & cap & QUOTE & ":" & CRLF & CRLF & sysError
        end if
    end if
    sysMediaSuspend = sMS
}


ACTION "Festlegen von Mischpult-Werten"
BEHAVIOR "Legt die LautstΣrke des virtuellen Audio-Mischpults fest"
CATEGORIES Multimedia
ARG EATyp oneOf "device_in,device_out" is "device_in" help "Eingabe oder Ausgabe auswΣhlen"
ARG GerΣtetyp oneOf "AMP,AUX,CDA,MIC,MUS,WAV" is "WAV" help "Gewⁿnschten GerΣtetyp auswΣhlen"
ARG Kanal oneOf "LEFT,RIGHT,BOTH" is "BOTH" help "Kanal auswΣhlen"
ARG Wert oneOf "1,2,3,4,5,6,7,8,9,10,11,12,13,14,15,16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31,32,33,34,35,36,37,38,39,40,41,42,43,44,45,46,47,48,49,50,51,52,53,54,55,56,57,58,59,60,61,62,63,64,65,66,67,68,69,70,71,72,73,74,75,76,77,78,79,80,81,82,83,84,85,86,87,88,89,90,91,92,93,94,95,96,97,98,99,100" is "99" help "Prozent der maximalen LautstΣrke auswΣhlen"
{
    -- Das virtuelle Mischpult arbeitet so gut wie m÷glich
    -- mit der auf dem ZielgerΣt installierten Soundkarte. Da
    -- es keinen wirklichen Standard gibt, ist das Ergebnis
    -- je nach Soundkarte verschieden
    clear sysError
    get mixerCommand("set tbkmixer $$EATyp $$GerΣtetyp control volume $$Kanal Wert")
    if it = 0
        if $$Kanal <> "both"
            request "LautstΣrke des $$Kanal Kanals des GerΣts $$GerΣtetyp ist auf $$Wert festgelegt"
        else
            request "Die LautstΣrke beider KanΣle des GerΣts $$GerΣtetyp ist auf $$Wert festgelegt"
        end if
    else
        request sysError
    end if
}

ACTION "Festlegen von Mischpult-Werten fⁿr ein GerΣt auf Leserebene"
BEHAVIOR "Erm÷glicht dem Benutzer, die LautstΣrke des virtuellen Audio-Mischpults festulegen"
CATEGORIES Multimedia
ARG EATyp oneOf "device_in,device_out" is "device_in" help "Eingabe oder Ausgabe auswΣhlen"
ARG GerΣtetyp oneOf "AMP,AUX,CDA,MIC,MUS,WAV" is "WAV" help "Gewⁿnshtes MCI-GerΣt zum Abfragen auswΣhlen"
{
    -- Das virtuelle Mischpult arbeitet so gut wie m÷glich
    -- mit der auf dem ZielgerΣt installierten Soundkarte. Da
    -- es keinen wirklichen Standard gibt, ist das Ergebnis
    -- je nach Soundkarte verschieden
    -- Dieses Skript ⁿberlΣ▀t dem Autoren die Auswahl des
    -- GerΣts, ⁿberlΣ▀t dem Benutzer jedoch die Auswahl des Werts
    local l_Abbrechen,l_Kanal,l_Wert
    request "Fⁿr welchen Kanal wollen Sie die LautstΣrke einstellen: Links Rechts oder Beides?" \
        with "Links" or "Rechts" or "Beides"
    if it <> null -- Null, falls it der System-SchaltflΣche oder alt+F4 abgebrochen wurde
        set l_Kanal to it
    else
        set l_Abbrechen to TRUE,"vom Benutzer abgebrochen."
    end if

    if item 1 of l_Abbrechen <> TRUE
        ask "Auf welchen Prozent des maximalen Werts soll die LautstΣrke eingestellt werden?" with "50"
        if isType(INT,it) and it >= 0  and it <=100
            set l_Wert to it
        else
            set l_Abbrechen to TRUE,"Ungⁿltiger Wert fⁿr LautstΣrke."
        end if
    end if
    clear sysError
    if item 1 of l_Abbrechen <> TRUE
        get mixerCommand("set tbkmixer $$EATyp $$GerΣtetyp control volume" && l_Kanal && l_Wert)
        if it = 0
            if l_Kanal <> "both"
                request "Kanal: "&& l_Kanal && " des GerΣtetyps $$GerΣtetyp device wurde auf folgenden Wert festgelegt:" && l_Wert
            else
                request "Die LautstΣrke beider KanΣle des GerΣts $$GerΣtetyp wurde auf folgenden Wert festgelegt" && l_Wert
            end if
        else
            request sysError
        end if
    else
        request "Der Befehl wurde nicht ausgefⁿhrt. Ursache:" && item 2 of l_Abbrechen
    end if
}

ACTION "Abrufen der Mischpult-Werte"
BEHAVIOR "Ermittelt die LautstΣrke des virtuellen Audio-Mischpults"
CATEGORIES Multimedia
ARG EATyp oneOf "device_in,device_out" is "device_in" help "Eingabe oder Ausgabe wΣhlen"
ARG GerΣtetyp oneOf "AMP,AUX,CDA,MIC,MUS,WAV" is "WAV" help "Das gewⁿnschte MCI-GerΣt zum Abfragen auswΣhlen"
ARG Kanal oneOf "LEFT,RIGHT,BOTH" is "BOTH" help "Kanal auswΣhlen"
{
    -- Das virtuelle Mischpult arbeitet so gut wie m÷glich
    -- mit der auf dem ZielgerΣt installierten Soundkarte. Da
    -- es keinen wirklichen Standard gibt, ist das Ergebnis
    -- je nach Soundkarte verschieden
    clear sysError
    get mixerCommand("get tbkmixer $$EATyp $$GerΣtetyp control volume $$Kanal")
    if sysError is NULL
        if $$Kanal <> "both"
            request "LautstΣrke des Kanals: $$Kanal des GerΣts $$GerΣtetyp ist auf folgenden Wert festgelegt:" && it
        else
            request "LautstΣrke fⁿr beide KanΣle des GerΣts $$GerΣtetyp ist auf folgenden Wert festgelegt" && it
        end if
    else
        request sysError
    end if
}

ACTION "Image-Befehl - FunktionalitΣt"
BEHAVIOR "Ruft Informationen ⁿber die FunktionalitΣt des Bitmap-Anzeigemoduls ab."
CATEGORIES Bilder
ARG Argumente oneOf "compound device,device type,has files,has video,static,uses palettes" is "device type" help "FunktionalitΣt auswΣhlen."
{
    get imageCommand("capability placeHolder $$Argumente")
    request it
}

ACTION "Image-Befehl - Close"
BEHAVIOR "Schlie▀t das Fenster und die mit dem Alias verbundene Datei"
CATEGORIES Bilder
ARG Alias is "myAlias" help "Der Dateiname bzw. der Alias, den Sie schlie▀en wollen, oder 'alle', um alle ge÷ffneten Bitmaps zu schlie▀en."
{
    get imageCommand("close $$Alias")
}

ACTION "Image-Befehl - Info"
BEHAVIOR "Ruft Informationen ⁿber das Fenster oder die mit dem Alias verbundene Datei auf"
CATEGORIES Bilder
ARG Alias is "myAlias" help "Der Dateiname oder der Alias, dessen Informationen Sie abrufen wollen."
ARG Argumente oneOf "product,text,file" is "file" help "Die Art der gewⁿnschten Informationen."
{
    get imageCommand("Info $$Alias $$Argumente")
    request it
}

ACTION "Image-Befehl - ╓ffnen"
BEHAVIOR "Initialisiert das Anzeigemodus und verbindet die Datei mit dem Alias"
CATEGORIES Bilder
ARG myBitmap FILE "Bitmap-Dateien(*.BMP),*.bmp,(*.DIB),*.dib" is "Cars.bmp" help "Die Bitmap-Datei, die angezeigt werden soll."
ARG Alias is "myAlias" help "Der Alias, der mit dieser Datei verbunden werden soll."
ARG Stil oneOf "overlapped,popup,child" is "overlapped" help "Choose the Stil of the window."
{
    get imageCommand("open $$myBitmap Alias $$Alias style $$Stil")
}

ACTION "Image-Befehl - Anzeigen"
BEHAVIOR "Zeigt die Datei im Fenster an, das mit dem Alias verbunden ist"
CATEGORIES Bilder
ARG Alias is "myAlias" help "Der Dateiname oder der Alias, der angezeigt werden soll!"
{
    get imageCommand("play $$Alias")
}


ACTION "Image-Befehl - Positionieren"
BEHAVIOR "Zeigt die Datei im Fenster an, das mit dem Alias verbunden ist"
CATEGORIES Bilder
ARG Alias is "myAlias" help "Der Dateiname oder der Alias, der angezeigt werden soll"
ARG Position oneOf "source,destination" is "destination" help "Offset und Position der Quelle oder des Ziels."
ARG x1 is "0" help "Offset horizontal."
ARG y1 is "0" help "Offset vetikal."
ARG x2 is "100" help "Position horizontal."
ARG y2 is "100" help "Position vertikal."
{
    get imageCommand("put $$Alias $$Position at $$x1 $$y1 $$x2 $$y2")
}


ACTION "Image-Befehl  - Status"
BEHAVIOR "Ermittelt den Status des Fensters und der Datei, das bzw. der mit dem Alias verbunden ist"
CATEGORIES Bilder
ARG Alias is "myAlias" help "Der Dateiname oder der Alias, dessen Status Sie abrufen wollen!"
ARG Argumente oneOf "window,position,extent,size,visible,style,palette" is "position" help "Das Element, dessen Status Sie abrufen wollen."
{
    get imageCommand("status $$Alias $$Argumente")
    request it
}

ACTION "Image Command - Bereich"
BEHAVIOR "Ermitteln das Rechteck, das den Quell- bzw. Zielbereich des Bilds bestimmt."
CATEGORIES Bilder
ARG Position oneOf "source,destination" is "destination" help "Offset und Position der Quelle bzw. des Ziels bestimmen."
ARG Alias is "myAlias" help "Der Dateiname bzw. des Alias, dessen Bereich bestimmt werden soll!"
{
    get imageCommand("where $$Alias $$Position")
    request it
}

ACTION "Image-Befehl - Fenster"
BEHAVIOR "Parameter des mit dem Alias verbundenen Fensters Σndern"
CATEGORIES Bilder
ARG Alias is "myAlias" help "Der Dateiname bzw. der Alias, der geschlossen werden soll, oder 'Alle, um alle ge÷ffneten Bitmaps zu schlie▀en!"
ARG Argumente oneOf "text,position,size" is "position" help "Den zu Σndernden Akspekt des Fenster auswΣhlen."
ARG Wert help "Unter 'Text' die Beschrift des Fensters, oder 'Default' fⁿr den Namen der Bitmap. Fⁿr 'Position' und 'Gr÷▀e' verwenden Sie zwei Pixelwerte, z.B. '100,100'."
{
    get imageCommand("window $$Alias $$Argumente $$Wert")
}

ACTION "Image Command - Fensterzustand"
BEHAVIOR "─ndert den Zustand des mit dem Alias verbundenen Fensters"
CATEGORIES Bilder
ARG Alias is "myAlias" help "Der zu schlie▀ende Dateiname bzw. Alias, oder 'Alle, um alle ge÷ffneten Bitmaps zu schlie▀en"
ARG Wert oneOf "hide,minimize,minimized,show,maximize,iconic,asIs,asWas,normal" is "show" help "Mit diesen Konstanten k÷nnen Sie die Fensteranzeige genauer steuern."
{
    get imageCommand("window $$Alias state $$Wert")
}

ACTION    "Abspielen einer Klangdatei als neuen Clip"
BEHAVIOR "Erstellt einen Clip von einer Klangdatei unter Verwendung von 'Klangdatei' ($$Klangdatei) und spielt den Clip ab."
CATEGORY    Clips,Audio
ARG     Klangdatei FILE "Klangdateien (*.WAV),*.wav" is "Akkord.Wav" help "╓ffnet die gewⁿnschte Klangdatei."
ARG clipName is "myClip" help "Dem neuen Clip einen Namen zuweisen."
ARG Startzeit is "0:00:00" help "Legt eine Zeitdauer in 'Minuten:Sekunden:Millisekunden-Format; Voreinstellung ist der Anfang der Datei."
ARG EndZeit is "0:10:00" help "Legt eine Zeitdauer in 'Minuten:Sekunden:Millisekunden-Format; Voreinstellung ist 10 Sekunden nach dem Anfang der Datei."

{
     -- Der neue Clip wird erstellt, wenn das Skript
    -- aktiviert wird (nicht wenn es geschrieben
    -- wird), also mⁿssen Sie sicherstellen, da▀
    -- sich die Klangdatei im richtigen Verzeichnis
    -- befindet, bevor das Skript aktiviert wird
      new clip from "$$Klangdatei"
      name of it = "$$clipName"
      mediaRef = clip "$$clipName"
      mmTimeFormat of mediaRef = "MSms"
      mmBeginPoint of mediaRef = "$$Startzeit"
      mmEndPoint of mediaRef = "$$Endzeit"
      mmPlay mediaRef autoclose
}



ACTION    "Abspielen einer AVI-Datei als Clip"
BEHAVIOR "Erstellt einen Clip von einer AVI-Datei unter Verwendung von 'AVIDatei' ($$AVIDatei) und spielt ihn ab."
CATEGORY    Clips,Video
ARG     AVIDatei FILE "AVI-Dateien (*.avi),*.avi" is "windmⁿhle.avi" help "╓ffnet die AVI-Datei."
ARG clipName is "myClip" help "Dem neuen Clip einen Namen zuweisen."
ARG Startzeit is "0" help "Einzelbildnummer festlegen, Voreinstellung ist der Anfang der Datei."
ARG Endzeit is "300" help "Einzelbildnummer festlegen, Voreinstellung ist Einzelbild 300."
ARG ClipRahmen OBJTYP "Stage" is "stage myStage" help "Clip-Rahmen-Objekt fⁿr die Wiedergabe auswΣhlen"
{
     -- Der neue Clip wird erstellt, wenn das Skript
    -- aktiviert wird (nicht wenn es geschrieben
    -- wird), also mⁿssen Sie sicherstellen, da▀
    -- sich die AVI-Datei im richtigen Verzeichnis
    -- befindet, bevor das Skript aktiviert wird
      new clip from "$$AVIDatei"
      name of it = "$$clipName"
      mediaRef = clip "$$clipName"
      mmTimeFormat of mediaRef = "frames"
      mmBeginPoint of mediaRef = "$$Startzeit"
      mmEndPoint of mediaRef = "$$Endzeit"
      mmPlay mediaRef in $$ClipRahmen autoclose
}


ACTION    "Erstellen und Abspielen eines AVI-Clips ohne Clip-Manager"
BEHAVIOR "Erm÷glicht dem Benutzer, einen AVI-Clip zu erstellen und diesen abzuspielen."
CATEGORY    Clips,Video
ARG ClipName is "Namen des neuen Clips eingeben" help "Dies ist der Standardtext, den der Benutzer sehen wird, Sie k÷nnen ihn auch nach Bedarf anpassen."
ARG ClipRahmen OBJTYP "Stage" is "stage myStage" help "Clip-Rahmen-Objekt fⁿr die Wiedergabe auswΣhlen"
ARG AnfPunkt is "Anfangspunkt fⁿr den Clip in Einzelbildern eingeben" help "Dies ist der Standardtext, den der Benutzer sehen wird, Sie k÷nnen ihn auch nach Bedarf anpassen."
ARG Endpunkt is "Geben Sie einen Endpunkt fⁿr den Clip in Einzelbildern ein" help "Dies ist der Standardtext, den der Benutzer sehen wird, Sie k÷nnen ihn auch nach Bedarf anpassen."
ARG    Beschrift    is    "╓ffnen einer AVI-Datei"    help "Dies ist der Standardtext, den der Benutzer sehen wird, Sie k÷nnen ihn auch nach Bedarf anpassen."
ARG    Hilfetext    is    "Zu ÷ffnende AVI-Datei auswΣhlen" help "Dies ist der Standardtext, den der Benutzer sehen wird, Sie k÷nnen ihn auch nach Bedarf anpassen."
{
     -- Der neue Clip wird vom Benutzer erstellt, also ist dies
    -- flexibler als das Skript fⁿr 'Abspielen einer Klangdatei als Clip'.
     -- Dies ist ein gutes Beispielskript, da Voreinstellungen und Fehler
    --  behandelt werden.
    while not (sysSupportedMedia contains "digitalVideo")
        request  "Fehler: Skriptausfⁿhrung abgebrochen." & CRLF \
          & "Multimedia ToolBook kann auf digitales Video nicht zugreifen." & CRLF \
          & "M÷glicherweise fehlen die ben÷tigten Treiber."
        break to system
    end while
    linkDll sysToolBookDirectory & "tb30dlg.dll"
        string openDlg(string,string,string,string)
    end    linkDLL

    get openDlg(".","*.avi","$$Hilfetext","$$Beschrift")
    if it <> null
        newAVI = it

        do
            ask "$$ClipName" with "newClip"
            if it is null
                request "Wollen Sie die Clip-Erstellung wirklich abbrechen?" \
                  with "Ja, abbrechen" or "Nein, erneut versuchen"
                if it contains "Ja"
                    break to system
                else
                    clear it
                  end if
            end if
        until it <> null
        clipName = it

        new clip from newAVI
        name of it = clipName
        mediaRef = clip clipName
        while not (mmPlayable of mediaRef)
            request "Dieser Clip kann nicht abgespielt werden"
            break to system
        end while
        mmTimeFormat of mediaRef = "frames"

         sS = sysSuspend
        sMS = sysMediaSuspend
        sysSuspend = FALSE
        sysMediaSuspend = FALSE

        ask  "$$AnfPunkt" with "0"
        clear sysError
        mmBeginPoint of mediaRef = it
        if sysError <> null
            request "Fehler: der Anfangspunkt des Clips ist auf die Voreinstellung festgelegt: ""0"""
            mmBeginPoint of mediaRef = "0"
        end if

        ask "$$Endpunkt" with "300"
        clear sysError
         mmEndPoint of mediaRef = it
        if sysError <> null
            request "Fehler: der Endpunkt des Clips ist auf die Voreinstellung festgelegt: ""300"""
            mmEndPoint of mediaRef = "300"
        end if

        sysSuspend = sS
        sysMediaSuspend = sMS
        if mmPlayable of mediaRef
            mmPlay mediaRef in $$ClipRahmen autoclose
        end if
    end if

    unlinkDLL sysToolBookDirectory & "tb30dlg.dll"
}

ACTION    "Erstellen und Abspielen eines Klang-Clips"
BEHAVIOR "Erm÷glicht dem Benutzer, einen Clip von einer Klangdatei zu erstellen, und spielt ihn ab."
CATEGORY    Clips,Audio
ARG ClipName is "Namen des neuen Clips eingeben" help "Voreinstellung ⁿbernehmen oder nach Bedarf anpassen."
ARG AnfPunkt is "AnfPunkt fⁿr den Clip im 'Minuten:Sekunden:Millisekunden'-Format eineben" help "Voreinstellung ⁿbernehmen oder nach Bedarf anpassen."
ARG Endpunkt is "Endpunkt fⁿr den Clip im 'Minuten:Sekunden:Millisekunden'-Format eineben" help "Voreinstellung ⁿbernehmen oder nach Bedarf anpassen."
ARG    Beschrift    is    "Klangdatei ÷ffnen"    help "Voreinstellung ⁿbernehmen oder nach Bedarf anpassen."
ARG    Hilfetext    is    "Zu ÷ffnende Klangdatei auswΣhlen" help "Voreinstellung ⁿbernehmen oder nach Bedarf anpassen."
{
     -- Der neue Clip wird vom Benutzer erstellt, also ist dies
    -- flexibler als das Skript fⁿr 'Abspielen einer Klangdatei als Clip'.
     -- Dies ist ein gutes Beispielskript, da Voreinstellungen und Fehler
    --  behandelt werden.

    -- Diese Struktur korrigiert die Tendenz der Auto-Skript-Funktion,
    -- die break-Anweisung in einer if-Struktur nicht richtig zu verarbeiten
    while not (sysSupportedMedia contains "waveAudio")
        request  "Fehler: Skriptausfⁿhrung wird abgebrochen." & CRLF \
          & "Der Multimedia-Treiber kann das waveAudio-GerΣt nicht finden." & CRLF \
          & "M÷glicherweise sind die erforderlichen Treiber nicht verfⁿgbar."
        break to system
    end while
    linkDll sysToolBookDirectory & "tb30dlg.dll"
        string openDlg(string,string,string,string)
    end    linkDLL

    get openDlg(".","*.wav","$$Hilfetext","$$Beschrift")
    if it <> null
        newWave = it

        do
            ask "$$ClipName" with "newClip"
            if it is null
                request "Wollen Sie die Clip-Erstellung wirklich abbrechen?" \
                  with "Ja, abbrechen" or "Nein, erneut versuchen"
                if it contains "Ja"
                    break to system
                else
                    clear it
                  end if
            end if
        until it <> null
        clipName = it

        new clip from newWave
        name of it = clipName
        mediaRef = clip clipName
        mmTimeFormat of mediaRef = "MSms"

         sS = sysSuspend
        sMS = sysMediaSuspend
        sysSuspend = FALSE
        sysMediaSuspend = FALSE

        ask  "$$AnfPunkt" with "0:00:00"
        clear sysError
        mmBeginPoint of mediaRef = it
        if sysError <> null
            request "Fehler: der Anfangspunkt des Clips ist auf die Voreinstellung festgelegt: ""0:00:00"""
            mmBeginPoint of mediaRef = "0:00:00"
        end if

        ask "$$Endpunkt" with "0:05:00"
        clear sysError
         mmEndPoint of mediaRef = it
        if sysError <> null
            request "Fehler: der Endpunkt des Clips ist auf die Voreinstellung festgelegt: ""0:05:00"""
            mmEndPoint of mediaRef = "0:05:00"
        end if

        sysSuspend = sS
        sysMediaSuspend = sMS
        if mmPlayable of mediaRef
            mmPlay mediaRef autoclose
        end if
    end if

    unlinkDLL sysToolBookDirectory & "tb30dlg.dll"
}

ACTION    "Automatisches Starten und Ausfⁿhren eines Buchs"
BEHAVIOR    "Beispielprogramm fⁿr ein fortlaufendes Buch."
HANDLERS    enterApplication, enterBook, enterBackground, buttonClick, buttonUp, buttonDown
CATEGORIES Seitenwechsel
ARG    Effekt    oneOf    "blinds,dissolve,drip,fade,iris,puzzle,tear"  is "fade"
ARG    Geschw    oneOf    "Normal,Fast,Slow"    is    "Normal"
ARG PauseZeit    oneof    "1,2,3,4,5,6,7,8,9,10" is "5" help "Die Zeitdauer in Sekunden, die jede Seite angezeigt werden soll."
{
     send reader
    send sizeToPage
    set caption of mainWindow to name of this page
    forward

    -- unterbindet die Bildschirmaktualisierung
    set sysLockScreen to TRUE
    set sysLockScreen to FALSE

    show statusBar
    set caption of statusBar to "Leertaste gedrⁿckt halten, um die Demo abzubrechen"

    while keyState(keySpace) <> down
        transition    "$$Effekt $$Geschw" to next page
        set caption of mainWindow to name of this page
        pause $$PauseZeit
    end while
    set caption of statusBar to " "
}

ACTION "Schrittweises Durchlaufen eines Clips"
BEHAVIOR "Zeigt ein Video oder eine Animation schrittweise an"
CATEGORIES Clips, Video
ARG ClipRef  Clip is "clip id 100" help "Zu spielenden Clip auswΣhlen."
ARG Schritt is "1" help "Eine ganze Zahl von 1 bis zur Anzahl der Einzelbilder im Clip."
ARG ClipRahmen OBJTYP "Stage" is "stage myStage" help "Clip-Rahmen fⁿr die Clip-Wiedergabe auswΣhlen"
ARG Verz÷g is "100" help "Verz÷gerung in ticks (1/100 Sekunde), also ist '100' = 1 Sekunde, '50' = 1/2 Sekunde."
{
    if mmIsOpen of $$ClipRef
        mmClose $$ClipRef wait
    end if
    mmOpen $$ClipRef  wait

    altZeitFor = mmTimeFormat of $$ClipRef
    mmTimeFormat of $$ClipRef  = "frames"
    BildVar = $$Schritt

    maxFrame = mmLength of $$ClipRef
    conditions
    when BildVar < 1
        BildVar = 1
    when BildVar > maxFrame
        BildVar = maxFrame
    end conditions

    mmCue $$ClipRef

    conditions
    when $$Verz÷g < 1
        myDelay = 1
    when $$Verz÷g > 231
        myDelay = 231
    else
        myDelay = $$Verz÷g
    end conditions
    step i from 1 to (floor(maxframe/BildVar))-1
        mmShow $$ClipRef  in $$ClipRahmen  wait
        pause myDelay
        mmStep $$ClipRef by BildVar
    end step
    mmShow clip "windmⁿhle"  in $$ClipRahmen  wait
    mmSeek clip "windmⁿhle" to maxFrame
    mmShow clip "windmⁿhle"  in $$ClipRahmen  wait
    mmTimeFormat of $$ClipRef  = altZeitFor
}

SCRIPT "Fortlaufendes Abspielen eines visuellen Clips"
BEHAVIOR "Mit der mmNotify-Botschaft k÷nnen Sie einen Animations- bzw. Video-Clips fortlaufend abspielen. Dieses Skript wird im Seitenskript implementiert."
CATEGORIES Clips,Video
ARG ClipRef CLIP is "clip id 100" help "Zu spielenden Clip auswΣhlen."
ARG ClipRahmen OBJTYP "Stage" is "stage myStage" help "Clip-Rahmen-Objekt fⁿr die Wiedergabe auswΣhlen"
{
to handle enterPage
    forward
    --Bei enterPage den Clip kennzeichnen und abspielen
    mmOpen $$ClipRef
    send playScore
end enterPage

to handle playScore
    mmPlay $$ClipRef in $$ClipRahmen notify self
end playScore

to handle mmNotify mediaRef, commandName, cErgebnis
    if (mediaRef = $$ClipRef) and (cErgebnis = "successful")
        send playScore
    end if
end mmNotify
}

SCRIPT "Fortlaufendes Abspielen eines beliebigen Clips"
BEHAVIOR "Mit der mmNotify-Botschaft k÷nnen Sie einen Clip fortlaufend abspielen. Dieses Skript wird im Seitenskript implementiert."
CATEGORIES Clips
ARG ClipRef CLIP is "clip id 100" help "Den abzuspielenden Clip auswΣhlen."
{
to handle enterPage
    forward
    --Clip bei enterPage kennzeichnen und abspielen
    mmOpen $$ClipRef
    send playScore
end enterPage

to handle playScore
    mmPlay $$ClipRef notify self
end playScore

to handle mmNotify mediaRef, commandName, cErgebnis
    if (mediaRef = $$ClipRef) and (cErgebnis = "successful")
        send playScore
    end if
end mmNotify
}

SCRIPT "Festlegen des Text eines Felds auf die Clip-Position"
BEHAVIOR "Zeigt die aktuelle Position eines Clips in einem Feld wΣhrend des Clip-Ablaufs an"
CATEGORIES Werkzeuge
ARG ClipRef CLIP is "clip id 100" help "Clip auswΣhlen, der ⁿberwacht werden soll."
{
-- Dieses Skript wird im Skript des Felds implementiert, das die Position anzeigen soll
notifyBefore idle
    cName = $$ClipRef
    if (mmIsOpen of cName)
        oldPos = my text
        newPos = mmPosition of cName
        if oldPos <> newPos
            my text = newPos
        end if
    end if
end idle
}