home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol2 / basic / line.asc < prev    next >
Text File  |  1996-06-30  |  8KB  |  177 lines
  1. 1 CLS
  2. 2 PRINT "   ***************************************************************"
  3. 3 PRINT "   *                      TRANSMISSION LINES                     *"
  4. 4 PRINT "   *  REFERENCE-JOHNSON AND JASIK, ANTENNA ENGINEERING HANDBOOK  *"
  5. 5 PRINT "   *                PROGRAM BY  R.P. HAVILAND, W4MB              *"
  6. 6 PRINT "   *                       COPYRGHT 1990                         *"
  7. 7 PRINT "   *          MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086        *"
  8. 8 PRINT "   ***************************************************************"
  9. 10 DEF FNP (X) = INT(100 * X + .5) / 100
  10. 20 PI = 3.141592
  11. 30 PRINT " THIS PROGRAM CALCULATES TRANSMISSION LINE DIMENSIONS AND CHARACTERISTICS"
  12. 40 PRINT
  13. 100 PRINT " ENTER TYPE OF TRANSMISION LINE"
  14. 110 PRINT "     1- COAXIAL"
  15. 120 PRINT "     2- BALANCED 2 WIRE"
  16. 130 PRINT "     3- BALANCED SHIELED"
  17. 140 PRINT "     4- PARALLEL PAIR"
  18. 150 PRINT "     5- SINGLE WIRE"
  19. 160 PRINT "     6- TROUGH LINE"
  20. 170 PRINT "     7- MICROSTRIP"
  21. 180 PRINT "     8- QUIT"
  22. 300 INPUT TYP
  23. 310 DIL = 1
  24. 320 ON TYP GOSUB 1000, 2000, 3000, 4000, 5000, 6000, 7000, 8000
  25. 330 CLS
  26. 340 GOTO 100
  27. 1000 CLS
  28. 1010 PRINT " ENTER 1- CONDUCTOR DIAMETER KNOWN, DO SHIELD DIAMETER"
  29. 1020 PRINT "       2- SHIELD DIAMETER KNOWN, DO CONDUCTOR DIAMETER"
  30. 1030 PRINT "       3- BOTH KNOWN, DO IMPEDANCE"
  31. 1040 INPUT KN
  32. 1050 ON KN GOSUB 1200, 1400, 1600
  33. 1060 GOSUB 1800
  34. 1070 PRINT
  35. 1080 INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
  36. 1090 IF T$ <> "" THEN 8000
  37. 1100 RETURN
  38. 1200 INPUT " ENTER CONDUCTOR OUTSIDE DIAMETER, INCHES"; COND
  39. 1210 INPUT "  ENTER DESIGN CHARACTERISTIC IMPEDANCE, OHMS"; ZO
  40. 1220 INPUT "   ENTER DIELECTRIC CONSTANT OF INSULATOR, 1 FOR AIR"; DIL
  41. 1230 SHLD = 10 ^ (ZO * SQR(DIL) / 138) * COND
  42. 1240 PRINT " SHIELD INSIDE DIAMETER="; FNP(SHLD); "INCHES"
  43. 1250 RETURN
  44. 1400 INPUT " ENTER SHIELD INSIDE DIAMETER, INCHES"; SHLD
  45. 1410 INPUT "  ENTER DESIGN CHARACTERISTIC IMPEDANCE, OHMS"; ZO
  46. 1420 INPUT "   ENTER DIELECTRIC CONSTANT OF INSULATOR, 1 FOR AIR"; DIL
  47. 1430 COND = SHLD / (10 ^ (ZO * SQR(DIL) / 138))
  48. 1440 PRINT " CONDUCTOR OUTSIDE DIAMETER="; FNP(COND); "INCHES"
  49. 1450 RETURN
  50. 1600 INPUT " ENTER CONDUCTOR OUTSIDE DIAMETER, INCHES"; COND
  51. 1610 INPUT "  ENTER SHIELD INSIDE DIAMETER, INCHES"; SHLD
  52. 1620 IF COND >= SHLD THEN PRINT " IMPOSSIBLE DESIGN": GOTO 1600
  53. 1630 INPUT "   ENTER DIELECTRIC CONSTANT OF INSULATOR, 1 FOR AIR"; DIL
  54. 1640 ZO = 60 / SQR(DIL) * LOG(SHLD / COND)
  55. 1650 PRINT " CHARACTERISTIC IMPEDANCE="; FNP(ZO); "OHMS"
  56. 1660 RETURN
  57. 1800 LAMC = PI * SQR(DIL) * (COND + SHLD) / 2 * 2.54
  58. 1810 PRINT " THE LOWER CUTOFF WAVELENGTH FOR WAVEGUIDE MODE IS"; FNP(LAMC); "CM"
  59. 1820 ATC = 8.68 * .8753 / 4 / PI / ZO * (1 / COND + 1 / SHLD) / 39.37 * 30.48
  60. 1830 PRINT "  THE COPPER LOSS AT 10 MHZ IS"; FNP(ATC); "DB/100 FEET"
  61. 1840 PRINT "   THE VELOCITY FACTOR IS"; FNP(1 / SQR(DIL))
  62. 1860 RETURN
  63. 2000 CLS
  64. 2010 PRINT "   ENTER 1- CONDUCTOR DIAMETER KNOWN"
  65. 2020 PRINT "         2- SPACING KNOWN"
  66. 2030 PRINT "         3- BOTH KNOWN"
  67. 2040 INPUT KN
  68. 2050 ON KN GOSUB 2200, 2400, 2600
  69. 2060 PRINT "  THE VELOCITY FACTOR IS"; FNP(1 / SQR(DIL))
  70. 2070 PRINT
  71. 2080 INPUT " PRESS RETURN TO RERUN, ANY OTHER + RETURN= QUIT"; T$
  72. 2090 IF T$ = "" THEN 2000
  73. 2100 RETURN
  74. 2200 CLS
  75. 2210 INPUT " ENTER CONDUCTOR OUTSIDE DIAMETER, INCHES"; CDIA
  76. 2220 INPUT "  ENTER DESIGN CHARACTERISTIC IMPEDANCE, OHMS"; ZO
  77. 2230 SPAC = 10 ^ (ZO / 276) * CDIA / 2
  78. 2240 PRINT
  79. 2250 PRINT " SPACING BETWEEN CONDUCTOR CENTERS ="; FNP(SPAC); "INCHES"
  80. 2260 RETURN
  81. 2400 CLS
  82. 2410 INPUT " ENTER SPACING BETWEEN CONDUCTOR CENTERS, INCHES"; SPAC
  83. 2420 INPUT "  ENTER DESIGN CHARACTERISTIC IMPEDANCE, OHMS"; ZO
  84. 2430 CDIA = 2 * SPAC / (10 ^ (ZO / 276))
  85. 2440 PRINT
  86. 2450 PRINT " CONDUCTOR OUTSIDE DIAMETER="; FNP(CDIA); "INCHES"
  87. 2460 RETURN
  88. 2600 CLS
  89. 2610 INPUT " ENTER CONDUCTOR OUTSIDE DIAMETER, INCHES"; CDIA
  90. 2620 INPUT "  ENTER SPACING BETWEEN CONDUCTOR CENTERS, INCHES"; SPAC
  91. 2630 ZO = 120 * LOG(2 * SPAC / CDIA)
  92. 2640 PRINT
  93. 2650 PRINT " CHARACTERISTIC IMPEDANCE="; FNP(ZO); "OHMS"
  94. 2660 RETURN
  95. 3000 CLS
  96. 3010 INPUT " ENTER CONDUCTOR DIAMETER, INCHES"; CDIA
  97. 3020 INPUT "  ENTER SPACING BETWEEN CONDUCTOR CENTERS , INCHES"; SPAC
  98. 3030 IF CDIA >= SPAC THEN PRINT " IMPOSSIBLE DESIGN": GOTO 3010
  99. 3040 INPUT "   ENTER SHIELD INSIDE DIAMETER, INCHES"; SHDIA
  100. 3050 IF (4 * CDIA + CSPAC) > SHDIA THEN PRINT " IMPOSSIBLE DESIGN": GOTO 3010
  101. 3060 INPUT "   ENTER DIELECTRIC CONSTANT OF INSULATOR, 1 FOR AIR"; DIL
  102. 3070 NU = SPAC / CDIA
  103. 3080 SIG = SPAC / SHDIA
  104. 3090 ZO = 69 * SQR(DIL) / 2.3 * LOG((NU / 2 / SIG / SIG) * (1 - SIG ^ 4))
  105. 3200 PRINT
  106. 3210 PRINT " CHARACTERISTIC IMPEDANCE="; FNP(ZO); "OHMS"
  107. 3220 PRINT "  THE VELOCITY FACTOR IS"; FNP(1 / SQR(DIL))
  108. 3230 PRINT
  109. 3240 INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
  110. 3250 IF T$ <> "" THEN 8000
  111. 3260 RETURN
  112. 4000 CLS
  113. 4010 INPUT " ENTER CONDUCTOR DIAMETER, INCHES"; CDIA
  114. 4020 INPUT "  ENTER SPACING BETWEEN CONDUCTOR CENTERS , INCHES"; SPAC
  115. 4030 IF CDIA >= SPAC THEN PRINT " IMPOSSIBLE DESIGN": GOTO 4010
  116. 4040 INPUT "   ENTER HEIGHT OF CONDUCTORS ABOVE GROUND, INCHES"; HTG
  117. 4050 IF CDIA / 2 >= HTG THEN PRINT " IMPOSSIBLE DESIGN": GOTO 4010
  118. 4060 ZO = 69 / 2.3 * LOG((4 * HTG / CDIA) * SQR(1 + (2 * HTG / SPAC) ^ 2))
  119. 4100 PRINT
  120. 4110 PRINT " THE CHARACTERISTIC IMPEDANCE IS"; FNP(ZO); "OHMS"
  121. 4120 PRINT : INPUT " PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
  122. 4130 IF T$ <> "" THEN 8000
  123. 4140 RETURN
  124. 5000 CLS
  125. 5010 INPUT " ENTER CONDUCTOR DIAMETER, INCHES"; CDIA
  126. 5020 INPUT "  ENTER HEIGHT OF CONDUCTOR ABOVE GROUND, INCHES"; HTG
  127. 5030 IF CDIA / 2 >= HTG THEN PRINT " IMPOSSIBLE DESIGN": GOTO 5010
  128. 5040 ZO = 138 / 2.3 * LOG(4 * HTG / CDIA)
  129. 5100 PRINT
  130. 5110 PRINT " THE CHARACTERISTIC IMPEDANCE IS"; FNP(ZO); "OHMS"
  131. 5120 PRINT : INPUT "  PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
  132. 5130 IF T$ <> "" THEN 8000
  133. 5140 RETURN
  134. 6000 CLS
  135. 6010 INPUT " ENTER CONDUCTOR DIAMETER, INCHES"; CDIA
  136. 6020 INPUT "  ENTER WIDTH OF TROUGH, INCHES (CONDUCTOR CENTERED)"; TWID
  137. 6030 IF CDIA >= TWID THEN PRINT " IMPOSSIBLE DESIGN": GOTO 6010
  138. 6040 INPUT "   ENTER HEIGHT OF TROUGH, INCHES (CONDUCTOR CENTERED)"; HTG
  139. 6050 FAC = PI * HTG / 2 / TWID * 2
  140. 6060 TANH = (1 - EXP(-FAC)) / (1 + EXP(-FAC))
  141. 6070 ZO = 138 / 2.3 * LOG((4 * TWID / PI / CDIA) * TANH)
  142. 6100 PRINT
  143. 6110 PRINT " THE CHARACTERISTIC IMPEDANCE IS"; FNP(ZO); "OHMS"
  144. 6120 PRINT : INPUT "  PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
  145. 6130 IF T$ <> "" THEN 8000
  146. 6140 RETURN
  147. 7000 CLS
  148. 7010 PRINT " BASED ON WHEELER AND SCHNEIDER FORMULAS"
  149. 7020 PRINT
  150. 7030 INPUT " ENTER STRIP WIDTH, MILS"; WID: WID = WID / 1000
  151. 7040 INPUT "  ENTER STRIP THICKKNESS, MILS (1 OZ CU=1.4 MIL THICK)"; TIK: TIK = TIK / 1000
  152. 7050 INPUT "   ENTER SUBSTRATE THICKNESS, MILS"; HTG: HTG = HTG / 1000
  153. 7060 PRINT " TYPICAL DILECTRIC CONSTANTS; TEFLON=GLASS=2.55; GLASS EPOXY=4.8"
  154. 7070 INPUT "    ENTER SUBSTRATE DIELECTRIC CONSTANT"; DIL
  155. 7080 HE = HTG - 2 * TIK
  156. 7090 WE = WID + TIK / PI * (LOG(2 * HE / TIK + 1))
  157. 7100 IF WID / HTG > 1 THEN 7400
  158. 7200 EE = (DIL + 1) / 2 + (DIL - 1) / 2 * ((1 + 12 * HTG / WE) ^ -.5 + .04 * (1 - WE / HTG) ^ 2)
  159. 7210 ZO = 60 / SQR(EE) * LOG(8 * HTG / WE + .25 * WE / HTG)
  160. 7220 VP = 1 / SQR(EE)
  161. 7230 GOTO 7600
  162. 7400 EE = (DIL + 1) / 2 + (DIL - 1) / 2 * (1 + 12 * HTG / WE) ^ -.5
  163. 7410 ZO = 377 / SQR(EE) / (WE / HTG + 1.393 + .667 * (LOG(WE / HTG + 1.444)))
  164. 7420 VP = 1 / SQR(EE)
  165. 7600 PRINT
  166. 7610 PRINT " THE EFFECTIVE STRIP WIDTH IS"; FNP(WE); "INCHES"
  167. 7620 PRINT "  THE EFFECTIVE SUBSTRATE THICKNESS IS"; FNP(HE); "INCHES"
  168. 7630 PRINT "   THE EFFECTIVE DILECTRIC CONSTANT IS"; FNP(EE)
  169. 7640 PRINT
  170. 7650 PRINT " THE CHARACTERISTIC IMPEDANCE IS"; FNP(ZO); "OHMS"
  171. 7660 PRINT "  THE PROPAGATION FACTOR IS"; VP
  172. 7670 PRINT : INPUT "  PRESS ENTER TO RERUN, ANY OTHER + RETURN = QUIT"; T$
  173. 7680 IF T$ <> "" THEN 8000
  174. 7690 RETURN
  175. 8000 END
  176.  
  177.