home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / vubb.asc < prev    next >
Text File  |  1996-06-30  |  6KB  |  124 lines
  1. 1 CLS
  2. 2 ON ERROR GOTO 60000
  3. 10 PRINT "   *************************************************************"
  4. 20 PRINT "   *                      BROAD-BAND DIPOLES                   *"
  5. 30 PRINT "   *             REFERENCE- KRAUS,ANTENNAS, 2ND EDITION        *"
  6. 40 PRINT "   *                PROGRAM BY  R.P. HAVILAND, W4MB            *"
  7. 50 PRINT "   *                       COPYRGHT 1990                       *"
  8. 60 PRINT "   *          MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086      *"
  9. 70 PRINT "   *************************************************************"
  10. 80 DEF FNP (X) = INT(100 * X + .5) / 100
  11. 200 PRINT
  12. 210 PRINT " THIS PROGRAM GIVES DESIGN DATA FOR TWO BROAD=BAND DIPOLES"
  13. 220 PRINT "  PRIMARILY FOR METER-WAVE BAND OPERATION."
  14. 230 PRINT
  15. 240 PRINT "   ENTER 1- SUPER-TURNSTILE"
  16. 250 PRINT "         2- BOW TIE"
  17. 260 PRINT "         3- SEE ANTENNA DRAWING (SCHEMATIC)"
  18. 270 PRINT "         4- QUIT"
  19. 300 INPUT TEM
  20. 310 ON TEM GOSUB 1000, 2000, 3000, 4000
  21. 320 GOTO 230
  22. 1000 CLS 'SUPER-TURNSTILE
  23. 1010 INPUT " ENTER BAND-CENTER FREQUENCY, MHZ"; FO
  24. 1020 IF FO <= 0 THEN 1010
  25. 1030 LAM = 299.8 / FO
  26. 1040 LAMIN = LAM * 39.37
  27. 1100 HEIGHT = .65 * LAM
  28. 1110 HEIGHTIN = .65 * LAMIN
  29. 1120 TWID = .23 * LAM
  30. 1130 TWIDIN = .23 * LAMIN
  31. 1140 CWID = .085 * LAM
  32. 1150 CWIDIN = .085 * LAMIN
  33. 1160 FS = .025 * LAM
  34. 1170 FSIN = .025 * LAMIN
  35. 1180 FMIN = .85 * FO
  36. 1190 FMAX = 1.15 * FO
  37. 1200 WOA = 2 * (TWID + FS)
  38. 1210 WOAIN = 2 * (TWIDIN + FSIN)
  39. 1220 DR = .006 * LAM
  40. 1230 DRIN = .006 * LAMIN
  41. 1240 CURV = .02 * LAM
  42. 1250 CURVIN = .02 * LAMIN
  43. 1500 PRINT
  44. 1510 PRINT " TYPICAL FEED POINT SEPARATION FROM POLE="; FNP(FS); "METERS"
  45. 1520 PRINT "                                        ="; FNP(FSIN); "INCHES"
  46. 1530 PRINT " WIDTH, FEED POINT TO CENTER="; FNP(CWID); "METERS"
  47. 1540 PRINT "                            ="; FNP(CWIDIN); "INCHES"
  48. 1550 PRINT " WIDTH OF HALF RADIATOR, AT TOP, BOTTOM="; FNP(TWID); "METERS"
  49. 1560 PRINT "                                       ="; FNP(TWIDIN); "INCHES"
  50. 1570 PRINT " OVERALL WIDTH="; FNP(WOA); "METERS"
  51. 1580 PRINT "             ="; FNP(WOAIN); "INCHES"
  52. 1590 PRINT "      PLUS POLE DIAMETER"
  53. 1600 PRINT " HEIGHT PER SECTION="; FNP(HEIGHT); "METERS"
  54. 1610 PRINT "                   ="; FNP(HEIGHTIN); "INCHES"
  55. 1620 PRINT " TYPICAL RADIUS OF CURVATURE, OUTER CORNERS="; FNP(CURV); "METERS"
  56. 1630 PRINT "                                           ="; FNP(CURVIN); "INCHES"
  57. 1640 PRINT " TYPICAL ROD DIAMETER="; FNP(DR); "METERS"
  58. 1650 PRINT "                     ="; FNP(DRIN); "INCHES"
  59. 1700 PRINT " TWO OF ABOVE SECTIONS 180 DEGREES APART FORM A DIPOLE RADIATOR "
  60. 1710 PRINT "   WITH A DRIVE IMPEDANCE OF 70 +/- J 50 OHMS"
  61. 1720 PRINT "    4 AT 90 DEGREES FED IN QUADATURE ARE OMNI-DIRECTIONAL"
  62. 1730 PRINT " APPROXIMATE MINIMUM USEFUL FREQUENCY="; FNP(FMIN); "MHZ"
  63. 1740 PRINT "             MAXIMUM                 ="; FNP(FMAX); "MHZ"
  64. 1800 PRINT " TYPICAL SEPARATION, STACKED ELEMENTS="; FNP(LAM); "METERS"
  65. 1810 PRINT "                                      ="; FNP(LAMIN); "INCHES"
  66. 1990 INPUT "PRESS RETURN TO CONTINUE"; T$
  67. 1999 RETURN
  68. 2000 CLS 'BOW-TIE
  69. 2010 INPUT " ENTER BAND-CENTER FREQUENCY, MHZ"; FO
  70. 2020 IF FO <= 0 THEN 1010
  71. 2030 LAM = 299.8 / FO
  72. 2040 LAMIN = LAM * 39.37
  73. 2100 LGN = .41 * LAM
  74. 2110 LGNIN = .82 * LAMIN
  75. 2120 WID = 2 * .41 * LAM * .5'60 INCLUDED ANGLE
  76. 2130 WIDIN = 2 * .41 * LAMIN * .5
  77. 2140 RRAD = .01 * LAM
  78. 2150 RRADIN = .01 * LAMIN
  79. 2200 PRINT
  80. 2210 PRINT " LENGTH OVERALL (BOTH HALVES)="; FNP(LGN); "METERS"
  81. 2220 PRINT "                             ="; FNP(LGNIN); "INCHES"
  82. 2230 PRINT " WIDTH AT OUTER END="; FNP(WID); "METERS"
  83. 2240 PRINT "                   ="; FNP(WIDIN); "INCHES"
  84. 2250 PRINT " ROUND ALL CORNERS TO"; FNP(RRAD); "METERS RADIUS"
  85. 2260 PRINT "                   OR"; FNP(RRADIN); "INCHES RADIUS"
  86. 2270 PRINT
  87. 2300 PRINT " APPROXIMATE LOWER USEFUL FREQUENCY ="; FNP(.67 * FO); "MHZ"
  88. 2310 PRINT "  APPROXIMATE UPPER USEFUL FREQUENCY ="; FNP(1.35 * FO); "MHZ"
  89. 2320 PRINT
  90. 2340 PRINT " DRIVE IMPEDANCE 300 OHMS, BALANCED, WITH 2:1 SWR MAX."
  91. 2350 PRINT "  GAIN AT DESIGN FREQUENCY 2 DB ABOVE A DIPOLE"
  92. 2360 PRINT
  93. 2990 INPUT " PRESS RETURN TO CONTINUE"; T$
  94. 2999 RETURN
  95. 3000 CLS
  96. 3010 PRINT
  97. 3020 PRINT "        P"
  98. 3030 PRINT "        PSRRRRRRRRRRRR"
  99. 3040 PRINT "        P R         R                                  C"
  100. 3050 PRINT "        P RRRRRRRRR                                CCCCC"
  101. 3060 PRINT "        P R       R                            CCCCCCCCC"
  102. 3070 PRINT "        P RRRRRRRR                         CCCCCCCCCCCCC"
  103. 3080 PRINT "        P R     R                      CCCCCCCCCCCCCCCCC"
  104. 3090 PRINT "        P FRRRRR                  FCCCCCCCCCCCCCCCCCCCCC"
  105. 3100 PRINT "        P R     R                 P    CCCCCCCCCCCCCCCCC"
  106. 3110 PRINT "        P RRRRRRRR                P        CCCCCCCCCCCCC"
  107. 3120 PRINT "        P R       R               P            CCCCCCCCC"
  108. 3130 PRINT "        P RRRRRRRRRR              P                CCCCC"
  109. 3140 PRINT "        P R         R             P                    C"
  110. 3150 PRINT "        PSRRRRRRRRRRRR            P"
  111. 3160 PRINT "        P                         P"
  112. 3170 PRINT
  113. 3200 PRINT "RIGHT HALF OF A SUPER-TURNSTILE    RIGHT HALF OF A BOW TIE"
  114. 3210 PRINT "    WHERE P= SUPPORT POLE    R= CONDUCTOR ROD   S=STUB"
  115. 3220 PRINT "          F= FEED            C= CONDUCTOR SHEET"
  116. 3230 PRINT " OUTER CORNERS ARE ROUNDED TO A SMALL RADIUS,"
  117. 3240 PRINT "  AND EDGES ARE STRAIGHT LINES- SEE REFERENCE"
  118. 3250 INPUT " PRESS RETURN TO CONTINUE"; T$
  119. 3260 RETURN
  120. 4000 END
  121. 60000 PRINT "ERROR"; ERR; "AT LINE"; ERL
  122. 60010 STOP
  123.  
  124.