home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 6 / AACD06.ISO / AACD / Graphics / XTrace / Documentation / German / Install_Doc next >
Text File  |  1998-05-31  |  12KB  |  260 lines
  1. ; $VER: Install 2.00 - Copyright by Condor's, Inc. All Rights Reserved.
  2. ; Script to install the XTrace V 2.00 documentation
  3.  
  4. ; ============================================================================
  5. ; Variables
  6. ; ============================================================================
  7.  
  8. (SET #TRUE              1)
  9. (SET #FALSE             0)
  10.  
  11. (SET #Stack_Multiview   25000)
  12. (SET #Stack_XTrace       4096)
  13.  
  14. (SET #xPos_Guides       185)
  15. (SET #yPos_Guides        30)
  16.  
  17. (SET #xPos_ReadMe       180)
  18. (SET #yPos_ReadMe       110)
  19.  
  20. (SET #xPos_RegForm      280)
  21. (SET #yPos_RegForm      110)
  22.  
  23. (SET #xPos_MainGuide     50)
  24. (SET #yPos_MainGuide     11)
  25.  
  26. (SET #IPT_NoChange      0)
  27. (SET #IPT_Snapshot      1)
  28. (SET #IPT_Unsnapshot    2)
  29.  
  30. ; ****************************************************************************
  31. ; Procedures
  32. ; ****************************************************************************
  33.  
  34. ; ============================================================================
  35. ; XTINST_COPYICON
  36. ; Note: #CI_NewName WITHOUT ".info" !
  37. ; ============================================================================
  38.  
  39. (PROCEDURE XTINST_COPYICON #CI_Source #CI_Dest #CI_NewName #CI_PosType #CI_xPos #CI_yPos #CI_DefaultTool #CI_Stacksize
  40.  (
  41.   ; Copy
  42.  
  43.   (COPYFILES (SOURCE #CI_Source) (DEST #CI_Dest) (NEWNAME (CAT #CI_NewName ".info")))
  44.  
  45.   ; Build icon name
  46.  
  47.   (SET #CI_IconName (TACKON #CI_Dest #CI_NewName))
  48.  
  49.   ; Set default tool and stack size
  50.  
  51.   (TOOLTYPE (DEST #CI_IconName) (SETSTACK #CI_Stacksize) (SETDEFAULTTOOL #CI_DefaultTool))
  52.  
  53.   ; Set position
  54.  
  55.   (IF (= #CI_PosType #IPT_Snapshot)   (TOOLTYPE (DEST #CI_IconName) (SETPOSITION #CI_xPos #CI_yPos)))
  56.   (IF (= #CI_PosType #IPT_Unsnapshot) (TOOLTYPE (DEST #CI_IconName) (NOPOSITION)))
  57.  )
  58. )
  59.  
  60. ; ****************************************************************************
  61. ; Main
  62. ; ****************************************************************************
  63.  
  64. ; ============================================================================
  65. ; Strings and language depend variables
  66. ; ============================================================================
  67.  
  68. (IF (= @language "deutsch")
  69.  (
  70.   ; German strings
  71.  
  72.   (SET #Msg_Welcome           "Willkommen zur Installation der\ndeutschen XTrace V 2.00 Dokumentation !\n\nCopyright by Ronny Schütz / Condor's, Inc. Leipzig\nAll rights reserved.\n\nSie können jederzeit die Installation abbrechen und alle neu installierten Teile von XTrace werden gelöscht.\n\nDiese Install-Script wurde mit dem Installer V43.3 (aminet:util/misc/Installer-43_3.lha) getestet.")
  73.   (SET #Msg_Dir               "Wählen Sie bitte das Verzeichnis in dem sich das XTrace VERZEICHNIS befindet.")
  74.   (SET #Msg_ErrorDir          "XTrace V2.00 wurde nicht oder nicht korrekt installiert.\n\nBitte installieren Sie XTrace bevor Sie die Dokumentation installieren.\n\nWenn Sie alle nötigen XTrace Archive in dasselbe Verzeichnis entpackt haben können Sie diese Dokumentation zusammen mit den anderen XTrace Teilen installieren. Für weitere Informationen lesen Sie bitte die Datei 'Read_Me_First'.")
  75.   (SET #Msg_Bye               "\n\n\n\nDanke das Sie die deutsche XTrace Dokumentation installiert haben. Vergessen Sie nicht sich registrieren zu lassen !")
  76.   (SET #Msg_ByeReg            "\n\n\n\nDanke das Sie die deutsche XTrace Dokumentation installiert haben.")
  77.  
  78.   (SET #Msg_IconType_Standard "Standard Icons")
  79.   (SET #Msg_IconType_MagicWB  "MagicWB Icons")
  80.  
  81.   (SET #Msg_Abort             "Installation abgebrochen. Wollen Sie die bereits installierten Dateien löschen ?\n\nDa Sie eine installierte Dokumentation geupdatet haben könnte diese bereits überschrieben worden sein. Installieren Sie diese alte Dokumentation bitte neu.\n\n")
  82.   (SET #Msg_Abort_RYes        "Ja, entfernen")
  83.   (SET #Msg_Abort_RNo         "Nein")
  84.  
  85.   ; Additional language depend variables (do not translate !)
  86.  
  87.   (SET #LangDirectory "German")
  88.   (SET #LangAbbrev    "Ger")
  89.  )
  90.  (
  91.   (IF (= @language "français")
  92.    (
  93.     ; French strings
  94.  
  95.     (SET #Msg_Welcome           "Bienvenue à l'installation de la documentation\nfrançaise de XTrace V 2.00 !\n\nCopyright Ronny Schütz / Condor's, Inc. Leipzig\nTraduction par Franck Anière\nTous droits réservés.\n\nVous pouvez toujours interrompre l'installation,\nles parties installées seront effacées proprement.\n\nCe script d'installation a été testé avec Installer V43.3\n(aminet:util/misc/Installer-43_3.lha).")
  96.     (SET #Msg_Dir               "Veuillez choisir le répertoire où est situé le tiroir de XTrace.")
  97.     (SET #Msg_ErrorDir          "XTrace n'est pas installé, ou est installé de façon incorrecte.\n\nVeuillez installer XTrace avant d'installer la documentation.\n\nSi vous avez extrait toutes les archives requises de XTrace\ndans le même répertoire, vous pouvez également installer cette\ndocumentation en même temps que les autres parties de XTrace.\n\nPour plus d'informations veuillez consulter le fichier\n'Read_Me_First'.")
  98.     (SET #Msg_Bye               "\n\n\n\nMerci d'avoir installé la documentation française de XTrace.\n\nN'oubliez pas de vous enregistrer !")
  99.     (SET #Msg_ByeReg            "\n\n\n\nMerci d'avoir installé la documentation française de XTrace.")
  100.  
  101.     (SET #Msg_IconType_Standard "Standard icons")
  102.     (SET #Msg_IconType_MagicWB  "MagicWB icons")
  103.  
  104.     (SET #Msg_Abort             "Installation interrompue. Voulez-vous effacer les fichiers installés ?\n\nComme vous avez mis à jour une documentation déjà installée,\nelle risque d'avoir déjà été écrasée,\ndonc vous devez ré-installer l'ancienne documentation.\n\n")
  105.     (SET #Msg_Abort_RYes        "Oui")
  106.     (SET #Msg_Abort_RNo         "Non")
  107.  
  108.     ; Additional language depend variables (do not translate !)
  109.  
  110.     (SET #LangDirectory "French")
  111.     (SET #LangAbbrev    "Fre")
  112.    )
  113.    (
  114.     ; English strings
  115.  
  116.     (SET #Msg_Welcome           "Welcome to the installation of the\nenglish XTrace V 2.00 documentation !\n\nCopyright by Ronny Schütz / Condor's, Inc. Leipzig\nTranslated by Manou Billa\nAll rights reserved.\n\nYou can always abort the installation and the new installed parts will be safely deleted.\n\nThis install script was tested with Installer V43.3 (aminet:util/misc/Installer-43_3.lha).")
  117.     (SET #Msg_Dir               "Please choose the directory where the XTrace DRAWER is located.")
  118.     (SET #Msg_ErrorDir          "XTrace is not installed or not installed correctly.\n\nPlease install XTrace before you install the documentation.\n\nIf you have extract all needed XTrace archives into the same directory, you can also install this documentation together with the other XTrace parts. For further information please read the file 'Read_Me_First'.")
  119.     (SET #Msg_Bye               "\n\n\n\nThank you for installing the english XTrace documentation. Don't forget to register !")
  120.     (SET #Msg_ByeReg            "\n\n\n\nThank you for installing the english XTrace documentation.")
  121.  
  122.     (SET #Msg_IconType_Standard "Standard icons")
  123.     (SET #Msg_IconType_MagicWB  "MagicWB icons")
  124.  
  125.     (SET #Msg_Abort             "Installation aborted. Do you want to delete the files that were installed?\n\nBecause of you've updated an installed documentation, it may have already been overwritten, so you must reinstall the old documentation.\n\n")
  126.     (SET #Msg_Abort_RYes        "Yes, remove")
  127.     (SET #Msg_Abort_RNo         "No")
  128.  
  129.     ; Additional language depend variables  (do not translate !)
  130.  
  131.     (SET #LangDirectory "English")
  132.     (SET #LangAbbrev    "Eng")
  133.    )
  134.   )
  135.  )
  136. )
  137.  
  138. ; ============================================================================
  139. ; Initialization
  140. ; ============================================================================
  141.  
  142. ; Set up error routine
  143.  
  144. (ONERROR
  145.  (IF (EXISTS "XTDest:" (NOREQ))
  146.  (
  147.   (IF (ASKBOOL
  148.    (PROMPT #Msg_Abort)
  149.    (HELP @ASKBOOL-HELP)
  150.    (CHOICES #Msg_Abort_RYes
  151.             #Msg_Abort_RNo)
  152.    (DEFAULT 0))
  153.    (
  154.     (DELETE "XTDest:XTrace/Guides/#?"       (OPTIONAL FORCE))
  155.     (DELETE "XTDest:XTrace/Guides"          (OPTIONAL FORCE))
  156.     (DELETE "XTDest:XTrace/Guides.info"     (OPTIONAL FORCE))
  157.     (DELETE "XTDest:XTrace/Read_Me_First#?" (OPTIONAL FORCE))
  158.     (DELETE "XTDest:XTrace/RegisterForm#?"  (OPTIONAL FORCE))
  159.    )
  160.   )
  161.  
  162.   (MAKEASSIGN "XTSrc"  (SAFE))
  163.   (MAKEASSIGN "XTDest" (SAFE))
  164.  ))
  165. )
  166.  
  167. ; ============================================================================
  168. ; Installation
  169. ; ============================================================================
  170.  
  171. (MESSAGE #Msg_Welcome)
  172. (COMPLETE 0)
  173.  
  174. ; cancel the assign in case of installation restart
  175.  
  176. (MAKEASSIGN "XTSrc" (SAFE))
  177. (MAKEASSIGN "XTDest" (SAFE))
  178.  
  179. ; ============================================================================
  180. ; Ask for directory (got some parts from St. Kosts SoundFX install script.
  181. ; Thanks Stefan.)
  182. ; ============================================================================
  183.  
  184. ; Check if there are assigns, which could contain graphic/DTP programs
  185.  
  186. (IF (= (EXISTS "Graphics:" (NOREQ)) 2) (SET @default-dest "Graphics:"))
  187. (IF (= (EXISTS "Grafik:"   (NOREQ)) 2) (SET @default-dest "Grafik:"))
  188. (IF (= (EXISTS "DTP:"      (NOREQ)) 2) (SET @default-dest "DTP:"))
  189.  
  190. ; Was XTrace already installed in the past ?
  191.  
  192. (SET #LastDest (GETENV "Installer/Programs/XTracePath"))
  193. (IF (<> (STRLEN #LastDest) 0) (SET @default-dest #LastDest))
  194.  
  195. ; Let the user choose now
  196.  
  197. (SET XTDest (TACKON (ASKDIR (PROMPT #Msg_Dir) (HELP @ASKDIR-HELP) (DEFAULT @default-dest)) "XTrace"))
  198. (MAKEASSIGN "XTDest" (PATHONLY XTDest) (SAFE))
  199.  
  200. (MAKEASSIGN "XTSrc" "//")
  201. (SET @default-dest (EXPANDPATH "XTDest:"))
  202.  
  203. ; ============================================================================
  204. ; Check directories
  205. ; ============================================================================
  206.  
  207. (IF (NOT (EXISTS "XTDest:XTrace")) (ABORT #Msg_ErrorDir))
  208.  
  209. ; ============================================================================
  210. ; Copy guides, Read_Me_First and Registerform
  211. ; ============================================================================
  212.  
  213. (MAKEDIR "XTDest:XTrace/Guides")
  214.  
  215. (SET #DocSourcePath (TACKON "XTSrc:" (TACKON "Documentation" #LangDirectory)))
  216.  
  217. (COPYFILES (SOURCE #DocSourcePath)                          (DEST "XTDest:XTrace/Guides/") (PATTERN "XTrace_#?.guide"))
  218. (COPYFILES (SOURCE (TACKON #DocSourcePath "Read_Me_First")) (DEST "XTDest:XTrace/"))
  219. (COPYFILES (SOURCE (TACKON #DocSourcePath "RegisterForm"))  (DEST "XTDest:XTrace/"))
  220.  
  221. ; ============================================================================
  222. ; Copy icons
  223. ; ============================================================================
  224.  
  225. (SET #IconType (ASKCHOICE
  226.                 (PROMPT #Msg_IconType)
  227.                 (HELP @ASKCHOICE-HELP)
  228.                 (CHOICES (#Msg_IconType_Standard) (#Msg_IconType_MagicWB))
  229.                )
  230. )
  231.  
  232. ; Build path, depend on icon type
  233.  
  234. (SET #IconPath (TACKON "XTSrc:Icons" (SELECT #IconType "Standard" "MWB")))
  235.  
  236. ; Install icons
  237. ; Textfiles, Guides
  238.  
  239. (XTINST_COPYICON (TACKON #IconPath (CAT "Project_ReadMeFirst_" #LangAbbrev ".info")) "XTDest:XTrace/"        "Read_Me_First"     #IPT_Snapshot #xPos_ReadMe    #yPos_ReadMe    "Multiview" #Stack_Multiview)
  240. (XTINST_COPYICON (TACKON #IconPath (CAT "Project_RegForm_"     #LangAbbrev ".info")) "XTDest:XTrace/"        "RegisterForm"      #IPT_Snapshot #xPos_RegForm   #yPos_RegForm   "Multiview" #Stack_Multiview)
  241. (XTINST_COPYICON (TACKON #IconPath (CAT "Drawer_Doc_"          #LangAbbrev ".info")) "XTDest:XTrace/"        "Guides"            #IPT_Snapshot #xPos_Guides    #yPos_Guides    ""                         0)
  242. (XTINST_COPYICON (TACKON #IconPath (CAT "Project_Doc_"         #LangAbbrev ".info")) "XTDest:XTrace/Guides/" "XTrace_Main.guide" #IPT_Snapshot #xPos_MainGuide #yPos_MainGuide "Multiview" #Stack_Multiview)
  243.  
  244. ; ============================================================================
  245. ; Cleanup & End
  246. ; ============================================================================
  247.  
  248. (COMPLETE 100)
  249.  
  250. ; Check for keyfile
  251.  
  252. (SET #KeyfileAvailable (OR (EXISTS "DEVS:KeyFiles/XTrace.key") (EXISTS "XTDest:XTrace/XTrace.key")))
  253. (IF (<> (STRLEN (GETENV "KEYPATH")) 0) (SET #KeyfileAvailable (OR (EXISTS (TACKON (GETENV "KEYPATH") "XTrace.key")) #KeyfileAvailable)))
  254.  
  255. (MAKEASSIGN "XTSrc"  (SAFE))
  256. (MAKEASSIGN "XTDest" (SAFE))
  257.  
  258. (IF (= #KeyfileAvailable #TRUE) (EXIT #Msg_ByeReg) (EXIT #Msg_Bye))
  259.  
  260.