home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 26 / AACD 26.iso / AACD / Programming / ace_gpl_release / src / lib / asm / scrwin.s < prev    next >
Encoding:
Text File  |  1998-10-04  |  17.8 KB  |  929 lines
  1. ;
  2. ; scrwin.s -- an ACE linked library module: screen and window functions.
  3. ; Copyright (C) 1998 David Benn
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ;
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ;
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ;
  19. ; Author: David J Benn
  20. ;   Date: 3rd-30th November, 1st-13th December 1991,
  21. ;      20th, 23rd,25th-27th January 1992, 
  22. ;         2nd,4th,6th,12th-19th,21st-24th,29th February 1992,
  23. ;      1st,14th March 1992,
  24. ;      4th,7th,21st,22nd,26th April 1992,
  25. ;      2nd,3rd,5th,7th,8th,10th-17th May 1992,
  26. ;      6th,8th,11th,12th,28th,30th June 1992,
  27. ;      1st-3rd,13th,14th,18th-20th,22nd July 1992,
  28. ;      9th August 1992,
  29. ;      5th,12th,13th,19th December 1992,
  30. ;      18th February 1993,
  31. ;      1st March 1993,
  32. ;      6th,12th June 1993,
  33. ;      9th,10th,24th-26th,29th,31st October 1993,
  34. ;      1st November 1993,
  35. ;      25th December 1993,
  36. ;      16th February 1994,
  37. ;      6th,7th,19th March 1994,
  38. ;      12th,25th,28th July 1994,
  39. ;      10th,28th August 1994,
  40. ;      11th September 1994
  41. ;
  42. ; registers d0-d6 and a0-a3 are modified by some of the following. BEWARE!
  43. ;
  44. ; a4,a5 are used by link/unlk.
  45. ; a6 is library base holder.
  46. ; a7 is stack pointer. 
  47. ; d7 is used for array index calculations.
  48. ;
  49.  
  50. ; * CONSTANTS *
  51. MAXSTRINGSIZE     equ 1024
  52. Width        equ 8
  53. Height        equ 10
  54. cp_x        equ 36
  55. cp_y        equ 38
  56. BitMap        equ 184
  57. Depth        equ 5
  58. Font        equ 52
  59. tf_YSize    equ 20
  60. tf_XSize    equ 24
  61. lib_Version    equ 20
  62. CTRL_C_BREAK    equ 4096
  63. VANILLAKEY    equ $00200000
  64. UserPort    equ 86
  65.  
  66. Class        equ 0        ; member of IntuiInfo structure
  67. Code        equ 4        ; member of IntuiInfo structure
  68.                 ; (see intuievent.h)
  69.  
  70. SCREEN_OPEN_ERR equ 600
  71.  
  72.  
  73.     ; window & screen routines
  74.     xdef    _openscreen
  75.     xdef    _closescreen
  76.     xdef    _change_screen_depth
  77.     xdef    _changetextcolor
  78.     xdef    _palette
  79.     xdef    _shortprints
  80.     xdef    _longprints
  81.     xdef    _singleprints
  82.     xdef    _stringprints
  83.     xdef    _horiz_tab
  84.     xdef    _printsLF
  85.     xdef    _printsTAB
  86.     xdef    _printsSPC
  87.     xdef    _cls
  88.     xdef    _ptab
  89.     xdef    _ctrl_c_test
  90.  
  91.        ; external references
  92.     xref    _locate
  93.     xref    _scroll_screen
  94.     xref    _slash
  95.     xref    _radconv
  96.     xref    _longtemp
  97.     xref    _formfeed
  98.     xref    _forcebgndcolr
  99.     xref    _textcolr
  100.     xref    _raw
  101.     xref    _Wdw_width_list
  102.     xref    _Wdw_height_list
  103.     xref    _fgdpen_list
  104.     xref    _bgpen_list
  105.     xref    _Wdw_list
  106.     xref    _RPort_list
  107.     xref    _stdout_list
  108.     xref    _stdin_list
  109.     xref    _mode_oldfile
  110.     xref    _ScreenWdw
  111.     xref    _ScreenRPort
  112.     xref    _ScreenViewPort
  113.     xref    _Screen_list
  114.     xref    _newscreen
  115.     xref    _newwindow
  116.     xref    _horiz_tabstring
  117.     xref    _NULL_string
  118.  
  119.     xref    _x1
  120.     xref    _x2
  121.     xref    _y1
  122.     xref    _y2
  123.     xref    _titleaddr
  124.     xref    _tempstr
  125.     xref    _rawname
  126.     xref    _tempWdw_id
  127.     xref    _screen_id
  128.     xref    _rport_addr
  129.     xref    _viewport_addr
  130.     xref    _screen_addr
  131.     xref    _scr_wdw_addr
  132.     xref    _color_id
  133.     xref    _red
  134.     xref    _green
  135.     xref    _blue
  136.     xref    _strbuf
  137.     xref    _max_line
  138.     xref    _font_height
  139.     xref    _wdth
  140.     xref    _hgt
  141.     xref    _horiz_pos
  142.     
  143.     xref    _putchar
  144.     xref    _sprintf
  145.     xref    _strcpy    
  146.     xref    _strcat
  147.     xref    _strlen
  148.     xref    _strshort
  149.     xref    _strlong
  150.     xref    _strsingle
  151.     xref    _IntuitionBase
  152.      xref      _stdout
  153.     xref    _stdin
  154.     xref     _AbsExecBase
  155.     xref    _LVOSetSignal
  156.     xref    _GfxBase
  157.     xref    _LVOMove
  158.     xref    _LVOText
  159.     xref    _LVOSetAPen
  160.     xref    _LVOSetRGB4
  161.     xref    _LVOClearScreen
  162.     xref    _LVOScrollRaster
  163.     xref    _LVOOpenScreen
  164.     xref    _LVOCloseScreen
  165.     xref    _LVOOpenWindow
  166.     xref    _LVOCloseWindow
  167.     xref    _LVOScreenToFront
  168.     xref    _LVOScreenToBack
  169.     xref    _DOSBase
  170.     xref    _LVOWrite
  171.     xref    _LVOOpen
  172.     xref    _LVOClose
  173.     xref    _MathBase
  174.     xref    _MathTransBase
  175.     xref    _LVOSPFix
  176.     xref    _LVOSPMul
  177.     xref    _RPort
  178.     xref    _ViewPort
  179.     xref    _Scrn
  180.     xref    _Wdw
  181.     xref    _Wdw_width
  182.     xref    _Wdw_height
  183.     xref    _Wdw_id
  184.     xref    _WBWdw
  185.     xref    _WBRPort
  186.     xref    _WBViewPort
  187.     xref    _WBScrn
  188.     xref    _WBbgpen
  189.     xref    _WBfgdpen
  190.     xref    _IntuiMode
  191.     xref    _fgdpen
  192.     xref    _bgpen
  193.     xref    _tg_initx
  194.     xref    _tg_tx
  195.     xref    _tg_inity
  196.     xref    _tg_ty
  197.     xref    _tg_degs
  198.     xref    _tg_pen
  199.     xref    _tg_xy_ratio
  200.     xref    _cursorON
  201.     xref    _turncursoron
  202.     xref    _turncursoroff
  203.     xref    _pos
  204.     xref    _csrlin
  205.     xref    _last_IDCMP_event
  206.     xref    _only_shell_is_active
  207.     xref    _check_for_open_window
  208.     xref    _GetIntuiEvent
  209.     xref    _ClearIntuiEvent
  210.  
  211.     xref    _error_code
  212.  
  213.     SECTION scrwin_code,CODE
  214.  
  215. ;
  216. ; PTAB(n) - moves to nth pixel position in current output window.
  217. ;      - d0 = n = x-position.
  218. ;
  219. _ptab:
  220.     movea.l    _GfxBase,a6
  221.     movea.l    _RPort,a1
  222.     move.w    cp_y(a1),d1
  223.     jsr    _LVOMove(a6)
  224.         
  225.     lea    _NULL_string,a0        ; dummy string
  226.  
  227.     rts
  228.     
  229. ;
  230. ; TAB(n) - moves cursor to nth column in current output window.
  231. ;     - d0 = # of columns to move right. Control string returned in a0
  232. ;       for use by _printstring. This is the NULL string if we're in
  233. ;       IntuiMode since a LOCATE is performed.
  234. ;
  235. _horiz_tab:
  236.         subi.w    #1,d0            ; shift back 1 column
  237.     move.w    d0,_horiz_pos        ; store it
  238.  
  239.        ; make sure not too high
  240.     cmpi.w    #80,d0
  241.     ble.s    _tab_mode
  242.     move.w    #80,d0            ; columns > 80 so columns=80 
  243.     move.w    d0,_horiz_pos
  244.  
  245. _tab_mode:
  246.     ; are we in IntuiMode?
  247.     cmpi.b    #1,_IntuiMode
  248.     bne.s    _get_tab_digits        ; NO -> DOS window TAB
  249.     
  250.     ; YES -> re-LOCATE to nth column on current line
  251.     addi.w    #1,_horiz_pos        ; adjust for screen/window
  252.  
  253.     cmpi.w    #0,_horiz_pos
  254.     blt.s    _exit_intuitab        ; do nothing more if column<=0
  255.  
  256.     jsr    _csrlin
  257.     move.w    _horiz_pos,d1
  258.     jsr    _locate
  259.  
  260. _exit_intuitab:
  261.     lea    _NULL_string,a0
  262.     
  263.     rts
  264.  
  265. _get_tab_digits:
  266.     ; convert column value to 2 ASCII digits and place in tab string
  267.     ext.l    d0
  268.     divu    #10,d0
  269.     move.l    d0,_longtemp
  270.     lea    _horiz_tabstring,a0
  271.     add.w    #48,d0
  272.     and.b    #$ff,d0
  273.     move.b    d0,1(a0)
  274.     move.l    _longtemp,d0
  275.     swap    d0
  276.     add.w    #48,d0
  277.     and.b    #$ff,d0
  278.     move.b    d0,2(a0)
  279.  
  280.     ; move print position to leftmost column
  281.     move.l    #13,-(sp)        ; CR
  282.     jsr    _putchar
  283.     addq    #4,sp
  284.  
  285.     cmpi.w    #0,_horiz_pos
  286.     ble.s    _quit_horiz_tab        ; do nothing more if column<=0
  287.         
  288.     lea    _horiz_tabstring,a0    ; control string to be printed  
  289.  
  290. _quit_horiz_tab:
  291.     rts
  292.  
  293. ;
  294. ; CLS - clear the screen (window).
  295. ;
  296. _cls:
  297.     ; check whether in Screen Mode
  298.     cmpi.b    #0,_IntuiMode
  299.     beq.s    _wbscreencls    
  300.  
  301.     ; clear a user-defined intuition window
  302.     movea.l    _GfxBase,a6
  303.     move.l    _RPort,a1
  304.     move.w    #0,d0
  305.     move.w    #0,d1
  306.     jsr    _LVOMove(a6)
  307.  
  308.     move.l    _RPort,a1
  309.     jsr    _LVOClearScreen(a6)
  310.     
  311.     move.w    #1,d0    
  312.     move.w    #1,d1
  313.     jsr    _locate
  314.  
  315.     rts
  316.  
  317. _wbscreencls:
  318.     ; first set the background colour 
  319.     ; (only necessary under 2.04)
  320.  
  321.     ; check version (ExecBase->LibNode.lib_Version)
  322.     movea.l    _AbsExecBase,a0
  323.     move.w    lib_Version(a0),d0
  324.     cmpi.w    #34,d0
  325.     ble.s    _justclearscreen    ; if Exec version <= 34, just do CLS
  326.  
  327.     lea    _forcebgndcolr,a0
  328.     move.w    _bgpen,d0
  329.     addi.b    #48,d0
  330.     move.b    d0,2(a0)        ; modify the CSI>[n]m string
  331.  
  332.     move.l    _DOSBase,a6
  333.     move.l    _stdout,d1
  334.     move.l    #_forcebgndcolr,d2    ; force background colour to change
  335.     move.l    #4,d3
  336.     jsr    _LVOWrite(a6)
  337.  
  338. _justclearscreen:    
  339.     ; now clear the window!
  340.     move.l    _DOSBase,a6
  341.     move.l    _stdout,d1
  342.     move.l    #_formfeed,d2        ; form feed = CLS
  343.     move.l    #1,d3
  344.     jsr    _LVOWrite(a6)
  345.  
  346.     rts
  347.  
  348. ;
  349. ; change color of text foreground and background (d0=fgnd, d1=bgnd).
  350. ;
  351. _changetextcolor:
  352.     ; only do it if in a window!
  353.     cmpi.b    #1,_IntuiMode
  354.     beq.s    _exitchangetextcolor
  355.  
  356.     ; convert colors to ASCII
  357.     add.w    #48,d0
  358.     add.w    #48,d1
  359.     
  360.     ; change the color command string
  361.     lea    _textcolr,a0
  362.     move.b    d0,4(a0)
  363.     move.b    d1,7(a0)
  364.  
  365.     ; apply the text colors
  366.     move.l    _DOSBase,a6
  367.     move.l    _stdout,d1
  368.     move.l    #_textcolr,d2
  369.     move.l    #9,d3
  370.     jsr    _LVOWrite(a6)
  371.  
  372. _exitchangetextcolor:
  373.     rts
  374.  
  375. ;
  376. ; turn cursor ON (after printing).
  377. ;
  378. _turncursoron:
  379.     move.l    _stdout,d1
  380.     move.l    #_cursorON,d2
  381.     moveq    #3,d3
  382.     move.l    _DOSBase,a6
  383.     jsr    _LVOWrite(a6)
  384.     rts
  385.  
  386. ;
  387. ; open a screen - d0=screen-id,d1=width,d2=height,d3=depth,d4=mode.
  388. ;
  389. _openscreen:
  390.     ; store screen-id
  391.     move.w    d0,_screen_id
  392.  
  393.     ; check parameters
  394.     cmpi.w    #1,d0        ; screen-id < 1?
  395.     blt    _quitopenscreen
  396.     cmpi.w    #9,d0        ; screen-id > 9?
  397.     bgt    _quitopenscreen
  398.  
  399.     cmpi.w    #1,d1        ; width < 1?
  400.     blt    _quitopenscreen
  401.     cmpi.w    #640,d1        ; width > 640?
  402.     bgt    _quitopenscreen
  403.  
  404.     cmpi.w    #1,d2        ; height < 1?
  405.     blt    _quitopenscreen
  406.     cmpi.w    #512,d2        ; height > 512?     * this is arbitrarily large! *
  407.     bgt    _quitopenscreen
  408.  
  409.     cmpi.w    #1,d3        ; depth < 1?
  410.     blt    _quitopenscreen
  411.     cmpi.w    #6,d3        ; depth > 6?
  412.     bgt    _quitopenscreen
  413.  
  414.     cmpi.w    #1,d4        ; mode < 1?
  415.     blt    _quitopenscreen
  416.     cmpi.w    #6,d4        ; mode > 6?
  417.     bgt    _quitopenscreen
  418.  
  419.     ; calculate place in screen lists
  420.     move.w    _screen_id,d0
  421.     mulu    #4,d0        ; offset from start of screen lists
  422.  
  423.     move.l    #_ScreenWdw,d5
  424.     add.l    d0,d5
  425.     move.l    d5,_scr_wdw_addr
  426.  
  427.     move.l    #_ScreenRPort,d5
  428.     add.l    d0,d5
  429.     move.l    d5,_rport_addr
  430.  
  431.     move.l    #_ScreenViewPort,d5
  432.     add.l    d0,d5
  433.     move.l    d5,_viewport_addr
  434.  
  435.     move.l    #_Screen_list,d5
  436.     add.l    d0,d5
  437.     move.l    d5,_screen_addr
  438.         
  439.     ; is this screen-id being used?
  440.     movea.l    _screen_addr,a0
  441.     move.l    (a0),d0
  442.     cmpi.l    #0,d0
  443.     bne    _quitopenscreen    ; if not ZERO -> quit!
  444.  
  445.     ; complete NewScreen and NewWindow structures.    
  446.  
  447.     lea    _newwindow,a0
  448.     move.w    d1,4(a0)    ; width
  449.     move.w    d2,6(a0)    ; height
  450.  
  451.     lea    _newscreen,a0
  452.     move.w    d1,4(a0)    ; width
  453.     move.w    d2,6(a0)    ; height
  454.     move.w    d3,8(a0)    ; depth
  455.     
  456.     ; screen mode
  457.     cmpi.w    #1,d4
  458.     bne.s    _hires1
  459.     move.w    #0,12(a0)        ; lo-res
  460.     move.l    #$f0000140,_tg_xy_ratio    ; ratio = 0.9375
  461.     bra.s    _openthescreen
  462. _hires1:
  463.     cmpi.w    #2,d4
  464.     bne.s    _lores2
  465.     move.w    #$8000,12(a0)        ; hi-res
  466.     move.l    #$f0000141,_tg_xy_ratio    ; ratio = 1.875
  467.     bra.s    _openthescreen
  468. _lores2:
  469.     cmpi.w    #3,d4
  470.     bne.s    _hires2
  471.     move.w    #4,12(a0)        ; lo-res, interlaced
  472.     move.l    #$f000013f,_tg_xy_ratio    ; ratio = 0.46875
  473.     bra.s    _openthescreen    
  474. _hires2:
  475.     cmpi.w    #4,d4
  476.     bne.s    _ham
  477.     move.w    #$8004,12(a0)        ; hi-res, interlaced
  478.     move.l    #$f0000140,_tg_xy_ratio    ; ratio = 0.9375
  479.     bra.s    _openthescreen
  480. _ham:
  481.     cmpi.w    #5,d4
  482.     bne.s    _halfbrite
  483.     move.w    #$800,12(a0)        ; hold-and-modify
  484.     move.l    #$f0000140,_tg_xy_ratio    ; ratio = 0.9375
  485.     bra.s    _openthescreen
  486. _halfbrite:
  487.     move.w    #$80,12(a0)        ; extra-halfbrite
  488.     move.l    #$f0000140,_tg_xy_ratio    ; ratio = 0.9375
  489.     
  490. _openthescreen:
  491.     ; open the screen
  492.     movea.l    _IntuitionBase,a6
  493.     lea    _newscreen,a0
  494.     jsr    _LVOOpenScreen(a6)
  495.     move.l    d0,_Scrn
  496.     cmpi.l    #0,d0
  497.     beq    _quitopenscreen    ; quit if can't open screen!
  498.     
  499.     ; open a borderless window 
  500.     movea.l    _IntuitionBase,a6
  501.     lea    _newwindow,a0
  502.     move.l    _Scrn,30(a0)    ; link to screen just opened
  503.     jsr    _LVOOpenWindow(a6)
  504.     move.l    d0,_Wdw
  505.     cmpi.l    #0,d0
  506.     beq    _quitopenscreen    ; quit if can't open window!
  507.     
  508.     ; update lists and set screen mode
  509.     move.b    #1,_IntuiMode
  510.  
  511.     ; store screen
  512.     movea.l    _screen_addr,a0
  513.     move.l    _Scrn,(a0)
  514.     
  515.     ; store window
  516.     movea.l    _scr_wdw_addr,a0
  517.     move.l    _Wdw,(a0)
  518.  
  519.     movea.l    _rport_addr,a0
  520.     movea.l    _Wdw,a1
  521.     move.l    50(a1),(a0)
  522.     move.l    50(a1),_RPort
  523.     
  524.     ; store viewport
  525.     movea.l    _viewport_addr,a0
  526.     move.l    _Scrn,d0
  527.     add.l    #44,d0
  528.     move.l    d0,(a0)
  529.     move.l    d0,_ViewPort
  530.  
  531.     ; set first PRINT position in screen's default window
  532.     moveq    #3,d0
  533.     moveq    #1,d1
  534.     jsr    _locate
  535.  
  536.     ; set foreground pen in window
  537.     movea.l    _GfxBase,a6
  538.     movea.l    _RPort,a1
  539.     moveq    #1,d0
  540.     jsr    _LVOSetAPen(a6)
  541.     
  542.     rts        
  543.  
  544. _quitopenscreen:    
  545.     move.l    #SCREEN_OPEN_ERR,_error_code    ; !! ERROR !!
  546.     rts
  547.  
  548. ;
  549. ; close a screen - d0=screen-id.
  550. ;
  551. _closescreen:
  552.     ; store screen-id
  553.     move.w    d0,_screen_id
  554.  
  555.     ; check parameters
  556.     cmpi.w    #1,d0        ; screen-id < 1?
  557.     blt    _quitclosescreen
  558.     cmpi.w    #9,d0        ; screen-id > 9?
  559.     bgt    _quitclosescreen
  560.  
  561.     ; calculate place in screen lists
  562.     move.w    _screen_id,d0
  563.     mulu    #4,d0        ; offset from start of screen lists
  564.  
  565.     move.l    #_Screen_list,d5
  566.     add.l    d0,d5
  567.     movea.l    d5,a0
  568.  
  569.     ; is screen-id being used?
  570.     move.l    (a0),d0
  571.     cmpi.l    #0,d0
  572.     beq    _quitclosescreen    ; if ZERO -> quit!
  573.     
  574.      ; close the window
  575.     movea.l    _IntuitionBase,a6
  576.     move.w    _screen_id,d0
  577.     mulu    #4,d0
  578.     move.l    #_ScreenWdw,d5
  579.     add.l    d0,d5
  580.     movea.l    d5,a1
  581.     movea.l    (a1),a0
  582.     jsr    _LVOCloseWindow(a6)
  583.  
  584.     ; close the screen
  585.     movea.l    _IntuitionBase,a6
  586.     move.w    _screen_id,d0
  587.     mulu    #4,d0
  588.     move.l    #_Screen_list,d5
  589.     add.l    d0,d5
  590.     movea.l    d5,a1
  591.     movea.l    (a1),a0
  592.     jsr    _LVOCloseScreen(a6)
  593.     
  594.     ; zero all list elements -> screen,rastport,viewport
  595.     move.w    _screen_id,d0
  596.     mulu    #4,d0        ; offset from start of screen lists
  597.  
  598.     move.l    #_Screen_list,d5
  599.     add.l    d0,d5
  600.     movea.l    d5,a0
  601.     move.l    #0,(a0)
  602.  
  603.     move.l    #_ScreenWdw,d5
  604.     add.l    d0,d5
  605.     movea.l    d5,a0
  606.     move.l    #0,(a0)
  607.     
  608.     move.l    #_ScreenRPort,d5
  609.     add.l    d0,d5
  610.     movea.l    d5,a0
  611.     move.l    #0,(a0)
  612.  
  613.     move.l    #_ScreenViewPort,d5
  614.     add.l    d0,d5
  615.     movea.l    d5,a0
  616.     move.l    #0,(a0)
  617.  
  618.     ; find open screen (starting from 9)
  619.     move.w    #10,d1
  620. _findopenscreen:
  621.     sub.w    #1,d1        ; start counter at 9
  622.     cmpi.w    #0,d1
  623.     beq    _foundwbscreen    ; no open screens except Wb
  624.  
  625.     move.w    d1,d0
  626.     mulu    #4,d0        ; offset from start of screen lists
  627.     
  628.     move.l    #_Screen_list,d5
  629.     add.l    d0,d5
  630.     movea.l    d5,a0
  631.     cmpi.l    #0,(a0)
  632.     beq.s    _findopenscreen    ; try next screen list position    
  633.     
  634.     ; there is still an open screen -> update _Scrn,_RPort,_ViewPort 
  635.     move.l    (a0),_Scrn
  636.  
  637.     move.l    #_ScreenWdw,d5
  638.     add.l    d0,d5            ; d0=offset from start of list
  639.     movea.l    d5,a0
  640.     move.l    (a0),_Wdw
  641.     
  642.     move.l    #_ScreenRPort,d5
  643.     add.l    d0,d5            ; d0=offset from start of list
  644.     movea.l    d5,a0
  645.     move.l    (a0),_RPort
  646.  
  647.     move.l    #_ScreenViewPort,d5
  648.     add.l    d0,d5            ; d0=offset from start of list
  649.     movea.l    d5,a0
  650.     move.l    (a0),_ViewPort
  651.  
  652.     ; Is there an open window on this new screen?
  653.     ; If so, make the highest numbered one the current output window.
  654.     jsr    _check_for_open_window
  655.  
  656.     bra.s    _quitclosescreen
  657.  
  658. _foundwbscreen:
  659.     ; only Wb screen open -> update _Scrn,_RPort,_ViewPort,_fgdpen,_bgpen
  660.     ; and reset _IntuiMode if only a shell/CLI is open.
  661.     move.l    _WBWdw,_Wdw
  662.     move.l    _WBRPort,_RPort
  663.     move.l    _WBScrn,_Scrn
  664.     move.l    _WBViewPort,_ViewPort
  665.     move.l    _WBfgdpen,_fgdpen
  666.     move.l    _WBbgpen,_bgpen    
  667.  
  668.     jsr    _only_shell_is_active
  669.     cmpi.w    #0,d0
  670.     beq.s    _quitclosescreen
  671.  
  672.     move.b    #0,_IntuiMode
  673.         
  674. _quitclosescreen:
  675.     rts
  676.  
  677. ;
  678. ; SCREEN FORWARD | BACK screen-id. 
  679. ;
  680. ; d0 = screen_id; d1 = forward/back (1 or 2).
  681. ;
  682. _change_screen_depth:
  683.     ; check parameters
  684.     cmpi.w    #1,d0        ; screen-id < 1?
  685.     blt    _quit_change_screen_depth
  686.     cmpi.w    #9,d0        ; screen-id > 9?
  687.     bgt    _quit_change_screen_depth
  688.  
  689.     ; calculate place in screen list
  690.     mulu    #4,d0        ; offset from start of screen lists
  691.  
  692.     move.l    #_Screen_list,d5
  693.     add.l    d0,d5
  694.     movea.l    d5,a0
  695.  
  696.     ; is screen-id being used?
  697.     move.l    (a0),d0
  698.     cmpi.l    #0,d0
  699.     beq.s    _quit_change_screen_depth    ; store screen-id
  700.  
  701.     ; change the screen's depth!
  702.     cmpi.w    #1,d1
  703.     bne.s    _test_for_screen_back_move
  704.     movea.l    _IntuitionBase,a6
  705.     movea.l    d0,a0
  706.     jsr    _LVOScreenToFront(a6)        ; SCREEN FRONT
  707.     rts
  708.  
  709. _test_for_screen_back_move:
  710.     cmpi.w    #2,d1
  711.     bne.s    _quit_change_screen_depth
  712.     movea.l    _IntuitionBase,a6
  713.     movea.l    d0,a0
  714.     jsr    _LVOScreenToBack(a6)        ; SCREEN BACK
  715.     
  716. _quit_change_screen_depth:
  717.     rts
  718.  
  719. ;
  720. ; define palette for current viewport. d0=color-id,d1=red,d2=green,d3=blue. 
  721. ;
  722. _palette:
  723.     ; store color-id
  724.     move.w    d0,_color_id
  725.  
  726.     ; check for legal color-id
  727.     cmpi.w    #0,d0
  728.     blt    _quitpalette    ; color-id < 0?
  729.     
  730.     cmpi.w    #63,d0
  731.     bgt    _quitpalette    ; color-id > 63?
  732.  
  733.     ; store RGB values.
  734.     move.l    d1,_red
  735.     move.l    d2,_green
  736.     move.l    d3,_blue
  737.  
  738.     ; Convert single-precision RGB values (0-1) to integers (0-15).
  739.     ; Each FFP value must be multiplied by 15.
  740.  
  741.     movea.l    _MathBase,a6
  742.         
  743.     move.l    _red,d0
  744.     move.l    #$f0000044,d1    ; 15
  745.     jsr    _LVOSPMul(a6)
  746.     jsr    _LVOSPFix(a6)
  747.     move.l    d0,_red
  748.  
  749.     move.l    _green,d0
  750.     move.l    #$f0000044,d1    ; 15
  751.     jsr    _LVOSPMul(a6)
  752.     jsr    _LVOSPFix(a6)
  753.     move.l    d0,_green
  754.  
  755.     move.l    _blue,d0
  756.     move.l    #$f0000044,d1    ; 15
  757.     jsr    _LVOSPMul(a6)
  758.     jsr    _LVOSPFix(a6)
  759.     move.l    d0,_blue    
  760.  
  761.     ; change colormap values with SetRGB4
  762.     movea.l    _GfxBase,a6
  763.     movea.l    _ViewPort,a0
  764.     move.w    _color_id,d0        
  765.     move.l    _red,d1
  766.     and.b    #$ff,d1
  767.     move.l    _green,d2
  768.     and.b    #$ff,d2
  769.     move.l    _blue,d3
  770.     and.b    #$ff,d3
  771.     jsr    _LVOSetRGB4(a6)
  772.         
  773. _quitpalette:
  774.     rts
  775.  
  776. ;
  777. ; print a short integer on current screen. d0=short integer to be printed.
  778. ;
  779. _shortprints:
  780.     lea    _strbuf,a0
  781.     jsr    _strshort
  782.     jsr    _stringprints
  783.         
  784.     rts
  785.  
  786. ;
  787. ; print a long integer on current screen. d0=long integer to be printed.
  788. ;
  789. _longprints:
  790.     lea    _strbuf,a0
  791.     jsr    _strlong
  792.     jsr    _stringprints
  793.  
  794.     rts
  795.  
  796. ;
  797. ; print a single-precision value on current screen. 
  798. ; d0=single-precision float to be printed.
  799. ;
  800. _singleprints:
  801.     move.l    d0,-(sp)
  802.     jsr    _strsingle
  803.     addq    #4,sp
  804.     move.l    d0,a0
  805.     jsr    _stringprints
  806.     
  807.     rts
  808.  
  809. ;
  810. ; print a string on current screen. a0=string to be printed.
  811. ;
  812. _stringprints:
  813.     ; find length of string
  814.     movea.l    a0,a2
  815.     jsr    _strlen        ; d0=length 
  816.     and.w    #$ffff,d0
  817.  
  818.     ; print it
  819.     movea.l    _RPort,a1
  820.     movea.l _GfxBase,a6
  821.     jsr    _LVOText(a6)    
  822.     
  823.     rts
  824.  
  825. ;
  826. ; print a line feed in current screen using locate,
  827. ; scrolling if necessary.
  828. ;
  829. _printsLF:
  830.     jsr    _csrlin
  831.     addq    #1,d0    ; d0=LINE
  832.     
  833.     move.w    #1,d1    ; d1=COLUMN
  834.  
  835.     jsr    _locate
  836.     jsr    _scroll_screen
  837.  
  838.     rts
  839.  
  840. ;
  841. ; print a BASIC TAB in current Intuition window using LOCATE.
  842. ; 
  843. ; *note* that this is not the same as the CON/RAW window comma-TAB
  844. ; used by print which consists of CHR$(9) x 2.
  845. ; 
  846. _printsTAB:
  847.     jsr    _csrlin     ; d0=LINE
  848.     move.w    d0,-(sp) ; store LINE
  849.     
  850.     jsr    _pos
  851.     move.w    d0,d1
  852.  
  853. _seekintuitabpos:
  854.     ; find the next tab position (every 10 character positions)
  855.     add.w    #1,d1     ; d1=COLUMN
  856.     move.w    d1,d2
  857.     ext.l    d2
  858.     divu    #10,d2
  859.     swap    d2     ; d2 MOD 10 
  860.     cmpi.w    #0,d2    
  861.     bne.s    _seekintuitabpos
  862.  
  863.     move.w    (sp)+,d0 ; pop LINE
  864.  
  865.     jsr    _locate
  866.  
  867.     rts
  868.  
  869. ;
  870. ; print a single space in current screen using locate.
  871. ;
  872. _printsSPC:
  873.     jsr    _csrlin     ; d0=LINE
  874.     move.w    d0,-(sp) ; store LINE
  875.  
  876.     jsr    _pos
  877.     move.w    d0,d1
  878.     addq    #1,d1     ; d1=COLUMN
  879.     move.w    (sp)+,d0 ; pop LINE
  880.  
  881.     jsr    _locate
  882.  
  883.     rts
  884.  
  885. ;
  886. ; Test for a control-c break. Return 0L or non-zero value in d0. 
  887. ;
  888. _ctrl_c_test:
  889.     cmpi.b    #1,_IntuiMode
  890.     beq.s    _intui_ctrl_c_test
  891.  
  892.     ; DOS window ctrl-c signal test
  893.     movea.l    _AbsExecBase,a6
  894.     moveq    #0,d0
  895.     move.l    #CTRL_C_BREAK,d1
  896.     jsr    _LVOSetSignal(a6)
  897.     andi.l    #CTRL_C_BREAK,d0    ; Quit with 0 or 4096
  898.     rts
  899.  
  900. _intui_ctrl_c_test:
  901.     ; Test for ASCII 3 from IDCMP for current window
  902.     movea.l    _Wdw,a0
  903.     move.l    UserPort(a0),-(sp)
  904.     jsr    _GetIntuiEvent
  905.     addq    #4,sp
  906.     tst.l    d0
  907.     beq.s    _exit_ctrl_c_test    ; No message! Quit with 0
  908.  
  909.     movea.l    d0,a0            ; pointer to IntuiInfo structure
  910.     move.l    Class(a0),d1        ; Message->Class
  911.     andi.l    #VANILLAKEY,d1
  912.     cmpi.l    #VANILLAKEY,d1
  913.     beq.s    _get_vanilla_key    ; No vanillakey event: quit
  914.     moveq    #0,d0            ; Quit with 0
  915.     rts
  916.  
  917. _get_vanilla_key:
  918.     moveq    #0,d0            ; assume it's not ASCII 3 -> 0 result
  919.     move.w    Code(a0),d1        ; Message->Code
  920.     cmpi.w    #3,d1
  921.     bne.s    _exit_ctrl_c_test
  922.     jsr    _ClearIntuiEvent
  923.     moveq    #1,d0            ; Quit with 1 -> it's an ASCII 3!
  924.                 
  925. _exit_ctrl_c_test:
  926.     rts
  927.     
  928.     END
  929.