home *** CD-ROM | disk | FTP | other *** search
/ Boink! 1995 May/June / Image.bin / spiele / 3dspiel / dummtool / doomco.bat < prev    next >
DOS Batch File  |  1994-04-15  |  1KB  |  56 lines
  1. @ECHO OFF
  2. REM By Fred Hennige 4/10/94 (74247,716)
  3. REM Thanks to Cris Williams (75300,2704)
  4. REM 
  5. REM DOOMCOM.BAT starts raw communications for modem-to-modem games. It
  6. REM bypasses the SERSETUP program.
  7. REM
  8. REM Type DOOMCOM c ####### to initiate a call for a modem-to-modem
  9. REM game (where ####### is another player's the phone #). Then follow the 
  10. REM prompts.
  11. REM
  12. REM Type DOOMCOM r to receive a call for a modem-to-modem game. Then 
  13. REM follow the prompts.
  14. REM
  15. REM This batch file assumes that you are using COM2 for your modem. Make
  16. REM changes to all references to the appropriate COM port if necessary.
  17. IF %1x == x goto noparm
  18. MODE COM2:96,n,8,1,p
  19. REM Change next line to match your modem's setup string for no compression 
  20. REM or error checking.
  21. ECHO AT Z \N1 >COM2
  22. IF %1 == r goto rcall
  23. IF %1 == R goto rcall
  24. IF %1 == c goto ccall
  25. IF %1 == C goto ccall
  26. GOTO invparm
  27. :rcall
  28. ECHO Wait for modem to receive call then
  29. PAUSE
  30. ECHO ATA >COM2
  31. goto start
  32. :ccall
  33. IF %2x == x GOTO nonumber
  34. ECHO Ready modem to dial.
  35. PAUSE
  36. REM The *70, in the next line disables call waiting. Remove it (*70,) if you want.
  37. ECHO ATDT*70,%2 >COM2
  38. GOTO start
  39. :noparm
  40. ECHO No parameters entered.
  41. GOTO end
  42. :nonumber
  43. ECHO No phone number entered.
  44. GOTO end
  45. :invparm
  46. ECHO Invalid command line parameter.
  47. GOTO end
  48. :start
  49. ECHO Wait for connection then
  50. PAUSE
  51. REM If drive and/or directory are different, change the next two lines.
  52. D:
  53. CD \DOOM
  54. SETUP
  55. :end
  56.