home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol1 / basic / multrap.asc < prev    next >
Text File  |  1996-06-30  |  3KB  |  97 lines
  1. 10 CLS : PRINT "  ***********************************"
  2. 20 PRINT "  *      MULTI-BAND TRAP ANTENNA    *"
  3. 30 PRINT "  *          REFERENCE-BOYER        *"
  4. 40 PRINT "  *    CQ MAGAZNE, FEB.-MAY, 1977   *"
  5. 50 PRINT "  *      PROGRAM COPYRIGHT, 1985    *"
  6. 60 PRINT "  *        R. P. HAVILAND, W4MB     *"
  7. 80 PRINT "  ***********************************"
  8. 85 REM PROGRAM 8
  9. 90 PI = 3.14159
  10. 100 PRINT "THIS PROGRAM CALCULATES SECTIONS AND "
  11. 105 PRINT "TRAPS FOR MULTI-BAND VERTICALS"
  12. 110 PRINT "AND HALF OF DIPOLES."
  13. 120 PRINT "SECTION LENGTHS ARE IN ELECTRICAL"
  14. 130 PRINT "DEGREES AND INCHES."
  15. 140 PRINT
  16. 150 PRINT " ENTER NUMBER OF BANDS"
  17. 160 INPUT J
  18. 170 DIM F(J), D(J), L(J), C(J), T(J), H(J), Z(J)
  19. 200 PRINT "ENTER TRAP KNOWN, L OR C, OR T IF A COAX TRAP"
  20. 210 INPUT K$
  21. 220 PRINT "STARTING WITH HIGHEST BAND, IN ORDER;"
  22. 230 FOR N = 1 TO J
  23. 240 PRINT "ENTER FREQ "; N,
  24. 250 INPUT F(N)
  25. 260 PRINT "SECTON "; N; "  DIA., INCHES "
  26. 270 INPUT D(N): IF N = J THEN 340
  27. 280 PRINT "TRAP-"; N; " L-UH,C-PF OR 0=COAX TRAP"
  28. 290 INPUT TE
  29. 300 IF K$ = "L" THEN L(N) = TE
  30. 310 IF K$ = "C" THEN C(N) = TE
  31. 320 IF K$ = "T" AND TE <> 0 GOTO 280
  32. 330 PRINT TE
  33. 340 NEXT N
  34. 350 IF K$ <> "T" GOTO 600
  35. 400 REM COAX TRAP
  36. 410 PRINT "ENTER TRAP DIA.; 1.5 OR .875 INCHES, OR MODIFY PROGRAM FOR OTHER DIAS."
  37. 420 INPUT TP
  38. 430 FOR N = 1 TO J - 1
  39. 440 IF TP = .875 THEN T(N) = 136.7 * F(N) ^ -.91
  40. 450 IF TP = 1.5 THEN T(N) = 68.9 * F(N) ^ -.86
  41. 460 IF TP = .875 OR TP = 1.5 GOTO 480
  42. 470 GOTO 410
  43. 480 L(N) = (TP + .2) ^ 2 * T(N) * 2 / (20 * (TP + .2) + 8 * T(N))
  44. 490 NEXT N
  45. 600 REM DO L OR C
  46. 610 FOR N = 1 TO J - 1
  47. 620 IF K$ = "L" OR K$ = "T" THEN TE = 2 * PI * F(N) * L(N)
  48. 630 IF K$ = "C" THEN TE = 10 ^ 6 / (2 * PI * F(N) * C(N))
  49. 640 IF K$ = "L" OR K$ = "T" THEN C(N) = 10 ^ 6 / (2 * PI * F(N) * TE)
  50. 650 IF K$ = "C" THEN L(N) = TE / (2 * PI * F(N))
  51. 660 NEXT N
  52. 800 REM DO SECTION Z
  53. 810 FOR N = 1 TO J
  54. 820 TE = 11808 / F(N)
  55. 830 Z(N) = 60 * (LOG(TE / D(N)) - 1)
  56. 840 NEXT N
  57. 1000 REM MAIN LOOPS
  58. 1010 H(1) = PI / 2
  59. 1015 IF J = 1 GOTO 2000
  60. 1020 FOR N = 2 TO J
  61. 1030 FOR P = 1 TO N - 1
  62. 1040 M = F(N) / F(P)
  63. 1050 DE = DE + H(P) * M
  64. 1060 RE = 2 * PI * F(P) * L(P) / ((1 / M - M) * Z(N))
  65. 1070 RE = RE + TAN(DE)
  66. 1080 DE = ATN(RE)
  67. 1090 NEXT P
  68. 1100 H(N) = PI / 2 - DE
  69. 1110 DE = 0
  70. 1120 NEXT N
  71. 2000 REM OUTPUT
  72. 2010 PRINT
  73. 2020 PRINT "FREQ    DIA  L-UH C-PF  H-DEG H-IN";
  74. 2025 IF K$ = "T" THEN PRINT " TURNS";
  75. 2030 PRINT : LO = 0
  76. 2040 FOR N = 1 TO J
  77. 2050 PRINT F(N);
  78. 2060 PRINT TAB(8); D(N);
  79. 2070 PRINT TAB(13); INT(10 * L(N)) / 10;
  80. 2080 PRINT TAB(18); INT(C(N) + .5);
  81. 2090 PRINT TAB(24); (INT(10 * H(N) * 180 / PI)) / 10;
  82. 2100 FA = .673 * Z(N) ^ .053
  83. 2110 FA = FA * 11806 / F(N)
  84. 2120 FA = FA * H(N) / 2 / PI
  85. 2130 LO = LO + FA
  86. 2140 PRINT TAB(31); INT(FA);
  87. 2150 IF K$ = "T" THEN PRINT TAB(36); (INT(10 * T(N))) / 10;
  88. 2160 PRINT
  89. 2170 NEXT N
  90. 2180 PRINT : PRINT "LOA= "; INT(LO / 12); " FEET": PRINT : PRINT
  91. 3000 REM RERUN
  92. 3010 PRINT "PRESS R TO RERUN, ANY OTHER KEY TO STOP"
  93. 3020 Q$ = INKEY$: IF Q$ = "" GOTO 3020
  94. 3030 IF Q$ = "R" OR Q$ = "r" THEN RUN
  95. 3040 END
  96.  
  97.