home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Antennas
/
Antennas_CD-ROM_Walnut_Creek_September_1996.iso
/
w4mb
/
vol1
/
basic
/
ophorn.asc
< prev
next >
Wrap
Text File
|
1996-06-30
|
3KB
|
67 lines
100 CLS : PRINT " ************************************"
110 PRINT " * OPTIMUM HORN ANTENNAS *"
120 PRINT " * SCHRANK,PAGE 25-26 DECEMBER 1983 *"
130 PRINT " * IEEE-AP NEWSLETTER *"
140 PRINT " * PROGRAM COPYRIGHT 1985 *"
150 PRINT " * R.P.HAVILAND, W4MB *"
160 PRINT " ************************************"
170 REM PROGRAM 22
180 DEF FNP (X) = INT(10 * X + .5) / 10
200 PRINT " THIS PROGRAM GIVES MINIMUM HORN LENGTH FOR A SPECIFIED GAIN"
210 PRINT : PRINT : INPUT "DESIGN GAIN, DB"; GA
220 IF GA < 10 OR GA > 32 THEN PRINT "GAIN RANGE OF TABLES IS 10-32 DB": GOTO 210
230 INPUT " DESIGN FREQUENCY, MHZ"; FO
240 LA = 11808 / FO
250 GB = LOG(GA)
300 PRINT : PRINT " PRESS C=CONICAL HORN"
310 PRINT " P=PYRAMIDAL HORN"
320 PRINT " R=RERUN"
330 PRINT " Q=QUIT"
340 Q$ = INKEY$: IF Q$ = "" THEN 340
350 IF Q$ = "P" THEN 1500
360 IF Q$ = "C" THEN 1000
370 IF Q$ = "Q" THEN STOP
380 IF Q$ = "R" THEN RUN
390 GOTO 340
1000 REM CONICAL HORN
1010 DI = -2.9475 + .434151 * EXP(GB) - .015246 * EXP(2 * GB) + 2.3004E-04 * EXP(3 * GB): DI = EXP(DI)
1020 LE = -7.4304 + .83708 * EXP(GB) - .02629 * EXP(2 * GB) + 3.78453E-04 * EXP(3 * GB): LE = EXP(LE)
1030 DL = DI * LA
1040 LL = LE * LA
1050 PRINT "CONICAL HORN DIMENSIONS ARE"
1060 PRINT " MOUTH DIAMETER="; FNP(DI); "WAVELENGTHS"
1070 PRINT " ="; FNP(DL); "INCHES"
1080 PRINT
1090 PRINT " LENGTH="; FNP(LE); "WAVELENGTHS"
1100 PRINT " ="; FNP(LL); "INCHES"
1110 GOSUB 2000
1120 PRINT : PRINT "PRESS A KEY FOR MORE"
1130 Q$ = INKEY$: IF Q$ = "" THEN 1130
1140 GOTO 300
1500 REM PYRAMIDAL HORM
1510 HW = -.6885 + .11113 * EXP(GB): HW = EXP(HW)
1520 EW = -1.075368 + .11697 * EXP(GB): EW = EXP(EW)
1530 LE = -3.58868 + .25922 * EXP(GB): LE = EXP(LE)
1540 HL = HW * LA
1550 EL = EW * LA
1560 LL = LE * LA
1600 PRINT "PYRAMIDAL HORN DIMENSIONS ARE"
1610 PRINT : PRINT " H-PLANE MOUTH WIDTH="; FNP(HW); "WAVELENGTHS"
1620 PRINT " ="; FNP(HL); "INCHES"
1630 PRINT
1640 PRINT " E-PLANE MOUTH HEIGHT="; FNP(EW); "WAVELENGTHS"
1650 PRINT " ="; FNP(EL); "INCHES"
1660 PRINT
1670 PRINT " LENGTH="; FNP(LE); "WAVELENGTHS"
1680 PRINT " ="; FNP(LL); "INCHES"
1690 PRINT
1700 GOSUB 2000
1710 PRINT : PRINT "PRESS A KEY FOR MORE"
1720 Q$ = INKEY$: IF Q$ = "" THEN 1720
1730 GOTO 300
2000 PRINT : PRINT "LENGTH IS APERTURE PLANE TO CENTER-LINE INTERCEPT."
2010 PRINT "SIDE CONVERGES FROM MOUTH TO INTERCEPT."
2020 PRINT " JOIN HORN TO SELECTED WAVEGUIDE."
2030 RETURN