home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Archive Magazine 1996
/
ARCHIVE_96.iso
/
discs
/
shareware
/
share_46
/
fre
/
re_formal
< prev
Wrap
Text File
|
1992-04-21
|
2KB
|
82 lines
re ::- expr*
any_char ::- `.'
c_escape_sequence ::- literal_c_escape
| octal_c_escape
| hex_c_escape
charset ::- set
| literal
| literal `-' literal
command ::- literal_command
| compound_command
| set
| `\' literal_command
| `[' charset* `]'
| literal
compound_command ::- start_string
| end_string
| start_word
| end_word
| word_boundary
| start_symbol
| end_symbol
| symbol
| word
end_line ::- `$'
end_string ::- `\''
end_symbol ::- `\╗'
end_word ::- `\>'
expr ::- command operator*
| `(' expr? ')'
| `\{' expr? `\}'
| memory
hex_c_escape ::- `x' hex_digit hex_digit?
hex_digit ::- [0-9a-fA-F]
initial_symbol_char ::- `\s'
literal ::- `\' c_escape_sequence
| <char>
literal_c_escape ::- `a'
| `b'
| `f'
| `n'
| `r'
| `t'
| `v'
literal_command ::- any_char
| start_line
| end_line
| not
many ::- `+'
memory ::- `\' [1-9]
not ::- `~' command
octal_c_escape ::- `0' octal_digit? octal_digit?
octal_digit ::- [0-7]
operator ::- repeat
| many
| optional
| or
optional ::- `?'
or ::- `|' re
repeat ::- `*'
set ::- word_char
| symbol_char
| initial_symbol_char
start_line ::- `^'
start_string ::- `\`'
start_symbol ::- `\½'
start_word ::- `\<'
symbol ::- `\S'
symbol_char ::- `\y'
word ::- `\W'
word_boundary ::- `\@'
KEY
===
(symbol) ? = 0 or 1 times
(symbol) * = 0 or many times
(symbol) + = 1 or many times
(symbol) | (symbol) = either
[] = a range of characters