home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol2
/
basic
/
clpa.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
6KB
|
155 lines
2 ON ERROR GOTO 60000
3 CLS
10 PRINT " ****************************************************************"
20 PRINT " * G3JVL LONG BOOM CIRCULAR LOOP ARRAYS *"
30 PRINT " * REFERENCE VHF/UHF WORLD, JOE REISERT, HAM RADIO SEPT. 1985 *
40 PRINT " * PROGRAM BY R.P. HAVILAND, W4MB *"
50 PRINT " * COPYRGHT 1990 *"
60 PRINT " * MINILAB BOOKS, DAYTONA BEACH, FL 32121-1086 *"
70 PRINT " ****************************************************************"
80 DEF FNP(X)=INT(1000*X+.5)/1000
90 PI=3.141592
100 DIM SPAC(8),LLEN(2,7),SIZ(3,45),SIZFAC(44)
110 FOR N=0 TO 8
120 READ SPAC(N)
130 NEXT N
200 FOR N= 0 TO 5
210 READ LLEN(0,N)
220 NEXT N
300 FOR N= 0 TO 6
310 READ LLEN(1,N)
320 NEXT N
400 FOR N= 0 TO 7
410 READ LLEN(2,N)
420 NEXT N
500 DEF FNBOOM(X)=-.732286+.042287*X+2.765712*X*X
510 DEF FNWID(X)=.9-5*X
520 DEF FNTIK(X)=-.506+17.7*X
600 PROFREQ=1296
700 PRINT " THIS PROGRAM SCALES G3JVL LOOP ARRAYS TO A SPECIFIC FREQUENCY."
710 PRINT " LOOPS ARE MADE OF THIN STRAPS, FORMED INTO A CIRCLE, AND"
720 PRINT " FASTENED TO THE BOOM BY A SINGLE SCREW"
730 PRINT " TO GIVE A LOW RESISTANCE CONTACT BETWEEN STRAP ENDS."
740 PRINT " ANTI-CORROSION TREATMENT OF JOINT IS NECESSARY FOR GOOD LIFE."
750 PRINT " STRAP CAN BE ALUMINUM OR COPPER OR SILVER PLATED COPPER."
760 PRINT " TO USE THIN MATERIAL, FORM STRAP INTO A SHALLOW VEE"
770 PRINT " OVER A CONICAL MANDREL."
780 PRINT " FEED LINE PASSES THROUGH BOOM, TO POINT 180 DEG. FROM"
790 PRINT " DRIVEN ELEMENT ATTACHMENT TO BOOM."
800 PRINT " MATCHING SECTION CAN BE ATTACHED TO BOOM."
810 PRINT " DIMENSIONS ARE CRITICAL- *** CONSTRUCT CAREFULLY ***."
820 PRINT
1000 INPUT "ENTER DESIGN FREQUENCY, MHZ";DESFREQ
1010 IF DESFREQ=<0 THEN 1000
1020 PRINT
1030 SCL=PROFREQ/DESFREQ
1040 PRINT " DESIGNS ARE PROVIDED FOR"
1050 PRINT "# ELEMENTS BOOM, INCHES BOOM, FEET GAIN-DB"
1060 PRINT 28, FNP(SCL*80.76), FNP(SCL*80.76/12),19!
1070 PRINT 38, FNP(SCL*(80.76+10*3.56)), FNP(SCL*(80.76+10*3.56)/12),20
1090 PRINT 45, FNP(SCL*(80.76+17*3.56)), FNP(SCL*(80.76+17*3.56)/12),20.7
1100 PRINT
1110 INPUT "ENTER NUMBER OF ELEMENTS TO USE, 28,38, OR 45";NELE
1120 IF NELE=28 THEN 1200
1130 IF NELE=38 THEN 1200
1140 IF NELE=45 THEN 1200
1150 PRINT " DESIGNS ARE PROVIDED ONLY FOR"
1160 GOTO 1050
1200 PRINT
1210 PRINT " STANDARD DESIGN IS BASED ON A BOOM DIAMETER OF ";FNP(SCL*.5);"INCHES"
1220 INPUT " ENTER NEW VALUE, OR ENTER ONLY= NO CHANGE";T$
1230 IF T$="" THEN BOOM=SCL*.5:GOTO 1400
1240 BOOM=VAL(T$)
1400 PRINT
1410 PRINT " STANDARD DESIGN IS BASED ON A ELEMENT WIDTH OF ";FNP(SCL*.188);"INCHES"
1420 INPUT " ENTER NEW VALUE, OR ENTER ONLY= NO CHANGE";T$
1430 IF T$="" THEN WID=SCL*.188:GOTO 1600
1440 WID=VAL(T$)
1600 PRINT
1610 PRINT " STANDARD DESIGN IS BASED ON A ELEMENT THICKNESS OF ";FNP(SCL*.028);"INCHES"
1620 INPUT " ENTER NEW VALUE, OR ENTER ONLY= NO CHANGE";T$
1630 IF T$="" THEN TIK=SCL*.028:GOTO 1700
1640 TIK=VAL(T$)
1700 PRINT " WAIT- PROCESSING"
1800 IF NELE=28 THEN TYP=0
1810 IF NELE=38 THEN TYP=1
1820 IF NELE=45 THEN TYP=2
1830 FOR N=0 TO NELE-1
1840 IF N<2 THEN SIZFAC(N)=LLEN(TYP,0):GOTO 1920 'REF
1850 IF N<3 THEN SIZFAC(N)=LLEN(TYP,1):GOTO 1920 'RAD
1860 IF N<14 THEN SIZFAC(N)=LLEN(TYP,2):GOTO 1920
1870 IF N<21 THEN SIZFAC(N)=LLEN(TYP,3):GOTO 1920
1880 IF N<26 THEN SIZFAC(N)=LLEN(TYP,4):GOTO 1920
1890 IF N<28 THEN SIZFAC(N)=LLEN(TYP,5):GOTO 1920
1900 IF N<38 THEN SIZFAC(N)=LLEN(TYP,6):GOTO 1920
1910 SIZFAC(N)=LLEN(TYP,7)
1920 NEXT N
2000 CUMP=0
2010 FOR N=0 TO NELE-2
2020 IF N>8 THEN PSPC=SCL*SPAC(8):GOTO 2040
2030 PSPC = SCL * SPAC(N)
2040 SIZ(0,N)=PSPC
2050 CUMP=CUMP+PSPC
2060 SIZ(1,N)=CUMP
2070 NEXT N
3000 BOOMCOR=FNBOOM(BOOM/SCL)/100
3010 WIDCOR=FNWID(WID/SCL)/100
3020 TIKCOR=FNTIK(TIK/SCL)/100
3030 TCOR=BOOMCOR+WIDCOR+TIKCOR
4000 FOR N=0 TO NELE-1
4010 SIZ(2,N)=(1+TCOR)*SIZFAC(N)*SCL
4020 SIZ(3,N)=SIZ(2,N)+.5
4030 NEXT N
5000 CLS
5010 PRINT "# TYPE LOOP LOA LOOP DRILL SPACE NEXT POSITION"
5020 FOR N=0 TO NELE-1
5030 PRINT N+1;" ";
5040 IF N<2 THEN PRINT "REF. ";:GOTO 5070
5050 IF N=2 THEN PRINT "RAD. ";:GOTO 5070
5060 PRINT "DIR. ";
5070 PRINT FNP(SIZ(3,N)),FNP(SIZ(2,N)),FNP(SIZ(0,N)),FNP(SIZ(1,N))
5080 IF N=20 THEN INPUT "PRESS RETURN TO CONTINUE";T$
5090 IF N=40 THEN INPUT "PRESS RETURN TO CONTINUE";T$
5100 NEXT N
5500 INPUT "ENTER 1=PRINT RESULTS, 2=RERUN, 3=DRAWING, 4=QUIT";T$
5510 IF T$="1" THEN GOSUB 6000
5520 IF T$="2" THEN 1000
5530 IF T$="3" THEN GOSUB 8000
5540 IF T$="4" THEN STOP
5550 GOTO 5500
6000 LPRINT " DATA FOR A LONG-BOOM CIRCULAR LOOP ARRAY"
6010 LPRINT " FREQUENCY =";DESFREQ;"MHZ"
6020 LPRINT " BOOM DIAMETER =";FNP(BOOM);"INCHES
6030 LPRINT " ELEMENT STRAP WIDTH =";FNP(WID);"INCHES"
6040 LPRINT " STRAP THICKNESS =";FNP(TIK);"INCHES":LPRINT
6050 LPRINT "# ";"TYPE ";"LOOP LOA","LOOP DRILL","SPACE NEXT","POSITION"
6060 FOR N=0 TO NELE-1
6070 LPRINT N+1;" ";
6080 IF N<2 THEN LPRINT "REF. ";:GOTO 6110
6090 IF N=2 THEN LPRINT "RAD. ";:GOTO 6110
6100 LPRINT "DIR. ";
6110 LPRINT FNP(SIZ(3,N)),FNP(SIZ(2,N)),FNP(SIZ(0,N)),FNP(SIZ(1,N))
6120 NEXT N
6130 RETURN
8000 CLS
8010 PRINT " DETAIL OF A LOOP STRAP BEFORE FORMING INTO A CIRCLE"
8020 PRINT
8030 PRINT " SSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSS"
8040 PRINT " S S"
8050 PRINT " S O O S"
8060 PRINT " S S"
8070 PRINT " SSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSSS"
8080 PRINT
8100 PRINT " <------------- LOOP DRILL DISTANCE -------------->"
8110 PRINT " <--------------- LOOP LENGTH OVERALL ---------------->"
8120 PRINT
8130 PRINT
8140 INPUT "PRESS RETURN TO CONTINUE";T$
8990 RETURN
50000 DATA 3.1,.95,1.12,.83,1.78,1.78,1.25,2.31,3.56
50010 DATA 9.67,9.23,8.25,8,8,8
50020 DATA 9.67,9.23,8.25,8,7.7,7.7,7.7
50030 DATA 9.67,9.23,8.25,8,7.75,7.65,7.65,7.5
60000 PRINT "ERROR";ERR;"AT LINE";ERL
60010 STOP