home *** CD-ROM | disk | FTP | other *** search
/ AmigActive 3 / AACD03.BIN / AACD / Programming / sofa / archive / SmallEiffel.lha / SmallEiffel / lib_se / compile.e < prev    next >
Text File  |  1999-06-05  |  5KB  |  141 lines
  1. --          This file is part of SmallEiffel The GNU Eiffel Compiler.
  2. --          Copyright (C) 1994-98 LORIA - UHP - CRIN - INRIA - FRANCE
  3. --            Dominique COLNET and Suzanne COLLIN - colnet@loria.fr
  4. --                       http://SmallEiffel.loria.fr
  5. -- SmallEiffel is  free  software;  you can  redistribute it and/or modify it
  6. -- under the terms of the GNU General Public License as published by the Free
  7. -- Software  Foundation;  either  version  2, or (at your option)  any  later
  8. -- version. SmallEiffel is distributed in the hope that it will be useful,but
  9. -- WITHOUT ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  10. -- or  FITNESS FOR A PARTICULAR PURPOSE.   See the GNU General Public License
  11. -- for  more  details.  You  should  have  received a copy of the GNU General
  12. -- Public  License  along  with  SmallEiffel;  see the file COPYING.  If not,
  13. -- write to the  Free Software Foundation, Inc., 59 Temple Place - Suite 330,
  14. -- Boston, MA 02111-1307, USA.
  15. --
  16. class COMPILE
  17.    --
  18.    -- The `compile' command.
  19.    --
  20.  
  21. inherit COMMAND_FLAGS;
  22.  
  23. creation make
  24.  
  25. feature {NONE}
  26.  
  27.    command_name: STRING is "compile";
  28.  
  29.    make is
  30.       local
  31.          argc, argi: INTEGER;
  32.          arg, make_script_name, next_arg: STRING;
  33.       do
  34.          argc := argument_count;
  35.          if argc < 1 then
  36.             system_tools.bad_use_exit(command_name);
  37.          end;
  38.          search_for_verbose_flag;
  39.          search_for_cc_flag(argc);
  40.          system_tools.command_path_in(command,Command_compile_to_c);
  41.          from
  42.             argi := 1;
  43.          until
  44.             argi > argc
  45.          loop
  46.             arg := argument(argi);
  47.             if is_flag_version(arg) then
  48.                compile_to_c_pass_argument(arg);
  49.                argi := argi + 1;
  50.             elseif ("-c_code").is_equal(arg) then
  51.                echo.w_put_string(
  52.                   "Flag -c_code is now obsolete (this is the default since %
  53.                   %-0.81).%NSee documentation of `compile' (flag -clean).%N");
  54.                exec_clean_command := false;
  55.                argi := argi + 1;
  56.             elseif ("-clean").is_equal(arg) then
  57.                exec_clean_command := true;
  58.                argi := argi + 1;
  59.             elseif one_arg_flags.has(arg) then
  60.                compile_to_c_pass_argument(arg);
  61.                argi := argi + 1;
  62.                if argi <= argc then
  63.                   arg := argument(argi);
  64.                   compile_to_c_pass_argument(arg);
  65.                   argi := argi + 1;
  66.                end;
  67.             elseif argi < argc then
  68.                compile_to_c_pass_argument(arg);
  69.                next_arg := argument(argi + 1);
  70.                argi := system_tools.extra_arg(arg,argi,next_arg);
  71.                if argument(argi - 1) = next_arg then
  72.                   compile_to_c_pass_argument(next_arg);
  73.                end;
  74.             else
  75.                compile_to_c_pass_argument(arg);
  76.                argi := system_tools.extra_arg(arg,argi,Void);
  77.             end;
  78.          end;
  79.          check_for_root_class;
  80.          make_script_name := system_tools.remove_make_script;
  81.          echo.call_system(command);
  82.          system_tools.cygnus_bug(make_file,make_script_name);
  83.          if not make_file.is_connected then
  84.             echo.w_put_string(fz_01);
  85.             echo.w_put_string(make_script_name);
  86.             echo.w_put_string("%" not found. %
  87.                                 %Error(s) during `compile_to_c'.%N");
  88.             die_with_code(exit_failure_code);
  89.          end;
  90.          echo.put_string("C compiling using %"");
  91.          echo.put_string(make_script_name);
  92.          echo.put_string("%" command file.%N");
  93.          from
  94.             make_file.read_line;
  95.          until
  96.             make_file.last_string.count = 0
  97.          loop
  98.             command.copy(make_file.last_string);
  99.             echo.call_system(command);
  100.             make_file.read_line;
  101.          end;
  102.          make_file.disconnect;
  103.          if exec_clean_command then
  104.             command.clear;
  105.             system_tools.command_path_in(command,Command_clean);
  106.             command.extend(' ');
  107.             command.append(make_script_name);
  108.             echo.call_system(command);
  109.          else
  110.             echo.put_string("C code not removed.%N");
  111.          end;
  112.          echo.put_string(fz_02);
  113.       end;
  114.  
  115.    compile_to_c_pass_argument(arg: STRING) is
  116.       do
  117.          command.extend(' ');
  118.          command.append(arg);
  119.       end;
  120.  
  121.    exec_clean_command: BOOLEAN;
  122.          -- True if command clean must be called.
  123.  
  124.    make_file: STD_FILE_READ is
  125.       once
  126.          !!Result.make;
  127.       end;
  128.  
  129.    command: STRING is
  130.       once
  131.          !!Result.make(256);
  132.       end;
  133.  
  134.    one_arg_flags: ARRAY[STRING] is
  135.       once
  136.          Result := <<"-o", Flag_cc, "-cecil">>;
  137.       end;
  138.  
  139. end -- COMPILE
  140.  
  141.