home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol2
/
basic
/
vubb.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
6KB
|
124 lines
1 CLS
2 ON ERROR GOTO 60000
10 PRINT " *************************************************************"
20 PRINT " * BROAD-BAND DIPOLES *"
30 PRINT " * REFERENCE- KRAUS,ANTENNAS, 2ND EDITION *"
40 PRINT " * PROGRAM BY R.P. HAVILAND, W4MB *"
50 PRINT " * COPYRGHT 1990 *"
60 PRINT " * MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086 *"
70 PRINT " *************************************************************"
80 DEF FNP (X) = INT(100 * X + .5) / 100
200 PRINT
210 PRINT " THIS PROGRAM GIVES DESIGN DATA FOR TWO BROAD=BAND DIPOLES"
220 PRINT " PRIMARILY FOR METER-WAVE BAND OPERATION."
230 PRINT
240 PRINT " ENTER 1- SUPER-TURNSTILE"
250 PRINT " 2- BOW TIE"
260 PRINT " 3- SEE ANTENNA DRAWING (SCHEMATIC)"
270 PRINT " 4- QUIT"
300 INPUT TEM
310 ON TEM GOSUB 1000, 2000, 3000, 4000
320 GOTO 230
1000 CLS 'SUPER-TURNSTILE
1010 INPUT " ENTER BAND-CENTER FREQUENCY, MHZ"; FO
1020 IF FO <= 0 THEN 1010
1030 LAM = 299.8 / FO
1040 LAMIN = LAM * 39.37
1100 HEIGHT = .65 * LAM
1110 HEIGHTIN = .65 * LAMIN
1120 TWID = .23 * LAM
1130 TWIDIN = .23 * LAMIN
1140 CWID = .085 * LAM
1150 CWIDIN = .085 * LAMIN
1160 FS = .025 * LAM
1170 FSIN = .025 * LAMIN
1180 FMIN = .85 * FO
1190 FMAX = 1.15 * FO
1200 WOA = 2 * (TWID + FS)
1210 WOAIN = 2 * (TWIDIN + FSIN)
1220 DR = .006 * LAM
1230 DRIN = .006 * LAMIN
1240 CURV = .02 * LAM
1250 CURVIN = .02 * LAMIN
1500 PRINT
1510 PRINT " TYPICAL FEED POINT SEPARATION FROM POLE="; FNP(FS); "METERS"
1520 PRINT " ="; FNP(FSIN); "INCHES"
1530 PRINT " WIDTH, FEED POINT TO CENTER="; FNP(CWID); "METERS"
1540 PRINT " ="; FNP(CWIDIN); "INCHES"
1550 PRINT " WIDTH OF HALF RADIATOR, AT TOP, BOTTOM="; FNP(TWID); "METERS"
1560 PRINT " ="; FNP(TWIDIN); "INCHES"
1570 PRINT " OVERALL WIDTH="; FNP(WOA); "METERS"
1580 PRINT " ="; FNP(WOAIN); "INCHES"
1590 PRINT " PLUS POLE DIAMETER"
1600 PRINT " HEIGHT PER SECTION="; FNP(HEIGHT); "METERS"
1610 PRINT " ="; FNP(HEIGHTIN); "INCHES"
1620 PRINT " TYPICAL RADIUS OF CURVATURE, OUTER CORNERS="; FNP(CURV); "METERS"
1630 PRINT " ="; FNP(CURVIN); "INCHES"
1640 PRINT " TYPICAL ROD DIAMETER="; FNP(DR); "METERS"
1650 PRINT " ="; FNP(DRIN); "INCHES"
1700 PRINT " TWO OF ABOVE SECTIONS 180 DEGREES APART FORM A DIPOLE RADIATOR "
1710 PRINT " WITH A DRIVE IMPEDANCE OF 70 +/- J 50 OHMS"
1720 PRINT " 4 AT 90 DEGREES FED IN QUADATURE ARE OMNI-DIRECTIONAL"
1730 PRINT " APPROXIMATE MINIMUM USEFUL FREQUENCY="; FNP(FMIN); "MHZ"
1740 PRINT " MAXIMUM ="; FNP(FMAX); "MHZ"
1800 PRINT " TYPICAL SEPARATION, STACKED ELEMENTS="; FNP(LAM); "METERS"
1810 PRINT " ="; FNP(LAMIN); "INCHES"
1990 INPUT "PRESS RETURN TO CONTINUE"; T$
1999 RETURN
2000 CLS 'BOW-TIE
2010 INPUT " ENTER BAND-CENTER FREQUENCY, MHZ"; FO
2020 IF FO <= 0 THEN 1010
2030 LAM = 299.8 / FO
2040 LAMIN = LAM * 39.37
2100 LGN = .41 * LAM
2110 LGNIN = .82 * LAMIN
2120 WID = 2 * .41 * LAM * .5'60 INCLUDED ANGLE
2130 WIDIN = 2 * .41 * LAMIN * .5
2140 RRAD = .01 * LAM
2150 RRADIN = .01 * LAMIN
2200 PRINT
2210 PRINT " LENGTH OVERALL (BOTH HALVES)="; FNP(LGN); "METERS"
2220 PRINT " ="; FNP(LGNIN); "INCHES"
2230 PRINT " WIDTH AT OUTER END="; FNP(WID); "METERS"
2240 PRINT " ="; FNP(WIDIN); "INCHES"
2250 PRINT " ROUND ALL CORNERS TO"; FNP(RRAD); "METERS RADIUS"
2260 PRINT " OR"; FNP(RRADIN); "INCHES RADIUS"
2270 PRINT
2300 PRINT " APPROXIMATE LOWER USEFUL FREQUENCY ="; FNP(.67 * FO); "MHZ"
2310 PRINT " APPROXIMATE UPPER USEFUL FREQUENCY ="; FNP(1.35 * FO); "MHZ"
2320 PRINT
2340 PRINT " DRIVE IMPEDANCE 300 OHMS, BALANCED, WITH 2:1 SWR MAX."
2350 PRINT " GAIN AT DESIGN FREQUENCY 2 DB ABOVE A DIPOLE"
2360 PRINT
2990 INPUT " PRESS RETURN TO CONTINUE"; T$
2999 RETURN
3000 CLS
3010 PRINT
3020 PRINT " P"
3030 PRINT " PSRRRRRRRRRRRR"
3040 PRINT " P R R C"
3050 PRINT " P RRRRRRRRR CCCCC"
3060 PRINT " P R R CCCCCCCCC"
3070 PRINT " P RRRRRRRR CCCCCCCCCCCCC"
3080 PRINT " P R R CCCCCCCCCCCCCCCCC"
3090 PRINT " P FRRRRR FCCCCCCCCCCCCCCCCCCCCC"
3100 PRINT " P R R P CCCCCCCCCCCCCCCCC"
3110 PRINT " P RRRRRRRR P CCCCCCCCCCCCC"
3120 PRINT " P R R P CCCCCCCCC"
3130 PRINT " P RRRRRRRRRR P CCCCC"
3140 PRINT " P R R P C"
3150 PRINT " PSRRRRRRRRRRRR P"
3160 PRINT " P P"
3170 PRINT
3200 PRINT "RIGHT HALF OF A SUPER-TURNSTILE RIGHT HALF OF A BOW TIE"
3210 PRINT " WHERE P= SUPPORT POLE R= CONDUCTOR ROD S=STUB"
3220 PRINT " F= FEED C= CONDUCTOR SHEET"
3230 PRINT " OUTER CORNERS ARE ROUNDED TO A SMALL RADIUS,"
3240 PRINT " AND EDGES ARE STRAIGHT LINES- SEE REFERENCE"
3250 INPUT " PRESS RETURN TO CONTINUE"; T$
3260 RETURN
4000 END
60000 PRINT "ERROR"; ERR; "AT LINE"; ERL
60010 STOP