home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol2
/
basic
/
line.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
8KB
|
177 lines
1 CLS
2 PRINT " ***************************************************************"
3 PRINT " * TRANSMISSION LINES *"
4 PRINT " * REFERENCE-JOHNSON AND JASIK, ANTENNA ENGINEERING HANDBOOK *"
5 PRINT " * PROGRAM BY R.P. HAVILAND, W4MB *"
6 PRINT " * COPYRGHT 1990 *"
7 PRINT " * MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086 *"
8 PRINT " ***************************************************************"
10 DEF FNP (X) = INT(100 * X + .5) / 100
20 PI = 3.141592
30 PRINT " THIS PROGRAM CALCULATES TRANSMISSION LINE DIMENSIONS AND CHARACTERISTICS"
40 PRINT
100 PRINT " ENTER TYPE OF TRANSMISION LINE"
110 PRINT " 1- COAXIAL"
120 PRINT " 2- BALANCED 2 WIRE"
130 PRINT " 3- BALANCED SHIELED"
140 PRINT " 4- PARALLEL PAIR"
150 PRINT " 5- SINGLE WIRE"
160 PRINT " 6- TROUGH LINE"
170 PRINT " 7- MICROSTRIP"
180 PRINT " 8- QUIT"
300 INPUT TYP
310 DIL = 1
320 ON TYP GOSUB 1000, 2000, 3000, 4000, 5000, 6000, 7000, 8000
330 CLS
340 GOTO 100
1000 CLS
1010 PRINT " ENTER 1- CONDUCTOR DIAMETER KNOWN, DO SHIELD DIAMETER"
1020 PRINT " 2- SHIELD DIAMETER KNOWN, DO CONDUCTOR DIAMETER"
1030 PRINT " 3- BOTH KNOWN, DO IMPEDANCE"
1040 INPUT KN
1050 ON KN GOSUB 1200, 1400, 1600
1060 GOSUB 1800
1070 PRINT
1080 INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
1090 IF T$ <> "" THEN 8000
1100 RETURN
1200 INPUT " ENTER CONDUCTOR OUTSIDE DIAMETER, INCHES"; COND
1210 INPUT " ENTER DESIGN CHARACTERISTIC IMPEDANCE, OHMS"; ZO
1220 INPUT " ENTER DIELECTRIC CONSTANT OF INSULATOR, 1 FOR AIR"; DIL
1230 SHLD = 10 ^ (ZO * SQR(DIL) / 138) * COND
1240 PRINT " SHIELD INSIDE DIAMETER="; FNP(SHLD); "INCHES"
1250 RETURN
1400 INPUT " ENTER SHIELD INSIDE DIAMETER, INCHES"; SHLD
1410 INPUT " ENTER DESIGN CHARACTERISTIC IMPEDANCE, OHMS"; ZO
1420 INPUT " ENTER DIELECTRIC CONSTANT OF INSULATOR, 1 FOR AIR"; DIL
1430 COND = SHLD / (10 ^ (ZO * SQR(DIL) / 138))
1440 PRINT " CONDUCTOR OUTSIDE DIAMETER="; FNP(COND); "INCHES"
1450 RETURN
1600 INPUT " ENTER CONDUCTOR OUTSIDE DIAMETER, INCHES"; COND
1610 INPUT " ENTER SHIELD INSIDE DIAMETER, INCHES"; SHLD
1620 IF COND >= SHLD THEN PRINT " IMPOSSIBLE DESIGN": GOTO 1600
1630 INPUT " ENTER DIELECTRIC CONSTANT OF INSULATOR, 1 FOR AIR"; DIL
1640 ZO = 60 / SQR(DIL) * LOG(SHLD / COND)
1650 PRINT " CHARACTERISTIC IMPEDANCE="; FNP(ZO); "OHMS"
1660 RETURN
1800 LAMC = PI * SQR(DIL) * (COND + SHLD) / 2 * 2.54
1810 PRINT " THE LOWER CUTOFF WAVELENGTH FOR WAVEGUIDE MODE IS"; FNP(LAMC); "CM"
1820 ATC = 8.68 * .8753 / 4 / PI / ZO * (1 / COND + 1 / SHLD) / 39.37 * 30.48
1830 PRINT " THE COPPER LOSS AT 10 MHZ IS"; FNP(ATC); "DB/100 FEET"
1840 PRINT " THE VELOCITY FACTOR IS"; FNP(1 / SQR(DIL))
1860 RETURN
2000 CLS
2010 PRINT " ENTER 1- CONDUCTOR DIAMETER KNOWN"
2020 PRINT " 2- SPACING KNOWN"
2030 PRINT " 3- BOTH KNOWN"
2040 INPUT KN
2050 ON KN GOSUB 2200, 2400, 2600
2060 PRINT " THE VELOCITY FACTOR IS"; FNP(1 / SQR(DIL))
2070 PRINT
2080 INPUT " PRESS RETURN TO RERUN, ANY OTHER + RETURN= QUIT"; T$
2090 IF T$ = "" THEN 2000
2100 RETURN
2200 CLS
2210 INPUT " ENTER CONDUCTOR OUTSIDE DIAMETER, INCHES"; CDIA
2220 INPUT " ENTER DESIGN CHARACTERISTIC IMPEDANCE, OHMS"; ZO
2230 SPAC = 10 ^ (ZO / 276) * CDIA / 2
2240 PRINT
2250 PRINT " SPACING BETWEEN CONDUCTOR CENTERS ="; FNP(SPAC); "INCHES"
2260 RETURN
2400 CLS
2410 INPUT " ENTER SPACING BETWEEN CONDUCTOR CENTERS, INCHES"; SPAC
2420 INPUT " ENTER DESIGN CHARACTERISTIC IMPEDANCE, OHMS"; ZO
2430 CDIA = 2 * SPAC / (10 ^ (ZO / 276))
2440 PRINT
2450 PRINT " CONDUCTOR OUTSIDE DIAMETER="; FNP(CDIA); "INCHES"
2460 RETURN
2600 CLS
2610 INPUT " ENTER CONDUCTOR OUTSIDE DIAMETER, INCHES"; CDIA
2620 INPUT " ENTER SPACING BETWEEN CONDUCTOR CENTERS, INCHES"; SPAC
2630 ZO = 120 * LOG(2 * SPAC / CDIA)
2640 PRINT
2650 PRINT " CHARACTERISTIC IMPEDANCE="; FNP(ZO); "OHMS"
2660 RETURN
3000 CLS
3010 INPUT " ENTER CONDUCTOR DIAMETER, INCHES"; CDIA
3020 INPUT " ENTER SPACING BETWEEN CONDUCTOR CENTERS , INCHES"; SPAC
3030 IF CDIA >= SPAC THEN PRINT " IMPOSSIBLE DESIGN": GOTO 3010
3040 INPUT " ENTER SHIELD INSIDE DIAMETER, INCHES"; SHDIA
3050 IF (4 * CDIA + CSPAC) > SHDIA THEN PRINT " IMPOSSIBLE DESIGN": GOTO 3010
3060 INPUT " ENTER DIELECTRIC CONSTANT OF INSULATOR, 1 FOR AIR"; DIL
3070 NU = SPAC / CDIA
3080 SIG = SPAC / SHDIA
3090 ZO = 69 * SQR(DIL) / 2.3 * LOG((NU / 2 / SIG / SIG) * (1 - SIG ^ 4))
3200 PRINT
3210 PRINT " CHARACTERISTIC IMPEDANCE="; FNP(ZO); "OHMS"
3220 PRINT " THE VELOCITY FACTOR IS"; FNP(1 / SQR(DIL))
3230 PRINT
3240 INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
3250 IF T$ <> "" THEN 8000
3260 RETURN
4000 CLS
4010 INPUT " ENTER CONDUCTOR DIAMETER, INCHES"; CDIA
4020 INPUT " ENTER SPACING BETWEEN CONDUCTOR CENTERS , INCHES"; SPAC
4030 IF CDIA >= SPAC THEN PRINT " IMPOSSIBLE DESIGN": GOTO 4010
4040 INPUT " ENTER HEIGHT OF CONDUCTORS ABOVE GROUND, INCHES"; HTG
4050 IF CDIA / 2 >= HTG THEN PRINT " IMPOSSIBLE DESIGN": GOTO 4010
4060 ZO = 69 / 2.3 * LOG((4 * HTG / CDIA) * SQR(1 + (2 * HTG / SPAC) ^ 2))
4100 PRINT
4110 PRINT " THE CHARACTERISTIC IMPEDANCE IS"; FNP(ZO); "OHMS"
4120 PRINT : INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
4130 IF T$ <> "" THEN 8000
4140 RETURN
5000 CLS
5010 INPUT " ENTER CONDUCTOR DIAMETER, INCHES"; CDIA
5020 INPUT " ENTER HEIGHT OF CONDUCTOR ABOVE GROUND, INCHES"; HTG
5030 IF CDIA / 2 >= HTG THEN PRINT " IMPOSSIBLE DESIGN": GOTO 5010
5040 ZO = 138 / 2.3 * LOG(4 * HTG / CDIA)
5100 PRINT
5110 PRINT " THE CHARACTERISTIC IMPEDANCE IS"; FNP(ZO); "OHMS"
5120 PRINT : INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
5130 IF T$ <> "" THEN 8000
5140 RETURN
6000 CLS
6010 INPUT " ENTER CONDUCTOR DIAMETER, INCHES"; CDIA
6020 INPUT " ENTER WIDTH OF TROUGH, INCHES (CONDUCTOR CENTERED)"; TWID
6030 IF CDIA >= TWID THEN PRINT " IMPOSSIBLE DESIGN": GOTO 6010
6040 INPUT " ENTER HEIGHT OF TROUGH, INCHES (CONDUCTOR CENTERED)"; HTG
6050 FAC = PI * HTG / 2 / TWID * 2
6060 TANH = (1 - EXP(-FAC)) / (1 + EXP(-FAC))
6070 ZO = 138 / 2.3 * LOG((4 * TWID / PI / CDIA) * TANH)
6100 PRINT
6110 PRINT " THE CHARACTERISTIC IMPEDANCE IS"; FNP(ZO); "OHMS"
6120 PRINT : INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
6130 IF T$ <> "" THEN 8000
6140 RETURN
7000 CLS
7010 PRINT " BASED ON WHEELER AND SCHNEIDER FORMULAS"
7020 PRINT
7030 INPUT " ENTER STRIP WIDTH, MILS"; WID: WID = WID / 1000
7040 INPUT " ENTER STRIP THICKKNESS, MILS (1 OZ CU=1.4 MIL THICK)"; TIK: TIK = TIK / 1000
7050 INPUT " ENTER SUBSTRATE THICKNESS, MILS"; HTG: HTG = HTG / 1000
7060 PRINT " TYPICAL DILECTRIC CONSTANTS; TEFLON=GLASS=2.55; GLASS EPOXY=4.8"
7070 INPUT " ENTER SUBSTRATE DIELECTRIC CONSTANT"; DIL
7080 HE = HTG - 2 * TIK
7090 WE = WID + TIK / PI * (LOG(2 * HE / TIK + 1))
7100 IF WID / HTG > 1 THEN 7400
7200 EE = (DIL + 1) / 2 + (DIL - 1) / 2 * ((1 + 12 * HTG / WE) ^ -.5 + .04 * (1 - WE / HTG) ^ 2)
7210 ZO = 60 / SQR(EE) * LOG(8 * HTG / WE + .25 * WE / HTG)
7220 VP = 1 / SQR(EE)
7230 GOTO 7600
7400 EE = (DIL + 1) / 2 + (DIL - 1) / 2 * (1 + 12 * HTG / WE) ^ -.5
7410 ZO = 377 / SQR(EE) / (WE / HTG + 1.393 + .667 * (LOG(WE / HTG + 1.444)))
7420 VP = 1 / SQR(EE)
7600 PRINT
7610 PRINT " THE EFFECTIVE STRIP WIDTH IS"; FNP(WE); "INCHES"
7620 PRINT " THE EFFECTIVE SUBSTRATE THICKNESS IS"; FNP(HE); "INCHES"
7630 PRINT " THE EFFECTIVE DILECTRIC CONSTANT IS"; FNP(EE)
7640 PRINT
7650 PRINT " THE CHARACTERISTIC IMPEDANCE IS"; FNP(ZO); "OHMS"
7660 PRINT " THE PROPAGATION FACTOR IS"; VP
7670 PRINT : INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
7680 IF T$ <> "" THEN 8000
7690 RETURN
8000 END