home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / net94 / basic / joinnet.asc < prev    next >
Text File  |  1996-06-30  |  3KB  |  73 lines
  1. 2 ON ERROR GOTO 60000
  2. 3 CLS
  3. 10 PRINT " ************    JOIN NETWORKS      ************"
  4. 11 PRINT " *       SEE EDN FEB 4,1981, PP 126-133        *"
  5. 12 PRINT " *          BY R.P.HAVILAND, 1994              *"
  6. 13 PRINT " ***********************************************"
  7. 14 PRINT
  8. 20 PRINT " THIS PROGRAM JOINS TWO NETWORK94 .NET FILES INTO A NEW FILE,"
  9. 30 PRINT "  TO USE PREPARED NETWORK SECTIONS AS COMPONENTS."
  10. 40 PRINT "   USE NET94 TO CONNECT THE SELECTED SECTIONS."
  11. 50 PRINT
  12. 60 C$ = " "
  13. 70 LIN7$ = " 0  0  0  0  0  0  0"
  14. 80 LIN6$ = " 0  0  0  0  0  0"
  15. 100 INPUT " ENTER NAME OF FIRST NETWORK, .NET IS ADDED "; NA1$
  16. 110 INPUT "  ENTER FILEPATH TO FIRST NETWORK, INCLUDE ANY : AND / "; FP1$
  17. 120 OPEN FP1$ + NA1$ + ".NET" FOR INPUT AS #1
  18. 130 INPUT #1, X1, N1
  19. 140 IF X1 = N1 THEN 160
  20. 150 PRINT "*** UNCONNECTED NODE IN NET 1 WILL APPEAR IN JOINED NET ***"
  21. 160 PRINT N1; "   NODES IN FILE 1"
  22. 200 INPUT " ENTER NAME OF SECOND NETWORK, .NET IS ADDED"; NA2$
  23. 210 INPUT "  ENTER FILEPATH TO SECOND NETWORK, INCLUDE ANY : AND / "; FP2$
  24. 220 OPEN FP2$ + NA2$ + ".NET" FOR INPUT AS #2
  25. 230 INPUT #2, X2, N2
  26. 240 IF X2 = N2 THEN 260
  27. 250 PRINT "*** UNCONNECTED NODE IN NET 2 WILL APPEAR IN JOINED NET ***"
  28. 260 PRINT N2; "    NODES IN NET 2"
  29. 300 INPUT " ENTER NAME OF NEW, JOINED NETWORK, .NET IS ADDED "; NA3$
  30. 310 INPUT "  ENTER REFERENCE DATE OF NEW NETWORK"; DA3$
  31. 320 INPUT "   ENTER FILEPATH TO NEW NETWORK, INCLUDE ANY : AND / "; FP3$
  32. 330 OPEN FP3$ + NA3$ + ".NET" FOR OUTPUT AS #3
  33. 400 X3 = X1 + X2
  34. 410 N3 = N1 + N2
  35. 420 PRINT #3, X3; C$; N3
  36. 500 FOR M = 1 TO N1      'DO N1 SETS
  37. 510 LINE INPUT #1, LIN$  'GET A 7-LINE
  38. 520 PRINT #3, LIN$
  39. 530 FOR L = 1 TO N1
  40. 540 LINE INPUT #1, LIN$   'GET N1 6-LINES
  41. 550 PRINT #3, LIN$
  42. 560 NEXT L
  43. 600 FOR L = 1 TO N2       'ADD N2 DUMMY LINES
  44. 610 PRINT #3, LIN6$
  45. 620 NEXT L
  46. 630 NEXT M
  47. 700 FOR M = 1 TO N2       'DO N1 DUMMY SETS
  48. 710 PRINT #3, LIN7$
  49. 720 FOR L = 1 TO N1
  50. 730 PRINT #3, LIN6$
  51. 740 NEXT L
  52. 800 LINE INPUT #2, LIN$   'GET, DISCARD A 7-LINE
  53. 810 FOR L = 1 TO N2
  54. 820 LINE INPUT #2, LIN$   'GET N2 6-LINES
  55. 830 PRINT #3, LIN$
  56. 840 NEXT L
  57. 850 NEXT M
  58. 1000 PRINT #3, NA3$
  59. 1010 PRINT #3, DA3$
  60. 1020 CLOSE
  61. 2000 PRINT
  62. 2010 INPUT " CREATE ANOTHER JOINED NETWORK. Y/N"; T$
  63. 2020 IF T$ <> "Y" THEN STOP
  64. 2100 PRINT
  65. 2110 GOTO 100
  66. 60000 PRINT "   ERROR "; ERR; " AT LINE "; ERL
  67. 60010 IF ERL = 120 THEN PRINT " FILE NOT FOUND": RESUME 100
  68. 60020 IF ERL = 220 THEN PRINT " FILE NOT FOUND": RESUME 200
  69. 60030 IF ERL = 320 THEN PRINT " FILE CREATION FAILURE": RESUME 300
  70. 60040 STOP
  71. 60050 END
  72.  
  73.