home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / wgsa.asc < prev    next >
Text File  |  1996-06-30  |  11KB  |  269 lines
  1. 2 ON ERROR GOTO 60000
  2. 3 CLS
  3. 10 PRINT " ***************************************************************"
  4. 20 PRINT " *                    WAVEGUIDE-SLOT ANTENNA                   *"
  5. 30 PRINT " *        REFERENCE-  MIT/RADLAB, PRINCIPLES OF RADAR          *"
  6. 40 PRINT " *         MORENO, MICROWAVE TRANSMISSION DESIGN DATA          *"
  7. 50 PRINT " *                PROGRAM BY  R.P. HAVILAND, W4MB              *"
  8. 60 PRINT " *                       COPYRGHT 1990                         *"
  9. 70 PRINT " *          MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086        *"
  10. 80 PRINT " ***************************************************************"
  11. 90 DEF FNP(X)=INT(100*X+.5)/100
  12. 100 PI=3.141592
  13. 110 DIM RTABL(5,18),CTABL(2,13)
  14. 120 PRINT "  WHICH ASSUMES USE OF COMMERCIAL PIPE FOR DESIGNS,"
  15. 130 PRINT "   EIA AND MIL TYPES ARE USUALLY IDENTICAL IN SIZE."
  16. 140 PRINT " ONLY TWO SIMPLE TYPES ARE INCLUDED IN THIS PROGRAM,"
  17. 200 FOR N=1 TO 18
  18. 210 FOR M=1 TO 5
  19. 220 READ RTABL(M,N)
  20. 230 NEXT M
  21. 240 NEXT N
  22. 250 FOR N=1 TO 13
  23. 260 FOR M=1 TO 2
  24. 270 READ CTABL(M,N)
  25. 280 NEXT M
  26. 290 NEXT N
  27. 400 PRINT "    THE FOLLOWING ROUTINES ARE AVAILABLE"
  28. 410 PRINT "            1- SEE SCHEMATIC"
  29. 420 PRINT "            2- SEE STANDARD SIZES"
  30. 430 PRINT "            3- SET DESIGN"
  31. 440 PRINT "            4- CHANGE GUIDE SIZE"
  32. 450 PRINT "            5- UNITS CONVERT"
  33. 460 PRINT "            6- PRINT PAPER COPY"
  34. 470 PRINT "            7- QUIT"
  35. 500 INPUT " ENTER ROUTINE TO USE";RS
  36. 510 ON RS GOSUB 1000,2000,3000,4000,5000,6000,7000,400
  37. 520 CLS
  38. 530 GOTO 400
  39. 1000 CLS 
  40. 1010 PRINT 
  41. 1020 PRINT "    EEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEE"
  42. 1030 PRINT 
  43. 1040 PRINT "            T                                      T"
  44. 1050 PRINT "      SSSSSSSSSSSSSS      SSSSSSSSSSSSSS     SSSSSSSSSSSSSS"  
  45. 1060 PRINT "                                T"
  46. 1070 PRINT 
  47. 1080 PRINT "    EEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEEE"
  48. 1090 PRINT 
  49. 1100 PRINT "    E= EDGE OF WAVEGUIDE           S= SLOT"
  50. 1110 PRINT "    T= TUNING SCREW, PROJECTS INTO GUIDE"
  51. 1120 PRINT "        NOTE SIDE ALTERNATION"
  52. 1200 PRINT 
  53. 1210 PRINT " LENGTH OF SLOT= ONE-HALF WAVELENGTH IN AIR"
  54. 1220 PRINT "   C-C SPACING OF SLOTS= ONE-HALF WAVELENGTH IN GUIDE"
  55. 1230 PRINT "    WIDTH OF SLOT= 1/20 WAVELENGTH TYPICALLY"
  56. 1240 PRINT " A MATCHING SCREW MAY BE PLACED AT CENTER OF INTER-SLOT SPACE."
  57. 1250 PRINT "  WHEN GUIDE IS MOUNTED VERTICALLY, RADIATION IS HORIZONTALLY POLARIZED."
  58. 1260 PRINT 
  59. 1270 INPUT "PRESS RETURN TO CONTINUE";T$
  60. 1999 RETURN
  61. 2000 INPUT "ENTER GUIDE TYPE, R=RECTANGULAR, C=CIRCULAR";TG$
  62. 2010 IF TG$<>"R" AND TG$<>"C" THEN 2000
  63. 2060 IF TG$="R"THEN 2600
  64. 2100 CLS
  65. 2110 PRINT "    COMMERCIAL CIRCULAR COPPER TUBING SIZES"
  66. 2120 PRINT "          DIMENSIONS IN INCHES"
  67. 2130 PRINT "DIAMETER","WALL","LOWER WAVLENG","UPPER WAVLENG."
  68. 2140 FOR N=1 TO 13
  69. 2150 PRINT CTABL(1,N),CTABL(2,4),3.1*CTABL(1,N),3.6*CTABL(1,N)
  70. 2160 NEXT N
  71. 2170 GOTO 2990
  72. 2600 CLS
  73. 2610 PRINT "    COMMERCIAL RECTANGULAR COPPER TUBING SIZES"
  74. 2620 PRINT "A-HEIGHT","B-WIDTH","WALL","LOWER WAVLENG","UPPER WAVLENG."
  75. 2630 FOR N=1 TO 18
  76. 2640 PRINT RTABL(1,N),RTABL(2,N),RTABL(3,N),2.1*RTABL(2,N),3.3*RTABL(2,N)
  77. 2650 NEXT N
  78. 2660 PRINT "  FOR RECTANGULAR GUIDE, CAN USE 'PC-BOARD' TO CONSTRUCT GUIDE"
  79. 2990 INPUT "   PRESS RETURN TO CONTINUE";T$
  80. 2999 RETURN
  81. 3000 CLS
  82. 3010 INPUT" ENTER DESIGN CENTER FREQUENCY, MHZ";FO
  83. 3020 LAM=29980/FO
  84. 3030 LAMIN=LAM/2.54
  85. 3040 PRINT "   WAVELENGTH=";FNP(LAM);"CM, OR";FNP(LAMIN);"INCHES"
  86. 3050 INPUT " ENTER GUIDE TYPE, R=RECTANGULAR, C=CIRCULAR";TG$
  87. 3060 IF TG$<>"R" AND TG$<>"C" THEN 3050
  88. 3070 TN=1
  89. 3080 IF TG$="C" THEN 3500 
  90. 3090 IF TN>18 THEN PRINT " BEST SIZE IS BEYOND TABLES":TN=18:GOTO 3100
  91. 3100 IF LAMIN<RTABL(2,TN) THEN TN=TN+1:GOTO 3080
  92. 3110 ADIM=RTABL(2,TN)-2*RTABL(3,TN):BDIM=RTABL(1,TN)-2*RTABL(3,TN) 
  93. 3120 PRINT " TRIAL GUIDE =";ADIM;"BY";BDIM;"INCHES, INSIDE"
  94. 3130 MMODE=1:NMODE=0:MODT$="E"
  95. 3140 CWIN=2/SQR((MMODE/ADIM)^2+(NMODE/BDIM)^2) 'INCHES
  96. 3300 IF CWIN<LAMIN THEN PRINT " MODE IS BELOW CUTOFF":TN=TN-1:GOTO 3100
  97. 3310 IF CWIN>2*LAMIN THEN PRINT "*** NOT RECOMMENDED: MULTI-MODES LIKELY ***"
  98. 3320 CWCM=CWIN*2.54
  99. 3330 FC=29980/CWCM
  100. 3340 ZG=377*LGIN/LAMIN*2*BDIM/ADIM
  101. 3350 LGIN=LAMIN/SQR(1-(LAMIN/CWIN)^2)  
  102. 3360 LGCM=LGIN*2.54
  103. 3370 PRINT 
  104. 3380 PRINT " FOR GUIDE";ADIM;"BY";BDIM;"INCHES, INSIDE"
  105. 3390 PRINT "  NOMINALLY";RTABL(2,TN);"BY";RTABL(1,TN);"INCHES OUTSIDE"
  106. 3400 PRINT "   OPERATING IN MODE TE01"
  107. 3410 PRINT "    CUTOFF WAVELENGTH=";CWCM;"CM"
  108. 3420 PRINT " AT FREQUENCY OF";FO;"MHZ"
  109. 3430 PRINT "  WAVELENGTH IN AIR =";FNP(LAM);"CM"
  110. 3440 PRINT "                    =";FNP(LAMIN);"INCHES"
  111. 3450 PRINT "  WAVELENGTH IN GUIDE=";FNP(LGCM);"CM"
  112. 3460 PRINT "                     =";FNP(LGIN);"IN"
  113. 3470 GOTO 3800
  114. 3500 N=0
  115. 3510 IF TN>13 THEN PRINT " BEST SIZE IS BEYOND TABLES:TN=13:GOTO 3530
  116. 3520 IF LAMIN<CTABL(1,TN) THEN TN=TN+1:GOTO 3510
  117. 3530 RAD=CTABL(1,TN)/2-CTABL(2,TN)
  118. 3540 PRINT " TRIAL GUIDE=";2*RAD;"INCHES INSIDE DIAMETER"
  119. 3550 MMODE=0:NMODE=1:MODT$="M"
  120. 3560 CWIN=2*PI*RAD/2.405
  121. 3600 IF CWIN<LAMIN THEN PRINT " MODE IS BELOW CUTOFF":TN=TN-1:GOTO 3530
  122. 3610 IF CWIN>1.27*LAMIN THEN PRINT " *** MODE SUPPRESSORS MAY BE NEEDED ***"
  123. 3620 PRINT 
  124. 3630 CWCM=CWIN*2.54  
  125. 3640 FC=299.8/CWCM
  126. 3650 LGIN=LAMIN/SQR(1-(LAMIN/CWIN)^2)  
  127. 3660 LGCM=LGIN*2.54
  128. 3700 PRINT 
  129. 3710 PRINT " FOR GUIDE";2*RAD;"INCHES INSIDE DIAMETER"
  130. 3720 PRINT "   NOMINALLY";CTABL(1,TN);"INCHES OUTSIDE DIAMETER"
  131. 3730 PRINT "  OPERATING IN MODE ";"TM01"
  132. 3740 PRINT "   CUTOFF WAVELENGTH=";CWCM;"CM"
  133. 3750 PRINT "    AT FREQUENCY OF";FO;"MHZ"
  134. 3760 PRINT " WAVELENGTH IN AIR =";FNP(LAM);"CM"
  135. 3770 PRINT "                   =";FNP(LAMIN);"INCHES"
  136. 3780 PRINT " WAVELENGTH IN GUIDE=";FNP(LGCM);"CM"
  137. 3790 PRINT "                    =";FNP(LGIN);"IN"
  138. 3800 INPUT " PRESS RETURN TO CONTINUE";T$
  139. 3810 PRINT 
  140. 3820 PRINT " LENGTH OF SLOT=";FNP(LAM/2);"CM"
  141. 3830 PRINT "               =";FNP(LAMIN/2);"INCHES"
  142. 3840 PRINT " C-C SPACING OF SLOTS=";FNP(LGCM/2);"CM"
  143. 3850 PRINT "                     =";FNP(LGIN/2);"INCHES"
  144. 3860 PRINT " WIDTH OF SLOT, TYPICALLY=";LAM*.05;"CM"
  145. 3870 PRINT "                         =";LAMIN*.05;"INCHES"
  146. 3880 PRINT " DEPTH OF TUNING SCREW, TRIAL=";LAM*.025;"CM"
  147. 3890 PRINT "                             =";LAMIN*.025;"INCHES"
  148. 3900 PRINT " FEED AT ENDS OR AT CENTER OF LONG ARRAYS"
  149. 3910 PRINT "  MATCH AT FEED, OR BY ADDED SCREWS BETWEEN SLOTS,"
  150. 3920 PRINT "   WITH LOADING CONTROLLED BY SCREW DEPTH"
  151. 3930 PRINT " USE ARRAY PROGRAM TO CALCULATE LOBE PATTERNS"
  152. 3940 IF TG$="R" THEN PRINT "  GUIDES CAN BE STACKED SIDE-BY-SIDE."
  153. 3950 IF TG$="C" THEN PRINT " PLACE 4=7 SLOTS AROUND GUIDE FOR OMNIDIRECTIONAL PATTERN"
  154. 3960 PRINT "   SEE REFERENCES "
  155. 3970 PRINT 
  156. 3990 INPUT " PRESS RETURN TO CONTINUE";T$
  157. 3999 RETURN
  158. 4000 CLS
  159. 4010 INPUT " ENTER -1=SMALLER GUIDE, +1=LARGER, 0=NO CHANGE";TEM
  160. 4020 IF TEM<-1 OR TEM>1 THEN 4000
  161. 4030 TN=TN-TEM
  162. 4040 IF TG$="C" THEN GOTO 3530
  163. 4050 IF TG$="R" THEN GOTO 3110
  164. 4060 PRINT " DO SET DESIGN ROUTINE FIRST"
  165. 4070 PRINT "  PRESS RETURN TO CONTINUE" 
  166. 4990 RETURN
  167. 5000 CLS
  168. 5010 PRINT " CONVERSIONS, INPUT TO OUTPUT"
  169. 5020 PRINT "  ENTER 1 FOR INCHES TO CENTIMETERS"
  170. 5030 PRINT "        2 FOR FEET TO CENTIMETERS"
  171. 5040 PRINT "        3 FOR CENTIMETERS TO INCHES"
  172. 5050 PRINT "        4 FOR CENTIMETERS TO FEET"
  173. 5060 PRINT "        5 FOR FREQUENCY, MHZ TO WAVELENGTH, CM"
  174. 5070 PRINT "        6 FOR WAVELENGTH, CM TO FREQUENCY, MHZ"
  175. 5100 INPUT TEM
  176. 5110 ON TEM GOTO 5200,5250,5300,5350,5400,5450,5010
  177. 5200 INPUT " INCHES";INPV
  178. 5210 PRINT "  CM=";2.54*INPV
  179. 5220 GOTO 5980
  180. 5250 INPUT " FEET";INPV
  181. 5260 PRINT "  CM=";30.48*INPV
  182. 5270 GOTO 5980
  183. 5300 INPUT " CENTIMETERS";INPV
  184. 5310 PRINT "  INCHES=";INPV/2.54
  185. 5320 GOTO 5980
  186. 5350 INPUT " CENTIMETERS";INPV
  187. 5360 PRINT "  FEET=";INPV/30.48
  188. 5370 GOTO 5980
  189. 5400 INPUT " FREQUENCY,MHZ";INPV
  190. 5410 PRINT "  WAVELENGTH, CM=";29980/INPV
  191. 5420 GOTO 5980
  192. 5450 INPUT " WAVELENGTH, CM";INPV
  193. 5460 PRINT "  FREQUENCY,MHZ=";29980/INPV
  194. 5470 GOTO 5980
  195. 5980 INPUT " ENTER C- ANOTHER CONVERSION, OR RETURN TO FINISH";T$
  196. 5990 IF T$="C" THEN 5010
  197. 5999 RETURN
  198. 6000 IF TG$="C" THEN 6100
  199. 6010 IF TG$<>"R" THEN PRINT" DO DESIGN FIRST":GOSUB 3010
  200. 6020 LPRINT "   SLOTTED WAVEGUIDE ANTENNA":LPRINT
  201. 6030 LPRINT " FOR GUIDE";ADIM;"BY";BDIM;"INCHES, INSIDE"
  202. 6040 LPRINT "  NOMINALLY";RTABL(2,TN);"BY";RTABL(1,TN);"INCHES OUTSIDE"
  203. 6050 LPRINT "   OPERATING IN MODE TE01"
  204. 6060 GOTO 6200
  205. 6100 LPRINT " FOR GUIDE";2*RAD;"INCHES INSIDE DIAMETER"
  206. 6110 LPRINT "   NOMINALLY";CTABL(1,TN);"INCHES OUTSIDE DIAMETER"
  207. 6120 LPRINT "    OPERATING IN MODE ";"TM01"
  208. 6200 LPRINT "   CUTOFF WAVELENGTH=";CWCM;"CM"
  209. 6210 LPRINT " AT FREQUENCY OF";FO;"MHZ"
  210. 6220 LPRINT "  WAVELENGTH IN AIR =";FNP(LAM);"CM"
  211. 6230 LPRINT "                    =";FNP(LAMIN);"INCHES"
  212. 6240 LPRINT "  WAVELENGTH IN GUIDE=";FNP(LGCM);"CM"
  213. 6250 LPRINT "                     =";FNP(LGIN);"IN"
  214. 6800 LPRINT 
  215. 6810 LPRINT 
  216. 6820 LPRINT " LENGTH OF SLOT=";FNP(LAM/2);"CM"
  217. 6830 LPRINT "               =";FNP(LAMIN/2);"INCHES"
  218. 6840 LPRINT " C-C SPACING OF SLOTS=";FNP(LGCM/2);"CM"
  219. 6850 LPRINT "                     =";FNP(LGIN/2);"INCHES"
  220. 6860 PRINT " WIDTH OF SLOT, TYPICALLY=";LAM*.05;"CM"
  221. 6870 PRINT "                         =";LAMIN*.05;"INCHES"
  222. 6880 LPRINT " DEPTH OF TUNING SCREW, TRIAL=";LAM*.025;"CM"
  223. 6890 LPRINT "                             =";LAMIN*.025;"INCHES"
  224. 6900 LPRINT " FEED AT ENDS OR AT CENTER OF LONG ARRAYS"
  225. 6910 LPRINT "  MATCH AT FEED, OR BY ADDED SCREWS BETWEEN SLOTS,"
  226. 6920 LPRINT "   WITH LOADING CONTROLLED BY SCREW DEPTH"
  227. 6930 LPRINT " USE ARRAY PROGRAM TO CALCULATE LOBE PATTERNS"
  228. 6940 IF TG$="R" THEN LPRINT "  GUIDES CAN BE STACKED SIDE-BY-SIDE."
  229. 6950 IF TG$="C" THEN LPRINT " PLACE 4=7 SLOTS AROUND GUIDE FOR OMNIDIRECTIONAL PATTERN"
  230. 6960 LPRINT "   SEE REFERENCES "
  231. 6970 LPRINT
  232. 6990 RETURN 
  233. 7000 END
  234. 50000 DATA 11.75,23.25,.125,2300,290
  235. 50010 DATA 10.75,21.25,.125,2100,291
  236. 50020 DATA 9.25,18.25,.125,1800,201
  237. 50030 DATA 7.75,15.25,.125,1500,202
  238. 50040 DATA 6,11.75,.125,1150,203
  239. 50050 DATA 5.125,10,.125,975,204
  240. 50060 DATA 4.1,7.95,.125,770,205
  241. 50070 DATA 3.41,6.66,.08,650,69
  242. 50080 DATA 2.31,4.46,.08,430,104
  243. 50090 DATA 1.86,3.56,.08,340,112
  244. 50100 DATA 1.5,3,.081,284,48
  245. 50110 DATA 1,2,.064,187,49
  246. 50120 DATA .75,1.5,.064,137,50
  247. 50130 DATA .625,1.25,.064,112,51
  248. 50140 DATA .5,1,.064,90,52
  249. 50150 DATA .375,.75,.064,0,0
  250. 50160 DATA .25,.5,.04,42,53
  251. 50170 DATA .25,.4375,.05,34,0
  252. 50400 DATA 12.125,.28
  253. 50410 DATA 10.125,.25
  254. 50420 DATA 8.125,.2
  255. 50430 DATA 6.125,.14                        
  256. 50440 DATA 5.125,.125
  257. 50450 DATA 4.125,.11
  258. 50460 DATA 3.125,.09
  259. 50470 DATA 2.125,.07
  260. 50480 DATA 1.625,.06
  261. 50490 DATA 1.125,.05
  262. 50500 DATA .875,.045
  263. 50510 DATA .625,.04
  264. 50520 DATA .5,.035
  265. 60000 PRINT "ERROR";ERR;"AT LINE";ERL
  266. 60010 IF ERR=11 THEN PRINT "FREQUENCY, MODE AND TABLE SIZES OF GUIDE INCOMPATABLE"
  267. 60020 RESUME 400
  268. 64000 STOP
  269.