home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / w4mb / vol1 / basic / hgyagi.asc < prev    next >
Text File  |  1996-06-30  |  2KB  |  45 lines
  1. 10 CLS
  2. 15 PRINT "  ***********************************"
  3. 20 PRINT "  *          HIGH GAIN YAGI         *"
  4. 25 PRINT "  *  SEE TRANS IEEE AP-31,MAY 1983  *"
  5. 30 PRINT "  *      PROGRAM COPYRIGHT 1985     *"
  6. 35 PRINT "  *        R P HAVILAND, W4MB       *"
  7. 40 PRINT "  ***********************************"
  8. 45 REM PROGRAM 20
  9. 50 PRINT : PRINT "THIS YAGI USES SHAPED ELEMENTS TO GIVE A GAIN OF 11.5 DBI"
  10. 60 PRINT " WITH A FEED IMPEDANCE IS 14 +J 32 OHMS."
  11. 70 DIM A(3), B(3), C(3), D(3), Z(3), Y(20, 4)
  12. 80 A(1) = .38: A(2) = .395: A(3) = .364
  13. 90 B(1) = 20.77: B(2) = 53.014: B(3) = 204.532
  14. 100 D(1) = .645: D(2) = .59: D(3) = .55
  15. 110 C(1) = -.162: C(2) = 0: C(3) = .151
  16. 120 D(1) = .645: D(2) = .59: D(3) = .55
  17. 130 PRINT : PRINT "ENTER FREQUENCY, MHZ ";
  18. 140 INPUT F
  19. 145 LAMDA = 984 / F
  20. 150 PRINT F: PRINT "ELEMENT LENGTH= "; 1.5 * LAMDA; " FEET"
  21. 160 PRINT "ELEMENT DIAMETER "; 12 * LAMDA / 100; " INCHES"
  22. 170 FOR N = 1 TO 14: FOR M = 3 TO 1 STEP -1
  23. 180 X = (N - 1) / 20
  24. 190 IF X > D(M) THEN Y(N, M) = 0: GOTO 220
  25. 200 Y(N, M) = A(M) * (1 - 1 / (1 + B(M) * X * X)) + C(M)
  26. 210 Y(N, 4) = X
  27. 220 NEXT M: NEXT N
  28. 230 PRINT "Y VS X COORDINATES, INCHES"
  29. 240 PRINT "X", "DIR", "ANT", "REF"
  30. 250 FOR N = 1 TO 13
  31. 260 X = INT(1200 * LAMDA * Y(N, 4)) / 100
  32. 270 FOR M = 1 TO 3
  33. 280 Z(M) = INT(1200 * LAMDA * Y(N, M)) / 100
  34. 290 NEXT M
  35. 300 PRINT X, Z(1),
  36. 302 IF N >= 13 THEN PRINT , , : GOTO 310
  37. 304 PRINT Z(2), Z(3)
  38. 310 NEXT N
  39. 315 PRINT " JOIN POINTS FOR AN ELEMENT WITH A SMOOTH CURVE"
  40. 320 PRINT : PRINT "PRESS R TO RERUN, ANY OTHER KEY TO STOP."
  41. 330 Q$ = INKEY$: IF Q$ = "" GOTO 330
  42. 340 IF Q$ = "R" OR Q$ = "r" THEN RUN
  43. 350 END
  44.  
  45.