AmigActive 1/AACD01.ISO/Welcome

AmigaDOS Script File | 1999-09-06 | 5KB | 174 lines

.key CHECK/K,NOHTML/K,VOL/K
.bra {
.ket }

;set echo on

;;; CD to AACD root if run from elsewhere, e.g. AutoRun
cd >NIL: {VOL}
;;;
;;; Check argument - exit if Welcome has been run, otherwise ask
    If {CHECK} EQ "YES"
        Assign >NIL: AACD: EXISTS
        If NOT WARN
            Skip ABORT
        Else
            set init `:System/C/RequestChoice "Amiga Active CD" "Some assigns need to be made before we can proceed.*NYou can remove them later with the RemoveCD icon" "OK|Cancel"`
            If $init EQ 0
                Skip ABORT
                EndIf
            EndIf
        EndIf
;;;
;;; Skip to HTML if Welcome has already been run
Assign >NIL: AACD: EXISTS
If NOT WARN
    Skip HTML
    EndIf
;;;
;;; Set up temporary assign
Assign AACDtmp: :
set ReqTitle Welcome to the Amiga Active CD
;;;
;;; Check for some system assigns
; MUI
Assign MUI: EXISTS >NIL:
If WARN
    AACDtmp:System/C/RequestChoice >NIL: "`get ReqTitle`" "Some of the software on this CD requires MUI*NIf you use it regularly you should install MUI to your hard drive.*NThe installer is in the CDTools drawer of this CD" "I see"
    EndIf
; ClassAct
If NOT EXISTS LIBS:window.class
    AACDtmp:System/C/RequestChoice >NIL: "`get ReqTitle`" "Some of the software on this CD requires ClassAct*NIf you use it regularly you should install MUI to your hard drive.*NThe installer is in the CDTools drawer of this CD" "I see"
    EndIf
;;;
;;; Start arexx if not running
AACDtmp:System/rexxc/rx "address command" >NIL:
If WARN
    AACDtmp:System/System/RexxMast >NIL:
    EndIf
;;;
;;; Make sure files needed by CD system are available
; icon.mcc
Version >NIL: MUI:Libs/MUI/Icon.mcc 1 1
If WARN
    Copy >NIL: AACDtmp:Icon.mcc MUI:Libs/MUI CLONE
    EndIf
; MUIRexx
which >NIL: MUIRexx
if WARN
    copy AACDtmp:MUIRexx SYS:Rexxc clone quiet'
    path SYS:Rexxc ADD
    endif
; AACDfile
If NOT EXISTS C:AACDfile
    Copy >NIL: AACDtmp:System/C/AACDfile C: CLONE QUIET
    EndIf
; IDer
Version >NIL: C:IDer 1 6
If WARN
    Copy >NIL: AACDtmp:System/C/IDer C: CLONE
    EndIf
; FlashFind
which >NIL: FlashFind
If WARN
    copy AACDtmp:System/C/FlashFind C: clone quiet
    Endif
; AWeb config
If NOT EXISTS ENVARC:AWeb3DEMO
    Makedir >NIL: ENVARC:AWeb3DEMO
    Makedir >NIL: ENV:AWeb3DEMO
    Endif
If NOT EXISTS ENVARC:AWeb3DEMO/Amigactive
    Makedir >NIL: ENVARC:AWeb3DEMO/Amigactive
    Makedir >NIL: ENV:AWeb3DEMO/Amigactive
    Copy AACDtmp:System/Prefs/env-archive/AWeb3DEMO/Amigactive/#? ENVARC:AWeb3DEMO/Amigactive CLONE QUIET
    Copy AACDtmp:System/Prefs/env-archive/AWeb3DEMO/Amigactive/#? ENV:AWeb3DEMO/Amigactive CLONE QUIET
    Endif
If EXISTS ENVARC:AWeb3
    If NOT EXISTS ENVARC:AWeb3/Amigactive
        Makedir >NIL: ENVARC:AWeb3/Amigactive
        Makedir >NIL: ENV:AWeb3/Amigactive
        Copy AACDtmp:System/Prefs/env-archive/AWeb3DEMO/Amigactive/#? ENVARC:AWeb3/Amigactive CLONE QUIET
        Copy AACDtmp:System/Prefs/env-archive/AWeb3DEMO/Amigactive/#? ENV:AWeb3/Amigactive CLONE QUIET
        Endif
    Endif
;;;
;;; Give option for setting CD preferences, if not already done
If NOT EXISTS ENV:AACD.prefs
    If NOT EXISTS S:AACD.prefs
        Version >NIL: version 39
        If NOT WARN
            Copy >NIL: AACDtmp:CDTools/S/AACD.prefs ENV:
            Copy >NIL: AACDtmp:CDTools/S/AACD.prefs ENVARC:
            set NoPrefs 1
        Else
            Copy >NIL: AACDtmp:CDTools/S/AACD.prefs_OS2 ENV:AACD.prefs
            EndIf
        EndIf
    EndIf
If NOT EXISTS ENV:AACDfile.prefs
    If NOT EXISTS S:AACDfile.prefs
        Version >NIL: version 39
        If NOT WARN
            Copy >NIL: AACDtmp:CDTools/S/AACDfile.prefs ENV:
            Copy >NIL: AACDtmp:CDTools/S/AACDfile.prefs ENVARC:
            set NoPrefs 1
        Else
            Copy >NIL: AACDtmp:CDTools/S/AACDfile.prefs_OS2 ENV:AACDfile.prefs
            EndIf
        EndIf
    EndIf
If $NoPrefs EQ 1
    set edit `RequestChoice "Amigaactive CD" "AACD has a preferences program to specify*N the tools used to view/hear different types of files.*NWould you like to run it now?" "Yes|No"`
    If $edit EQ 1
        MuiRexx AACDPrefs port AACDPREFS
    Else
        RequestChoice >NIL: "Amigaactive CD" "You can run AACD preferences at any time.*NEither from its icon or from the Setup page of the documentation." "OK"
        EndIf
    EndIf
;;;
;;; Set assigns for programs on this CD and system drawers
Execute AACDtmp:CDTools/S/ThisCD
Assign DEVS:    AACDtmp:System/Devs ADD
Assign Fonts:   AACDtmp:System/Fonts ADD
Assign Libs:    AACDtmp:System/Libs ADD
Assign L:       AACDtmp:System/L ADD
Assign S:       AACDtmp:CDTools/S ADD
Assign LIBS:    AACDtmp:System/Classes ADD

; Make environment variables defined on CD available to system
Failat 21
Assign >NIL: ENV: AACDtmp:System/Prefs/Env-Archive ADD
; For HappyENV users
If FAIL
    Assign >NIL: ENVARC: AACDtmp:System/Prefs/Env-Archive ADD
    EndIf
;;;
;;;Check for NewIcons if not already running
If $NoNewIcons NOT EQ TRUE
    AACDtmp:System/C/isnirunning
    If NOT WARN
        set RunNI `AACDtmp:System/C/RequestChoice "Amiga Active CD" "This CD is set up for use with NewIcons*NIf you do not run Newicons the icon*Nimages and layout may look strange.*N*NWould you like to run NewIcons now?" "Yes|No"`
        If $RunNI EQ 1
            Run <>NIL: AACDtmp:System/C/NewIcons
            EndIf
        EndIf
    EndIf
;;;
;;; Clean up
RequestChoice >NIL: "`get ReqTitle`" "We have set up some assigns to run software from the CD.*N*NIf you wish to remove the CD from the drive, doubleclick the RemoveCD icon,*Notherwise the icon will stay on your Workbench." " OK "
;; Change temporary assign to permanent one
Assign AACD: AACDtmp:
Assign AACDtmp:
;;;
;;; Load HTML
LAB HTML
If {NOHTML} NOT EQ "YES"
    Run >NIL: AACD:AACD/WebSites/AWeb3/AWebDemo Welcome.html LOCAL CONFIG Amigactive
    Endif
;;;
;;; Abort
LAB ABORT
;;;