home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol1 / basic / ophorn.asc < prev    next >
Text File  |  1996-06-30  |  3KB  |  67 lines
  1. 100 CLS : PRINT "  ************************************"
  2. 110 PRINT "  *      OPTIMUM HORN ANTENNAS       *"
  3. 120 PRINT "  * SCHRANK,PAGE 25-26 DECEMBER 1983 *"
  4. 130 PRINT "  *        IEEE-AP NEWSLETTER        *"
  5. 140 PRINT "  *      PROGRAM COPYRIGHT 1985      *"
  6. 150 PRINT "  *        R.P.HAVILAND, W4MB        *"
  7. 160 PRINT "  ************************************"
  8. 170 REM PROGRAM 22
  9. 180 DEF FNP (X) = INT(10 * X + .5) / 10
  10. 200 PRINT " THIS PROGRAM GIVES MINIMUM HORN LENGTH FOR A SPECIFIED GAIN"
  11. 210 PRINT : PRINT : INPUT "DESIGN GAIN, DB"; GA
  12. 220 IF GA < 10 OR GA > 32 THEN PRINT "GAIN RANGE OF TABLES IS 10-32 DB": GOTO 210
  13. 230 INPUT " DESIGN FREQUENCY, MHZ"; FO
  14. 240 LA = 11808 / FO
  15. 250 GB = LOG(GA)
  16. 300 PRINT : PRINT " PRESS   C=CONICAL HORN"
  17. 310 PRINT "         P=PYRAMIDAL HORN"
  18. 320 PRINT "         R=RERUN"
  19. 330 PRINT "         Q=QUIT"
  20. 340 Q$ = INKEY$: IF Q$ = "" THEN 340
  21. 350 IF Q$ = "P" THEN 1500
  22. 360 IF Q$ = "C" THEN 1000
  23. 370 IF Q$ = "Q" THEN STOP
  24. 380 IF Q$ = "R" THEN RUN
  25. 390 GOTO 340
  26. 1000 REM CONICAL HORN
  27. 1010 DI = -2.9475 + .434151 * EXP(GB) - .015246 * EXP(2 * GB) + 2.3004E-04 * EXP(3 * GB): DI = EXP(DI)
  28. 1020 LE = -7.4304 + .83708 * EXP(GB) - .02629 * EXP(2 * GB) + 3.78453E-04 * EXP(3 * GB): LE = EXP(LE)
  29. 1030 DL = DI * LA
  30. 1040 LL = LE * LA
  31. 1050 PRINT "CONICAL HORN DIMENSIONS ARE"
  32. 1060 PRINT " MOUTH DIAMETER="; FNP(DI); "WAVELENGTHS"
  33. 1070 PRINT "               ="; FNP(DL); "INCHES"
  34. 1080 PRINT
  35. 1090 PRINT " LENGTH="; FNP(LE); "WAVELENGTHS"
  36. 1100 PRINT "       ="; FNP(LL); "INCHES"
  37. 1110 GOSUB 2000
  38. 1120 PRINT : PRINT "PRESS A KEY FOR MORE"
  39. 1130 Q$ = INKEY$: IF Q$ = "" THEN 1130
  40. 1140 GOTO 300
  41. 1500 REM PYRAMIDAL HORM
  42. 1510 HW = -.6885 + .11113 * EXP(GB): HW = EXP(HW)
  43. 1520 EW = -1.075368 + .11697 * EXP(GB): EW = EXP(EW)
  44. 1530 LE = -3.58868 + .25922 * EXP(GB): LE = EXP(LE)
  45. 1540 HL = HW * LA
  46. 1550 EL = EW * LA
  47. 1560 LL = LE * LA
  48. 1600 PRINT "PYRAMIDAL HORN DIMENSIONS ARE"
  49. 1610 PRINT : PRINT " H-PLANE MOUTH WIDTH="; FNP(HW); "WAVELENGTHS"
  50. 1620 PRINT "                    ="; FNP(HL); "INCHES"
  51. 1630 PRINT
  52. 1640 PRINT " E-PLANE MOUTH HEIGHT="; FNP(EW); "WAVELENGTHS"
  53. 1650 PRINT "                     ="; FNP(EL); "INCHES"
  54. 1660 PRINT
  55. 1670 PRINT " LENGTH="; FNP(LE); "WAVELENGTHS"
  56. 1680 PRINT "       ="; FNP(LL); "INCHES"
  57. 1690 PRINT
  58. 1700 GOSUB 2000
  59. 1710 PRINT : PRINT "PRESS A KEY FOR MORE"
  60. 1720 Q$ = INKEY$: IF Q$ = "" THEN 1720
  61. 1730 GOTO 300
  62. 2000 PRINT : PRINT "LENGTH IS APERTURE PLANE TO CENTER-LINE INTERCEPT."
  63. 2010 PRINT "SIDE CONVERGES FROM MOUTH TO INTERCEPT."
  64. 2020 PRINT " JOIN HORN TO SELECTED WAVEGUIDE."
  65. 2030 RETURN
  66.  
  67.