home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 26 / AACD 26.iso / AACD / Programming / ace_gpl_release / src / lib / asm / ffp.s < prev    next >
Encoding:
Text File  |  1998-10-04  |  4.1 KB  |  197 lines
  1. ;
  2. ; ffp.s -- an ACE linked library module: fast-floating-point functions.
  3. ; Copyright (C) 1998 David Benn
  4. ; 
  5. ; This program is free software; you can redistribute it and/or
  6. ; modify it under the terms of the GNU General Public License
  7. ; as published by the Free Software Foundation; either version 2
  8. ; of the License, or (at your option) any later version.
  9. ;
  10. ; This program is distributed in the hope that it will be useful,
  11. ; but WITHOUT ANY WARRANTY; without even the implied warranty of
  12. ; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13. ; GNU General Public License for more details.
  14. ;
  15. ; You should have received a copy of the GNU General Public License
  16. ; along with this program; if not, write to the Free Software
  17. ; Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA  02111-1307, USA.
  18. ;
  19. ; Author: David J Benn
  20. ;   Date: 3rd-30th November, 1st-13th December 1991,
  21. ;      20th, 23rd,25th-27th January 1992, 
  22. ;         2nd,4th,6th,12th-19th,21st-24th,29th February 1992,
  23. ;      1st,14th March 1992,
  24. ;      4th,7th,21st,22nd,26th April 1992,
  25. ;      2nd,3rd,5th,7th,8th,10th-17th May 1992,
  26. ;      6th,8th,11th,12th,28th,30th June 1992,
  27. ;      1st-3rd,13th,14th,18th-20th,22nd July 1992,
  28. ;      9th August 1992,
  29. ;      5th December 1992,
  30. ;      14th,18th,19th February 1993,
  31. ;      1st March 1993,
  32. ;      11th October 1993
  33. ;
  34. ; registers d0-d6 and a0-a3 are modified by some of the following. BEWARE!
  35. ;
  36. ; a4,a5 are used by link/unlk.
  37. ; a6 is library base holder.
  38. ; a7 is stack pointer. 
  39. ; d7 is used for array index calculations.
  40. ;
  41.  
  42. ; * CONSTANTS *
  43. MAXSTRINGSIZE    EQU    1024
  44.  
  45.        ; ffp functions 
  46.        xdef      _round
  47.        xdef      _absf
  48.       xdef      _sgnf
  49.     xdef    _inputsingle
  50.     xdef    _modffp
  51.     xdef    _fix
  52.     xdef    _decimal_places
  53.  
  54.        ; external references
  55.     xref    _val
  56.        xref      _putchar
  57.     xref    _strsingle
  58.     xref    _Ustringinput
  59.  
  60.       xref      _LVOSPFix
  61.     xref    _LVOSPFlt
  62.     xref    _LVOSPFloor
  63.     xref    _LVOSPCeil
  64.     xref    _LVOSPAdd
  65.     xref    _LVOSPSub
  66.     xref    _LVOSPMul
  67.        xref      _LVOSPDiv
  68.        xref      _LVOSPAbs
  69.        xref      _LVOSPTst
  70.     xref    _LVOSPCmp
  71.        xref      _MathBase
  72.  
  73.     SECTION ffp_code,CODE
  74.  
  75. ;*** FAST-FLOATING-POINT FUNCTIONS ***
  76.  
  77. ;
  78. ; Rounds the single-precision value in d0. Returns a long integer in d0.
  79. ;
  80.  
  81. _round:
  82.     move.l    d0,_fnum    ; save number 
  83.  
  84.     move.l    d0,d1
  85.     jsr    _sgnf
  86.     move.l    d0,_sign    ; get the sign of fnum
  87.  
  88.     move.l    _fnum,d0
  89.     jsr    _absf        
  90.     move.l    d0,_fnum    ; fnum = ABS(fnum)    
  91.  
  92.     move.l    _MathBase,a6
  93.  
  94.     move.l    _fnum,d0
  95.     jsr    _LVOSPFix(a6)
  96.     jsr    _LVOSPFlt(a6)    ; take integer portion of fnum
  97.  
  98.     move.l    d0,d1        ; d1 = INT(fnum)
  99.     move.l    _fnum,d0
  100.     jsr    _LVOSPSub(a6)    ; d0 = fnum [d0] - INT(fnum) [d1]
  101.  
  102.     move.l    #$80000040,d1    ; 0.5
  103.     jsr    _LVOSPCmp(a6)    ; (fnum - INT(fnum)) [d0] >= 0.5 [d1] ?
  104.  
  105.     bge.s    _round_up
  106.  
  107.     ; round down
  108.     move.l    _fnum,d0
  109.     jsr    _LVOSPFloor(a6)
  110.     jsr    _LVOSPFix(a6)
  111.     bra.s    _check_sign
  112.  
  113. _round_up:
  114.     move.l    _fnum,d0
  115.     jsr    _LVOSPCeil(a6)
  116.     jsr    _LVOSPFix(a6)
  117.         
  118. _check_sign:
  119.     cmpi.l    #-1,_sign
  120.     bne.s    _exitround
  121.  
  122.     neg.l    d0        ; negate value if sign = -1
  123.  
  124. _exitround:        
  125.        rts
  126.  
  127. ;
  128. ; ffp abs function. assumes ffp value in d0.
  129. ;  
  130. _absf:
  131.        move.l  _MathBase,a6  
  132.        jsr    _LVOSPAbs(a6)
  133.        rts
  134.  
  135. ;
  136. ; ffp sgn function. d1=fnum. d0=result (-1,0,1).
  137. ;
  138. _sgnf:
  139.     move.l    _MathBase,a6
  140.     jsr    _LVOSPTst(a6)
  141.     rts
  142.  
  143. ;
  144. ; input a single-precision FFP value and return it in d0.
  145. ; (a1 = input buffer)
  146. ;
  147. _inputsingle:
  148.     move.l    a1,-(sp)
  149.     jsr    _Ustringinput
  150.     jsr    _val
  151.     addq    #4,sp
  152.     rts
  153.  
  154. ;
  155. ; ffp modulo. d0=ffp dividend, d1=ffp divisor. returns d0 mod d1 in d0. 
  156. ;
  157. _modffp:
  158.      move.l d0,_ffpdividend
  159.      move.l d1,_ffpdivisor
  160.  
  161.      movea.l _MathBase,a6
  162.  
  163.      jsr _LVOSPDiv(a6)     ; quotient=dividend/divisor
  164.      jsr _LVOSPFix(a6)     ; quotient=(long)quotient
  165.      jsr _LVOSPFlt(a6)     ; quotient=(single)quotient
  166.      move.l _ffpdivisor,d1
  167.      jsr _LVOSPMul(a6)     ; d0=quotient*divisor
  168.      move.l d0,d1  
  169.      move.l _ffpdividend,d0
  170.      jsr _LVOSPSub(a6)     ; d0=dividend-(quotient*divisor)
  171.  
  172.      rts 
  173.  
  174. ;
  175. ; FIX n    - Change the number of places to round FFP values to. d0=n.
  176. ;    - This value is used by arnd() and may be +ve or -ve (!). 
  177. ;
  178. _fix:
  179.     move.l    d0,_decimal_places    
  180.     rts
  181.  
  182. ;************************
  183.  
  184.     SECTION ffp_data,DATA
  185.  
  186. _decimal_places:    dc.l 8
  187.     
  188.     SECTION ffp_mem,BSS
  189.  
  190. _ffpdividend:        ds.l 1
  191. _ffpdivisor:        ds.l 1
  192. _fnum:            ds.l 1
  193. _sign:            ds.l 1
  194. _tmpstring:            ds.b MAXSTRINGSIZE
  195.  
  196.     END
  197.