Antennas/Antennas_CD-ROM_Walnut_Creek_September_1996.iso/w4mb/vol2/basic/corr.asc

Text File | 1996-06-30 | 8KB | 182 lines

2 ON ERROR GOTO 60000
3 CLS
10 PRINT "   ***************************************************************"
20 PRINT "   *                      CORNER REFLECTORS                      *"
30 PRINT "   *                  REFERENCE- KRAUS, ANTENNAS                 *"
40 PRINT "   *                PROGRAM BY  R.P. HAVILAND, W4MB              *"
50 PRINT "   *                       COPYRGHT 1990                         *"
60 PRINT "   *          MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086        *"
70 PRINT "   ***************************************************************"
80 DEF FNP (X) = INT(100 * X + .5) / 100
90 PI = 3.141592
100 RTOD = 360 / 2 / PI
110 DIM FLD(15), MUT(1, 25)
120 FOR N = 0 TO 25
130 READ MUT(0, N)
140 NEXT N
150 FOR N = 0 TO 25
160 READ MUT(1, N)
170 NEXT N
200 PRINT " THIS PROGRAM GIVES DESIGN DATA FOR THE TWO MAJOR CONFIGURATIONS"
210 PRINT "  OF REFLECTOR ANTENNAS, THE FLAT PLATE AND THE 90 DEG. CORNER."
220 INPUT " ENTER THE OPERATING FREQUENCY, MHZ"; FO
230 IF FO <= 0 THEN 220
240 LAM = 299.7 / FO
250 PRINT "  THE OPERATING WAVELENGTH="; FNP(LAM); "METERS"
260 PRINT "                          ="; FNP(LAM * 39.37); "INCHES"
300 PRINT
310 INPUT "  ENTER THE REFLECTOR ANGLE, 90 OR 180 DEGREES ONLY"; ANGL
320 IF ANGL = 90 THEN 350
330 IF ANGL = 180 THEN 350
340 GOTO 310
350 INPUT "   ENTER THE ANTENNA-REFLECTOR SPACING, WAVELENGTHS"; SP
360 IF SP < .01 OR SP > 1 THEN PRINT "OUT OF RANGE": GOTO 350
370 MXF = 0
400 PRINT
410 PRINT " ENTER 1= IDEAL PATTERN"
420 PRINT "       2= IDEAL GAIN"
430 PRINT "       3= CONSTRUCTION LIMITS"
440 PRINT "       4= NEW SPACING"
450 PRINT "       5= DATA PRINTOUT"
460 PRINT "       6= RERUN"
470 PRINT "       7= QUIT"
480 INPUT TEM
500 ON TEM GOSUB 1000, 2000, 3000, 350, 4000, 200, 5000
510 GOTO 400
1000 CLS
1010 PRINT , "+ ANGLE", "FIELD", " ANGLE", "FIELD"
1020 SR = SP * 2 * PI
1030 MXF = 0
1040 FOR N = 0 TO 15
1050 PANG = ANGL / 30 * N
1060 RADANG = PANG / RTOD
1070 FLD = SIN(SR * COS(RADANG))
1080 IF ANGL = 90 THEN FLD = COS(SR * COS(RADANG)) - COS(SR * SIN(RADANG))
1100 FLD = ABS(FLD)
1110 IF MXF < FLD THEN MXF = FLD
1120 FLD(N) = FLD
1130 NEXT N
1200 FOR N = 0 TO 15
1210 PANG = ANGL / 30 * N
1220 FLD(N) = ABS(FLD(N) / MXF)
1230 PRINT , PANG, FNP(FLD(N)), -PANG, FNP(FLD(N))
1240 NEXT N
1400 INPUT "PRESS RETURN TO CONTINUE"; T$
1999 RETURN
2000 CLS
2010 IF MXF = 0 THEN PRINT " DO PATTERN FIRST": GOTO 2999
2020 INPUT " ENTER REFLECTOR LOSS RES., TYPICALLY 1 OHM, 0=IDEAL"; R1L
2030 IF ANGL = 90 THEN 2200
2040 R11 = MUT(1, 0)
2050 SEP = 2 * SP
2060 GOSUB 2900
2070 R12 = MUTR
2080 GAIN = 2 * SQR((R11 + R1L) / (R11 + R1L - R12))
2090 GOTO 2800
2200 R11 = MUT(1, 0)
2210 SEP = 1.414 * SP
2220 GOSUB 2900
2230 R12 = MUTR
2240 SEP = 2 * SP
2250 GOSUB 2900
2260 R14 = MUTR
2270 GAIN = 2 * SQR((R11 + R1L) / (R11 + R1L + R14 - 2 * R12))
2280 GOTO 2800
2400 R11 = MUT(1, 0)
2410 SEP = .707 * SP
2420 GOSUB 2900
2430 R12 = MUTR
2440 SEP = 1.732 * SP
2450 GOSUB 2900
2460 R14 = MUTR
2470 SEP = 2 * SP
2480 GOSUB 2900
2490 R16 = MUTR
2500 GAIN = 2 * SQR((R11 + R1L) / (R11 + R1L + 2 * R14 - 2 * R12 - R16))
2800 GAIN = GAIN * MXF
2810 GAIN = 20 / 2.3 * LOG(GAIN)
2820 PRINT "  GAIN="; FNP(GAIN); "DB ABOVE A DIPOLE"
2830 PRINT "   AT THE PEAK OF THE LARGEST LOBE"
2899 RETURN
2900 N = 1
2910 IF SEP > MUT(0, N) THEN N = N + 1: GOTO 2910
2920 INPV = (MUT(0, N) - SEP) / (MUT(0, N) - MUT(0, N - 1))
2930 MUTR = MUT(1, N) - (MUT(1, N) - MUT(1, N - 1)) * INPV
2999 RETURN
3000 CLS
3010 PRINT " SPACING, RADIATOR TO REFLECTOR APEX="; FNP(SP * LAM); "METERS"
3020 PRINT "                                    ="; FNP(SP * LAM * 39.37); "INCHES"
3030 PRINT " MINIMUM SCREEN SIZE,APEX TO EDGE="; FNP(.75 * LAM); "METERS"
3040 PRINT "                                 ="; FNP(.75 * LAM * 39.37); "INCHES"
3050 PRINT " MINIMUM LENGTH OF SCREEN OR REFLECTOR RODS="; FNP(.7 * LAM); "METERS"
3060 PRINT "                                           ="; FNP(.7 * LAM * 39.37); "INCHES"
3100 PRINT " TYPICAL ROD SPACING="; FNP(.1 * LAM * 100); "CM"
3110 PRINT " THE RADIATOR MAY BE A BOW-TIE FOR BROAD-BAND OPERATION"
3120 PRINT "  WITH A LENGTH OF 0.8 WAVELENGTHS AT MID-BAND,"
3130 PRINT "                             ="; (.8 * LAM); "METERS"
3140 PRINT "                             ="; (.8 * LAM * 39.37); "INCHES"
3150 PRINT "  AND A WIDTH AT END OF .15 WAVELENGTHS, OR"
3160 PRINT "                             ="; (.15 * LAM); "METERS"
3170 PRINT "                              ="; (.15 * LAM * 39.37); "INCHES"
3180 PRINT " FORM DIPOLE TO BE PARALLEL TO REFLECTOR SIDES"
3190 PRINT "  USE LOWEST FREQUENCY FOR ABOVE MINIMUM DIMENSIONS"
3200 PRINT
3210 PRINT " THE RADIATOR MAY BE A BOW-TIE FOR BROAD-BAND OPERATION"
3220 PRINT "   WITH A LENGTH OF 0.8 WAVELENGTHS AT MID-BAND"
3230 PRINT "                              ="; FNP(.8 * LAM); "METERS"
3240 PRINT "                              ="; FNP(.8 * LAM * 39.37); "INCHES"
3250 PRINT "  AND A WIDTH AT END OF .15 WAVELENGTHS, OR"
3260 PRINT "                             ="; FNP(.15 * LAM); "METERS"
3270 PRINT "                             ="; FNP(.15 * LAM * 39.37); "INCHES"
3280 PRINT " FORM DIPOLE TO BE PARALLET TO REFLECTOR SIDES"
3290 PRINT "  USE LOWEST FREQUENCY TO OBTAIN MINIMUM REFLECTOR DIMENSIONS"
3300 PRINT
3400 INPUT "PRESS RETURN TO CONTINUE"; T$
3999 RETURN
4000 LPRINT " CORNER REFLECTOR ANTENNA"
4010 LPRINT "   FOR FREQUENCY="; FO; "MHZ"
4020 LPRINT "     CORNER ANGLE="; ANGL; "DEGREES"
4030 LPRINT " SPACING, RADIATOR TO REFLECTOR APEX="; FNP(SP * LAM); "METERS"
4040 LPRINT "                                    ="; FNP(SP * LAM * 39.37); "INCHES"
4050 LPRINT " MINIMUM SCREEN SIZE,APEX TO EDGE="; FNP(.75 * LAM); "METERS"
4060 LPRINT "                                 ="; FNP(.75 * LAM * 39.37); "INCHES"
4070 LPRINT " MINIMUM LENGTH OF SCREEN OR REFLECTOR RODS="; FNP(.7 * LAM); "METERS"
4080 LPRINT "                                           ="; FNP(.7 * LAM * 39.37); "INCHES"
4100 LPRINT " TYPICAL ROD SPACING="; FNP(.1 * LAM * 100); "CM"
4110 LPRINT " THE RADIATOR MAY BE A BOW-TIE FOR BROAD-BAND OPERATION"
4120 LPRINT "  WITH A LENGTH OF 0.8 WAVELENGTHS AT MID-BAND,"
4130 LPRINT "                             ="; (.8 * LAM); "METERS"
4140 LPRINT "                             ="; (.8 * LAM * 39.37); "INCHES"
4200 LPRINT
4210 LPRINT " THE RASIATOR MAY BE A BOW-TIE FOR BROAD-BAND OPERATION"
4220 LPRINT "   WITH A LENGTH OF 0.8 WAVELENGTHS AT MID-BAND"
4230 LPRINT "                              ="; FNP(.8 * LAM); "METERS"
4240 LPRINT "                              ="; FNP(.8 * LAM * 39.37); "INCHES"
4250 LPRINT "  AND A WIDTH AT END OF .15 WAVELENGTHS, OR"
4260 LPRINT "                             ="; FNP(.15 * LAM); "METERS"
4270 LPRINT "                             ="; FNP(.15 * LAM * 39.37); "INCHES"
4280 LPRINT " FORM DIPOLE TO BE PARALLET TO REFLECTOR SIDES"
4290 LPRINT "  USE LOWEST FREQUENCY TO OBTAIN MINIMUM REFLECTOR DIMENSIONS"
4300 LPRINT
4400 LPRINT "    MAIN LOBE PATTERN DATA"
4410 LPRINT " "
4420 LPRINT , "ANGLE", "REL.GAIN", "ANGLE", "REL.GAIN"
4430 FOR N = 0 TO 15
4440 PANG = ANG / 30 * N
4450 LPRINT , PANG, FNP(FLD(N)), -PANG, FNP(FLD(N))
4460 NEXT N
4500 LPRINT
4510 LPRINT "  GAIN="; FNP(GAIN); "DB ABOVE A DIPOLE"
4520 LPRINT "   AT THE PEAK OF THE LARGEST LOBE"
4530 LPRINT
4999 RETURN
5000 END
9000 DATA 0,.01,.05,.1,.125,.15,.2,.25,.3,.4,.5,.6,.7,.8,.9
9010 DATA 1,1.1,1.2,1.3,1.4,1.5,1.6,1.7,1.8,1.9,2
9020 DATA 73.13,73.07,71.65,67.5,64.4,60.6,51.6,40.9,29.4,6.3
9030 DATA -12.7,-23.4,-24.8,-18.6,-7.2,3.8,12.1,15.8,12.4,5.8
9040 DATA -2.4,-8.3,-10.7,-9.4,-4.8,1.1
60000 PRINT "ERROR"; ERR; "AT LINE"; ERL
60010 STOP