home *** CD-ROM | disk | FTP | other *** search
/ Antennas / Antennas_CD-ROM_Walnut_Creek_September_1996.iso / mininec / amiga / makedipl.asc < prev    next >
Text File  |  1996-06-30  |  2KB  |  59 lines
  1. 10 ON ERROR GOTO 6000
  2. 20 PRINT"      *******************************************"
  3. 30 PRINT"      *        DIPOLE ANTENNA DESIGNER          *"
  4. 40 PRINT"      *     PROGRAM BY R.P.HAVILAND, W4MB       *"
  5. 50 PRINT"      *          REFERENCE- HAVILAND            *"
  6. 60 PRINT"      *  PRACTICAL ANTENNA DESIGN AND ANALYSIS  *
  7. 70 PRINT"      *         PROGRAM  COPYRIGHT 1990         *"
  8. 80 PRINT"      *             MINILAB BOOKS               *"
  9. 90 PRINT"      *      DAYTONA BEACH, FL 32121-1086       *"
  10. 100 PRINT"      *******************************************"
  11. 200 DEF FN A(X)=INT(10*X+.5)/10
  12. 210 DEF FN B(X)=INT(100*X+.5)/100
  13. 300 PRINT
  14. 310 INPUT" ENTER RESONANT FREQUENCY, MHZ";FO
  15. 320 INPUT" ENTER CONDUCTOR DIAMETER, INCHES";DC
  16. 330 LA=984/FO :LM=299.8/FO
  17. 340 LD=LA/2
  18. 350 KR=12*LD/DC
  19. 360 LR=1-1/(4.6719*LOG(KR)-8)
  20. 370 TV=LA*LR/2
  21. 380 IF ABS(LD-TV)>.00001 THEN LD=TV:GOTO 350
  22. 390 PRINT " THE DIPOLE LENGTH IS";FNB(LD);"FEET, OR ";FNB(LD*12);" INCHES"
  23. 1200 PRINT :PRINT "  ENTER 1= SAVE AS HORIZONTALLY POLARIZED MININEC FILE"
  24. 1210 PRINT "        2= SAVE AS VERTICALLY POLARIZED MININEC FILE"
  25. 1220 PRINT "        3= REVISE DESIGN
  26. 1230 PRINT "        4= QUIT"
  27. 1240 INPUT TEM
  28. 1250 ON TEM GOTO 2000,2000,300,4000
  29. 1260 GOTO 1200
  30. 2000 PRINT :PRINT "ENTER NUMBER OF CALCULATION SEGMENTS"
  31. 2010 PRINT "    4-MINIMUM
  32. 2020 PRINT "    8=REASONABLE ACCURACY"
  33. 2030 PRINT "   16=GOOD ACCURACY"
  34. 2040 INPUT SG 
  35. 2100 INPUT "ENTER FILENAME OF ANTENNA, .GEO IS ADDED";NA$:
  36. 2110 INPUT "ENTER FILEPATH TO USE, INCLUDE AND : AND / ";FP$: NA$=FP$+NA$+".GEO"
  37. 2120 OPEN NA$ AS #1 LEN=30
  38. 2130 FIELD #1, 2 AS S$, 4 AS X1$, 4 AS Y1$, 4 AS Z1$, 4 AS X2$, 4 AS Y2$, 4 AS Z2$, 4 AS RW$
  39. 2140 LSET S$=MKI$(1)
  40. 2150 PUT #1
  41. 2160 Y1=0:Y2=Y1
  42. 2170 WRAD=DC/39.37/2
  43. 2180 DHL=LD/3.2808/2
  44. 2190 LSET S$=MKI$(SG)
  45. 2300 IF TEM=1 THEN X1=DHL:Z1=0
  46. 2310 IF TEM=1 THEN Z1=DHL:X1=0
  47. 2320 LSET X1$=MKS$(X1): LSET Y1$=MKS$(Y1): LSET Z1$=MKS$(Z1)
  48. 2330 X2=-X1:Z2=-Z1
  49. 2340 LSET X2$=MKS$(X2): LSET Y2$=MKS$(Y2):LSET  Z2$=MKS$(Z2)
  50. 2350 LSET RW$=MKS$(WRAD) 
  51. 2400 PUT #1
  52. 2600 CLOSE #1
  53. 2610 PRINT "   FILE CREATED AS ";NA$;", ON PATH ";FP$
  54. 2620 GOTO 1200
  55. 4000 END
  56. 6000 PRINT  "ERROR ";ERR;" AT LINE ";ERL
  57. 6010 IF ERL=2120 THEN RESUME 2100
  58. 6020 GOTO 1200
  59.