home *** CD-ROM | disk | FTP | other *** search
/ back2roots/padua / padua.7z / padua / ftp.vapor.com / microdot-1 / md1_src_02.lzx / mdc.a < prev    next >
Text File  |  1989-08-24  |  13KB  |  471 lines
  1. *
  2. * C initial startup procedure under AmigaDOS
  3. * 
  4. * Use the following command line to make c.o
  5. * asm -u -isc:Assembler_Include/ c.a
  6. *
  7.  
  8.         INCLUDE        "exec/types.i"
  9.         INCLUDE        "exec/alerts.i"
  10.         INCLUDE        "exec/nodes.i"
  11.         INCLUDE        "exec/lists.i"
  12.         INCLUDE        "exec/ports.i"
  13.         INCLUDE        "exec/libraries.i"
  14.         INCLUDE        "exec/tasks.i"
  15.         INCLUDE        "exec/memory.i"
  16.         INCLUDE        "exec/execbase.i"
  17.         INCLUDE        "libraries/dos.i"
  18.         INCLUDE        "libraries/dosextens.i"
  19.         INCLUDE        "workbench/startup.i"
  20.         INCLUDE        "exec/funcdef.i"
  21.         INCLUDE        "exec/exec_lib.i"
  22.         INCLUDE        "libraries/dos_lib.i"
  23.  
  24. MEMFLAGS        EQU        MEMF_CLEAR+MEMF_PUBLIC
  25. AbsExecBase     EQU        4
  26.  
  27.         xref    __ctors
  28.         xref    __dtors
  29.  
  30. ;;;
  31. ;;;   Stack map.
  32. ;;;
  33.       OFFSET  0
  34.            ds.b    4
  35. savereg    ds.b    13*4
  36. stackbtm   ds.b    4
  37.  
  38.  
  39.  
  40. ; some usefull macros:
  41.  
  42. callsys macro
  43.         CALLLIB _LVO\1
  44.         endm
  45.         
  46.         xdef        _XCEXIT                * exit(code) is standard way to leave C.
  47.         xdef        @_XCEXIT
  48.         
  49.         xref        LinkerDB        * linker defined base value
  50.         xref        _BSSBAS                * linker defined base of BSS
  51.         xref        _BSSLEN                * linker defined length of BSS
  52.         xref        __stack
  53.  
  54. *       library references
  55.  
  56.         section text,code
  57.  
  58.         xref    __main                  * Name of C program to start with.
  59.         xref    _MemCleanup             * Free all allocated memory
  60.  
  61. start0:
  62.         lea        restartflag(pc),a1
  63.         movem.l    d0/a0,6(a1)
  64.  
  65. start1:
  66.         clr.w    (a1)
  67.         movem.l    6(a1),d0/a0
  68.         bsr.s    start
  69.         lea        restartflag(pc),a1
  70.         tst.w    (a1)
  71.         bne.s    start1
  72.         rts
  73.  
  74. restartflag:
  75.         dc.w    0    ; 0
  76. wbmsgback:
  77.         dc.l    0    ; 2
  78. argps:
  79.         dc.l    0,0    ; 6
  80. cdtsave:
  81.         dc.l    0,0    ; 14
  82.  
  83.  
  84.         xdef    __dorestart
  85. __dorestart:
  86.         lea        restartflag(pc),a0
  87.         move.w    #'MD',(a0)+
  88.         move.l    _WBenchMsg(a4),(a0)
  89.         rts
  90.  
  91. start:
  92.         movem.l d1-d6/a0-a6,-(a7)       * save registers
  93.  
  94.         move.l  a0,a2                   * save command pointer
  95.         move.l  d0,d2                   * and command length
  96.         lea     LinkerDB,a4             * load base register
  97.         move.l  AbsExecBase.W,a6
  98.  
  99.  
  100.         IFND        RESIDENT
  101.         lea     _BSSBAS,a3              * get base of BSS
  102.         moveq   #0,d1
  103.         move.l  #_BSSLEN,d0             * get length of BSS in longwords
  104.         bra.s   clr_lp                  * and clear for length given
  105. clr_bss move.l  d1,(a3)+
  106. clr_lp  dbf     d0,clr_bss
  107.         move.l  a7,_StackPtr(A4)        * Save stack ptr
  108.         move.l  a6,SysBase(A4)
  109.  
  110. *------ get the size of the stack, if CLI use cli_DefaultStack
  111. *------                                 if WB use a7 - TC_SPLOWER
  112.         move.l        ThisTask(a6),A3
  113.         move.l        pr_CLI(A3),d0
  114.         beq.s         fromwb
  115.         lsl.l         #2,d0
  116.         move.l        d0,a0
  117.         move.l        cli_DefaultStack(a0),d0
  118.         lsl.l         #2,d0             * # longwords -> # bytes
  119.         bra.s         dostack
  120.  
  121. fromwb:
  122.         move.l        a7,d0                         
  123.         sub.l         TC_SPLOWER(a3),d0
  124. dostack:
  125.  
  126. *------ Set __base for stack checking
  127.         move.l       a7,d1
  128.         sub.l        d0,d1               * get top of stack
  129.         add.l        #128,D1             * allow for parms overflow
  130.         move.l       D1,__base(A4)       * save for stack checking
  131.         
  132.         cmp.l         __stack(a4),d0
  133.         bcc.s        nochange        
  134.  
  135. *-- current stack is not as big as __stack says it needs
  136. *-- to be. Allocate a new one.
  137.         move.l        __stack(a4),d0
  138.         add.l         #128,d0           * extra room
  139.         move.l        d0,newstacksize(a4)
  140.  
  141.         move.l        #MEMFLAGS,d1
  142.         callsys       AllocMem
  143.         tst.l         d0
  144.         beq.w         return
  145.         
  146.         move.l        d0,newstack(a4)
  147.         add.l         #128,d0           * extramain room
  148.         move.l        d0,__base(a4)
  149.         
  150.         add.l         __stack(a4),d0
  151.         move.l        d0,d1
  152.         
  153. *-- If we're running under 2.0, call StackSwap to set up
  154. *-- the new stack. Otherwise, just jam the new value into
  155. *-- A7.        
  156.         cmpi.w        #36,$14(a6)
  157.         blt.s         no20
  158.  
  159.         move.l        d0,mystk_Pointer(a4)
  160.         move.l        d1,mystk_Upper(a4)
  161.         sub.l         newstacksize(a4),d1
  162.         lea           mystk_Lower(a4),a0
  163.         move.l        d1,(a0)
  164.         callsys       StackSwap
  165.         bra.s         nochange
  166.            
  167. no20:   move.l        d0,a7
  168.                 
  169. nochange:
  170.         ENDC
  171.  
  172. clrwb:
  173.         clr.l        _WBenchMsg(A4)
  174.  
  175. *-----  clear any pending signals
  176.         moveq         #0,d0
  177.         move.l        #$00003000,d1
  178.         callsys       SetSignal
  179.  
  180.         move.l        ThisTask(a6),A3
  181.  
  182. *------ attempt to open DOS library:
  183.         lea           DOSName(PC),A1
  184.         moveq.l       #33,D0
  185.         callsys       OpenLibrary
  186.         move.l        D0,DOSBase(A4)
  187.         bne.s         ok2
  188.         moveq.l       #100,d0
  189.         bra.w         exit2
  190.  
  191. ok2:
  192.  
  193. *------ are we running as a son of Workbench?
  194.         move.l        pr_CurrentDir(A3),__curdir(A4)
  195.         tst.l         pr_CLI(A3)
  196.         beq.w         fromWorkbench
  197.         
  198. *=======================================================================
  199. *====== CLI Startup Code ===============================================
  200. *=======================================================================
  201. *
  202. * Entry: D2 = command length
  203. *        A2 = Command pointer
  204. fromCLI:
  205.  
  206. *------ find command name:
  207.         move.l      pr_CLI(a3),a0
  208.         add.l       a0,a0                   * bcpl pointer conversion
  209.         add.l       a0,a0
  210.         move.l      cli_CommandName(a0),a1
  211.  
  212.         add.l       a1,a1                   * bcpl pointer conversion
  213.         add.l       a1,a1
  214.  
  215. *------ collect parameters:
  216.         move.l      d2,d0                   * get command line length
  217.         moveq.l     #0,d1
  218.         move.b      (a1)+,d1
  219.         move.l      a1,_ProgramName(A4)
  220.         add.l       d1,d0                   * add length of command name
  221.         addq.l      #7,d0                   * allow for space after command, quotes
  222.                                             * and null terminator, as well as 
  223.         andi.w      #$fffc,D0               * force to long word boundary
  224.         move.l      d0,Commandlen(a4)
  225.    
  226.         movem.l     d1/a1,-(a7)
  227.         move.l      #MEMFLAGS,d1
  228.         callsys     AllocMem
  229.         movem.l     (a7)+,d1/a1
  230.         tst.l       d0
  231.         bne.s       ok_copy
  232.    
  233.         moveq.l     #30,d0                  * what should the return code be for out of mem?
  234.         move.l      d0,-(a7)                * put a return code on the stack
  235.         beq.w       nodofree                * Was exitToDOS
  236.    
  237. ok_copy:
  238.         move.l      d0,a0
  239.         move.l      d0,Commandbuf(a4)
  240.          
  241. *------ copy command line into memory
  242.         move.l     d2,d0                    * get command line length
  243.         subq.l     #1,d0
  244.         add.l      d1,d2
  245.    
  246. copy_line:
  247.         move.b     0(A2,D0.W),2(A0,D2.W)    * copy command line to stack
  248.         subq.l     #1,d2
  249.         dbf        d0,copy_line
  250.         move.b     #' ',2(a0,d2.w)          * add space between command and parms
  251.         subq.l     #1,d2
  252.         move.b     #'"',2(a0,d2.w)          * add end quote
  253.    
  254. copy_cmd:
  255.         move.b     0(a1,d2.w),1(a0,d2.w)    * copy command name to stack
  256.         dbf        d2,copy_cmd
  257.         move.b     #'"',(a0)
  258.         move.l     A0,-(A7)                 * push command line address
  259.         bra.s      main                     * call C entrypoint
  260.  
  261. *=======================================================================
  262. *====== Workbench Startup Code =========================================
  263. *=======================================================================
  264.  
  265. fromWorkbench:
  266.  
  267.  
  268. *------ we are now set up.  wait for a message from our starter
  269.         lea        wbmsgback(pc),a0
  270.         move.l    (a0),d0
  271.         beq.s    wbwaitmsg
  272.         clr.l    (a0)
  273.         bra.s    wbrestart
  274.  
  275. wbwaitmsg:
  276.         lea        pr_MsgPort(A3),a0         * our process base
  277.         callsys    WaitPort
  278.         lea        pr_MsgPort(A3),a0         * our process base
  279.         callsys    GetMsg
  280.  
  281. wbrestart:
  282.         move.l     d0,_WBenchMsg(a4)
  283.         move.l     d0,-(SP)
  284.  
  285.         move.l     d0,a2                     * get first argument
  286.         move.l     sm_ArgList(a2),d0
  287.         beq.s      do_main
  288.         move.l     DOSBase(a4),a6
  289.         move.l     d0,a0
  290.         move.l     wa_Lock(a0),d1
  291.         callsys    DupLock
  292.         move.l     d0,__curdir(A4)
  293.         move.l     d0,d1
  294.         callsys    CurrentDir
  295.  
  296. do_main:
  297.         move.l     _WBenchMsg(A4),a0         * get address of workbench message
  298.         move.l     a0,-(a7)                  * push argv
  299.         pea        NULL(a4)                  * push argc
  300.         move.l     sm_ArgList(a0),a0         * get address of arguments
  301.         move.l     wa_Name(a0),_ProgramName(A4) * get name of program
  302.  
  303. *=============================================
  304. *------ common code --------
  305. *=============================================
  306.  
  307. main
  308.         jsr        __fpinit(PC)              * Initialize floating point
  309.         jsr        __main(PC)                * call C entrypoint
  310.         moveq.l    #0,d0                     * set successful status
  311.         bra.s      exit2
  312. *
  313.  
  314. XCEXIT:
  315. _XCEXIT:
  316.         move.l     4(SP),d0                  * extract return code
  317. @XCEXIT:
  318. @_XCEXIT:
  319. exit2:
  320.  
  321. *-- Save Return Code
  322.         move.l     _StackPtr(a4),a2
  323.         move.l     d0,-(a2)
  324.  
  325. *-- Swap back to original stack
  326. *-- If we're running under 2.0, call StackSwap
  327. *-- Otherwise, just jam the new value into a7
  328.         move.l     AbsExecBase.W,A6
  329.         cmpi.w     #36,$14(a6)
  330.         blt.s      noswap
  331.         tst.l      mystk_Lower(a4)
  332.         beq.s      noswap
  333.  
  334.         lea        mystk_Lower(a4),a0
  335.         subq.l     #4,mystk_Pointer(a4)      * make room for the ret code  
  336.         callsys    StackSwap
  337.            
  338. noswap:  
  339.  
  340.         movea.l    a2,a7                     * restore stack ptr
  341.                 
  342.         move.l     _ONEXIT(A4),d0            * exit trap function?
  343.         beq.s      exit3
  344.         move.l     d0,a0
  345.         jsr        (a0)
  346. exit3:
  347.         jsr        __fpterm(PC)              * clean up any floating point
  348.         jsr        _MemCleanup(PC)           * cleanup leftover memory alloc.
  349.  
  350.         ifnd       RESIDENT
  351. *------ free the stack if we allocated one
  352.         move.l     newstacksize(a4),d0
  353.         beq.s      exit4
  354.         move.l     newstack(a4),a1
  355.         move.l     AbsExecBase.W,A6
  356.         callsys    FreeMem
  357.         endc
  358.  
  359. exit4:
  360. *------ if we ran from CLI, skip workbench cleanup:
  361.         tst.l      _WBenchMsg(A4)
  362.         beq.s      exitToDOS
  363.         move.l     DOSBase(A4),a6
  364.         move.l     __curdir(a4),d1
  365.         beq.s      done_5
  366.         callsys    UnLock
  367. done_5:
  368. *------ return the startup message to our parent
  369. *       we forbid so workbench can't UnLoadSeg() us
  370. *       before we are done:
  371.         move.l     AbsExecBase.W,A6
  372.  
  373.         tst.w        restartflag
  374.         bne.s        nodofree
  375.  
  376.         callsys    Forbid
  377.         move.l     _WBenchMsg(a4),a1
  378.         callsys    ReplyMsg
  379.  
  380.         bra.s      nodofree
  381.  
  382. exitToDOS:
  383.         move.l     AbsExecBase.W,a6
  384.  
  385. *------ free the command line buffer
  386.         move.l     Commandlen(a4),d0
  387.         beq.s      nodofree
  388.         move.l     Commandbuf(a4),a1
  389.         callsys    FreeMem
  390.    
  391. *------ this rts sends us back to DOS:
  392. nodofree:
  393.         move.l     DOSBase(A4),a1
  394.         callsys    CloseLibrary              * close Dos library
  395.  
  396.         IFD        RESIDENT
  397.         move.l     realdatasize(a4),d0
  398.         move.l     a4,a1
  399.         sub.l      #RESBASE,a1
  400.         callsys    FreeMem
  401.         ENDC
  402.         move.l     (a7)+,d0
  403.  
  404. return:        
  405.         movem.l    (a7)+,d1-d6/a0-a6
  406.         rts
  407.  
  408. __fpterm:    ; call dtors
  409.         move.l    a2,-(sp)
  410.         lea        __dtors(a4),a2
  411.         bra.s    fpil
  412.  
  413. __fpinit:    ; call ctors
  414.         move.l    a2,-(sp)
  415.         lea        __ctors(a4),a2
  416. fpil:
  417.         move.l    (a2)+,d0
  418.         beq.s    fpil2
  419.         move.l    d0,a0
  420.         jsr        (a0)
  421.         bra.s    fpil
  422. fpil2:
  423.         move.l    (sp)+,a2
  424.         rts
  425.  
  426. DOSName dc.b    'dos.library',0
  427.  
  428.         section __MERGED,BSS
  429.  
  430.         xref    DOSBase
  431.  
  432.         xdef    NULL,SysBase,_WBenchMsg
  433.         xdef    __curdir
  434.         xdef    _OSERR,_FPERR,_SIGFPE,_ONERR,_ONEXIT,_ONBREAK
  435.         xdef    _SIGINT
  436.         xdef    _ProgramName,_StackPtr,__base
  437.         ifd        CATCH
  438.         xdef        _ONGURU,_FMEM,_STAKOffset
  439.         endc
  440.  
  441.  
  442.         
  443. NULL          ds.b    4        
  444. __base        ds.b    4                   * base of stack
  445. _OSERR        ds.b    4
  446. _FPERR        ds.b    4
  447. _SIGFPE       ds.b    4
  448. _SIGINT       ds.b    4
  449. _ONERR        ds.b    4
  450. _ONEXIT       ds.b    4
  451. _ONBREAK      ds.b    4
  452. __curdir      ds.b    4
  453. SysBase       ds.b    4
  454. _WBenchMsg    ds.b    4
  455. _StackPtr     ds.b    4
  456. _ProgramName  ds.b    4
  457. Commandbuf    ds.b    4
  458. Commandlen    ds.b    4
  459. mystk_Lower   ds.b    4
  460. mystk_Upper   ds.b    4
  461. mystk_Pointer ds.b    4
  462.  
  463.  
  464.  
  465.         ifnd       RESIDENT
  466. newstack     ds.b    4                   * pointer to new stack (if needed)
  467. newstacksize ds.b    4                   * size of new stack
  468.         endc
  469.  
  470.              END
  471.