home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol2
/
basic
/
safe.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
2KB
|
54 lines
3 CLS
10 ON ERROR GOTO 60000
100 PRINT " ***********************************************************"
110 PRINT " * RF RADIATION SAFETY LIMITS *"
120 PRINT " * BASED ON ANSI STANDARD C95.1-1982 *"
140 PRINT " * FOR FREQUENCIES 3 MHZ TO 100 GHZ *"
150 PRINT " * REFERENCE- ARRL; THE ARRL ANTENNA HANDBOOK, CURRENT ED *"
160 PRINT " * PROGRAM BY R. P. HAVILAND, PE, W4MB *"
170 PRINT " * PROGRAM COPYRIGHT 1990 BY *"
180 PRINT " * MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086 *"
190 PRINT " ***********************************************************"
500 INPUT " ENTER OPERATING FREQUENCY, MHZ ";FREQ
510 IF FREQ=>1500 THEN DENS=5:GOTO 1000 'WATTS/CM/CM
520 IF FREQ=>300 THEN DENS=10^((LOG(FREQ)-LOG(300))/LOG(10)):GOTO 1000
530 IF FREQ=>30 THEN DENS=1:GOTO 1000
540 DENS=10^(2*((LOG(30)-LOG(FREQ))/LOG(10)))
1000 PRINT " ALLOWABLE FLUX DENSITY=";DENS;" MW/CM SQ"
1010 PRINT " =";DENS*10;" WATTS/METER SQUARE"
1200 SIG=SQR(377*DENS*10)
1210 PRINT
1220 PRINT " THE CORRRESPONDING SIGNAL LEVEL=";SIG;" VOLTS/METER"
1230 PRINT " =";SIG*1000000!;" UV/METER"
1500 PRINT
1510 INPUT " ENTER LENGTH OF LONGEST ANTENNA ELEMENT, FT.";LELEM
1520 LELEM=LELEM*.3048
1530 RMIN=2*LELEM*LELEM*FREQ/299.8
1540 INPUT " ENTER DISTANCE TO POINT, FEET";DISTFT
1550 DIST=DISTFT/3.28
1560 IF DIST>RMIN THEN 2000
1700 PRINT " POINT IS IN NEAR FIELD"
1710 PRINT " USE MININEC 3 TO CALCULATE NEAR-FIELD INTENSITY
1720 PRINT
1730 GOTO 1530
2000 PRINT
2010 INPUT " ENTER ANTENNA GAIN TOWARD POINT, DB";GAINDB
2020 GAIN =10^(GAINDB/10)
2030 INPUT "ENTER POWER RADIATER FROM ANTENNA, AVERAGE WATTS";PRAD
2040 PWRDENS=PRAD*GAIN/12.566/DIST/DIST
2050 PRINT " ESTIMATED RADIATED POWER DENSITY IS";PWRDENS;" WATTS/METER SQ."
2200 IF PWRDENS<10*DENS THEN 2300
2210 PRINT
2220 PRINT " **** WARNING-UNSAFE BY 1982 STANDARDS ****"
2300 SAFEFACT=INT(10*DENS/PWRDENS)
2310 PRINT
2320 PRINT " RADIATION SAFETY FACTOR IS";SAFEFACT
2500 PRINT " ENTER D- ANOTHER DISTANCE"
2510 PRINT " R- RERUN"
2520 PRINT " Q- QUIT"
2530 INPUT T$
2540 IF T$="D" THEN 1530
2550 IF T$="R" THEN 500
2560 IF T$<>"Q" THEN 2500
60000 END