home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.cs.arizona.edu
/
ftp.cs.arizona.edu.tar
/
ftp.cs.arizona.edu
/
icon
/
binaries
/
old
/
vms
/
vmsfix.com
< prev
Wrap
Text File
|
1992-06-05
|
942b
|
33 lines
$! vmsfix.com -- fix the blocksize of VMS BACKUP file
$!
$! This command file repairs a BACKUP file which has an incorrect block size.
$! That happens, for example, if a BACKUP file is transferred via FTP.
$!
$! The defaults are correct for fixing the VMS Icon distribution.
$!
$! usage: @VMSFIX [filename [blocksize]]
$! default: @VMSFIX VMS.BCK 8192
$!
$ FILE = "VMS.BCK"
$ BLKG = "8192"
$ PROC = f$environment("procedure")
$!
$ If "''p1'" .Nes. "" Then $ FILE = "''p1'"
$ If "''p2'" .Nes. "" Then $ BLKG = "''p2'"
$!
$ Backup 'PROC' XXTEMPXX.BCK/Save_Set/Block_Size='BLKG'
$ If f$extract(0,4,f$getsyi("version")) .Eqs. "V5.0" Then GoTo V50
$!
$! (fix for VMS 4.7, 5.1, or newer)
$!
$ Copy/Overlay 'FILE' XXTEMPXX.BCK
$ Rename XXTEMPXX.BCK 'FILE'
$ Exit 1
$!
$! (fix for VMS 5.0 only)
$V50:
$ Analyze/RMS/FDL/Output=XXTEMPXX.FDL XXTEMPXX.BCK
$ Convert/FDL=XXTEMPXX.FDL 'FILE' 'FILE'
$ Delete/NoConfirm/NoLog XXTEMPXX.*;*
$ Exit 1