home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / robot-pd / 22300.ZIP / 22300B.DSK / ucrlzh20.z80 < prev    next >
Text File  |  1998-05-08  |  42KB  |  1,283 lines
  1.     .SALL
  2.     TITLE 'UNCRrunch LZH v2.0  20 July 1991'
  3. ;************************************************************************
  4. ;*                                    *
  5. ;*               UNCRunch LZH v2.0                *
  6. ;*                  20 July 1991                *
  7. ;*                           - Roger Warren    *
  8. ;************************************************************************
  9. ;
  10. ;    With the kind permission of Mr. Steven Greenberg, author of 
  11. ;    UNCRunch, this program was generated from his UNCRunch v2.4 code
  12. ;    dated 15 Sept 1987.  Accordingly, the following notifications
  13. ;    are in order:
  14. ;
  15. ;     Portions Copyright (c)   S. Greenberg  09/15/87
  16. ;     Portions Copyright (c)   R. Warren     07/20/91
  17. ;    May be reproduced for non-profit use only
  18. ;
  19. ;    You can distribute it AS IS or modify it for your OWN use,
  20. ;    but public release of modified versions (source or object
  21. ;    files) without permission is prohibited, nor can it be sold.
  22.  
  23. ;UNCRLZH HISTORY:
  24. ; v2.0 Re-released because of new CRLZH algorithm changes.  Version 2.0
  25. ;    of CRLZH is 10% FASTER and compresses further than V1.1.  The output
  26. ;    files must be de-compressed with UNCRLZH version 2.0, which replaces
  27. ;    UNCRLZH 1.1.  UNCRLZH 2.0 handles LZH encoded files of both versions
  28. ;    as well as CRUCNCHED and SQUEEZED files.
  29. ;    With the kind permission of Gene Pizzetta, changes made to UNCR
  30. ;    thru version 2.8 have been incorporated into this program
  31. ;    taken from Steve Greenberg's version 2.4.  This program will
  32. ;    NOW handle date stamps ala ZSDOS.
  33. ;
  34. ; v1.1 Official first release.  No functional changes from Beta version.
  35. ;     Merely stepped version for differentiation.
  36. ;
  37. ; v1.0 Beta test version
  38. ; 
  39.  
  40. VERS    EQU    20
  41. SUBVERS    EQU    ' '
  42.  
  43.     .Z80
  44.  
  45.     CSEG
  46.  
  47. NO    EQU    0
  48. YES    EQU    NOT NO
  49. N    EQU    NO
  50. Y    EQU    YES
  51. CRUNCH    EQU    NO        ; Yes for CRUNCH, no for UNCR (for common)
  52. ;ZSYS    EQU    YES        ; Yes if exclusively for Z-System
  53.     .ACCEPT    'ZCPR3-Only Version [Y/N] ? ',ZSYS
  54.  
  55. ;=======================================================================
  56.  
  57.   IF ZSYS
  58.  
  59. MEMPAG    EQU    2300H        ; <== set! [see comment near end of program]
  60.  
  61.   ELSE    ; ZSYS
  62.  
  63. MEMPAG    EQU    2500H        ; <== set! [see comment near end of program]
  64.  
  65.   ENDIF    ; ZSYS
  66.  
  67. ;=======================================================================
  68.  
  69. REV    EQU    (VERS/10*16)+(VERS MOD 10) ; Program revision level in BCD
  70. SIGREV    EQU    20H        ; "Significant" revision level (compatibility)
  71. SIGRVY    EQU    20H        ; "Significant" revision level for LZH
  72.  
  73. NOPRED    EQU    0FFFFH        ; "No predecessor"
  74. IMPRED    EQU    07FFFH        ; Pred that can't be matched or bumped
  75.  
  76. SCRUPT1    EQU    01H        ; Screen update speeds
  77. SCRUPT2    EQU    07H
  78.  
  79. ; --- Reserved codes ---
  80.  
  81. EOFCOD    EQU    100H        ; EOF code
  82. RSTCOD    EQU    101H        ; Adaptive reset code
  83. NULCOD    EQU    102H        ; Null code
  84. SPRCOD    EQU    103H        ; Spare code
  85.  
  86. ; --- ASCII equates ---
  87.  
  88. CTRLC    EQU    03H        ; ^c
  89. BELL    EQU    07H        ; Beep
  90. BS    EQU    08H        ; Backspace
  91. LF    EQU    0AH        ; Linefeed
  92. CR    EQU    0DH        ; Carriage return
  93.  
  94. ; --- CP/M address equates ---
  95.  
  96. DFCB    EQU    5CH        ; Default FCB #1
  97. DFCB2    EQU    6CH        ; Default FCB #2
  98. DDMA    EQU    80H        ; Default DMA address
  99. BDOS    EQU    0005H        ; BDOS entry point
  100.  
  101. ; --- BDOS function equates ---
  102.  
  103. CONIN    EQU    1        ; Input a character from the console
  104. CONOUT    EQU    2        ; Output single char to console
  105. PRTSTR    EQU    9        ; Print string to console
  106. CONST    EQU    11        ; Get console status
  107. GETVER    EQU    12        ; Get CP/M version #
  108. SELDSK    EQU    14        ; Select disk
  109. OPEN    EQU    15        ; Open file
  110. CLOSE    EQU    16        ; Close file
  111. SFIRST    EQU    17        ; Search for first file
  112. SNEXT    EQU    18        ; Search for next file
  113. ERASE    EQU    19        ; Erase file
  114. READ    EQU    20        ; Read file (sequential)
  115. WRITE    EQU    21        ; Write file (sequential)
  116. MAKE    EQU    22        ; Make file
  117. GETDSK    EQU    25        ; Get currently logged drive
  118. SETDMA    EQU    26        ; Set DMA address
  119. GSUSER    EQU    32        ; Get/set user code
  120. RSTDRV    EQU    37        ; Reset drive
  121. SETMS    EQU    44        ; Set multi-sector count (cp/m+ only)
  122. GETDMA    equ    47        ; ZSDOS get current DMA address
  123. EXDOSV    equ    48        ; ZSDOS extended BDOS version
  124. GETFSTP    equ    102        ; ZSDOS get file stamp
  125. SETFSTP    equ    103        ; ZSDOS set file stamp
  126.  
  127. ;-----------------------------------------------------------------------
  128.  
  129.     EXTRN    USQREL,UNCR1
  130.  
  131.   IF NOT ZSYS
  132.     EXTRN    PARSEU
  133.   ENDIF    ; NOT ZSYS
  134.  
  135.     EXTRN    UNLZH
  136.  
  137.     ENTRY    GETBYT,OUT
  138.     ENTRY    GLZHUN,PLZHUN    ; for UNLZH
  139.  
  140. ;_______________________________________________________________________
  141. ;
  142. ; Macros to facilitate "horizontal" movement through the table.
  143. ; See "Table structure" comment near "initbl" for more information.
  144.  
  145. RIGHT1     MACRO
  146.     LD    A,H        ; }
  147.     ADD    A,10H        ; } move "right" one column (same row)
  148.     LD    H,A        ; }
  149.      ENDM
  150.  
  151. ;.......................................................................
  152.  
  153. START:    JP    STRT        ; <--- entry
  154.     DB    'Z3ENV',01H    ; ZCPR3 environment descriptor
  155. Z3ED:    DW    00h
  156.  
  157. ;-----------------------------------------------------------------------
  158.  
  159.     DW    0        ; filler
  160.     DB    'CRLZH'        ; for ZCNFG
  161.     DB    VERS/10+'0',VERS MOD 10+'0'
  162.     DB    ' '        ; Filler
  163. ARCHIV:    DB    0        ; Archive mode (not used, for CRUNCH)
  164. QUIFL:    DB    0        ; Quiet mode flag
  165. NPROFL:    DB    0        ; No prompt before overwrite flag
  166. TRBOFL:    DB    0        ; Defeat multi-sector i/o flag
  167. CNFRFL:    DB    0        ; Confirm every file flag
  168. WRMFLG:    DB    0        ; Warm boot flag
  169. BIGFLG:    DB    0        ; Bigger file prompt flag
  170. MAXUSR:    DB    31        ; Maximum user allowed by program
  171. MAXDRV:    DB    16        ; Maximum drive allowed by program
  172. SYSFL:    DB    0        ; System file inclusion flag
  173. TYPFL:    DB    'Y'        ; Default filetype (UNCRLZH only)
  174.  
  175. ;......................................................................
  176. ;
  177. ; File type exclusion list.  (for CRUNCH, not used by UNCR)
  178.  
  179. EXTBL:    DB    '               '    ; filled with spaces
  180.     DB    '               '
  181.  
  182. ;=*=-=*=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=
  183.  
  184. CPYRT:    DB    'UNCRLZH '
  185.   IF ZSYS
  186.     DB    'Z-'
  187.   ENDIF    ; ZSYS
  188.     DB    'Version ',VERS/10+'0','.',VERS MOD 10+'0',SUBVERS
  189.     DB    ' Copyright (c) 1987 by S. Greenberg',CR,LF
  190.         DB    '        Portions  Copyright (c) 1991 by R. Warren',CR,LF
  191.     DB    ' May be used/reproduced for non-profit use only',CR,LF,LF,'$'
  192.  
  193. ;=*=-=*=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=*=-=
  194.  
  195. STRT:
  196.   IF ZSYS
  197.     LD    HL,(Z3ED)    ; check for ZCPR3
  198.     LD    A,H
  199.     OR    L
  200.     JP    NZ,Z80
  201.   ELSE    ; ZSYS
  202.     SUB    A        ; Z-80 test [RAF]
  203.     JP    PO,Z80
  204.   ENDIF    ; ZSYS
  205.     LD    DE,WRNGUP    ; "Program requires Z-80 processor"
  206.     JP    MESS80        ; No frills exit w/ message
  207.  
  208. Z80:    LD    (OLDSTK),SP    ; Save os's stack
  209.     LD    SP,TOPSTK    ; Set local stack
  210.     CALL    STRTUP        ; Does a lot of stuff
  211.  
  212. ;=======================================================================
  213. ;
  214. ;    *****    Re-enter here for each matching file *****
  215. ;
  216. ; General wildcard operation:  When the program is first invoked, a ll
  217. ; matching filenames are put end to end in FNBUFF, 12 bytes each, in
  218. ; alalphabetical order.  Since a filename is only 11 characters long,
  219. ; the spare byte, which precedes each filename, is used as a "tag/flag".
  220. ; By the time file processing starts (now), a number of routines have
  221. ; already run (parts  of the STRTUP routine).  These routines set the
  222. ; tag-flag which indicates to us now in what manner the file should be
  223. ; processed:  "00" = "skip it", "01" = process it", "02" = "perform a
  224. ; direct copy (if possible)", "FF" = "no more files".
  225.  
  226. NXTFIL:    LD    SP,TOPSTK    ; 'just in case'
  227.     LD    A,CR
  228.     CALL    TYPE
  229.     XOR    A        ; clear embedded date flag
  230.     LD    (DATFLG),A
  231.     LD    (YFLAG),A    ; ..and lzh flag
  232.     LD    DE,INFCB    ; Input file fcb
  233.     CALL    CLRFCB        ; Init it to blanks and zeroes
  234.     INC    DE        ; Leave "DE" pointing at infcb+1 for below
  235.     LD    HL,(BUFPTR)    ; Pntr to name of next file from expansion bfr
  236. NXTSEL:    LD    A,(HL)
  237.     OR    A        ; If zero, the file is "unselected"
  238.     JR    NZ,ISSEL    ; Br if it is selected
  239.     LD    BC,12        ; Else just quietly skip to the next file
  240.     ADD    HL,BC
  241.     LD    (BUFPTR),HL
  242.     JR    NXTSEL
  243.  
  244. ;...............................
  245. ;
  246. ; The file is "selected"; prepare to process it
  247.  
  248. ISSEL:    CP    0FFH        ; An "FF" means done
  249.     JP    Z,RETCCP    ; Br if that is the case
  250.     PUSH    AF        ; Save stat (to see if file is "excluded" blw)
  251.  
  252.     LD    A,(QUIFM)
  253.     OR    A
  254.     PUSH    DE
  255.     LD    DE,DASHES    ; "-----" for visual separation
  256.     CALL    Z,MESAG2
  257.     POP    DE
  258.  
  259.     INC    HL        ; Skip to 1st filename char
  260.     LD    BC,11        ; Filename character count
  261.     LDIR            ; Put next file name into input fcb
  262.     LD    (BUFPTR),HL    ; Save new pointer for next file
  263.     CALL    INTRAM        ; Initialize all ram
  264.     LD    A,80H        ; (init'd by "INTRAM", but must be init'd
  265.     LD    (CSAVE),A    ; - differently for CRUNCH & UNCRunch)
  266.     POP    AF        ; Get file's status byte back again
  267.     CP    02H        ; 02 if file matched the "exclusion" list
  268.     JR    NZ,COPNIN    ; If not, definitly attempt to uncompress it
  269.     LD    A,(WLDFLG)    ; If so, see if prgm was invoked w/ wildcards
  270.     OR    A        ;
  271.     JP    NZ,COPY9    ; If so, do not uncompress; do a straight copy
  272.  
  273. ;.......................................................................
  274. ;
  275. ; Now open the input file.  A failure here is unusual, since the file
  276. ; existed at the time the filename expansion took place.  There are
  277. ; "normal" series of events which could lead up to this, however.
  278.  
  279. COPNIN:    CALL    OPNIN        ; Attempt to open the next input file "INFCB"
  280.     JR    NC,OPOK        ; Br if ok
  281.     LD    DE,ERR1        ; "input file not found"
  282.     JP    SKIP1        ; Skip to next file
  283.  
  284. ;.......................................................................
  285. ;
  286. ; If we got here, the input file is open.  The output file is not
  287.  
  288. OPOK:    LD    DE,OUTFCB    ; Now for the output fcb
  289.     CALL    CLRFCB        ; Clear it
  290.     INC    DE        ; Leave "DE" pointing at filename area
  291.     LD    A,' '        ; For proper alignment
  292.     CALL    TYPE
  293.     LD    HL,INFCB    ; Print input filename to console
  294.     CALL    PRNFIL
  295.     XOR    A        ; Init 1st char of date stamp bfr to zero
  296.     LD    (STAMP),A    ; (nulls the buffer; zero is the eof char)
  297.     CALL    GETCHR        ; Get a char from the input stream
  298.     JR    NC,NTMT        ; If carry set on first byte, file is empty
  299.     LD    DE,ERR0        ; "[ file empty ]"
  300.     JR    NCR2        ; Treat same as "Not compressed"
  301.  
  302. NTMT:    CP    76H        ; Check for crunched file header "76FE"
  303.     JR    NZ,NCRNCH    ; Br if not
  304.     CALL    GETCHR
  305.     CP    0FEH
  306.     JR    Z,YCRNCH
  307.     CP    0FDH        ; lzh?
  308.     JR    Z,YLZH        ; br if so
  309.     CP    0FFH        ; Squeezed?
  310.     JR    Z,YESQZ        ; Br if so
  311.  
  312. NCRNCH:    CALL    CLSIN        ; Not squeezed or crunched; close input file
  313.     LD    DE,MSG43    ; "[not compressed]"
  314.  
  315. NCR2:    CALL    MESAG2
  316.     LD    A,(WLDFLG)    ; Invoked w/ wildcards?
  317.     OR    A
  318.     JP    NZ,COPY9    ; Do straight copy ("copy" chks for diff du)
  319.     JP    NXTFIL        ; Else go on to next file
  320.  
  321. ;...............................
  322.  
  323. YESQZ:    LD    (SQZFLG),A    ; Flag file as squeezed using ff already in a
  324.     CALL    GETCHR        ; Get checksum byte #1
  325.     LD    L,A        ; Hold that
  326.     CALL    GETCHR        ; Checksum byte #2
  327.     LD    H,A
  328.     LD    (SQCKSM),HL    ; Save for later reference
  329.     JR    YCRNCH
  330.  
  331. YLZH:    LD    (YFLAG),A    ; flag file as lzh crunched
  332.  
  333. YCRNCH:    LD    DE,OUTFCB+1    ; Where output filename will be copied to
  334.     LD    B,12        ; Loop limiter (11 char filename + ".")
  335.  
  336. EATLP:    CALL    GETCHR        ; Get next char
  337.     OR    A        ; A zero byte indicates end of filename
  338.     JR    Z,ATEIT        ; Br when that is encountered
  339.     AND    7FH        ; Force valid ascii (should be already)
  340.     CALL    UCASE        ; Upcase the char- (may be lc if squeezed)
  341.     CP    '.'        ; Check for name / ext division char
  342.     JR    Z,ISDOT        ; Br when encountered
  343.     LD    (DE),A        ; Else copy char to output fcb
  344.     INC    DE        ; And incr that pointer
  345.     DJNZ    EATLP        ; Continue, but not past end of filename
  346.     JR    IGNORE        ; If no 0 detected, ignore following info
  347.  
  348. ;.......................................................................
  349. ;
  350. ; When "." is encountered, skip to the file extension bytes of the out-
  351. ; put FCB.  Any remaining non-extension bytes were init'd to blank).  Do
  352. ; not copy the "." to the output FCB.
  353.  
  354. ISDOT:    LD    DE,OUTFCB+9    ; Skip...
  355.     LD    B,3        ; Update loop limiter counter
  356.     JR    EATLP        ; And continue
  357.  
  358. ;...............................
  359.  
  360. IGNORE:    LD    A,(SQZFLG)    ; For squeezed files, nothing else to do
  361.     OR    A
  362.     JP    NZ,USQZIT    ; Go to it
  363.  
  364. IGNRLP:    CALL    GETCHR        ; Loop absorbs extraneous header info
  365.     JR    C,NCRNCH    ; Circumvent possible hangup (eof before 0)
  366.     OR    A        ; Wait for the terminating zero
  367.     JR    Z,ATEIT        ; If terminating zero is reached
  368.     CP    1        ; do we have a date stamp?
  369.     JR    NZ,IGNOR2    ; (no)
  370.  
  371.     LD    B,15        ; 15 bytes in date string
  372.     LD    DE,DATBUF    ; DE -> date buffer
  373. DATLP:    CALL    GETCHR
  374.     JR    C,NCRNCH
  375.     OR    A
  376.     JR    Z,ATEIT
  377.     CP    0FFh        ; if it's FFh, make it 0
  378.     JR    NZ,NOTFFH
  379.     CPL
  380. NOTFFH:    LD    (DE),A
  381.     INC    DE
  382.     DJNZ    DATLP
  383.     LD    A,0FFh
  384.     LD    (DATFLG),A
  385.     JR    IGNRLP
  386.  
  387. IGNOR2:    CP    '['        ; Else check for date stamp bof char
  388.     JR    NZ,IGNRLP    ; Other chars are extraneous at this point
  389.  
  390. ;...............................
  391.  
  392.     LD    DE,STAMP    ; Start copying file stamp info to this buffer
  393.     JR    ENTSLP
  394.  
  395. STMPLP:    CALL    GETCHR        ; Get a char
  396.     JP    C,NCRNCH    ; Circumvent hangup
  397. ENTSLP:    LD    (DE),A        ; Put char in dest
  398.     INC    DE        ; Incr dest pntr
  399.     OR    A
  400.     JR    NZ,STMPLP    ; Loop till zero is reached
  401.  
  402. ;...............................
  403.  
  404. ATEIT:    CALL    GETCHR        ; Get revision level, do nothing with it
  405.     LD    A,(YFLAG)    ; is it lzh?
  406.     OR    A
  407.     JR    NZ,YATEIT    ; (yes, check significant revision below)
  408.     CALL    GETCHR        ; Get significant revision level
  409.     CP    SIGREV        ; Compare to this prog
  410.     JP    C,OLDTYP    ; Br if old type1x crunched file
  411.     JR    Z,SIGOK        ; If equal, ok, else...
  412. YATERR:    LD    DE,ERR5        ; "can't uncrunch that file. newer revision of
  413.     JP    SKIP2        ; - this program needed" or some such remark
  414.  
  415. YATEIT:    CALL    GETCHR
  416.     CP    SIGRVY+1    ; compare to significant revision
  417.     JR    NC,YATERR    ; doesn't match
  418.     JP    OLDTYP        ; continue
  419.  
  420. SIGOK:    CALL    GETCHR        ; Get checksum flag
  421.     LD    (CKSMFL),A    ; Put it there
  422.     CALL    GETCHR        ; Get spare byte, do nothing with it
  423.     CALL    OPNOUT        ; Open output file & type "--->  <filename>"
  424.     PUSH    AF        ; Save stat from above
  425.     CALL    PRNID        ; Type any embedded date stamp info also
  426.     POP    AF
  427.     JP    C,SKIP2A    ; If user wants to skip it
  428.  
  429. ;.......................................................................
  430. ;
  431. ; Now both files are open.  Eventually either both will be closed, or
  432. ; the input file will be closed and the output deleted.
  433.  
  434.     LD    A,(QUIFM)    ; Skip column headings if in quiet mode
  435.     OR    A
  436.     JR    NZ,QUIET1
  437.     LD    DE,HEADNG    ; Type all the "in / out  ca  cr" stuff
  438.     CALL    MESAGE
  439.  
  440. QUIET1:    CALL    INITB2        ; Initialize the lzw table
  441.     LD    DE,NOPRED    ; Init to "NOPRED" (null value)
  442.  
  443. ;=======================================================================
  444. ;
  445. ;         *** Main Decoding loop(s). ***
  446. ;
  447. ;=======================================================================
  448.  
  449. MAINLP:    LD    (LASTPR),DE    ; Always keep a copy of the last "pred" here
  450.     CALL    GETCOD        ; Get bits to form a a new code in "DE"
  451.     JP    C,DUN        ; Br if eof node or physical end-of-file
  452.     PUSH    DE        ; Push a copy of the new pred
  453.     CALL    DECODE        ; Decode new pred
  454.     LD    HL,ENTFLG    ; Flag is "01" if "decode" made the entry
  455.     SRL    (HL)        ; Check (and zero) the flag
  456.     JR    C,NOENTR    ; Don't make the same entry twice!
  457.     LD    HL,(LASTPR)    ; Get old pred
  458.     LD    A,(CHAR)    ; And suffix char generated from the new pred
  459.     CALL    ENTERX        ; Make new table entry from those two
  460.  
  461. NOENTR:    POP    DE        ; Get newest pred again (not that new anymore)
  462.     LD    A,(FULFLG)    ; Monitor the table full flag
  463.     OR    A
  464.     JR    Z,MAINLP    ; Continue decoding & entering 'till full
  465.  
  466. ;...............................
  467.  
  468.     CP    0FEH        ; When this becomes "FF", we are done
  469.     JR    NZ,FASTLP    ; First it will become "FE", though. in that
  470.     INC    A        ; - case perf 1 more loop & change it to "FF"
  471.     LD    (FULFLG),A    ;
  472.     JR    MAINLP        ; One more!
  473.  
  474. ;.......................................................................
  475.  
  476. FASTLP:    LD    (LASTPR),DE    ; Table full loop similar to above ,except
  477.     CALL    GETCOD        ; - don't bother checking table full flag
  478.     JP    C,DUN        ; - call "ENTFIL", not "ENTERX" (for possible
  479.     PUSH    DE        ; - code reassignment
  480.     CALL    DECODE        ; Call to actually decode chars
  481.     LD    HL,(LASTPR)    ; Get old pred
  482.     LD    A,(CHAR)    ; And suffix char generated from the new pred
  483.     CALL    ENTFIL        ; Possibly make new table entry from those two
  484.     POP    DE
  485.     JR    FASTLP        ; Continue in code reassignment mode
  486.  
  487. ;        *** End of Main Processing Loop(s)
  488. ;_______________________________________________________________________
  489. ;
  490. ; Come here when one of the special codes is encountered (we may not
  491. ; really be "dun").  Actually, a null code should have been intercepted
  492. ; by the GET12 routine, leaving only EOF (actually done) or adaptive
  493. ; reset.
  494.  
  495. DUN:    LD    A,E        ; Some kind of special code encountered
  496.     CP    LOW(EOFCOD)    ; Actually done?
  497.     JR    Z,DUNDUN    ; Br if do
  498.     CP    LOW(RSTCOD)    ; Else better be reset (null was intercepted)
  499.     JP    NZ,FATBAD    ; File is invalid
  500.  
  501. ;.......................................................................
  502. ;
  503. ; --- Perform an adaptive reset ---
  504.  
  505.     LD    HL,0000        ; Reset entry # prior to table re-initialization
  506.     LD    (ENTRY),HL
  507.     LD    (TTOTAL),HL    ; Reset "codes reassigned"
  508.     XOR    A
  509.     LD    (FULFLG),A    ; Reset  "table full" flag
  510.     CALL    INITB2        ; Reset the entire table
  511.     LD    A,9        ; Reset the code length to "9"
  512.     LD    (CODLEN),A
  513.     LD    A,02H        ; Reset the target mask value accordingly
  514.     LD    (TRGMSK),A
  515.  
  516.     LD    DE,NOPRED    ; Set pred to "nopred"
  517.     LD    A,1        ; 1st entry is always a special case
  518.     LD    (ENTFLG),A    ; (trick it to make no table entry)
  519.     JP    MAINLP        ; And continue where we left off
  520.  
  521. ;_______________________________________________________________________
  522. ;
  523. ; --- Actually done, close things up ---
  524.  
  525. DUNDUN:    CALL    GETCHR        ; Get the checksum, always next
  526.     LD    E,A
  527.     CALL    GETCHR        ; Get checksum (hi-byte)
  528.     LD    D,A        ; Checksum (from input file) now in "DE"
  529.     LD    A,(CKSMFL)    ; Checksum override flag (not currently used)
  530.     AND    A        ; Check flag, also clear carry for below
  531.     JR    NZ,CHKSOK    ; If flag > 0, don't check checksum
  532.  
  533. DUNDUQ:    LD    HL,(CHKSUM)    ; Checksum (as computed)
  534.     SBC    HL,DE        ; Else check by subtraction
  535.     JR    Z,CHKSOK    ; Br if match
  536.     LD    DE,BADCHK    ; Bad checksum, issue warning
  537.     CALL    MESAGE
  538.  
  539. ;...............................
  540.  
  541. CHKSOK:    CALL    DONE        ; Write out remaining output buffer
  542.  
  543. CLOSE2:    CALL    CLSOUT        ; Close output file
  544.     CALL    CLSIN        ; Close input file
  545.     JR    NEXT
  546.  
  547. ;.......................................................................
  548.  
  549. COPY9:    CALL    COPY        ; Perform a straight copy
  550.     JP    C,NXTFIL    ; If copy didn't take place, don't count it
  551.  
  552. NEXT:    CALL    DATSTP        ; Move date stamp
  553.     LD    HL,(NFP)    ; If we got here, the file has been "processed"
  554.     INC    HL        ; So incr the "files processed" counter
  555.     LD    (NFP),HL
  556.     JP    NXTFIL        ; Go start next file
  557.  
  558. ;.......................................................................
  559.  
  560. SKIP1:    CALL    MESAGE        ; Entry if neither in nor output files open yet
  561.  
  562. SKIP1A:    JP    NXTFIL        ; (Entry here if no error text desired)
  563.  
  564. ;...............................
  565.  
  566. SKIP2:    CALL    MESAGE        ; Entry here if input file open only
  567.  
  568. SKIP2A:    CALL    CLSIN        ; (Entry here for no message)
  569.     JP    NXTFIL
  570.  
  571. ;.......................................................................
  572. ;
  573. ; The following routine actually performs the decoding.  The top section
  574. ; "DECODE" flags the entry as "referenced".  It then calls the recursive
  575. ; section below it, "DECODR", to do the actual work.
  576.  
  577. DECODE:    PUSH    DE        ; Save code. the code provides us an immediate
  578.     EX    DE,HL        ;   index into the main logical table
  579.  
  580.     LD    A,H        ; (Add offset to beg of table, of course)
  581.     ADD    A,TABLHI
  582.     LD    H,A
  583.     SET    5,(HL)        ; Set bit 5 of pred (hi) to flag entry as
  584.     POP    DE        ; - "referenced" (ie not bumpable)
  585.  
  586. ;.......................................................................
  587.  
  588. DECODR    EQU    $        ; Decode and output the index supplied in "DE"
  589.  
  590.     LD    IY,STKLIM    ; Stack overflow check as a safety precaution
  591.     ADD    IY,SP        ; (limit allows extra for this invocation lvl)
  592.     JP    NC,STKOVF    ; Br on overflow (shouldn't happen)
  593.  
  594.     PUSH    HL        ; Only "HL" need be saved
  595.  
  596.     LD    A,D        ; Convert index in "DE" to address in "HL"
  597.     ADD    A,TABLHI
  598.     LD    H,A
  599.     LD    L,E        ; Address now in "HL"
  600.  
  601.     LD    A,(HL)        ; Make sure the entry exists
  602.     AND    0DFH
  603.     CP    80H        ; (Value for a vacant entry)
  604.     JR    NZ,OK1        ; Br if so (normal case)
  605.  
  606. ;...............................
  607.  
  608.     LD    A,01H        ; The "ugly" exception, wswsw
  609.     LD    (ENTFLG),A    ; Set flag so entry isn't made twice
  610.     PUSH    HL        ; Save current stuff.
  611.     LD    HL,(LASTPR)    ; Get the last pred..
  612.     LD    A,20H        ; (setting this flag will flag the entry as
  613.     LD    (FFFLAG),A    ; - referenced,)
  614.     LD    A,(CHAR)    ; Get the last char
  615.     CALL    ENTERX        ; Make an on the fly entry...
  616.     XOR    A
  617.     LD    (FFFLAG),A    ; Put this back to normal
  618.     POP    HL        ; And presto...
  619.     LD    A,(HL)        ; It had better exist now!
  620.     CP    80H
  621.     JR    Z,FATBAD    ; *** else file is fatally invalid ***
  622.  
  623. ;...............................
  624.  
  625. OK1:    LD    D,(HL)        ; Normal code- get "pred" (hi)
  626.     RIGHT1            ; Move to "pred" (lo)
  627.     LD    E,(HL)        ; Get that. if MSB of hi byte is set, val must
  628.     BIT    7,D        ; - be "FF" (nopred) because it isn't "80H"
  629.     JR    NZ,TERM        ; If so, branch. this terminates recursion.
  630.     RES    5,D        ; Else clear flag bit & decode pred we found
  631.     CALL    DECODR        ; Decode and output the "pred" (recursive call)
  632.     RIGHT1            ; Move pointer ahead to the "suffix" byte
  633.     LD    A,(HL)        ; Get it
  634.  
  635. SAMABV:    CALL    SEND        ; Output the "suffix" byte
  636.     POP    HL        ; Restore reg and return
  637.     RET
  638.  
  639. TERM:    RIGHT1            ; Move pointer ahead to the suffix byte
  640.     LD    A,(HL)        ; Get it & save it. it is the 1st char of the
  641.     LD    (CHAR),A    ; - decoded string, and will be used later to
  642.     JR    SAMABV        ; - attempt to make a new table entry.
  643.                 ; (rest is same as above)
  644.  
  645. ;_______________________________________________________________________
  646.  
  647. FATBAD:    LD    DE,ERR4        ; "invalid crunched file"
  648.     CALL    MESAGE        ; ..print it
  649.     JP    CHKSOK        ; Write out whatever we have, then next file
  650.                 ; (Stack gets reloaded before next file)
  651.  
  652. ;_______________________________________________________________________
  653. ;
  654. ; Enter { <pred>, <suffix> } into the table, as defined in { HL, A }
  655.  
  656. ENTERX:    PUSH    AF        ; Save the suffix till we're ready to enter it
  657.     PUSH    HL        ; Save pred, xferred to "DE" just below
  658.     CALL    FIGURE        ; Puts result in "phyloc" only, affects nothing
  659.     POP    DE        ; Put pred in "DE" (pushed as "HL" above)
  660.     LD    HL,(ENTRY)    ; Get next avail entry #
  661.     LD    A,H        ; Convert that to an address
  662.     ADD    A,TABLHI
  663.     LD    H,A
  664.  
  665. ; Entries are made here, but not normally flagged as "referenced" until
  666. ; the are received by "DECODE".  Until they are flagged as referenced,
  667. ; theyare "bumpable" i.e., available for code reassignment.  If "FFFLAG"
  668. ; is set to 20H, however, they will be flagged now.  This only occurs
  669. ; during initialization (bumping an atomic entry would be most unfortu-
  670. ; nate) and when a WsWsW string encounter initiates an emergency entry,
  671. ; despite the code never having been received by "DECODE".
  672.  
  673.     LD    A,(FFFLAG)    ; Normally zero, as described above
  674.     OR    D
  675.     LD    (HL),A        ; Make the entry- pred (hi) first
  676.     RIGHT1            ; Move to pred (lo) position
  677.     LD    (HL),E        ; Put that in
  678.     RIGHT1            ; Move to suffix position
  679.     POP    AF        ; Retrieve the suffix, saved on entry
  680.     LD    (HL),A        ; Stick it in
  681.     LD    HL,(ENTRY)    ; Increment the entry # counter
  682.     INC    HL
  683.     LD    (ENTRY),HL
  684.     INC    HL        ; See if a new code length is indicated. the
  685.     LD    A,(TRGMSK)    ; - extra inc "HL" above is to account for
  686.     CP    H        ; - skew delays of uncruncher vs. cruncher
  687.     RET    NZ        ; Normally just return
  688.  
  689.     SLA    A        ; Change to a new code length
  690.     LD    (TRGMSK),A    ; This will be the next target mask
  691.     LD    A,(CODLEN)    ; Get the old code length, as a # of bits
  692.     INC    A        ; Increment it, too
  693.     CP    13        ; Check for overflow (12 bits is the max)
  694.     JR    Z,FLGFUL    ; If so, flag table as full
  695.     LD    (CODLEN),A    ; Else this is the new code length
  696.     RET
  697.  
  698. ;...............................
  699.  
  700. FLGFUL:    LD    A,0FEH        ; Flag table as full
  701.     LD    (FULFLG),A
  702.     RET
  703.  
  704. ;.......................................................................
  705. ;
  706. ; Get the next code by stripping the appropriate # of bits off the input
  707. ; stream, based on the current code length "CODLEN".  If the code is
  708. ; "NULL", don't even return; just get another one.  If the code is one
  709. ; of the other special codes, return with the carry flag set. "Spare" is
  710. ; actually treated like a "null" for the time being, since it's use has
  711. ; yet to be defined.
  712.  
  713. GETCOD:    LD    DE,0000        ; Init "shift register" to zero
  714.     LD    A,(CODLEN)    ; Get current code length
  715.     LD    B,A        ; Will be used as a loop counter
  716.     LD    A,(CSAVE)    ; "leftover" bits
  717.  
  718. GETLP:    SLA    A        ; Shift out a bit
  719.     CALL    Z,REF        ; Refill when necessary
  720.     RL    E        ; Shift in the bit shifted out
  721.     RL    D        ; Likewise
  722.     DJNZ    GETLP        ; Loop for # of bits needed
  723.  
  724.     LD    (CSAVE),A    ; Save "leftover" bits for next time
  725.     LD    A,D        ; If hi-byte = "01", we may have a special code
  726.     DEC    A        ; Set z if it was "1"
  727.     AND    A        ; Clr carry
  728.     RET    NZ        ; Rtn w/ clr carry if byte wasn't "01"
  729.  
  730. ;...............................
  731.  
  732.     LD    A,E        ; Else further analysis necessary
  733.     CP    4        ; Set carry on 100, 101, 102, 103
  734.     RET    NC        ; Else code is normal, rtn with clr carry
  735.     CP    LOW(NULCOD)    ; Is it the "NULL" code?
  736.     JR    Z,GETCOD    ; If so, just go get another code
  737.     CP    LOW(SPRCOD)    ; (treat the unimplemented "spare" like a null)
  738.     JR    Z,GETCOD    ; As above
  739.  
  740.     SCF            ; < rtn with carry set indicating special code
  741.     RET            ; (presumably "EOF" or "reset")
  742.  
  743. ;_______________________________________________________________________
  744. ;
  745. ; Routine to reload "A" with more bits from the input stream.  Note we
  746. ; pre-shift out the next bit, shifting in a "1" from the left.    Since
  747. ; the leftmost bit in the reg is a guaranteed "1", testing the zero
  748. ; stat of the  accumulator later is a necessary and sufficient condition
  749. ; for determining that all the bits in the accumulator have been used.
  750. ;
  751. ; The only things to be careful of is that the last bit is NOT used la-
  752. ; ter, and that the bit now in the carry flag IS used upon return from
  753. ; this    subroutine.  (This is the identical scheme used in USQFST.  An
  754. ; exact complement to it is incorporated for shifting bits out in the
  755. ; CRUNCH program).
  756.  
  757. REF:    CALL    GETCHR        ; Get the char
  758.     JR    C,PHYEOF    ; Br if unexpected physical eof encountered
  759.     SCF            ; To shift in the "1" from the right
  760.     RLA            ; Do that, shifting out a "real" bit
  761.     RET            ; Rtn (with that real bit in the carry flag)
  762.  
  763. ;_______________________________________________________________________
  764.  
  765. PHYEOF:    LD    SP,TOPSTK    ; "Emergency exit"- reset stack
  766.     LD    DE,UNXEOF    ; "Unexpected eof."
  767.     CALL    MESAGE
  768.     JP    CHKSOK        ; Write out what we have, then continue
  769.  
  770. ;_______________________________________________________________________
  771. ;
  772. ; Send character to the output buffer, plus related processing
  773.  
  774. SEND:    EXX            ; Alt regs used for output processing
  775.     SRL    B        ; If reg is "1", repeat flag is set
  776.                 ; (note, clears itself automatically)
  777.     JR    C,REPEAT    ; Go perf the repeat
  778.     CP    90H        ; Else see if char is the repeat spec
  779.     JR    Z,SETRPT    ; Br if so
  780.     LD    C,A        ; Else nothing special- but always keep
  781.     EXX            ; Back to normal regs
  782.     CALL    OUTC        ; Else just output the char;
  783.     RET
  784.  
  785. ;.......................................................................
  786. ;
  787. ; Set repeat flag; count value will come as the next byte. (Note: don't
  788. ; clobber C with the "90H"- it still has the prev character, the one to
  789. ; be repeated)
  790.  
  791. SETRPT:    INC    B        ; Set flag
  792.     EXX            ; Switch to primary regs & return.
  793.     RET
  794.  
  795. ;.......................................................................
  796. ;
  797. ; Repeat flag was previously set; current byte in a is a count value.
  798. ; A zero count is a special case which means send 90H itself.  Otherwise
  799. ; use B (was the flag) as a counter. The byte itself goes in A.
  800.  
  801. REPEAT:    OR    A        ; Check for special case
  802.     JR    Z,SND90H    ; Jump if so
  803.     DEC    A        ; Compute "count-1"
  804.     LD    B,A        ; Juggle registers
  805.     PUSH    BC        ; The count and the char
  806.     LD    B,0        ; Zero the count in advance
  807.     EXX
  808.     POP    BC
  809.  
  810. AGAIN:    LD    A,C
  811.     PUSH    BC
  812.     CALL    OUTC        ; Repeat b occurrences of byte in 'c'
  813.     POP    BC
  814.     DJNZ    AGAIN        ; Leaves b, the rpt flag, 0 as desired
  815.     RET
  816.  
  817. ;...............................
  818.  
  819. SND90H:    LD    A,90H        ; Special case code to send the byte 90h
  820.     EXX
  821.     CALL    OUTC
  822.     RET
  823.  
  824. ;.......................................................................
  825. ;
  826. ; Send the char in "A" to the output buffer and add it to the running
  827. ; checksum.
  828.  
  829. OUT    EQU    $
  830. OUTC:    CALL    OUTB        ; Output it
  831.     CALL    CKSUM        ; Add to the checksum
  832.     RET
  833.  
  834. ;_______________________________________________________________________
  835. ;
  836. ; Convert the middle letter of the filename extension to a "Z" if it is
  837. ; "?", AND "difdu" = 0.  If we are uncrunching to a different DU:, get
  838. ; all files.
  839.  
  840. FIXFCB:    LD    A,(DIFDU)
  841.     OR    A
  842.     RET    NZ        ; If this flag is set, leave ext char untouched
  843.     LD    HL,INFCB+10    ; Point to middle letter of extension
  844.     LD    A,'?'
  845.     CP    (HL)        ; See if it is ambiguous
  846.     RET    NZ        ; If not, we'll allow any letter (rev v1.2)
  847.     LD    A,(TYPFL)    ; Else force it to configuration choice
  848.     LD    (HL),A        ; "Z", "Y", or "Q".  This is mainly so
  849.     RET            ; the command line "UNCR *.*" will work well
  850.  
  851. ;_______________________________________________________________________
  852. ;
  853. ; Flag files to be copied, not uncompressed
  854.  
  855. EXCLUD:    LD    BC,12        ; Leave 12 in bc for incrementing ix
  856.     LD    IX,FNBUFF    ; Points to beg of filenames
  857.  
  858. OUTLP:    LD    A,(IX+0)    ; Get flag byte for this entry
  859.     CP    0FFH        ; Final [non-] entry?
  860.     RET    Z        ; (return if so)
  861.  
  862.     OR    A        ; Is it an untagged filename?
  863.     JR    Z,NXTFN        ; If so, leave it that way & move to next
  864.     LD    A,(IX+10)    ; Otherwise check middle letter of fn ext
  865.     CP    'Z'
  866.     JR    Z,NXTFN        ; If 'z', do not exclude it
  867.     CP    'Y'
  868.     JR    Z,NXTFN        ; nor if it's 'y'
  869.     CP    'Q'
  870.     JR    Z,NXTFN        ; Likewise 'q', else "exclude" it
  871.  
  872. ;-----------------------------------------------------------------------
  873.  
  874. AUTOM3:    LD    A,02H        ; Flag file as "excluded"
  875.     LD    (IX+0),A
  876.  
  877. NXTFN:    ADD    IX,BC        ; Move to next filename in "fnbuff"
  878.     JR    OUTLP
  879.  
  880. ;_______________________________________________________________________
  881. ;
  882. ; Type the stuff in the "stamp" buffer to the console.
  883.  
  884. PRNID:    LD    HL,STAMP    ; Point to that buffer
  885.     LD    B,40        ; Practical limit of 40 char "stamp"
  886.     LD    A,(HL)        ; is there a text string?
  887.     OR    A
  888.     RET    Z        ; (nope)
  889.     LD    A,' '        ; for aesthetics
  890.     CALL    TYPE
  891. PRFILP:    LD    A,(HL)        ; Get a character
  892.     OR    A        ; Zero terminates the field
  893.     RET    Z        ; Return when encountered
  894.     CALL    TYPE        ; Else type the char
  895.     CP    ']'        ; This terminates stamp also (after typing it)
  896.     RET    Z        ; Return if that happened
  897.     INC    HL        ; Else incr pointer
  898.     DJNZ    PRFILP        ; And loop
  899.     RET
  900.  
  901. ;_______________________________________________________________________
  902.  
  903. STKOVF:    LD    DE,ERR6        ; "*** stack overflow ***"
  904.     LD    SP,TOPSTK    ; Shouldn't happen, but we're still in control
  905.     JP    FATBAD        ; Reset and continue with next file, if any
  906.  
  907. ;_______________________________________________________________________
  908. ;
  909. ; Initialize the table to contain the 256 "atomic" entries - { "NOPRED",
  910. ; <char> },  for all values of <char> from 0 thru 255
  911.  
  912. INITB2:    CALL    PRESE2        ; "pre-initializes" the table (mostly zeroes)
  913.     LD    A,20H
  914.     LD    (FFFLAG),A
  915.     XOR    A        ; Start with a suffix of zero
  916.     LD    HL,NOPRED    ; Pred for all 256 atomic entries
  917.  
  918. INILP:    PUSH    HL
  919.     PUSH    AF
  920.     CALL    ENTERX
  921.     POP    AF
  922.     POP    HL
  923.     INC    A        ; Next suffix
  924.     JR    NZ,INILP    ; Loop 256 times
  925.  
  926. ;.......................................................................
  927. ;
  928. ; Now reserve the four reserved codes 100H - 103H (EOF, RESET, NULL, and
  929. ; SPARE.  This is easily achieved by inserting values in the table which
  930. ; cannot possibly be matched, and insuring that they cannot be reas-
  931. ; signed.  An occurrence of any of these codes is possible only when the
  932. ; cruncher explicitely outputs them for the special cases for which they
  933. ; are designated.
  934.  
  935.     LD    B,4        ; Loop counter for the 4 reserved entries
  936.  
  937. RSRVLP:    PUSH    BC
  938.     LD    HL,IMPRED    ; An "impossible" pred
  939.     XOR    A        ; Any old suffix will do
  940.     CALL    ENTERX        ; Make the entry
  941.     POP    BC
  942.     DJNZ    RSRVLP        ; Loop 4 times
  943.  
  944.     XOR    A        ; Now restore this flag to its normal value
  945.     LD    (FFFLAG),A
  946.     RET
  947.  
  948. ;.......................................................................
  949. ;
  950. ; Low-level table preset called before initialization above. This rou-
  951. ; tine presets the main table as follows: (see description of table
  952. ; elsewhere):  Column 1: 4096 x 80H, Columns 2 and 3: 4096 x 00H
  953.  
  954. PRESE2:    LD    HL,TABLE    ; Beginning of main table, 4096 rows x 3 columns
  955.     LD    DE,TABLE+1
  956.     LD    BC,1000H
  957.     LD    (HL),80H
  958.     LDIR            ; Put in 1000h "80H"'s
  959.     LD    (HL),0        ;
  960.     LD    BC,2*1000H-1    ; Note "-1"
  961.     LDIR            ; And 2000h more "00H"'s
  962.  
  963. ;.......................................................................
  964. ;
  965. ; The auxiliary physical translation table is 5003 rows 2 columns
  966. ; (logically speaking).  Actually 5120 rows, 2 columns are allocated.
  967. ; All entries are initialized to 80H.
  968.  
  969.     LD    HL,XLATBL    ; Physical <--> logical xlation table
  970.     LD    DE,XLATBL+1
  971.     LD    BC,2800H    ; Total entries = 1400h x 2
  972.     LD    (HL),80H
  973.     LDIR
  974.     LD    A,7FH
  975.     LD    (XLATBL+0),A
  976.     RET
  977.  
  978. ;_______________________________________________________________________
  979. ;
  980. ; Figure out what physical location the cruncher put its entry by repro-
  981. ; ducing the hashing process.  Insert the entry # into the corresponding
  982. ; physical location in XLATBL.
  983.  
  984. FIGURE:    LD    B,A        ; < suffix supplied goes into B
  985.     CALL    HASH        ; Get initial hash value into  "HL"
  986.  
  987. PHYLP:    LD    C,H        ; C  <-- extra copy of h
  988.     LD    A,(HL)        ; Check if any entry exists at that location
  989.     CP    80H        ; Value for a vacant spot
  990.     JR    Z,ISMT        ; Br if vacant
  991.     CALL    NM        ; Else find next in chain
  992.     JR    PHYLP        ; And continue
  993.  
  994. ;...............................
  995.  
  996. ISMT:    LD    DE,(ENTRY)    ; Get the logical entry #
  997.     LD    (HL),D        ; Stick in hi-byte
  998.     LD    A,H        ; Move "right1" for this table
  999.     ADD    A,14H
  1000.     LD    H,A
  1001.     LD    (HL),E        ; Low-byte goes there
  1002.     RET
  1003.  
  1004. ;...............................
  1005.  
  1006. NM    EQU    $        ; No match yet... find next "link" in chain
  1007.  
  1008.     LD    DE,(DISP)    ; Secondary probe- add disp computed by "HASH"
  1009.     ADD    HL,DE
  1010.     LD    A,H
  1011.     CP    XLATBH        ; Check for loop around
  1012.     JR    NC,NC9        ; Br if not
  1013.     LD    DE,5003        ; Else loop
  1014.     ADD    HL,DE
  1015.  
  1016. NC9:    RET
  1017.  
  1018. ;.......................................................................
  1019.  
  1020. ENTFIL    EQU    $        ; Try to enter the pred/suffix in HL|A
  1021.  
  1022.     CALL    HASH        ; Get initial hash value into  "HL"
  1023.  
  1024. ;.......................................................................
  1025.  
  1026. PHYLP2:    LD    A,(HL)        ; Check if any entry exists at that location
  1027.     CP    80H        ;
  1028.     RET    Z        ; End of chain, return w/o reassignment
  1029.  
  1030. ;...............................
  1031.  
  1032.     PUSH    HL        ; Save physical table pointer
  1033.     LD    D,(HL)        ; Get entry #, hi
  1034.     LD    A,H        ; }
  1035.     ADD    A,14H        ; } right 1 for this table
  1036.     LD    H,A        ; }
  1037.     LD    L,(HL)        ; Entry #, lo byte
  1038.     LD    A,D
  1039.     ADD    A,TABLHI    ; Convert to an addr in "HL"
  1040.     LD    H,A
  1041.     BIT    5,(HL)        ; See if entry is bumpable
  1042.     JR    Z,MAKIT        ; If so bumpable, go do it
  1043.     POP    HL        ; Else restore physical tbl pointer
  1044.     CALL    NM        ; Find next "link" in chain
  1045.     JR    PHYLP2        ; And continue
  1046.  
  1047. ;.......................................................................
  1048. ;
  1049. ; Reassign the entry pointed to by "avail", if any. Re-define the "last
  1050. ; pred entered" and "last suffix" variables.
  1051.  
  1052. MAKIT:    POP    DE        ; Get rid of extraneous physical pointer
  1053.     LD    DE,(TTOTAL)    ; Increase user's display count
  1054.     INC    DE
  1055.     LD    (TTOTAL),DE
  1056.     LD    DE,(LASTPR)    ; Get the pred
  1057.     LD    A,(CHAR)    ; And suffix
  1058.     LD    B,A        ; Put suffix here, ("right1" kills a)
  1059.     LD    (HL),D        ; Actually make the entry
  1060.     RIGHT1
  1061.     LD    (HL),E        ; [pred(lo)]
  1062.     RIGHT1
  1063.     LD    (HL),B        ; [suffix]
  1064.     RET            ; Done
  1065.  
  1066. ;.......................................................................
  1067. ;
  1068. ; For additional details about the hashing algorithm, see CRUNCH.
  1069.  
  1070. HASH    EQU    $
  1071.  
  1072.     LD    E,L        ; Save so low-nybble of pred can be used below
  1073.     ADD    HL,HL
  1074.     ADD    HL,HL
  1075.     ADD    HL,HL
  1076.     ADD    HL,HL        ; Shift whole pred value left 4 bits
  1077.     XOR    H        ; Xor hi-byte of that with suffix
  1078.     LD    L,A        ; Goes there as lo-byte of result
  1079.     LD    A,E        ; Get pred(lo) saved above
  1080.     AND    0FH        ; Want only low nybble of that
  1081.     ADD    A,XLATBH    ; Convenient time to add in table offset
  1082.     LD    H,A        ; Goes here as hi-byte of result
  1083.     INC    HL        ; Except add one. this eliminates poss. of 0.
  1084.     PUSH    HL        ; Save hash val for return
  1085.     LD    DE,-5003-XLATBL    ; Compute displacement value, - (5003-hash)
  1086.     ADD    HL,DE        ; (displacement has table offset removed again)
  1087.     LD    (DISP),HL    ; Secondary hashing value, a negative number.
  1088.     POP    HL        ; Get back orig hash address
  1089.     RET            ; And return it
  1090.  
  1091. ;=======================================================================
  1092. ;
  1093. ; For old style (v1.x) type crunched files, simply call the "UNCR1"
  1094. ; module.  LZH-encoded and squeezed files are handled identically,
  1095. ; except call "UNLZH" and "USQREL" modules, respectively.  All I/O
  1096. ; will be done by this program -- UNCR1 will get and feed data through
  1097. ; calls to entry points "GETBYT" and "OUT".  UNLZH will use "GLZHUN"
  1098. ; and "PLZHUN".
  1099.  
  1100. OLDTYP:    CALL    GETCHR        ; Get checksum flag
  1101.     LD    (CKSMFL),A    ; Put it there
  1102.     CALL    GETCHR        ; Get spare byte, do nothing with it *** nec??
  1103.  
  1104. USQZIT:    LD    A,0FFH        ; Flag this as an old style uncrunch
  1105.     LD    (OLDFLG),A    ; (controls type of screen updating)
  1106.     CALL    OPNOUT        ; Open output file & type "--> <filename>"
  1107.     PUSH    AF        ; Save stat from abv call
  1108.     LD    A,(SQZFLG)    ; *** necessary?
  1109.     OR    A
  1110.     CALL    Z,PRNID        ; Type any embedded id text also
  1111.     POP    AF        ; Get back carry stat
  1112.     JP    C,SKIP2A    ; If user wants to skip it
  1113.  
  1114.     LD    A,(QUIFM)
  1115.     OR    A
  1116.     LD    DE,HEADNY    ; Type all the "in / out" stuff
  1117.     CALL    Z,MESAGE
  1118.  
  1119.  
  1120.     EXX            ; Go back to start of file (already read some)
  1121.     LD    HL,IBUF
  1122.     EXX
  1123.  
  1124. FIX21:    LD    HL,SECNT    ; Bugger up the sector count since we just
  1125.     INC    (HL)        ; - reset the input pointer
  1126.     LD    HL,(INCTR)    ; [rev 2.1 fix]
  1127.     DEC    HL        ; Decr "inctr" for same reason
  1128.     LD    (INCTR),HL
  1129.     LD    A,'0'        ; [Rev 2.1 fix]
  1130.     LD    (PROGBF+5),A    ; Reset ascii display to zero
  1131.     LD    HL,TABLE    ; Point to large data area for uncr1 & lzh
  1132.     LD    A,(YFLAG)
  1133.     OR    A
  1134.     JR    NZ,USELZH    ; if lzh-encoded, call unlzh
  1135.     LD    A,(SQZFLG)
  1136.     OR    A
  1137.     JR    NZ,USESQZ    ; If squeezed, call usqrel
  1138.     CALL    UNCR1        ; Uncrunch the whole thing
  1139.  
  1140. ABVQ:    JP    NC,DUNDUN    ; A "normal" return
  1141.     JP    FATBAD        ; Any other error falls under "invalid.."
  1142.  
  1143. USESQZ:    CALL    USQREL        ; unsqueeze it
  1144.     LD    DE,(SQCKSM)    ; Get checksum read at beginning of file
  1145.     JP    NC,DUNDUQ    ; Terminate similarly (w/o reading cksm bytes)
  1146.     JP    FATBAD
  1147.  
  1148. USELZH:    CALL    UNLZH        ; uncrunch it a la lzh
  1149.     JR    ABVQ        ; check return
  1150.  
  1151. ;_______________________________________________________________________
  1152.  
  1153. PRCSTM:    LD    DE,PRSER1    ; "invalid argument" (no stamps allowed)
  1154.     JP    FATALU
  1155.  
  1156. ;_______________________________________________________________________
  1157.  
  1158. UCASE:    CP    'a'        ; Upper-case character in A
  1159.     RET    C
  1160.     SUB    20H        ; (Note "{","|","}",and "~" cannot occur)
  1161.     RET
  1162.  
  1163. ;_______________________________________________________________________
  1164. ;
  1165. ; All ASCII centralized here as a service to disassembly hobbyists.
  1166.  
  1167. INTRO:    DB    'LZH Uncruncher  Version ',VERS/10+'0','.',VERS MOD 10+'0'
  1168.     DB    SUBVERS,CR,LF,'$'
  1169. BADCHK:    DB    'Checksum error.',CR,LF,'$'
  1170. MSG43:    DB    '    [ Not compressed ]',CR,LF,'$'
  1171. ERR4:    DB    'Invalid Crunched File.',CR,LF,'$'
  1172. ERR5:    DB    'Requires newer version.',CR,LF,'$'
  1173. ERR6:    DB    'Stack Overflow.',CR,LF,'$'
  1174. UNXEOF:    DB    'Unexpected EOF.',CR,LF,'$'
  1175. USAGE:    DB    'Usage:',CR,LF
  1176.     DB    '   $'
  1177. PRGNAM:    DB    'UNCRLZH '        ; must end with space if < 8 characters
  1178. COMNAM:    DB    '        '
  1179. SYNTX1:    DB    ' {d$'
  1180. SYNTX2:    DB    ':}afn {d$'
  1181. USAGE1:    DB    ':} {/options}',CR,LF
  1182.     DB    'Second parameter is destination.',CR,LF
  1183.     DB    'Options following slash:',CR,LF
  1184.     DB    '   Q   Quiet mode o$'
  1185. USAGE2:    DB    CR,LF
  1186.     DB    '   I   Inspect (Tag) mode o$'
  1187. USAGE3:    DB    CR,LF
  1188.     DB    '   T   Same as I',CR,LF
  1189.     DB    '   E   $'
  1190. USAGE4:    DB    'Erase existing files$'
  1191. USAGE5:    DB    CR,LF
  1192.     DB    '   S   $'
  1193. USAGE6:    DB    'clude System files$'
  1194.  
  1195. ;=======================================================================
  1196.  
  1197. ; ** Include file begins here **
  1198.  
  1199.     INCLUDE    COMMONLZ.LIB
  1200.  
  1201. ; ** Include file ends here **
  1202. ;=======================================================================
  1203. ; - File I/O
  1204.  
  1205. PLZHUN    EQU    OUTC        ; for UNLZH module 'puts' thru this label
  1206. GLZHUN    EQU    GETBYT        ; for UNLZH module 'gets' thru this lable
  1207.  
  1208. ;=======================================================================
  1209.  
  1210. ; Additional miscellaneous ram locations which need not be initialized
  1211. ; or are initialized by the routines which use them.
  1212.  
  1213. CKSMFL:    DS    1        ; Skip checksum if flag non-zero
  1214. CHAR:    DS    1        ; Last char of the previously decoded string
  1215. FFFLAG:    DS    1
  1216. CSAVE:    DS    1
  1217. SQCKSM:    DS    2        ; squeezed file checksum
  1218. YFLAG:    DS    1        ; non-zero = LZH crunched file
  1219.  
  1220. ;...............................
  1221.  
  1222. STKSZ    EQU    8        ; Minimum stack size (pages)
  1223. IBUFSZ    EQU    8        ; Input buffer size (pages)
  1224.  
  1225. ;=======================================================================
  1226. ;
  1227. ; ===>    All tables will begin at "MEMPAG", defined at the top of the
  1228. ;    program.  This should be set to a page aligned value i.e., ad-
  1229. ;    dress that ends  in "00", which is ABOVE the end all program
  1230. ;    and data segments.  You may have to do one test link to deter-
  1231. ;    mine the proper value (changing "MEMPAG" will not change the
  1232. ;    length of the segments on the subsequent link).
  1233. ;
  1234. ; "MEMPAG" is defined at the beginning of this program to remind you to
  1235. ; set it properly.  If you set it higher than necessary, there will be
  1236. ; no negative effect other than an increase in the TPA required to run
  1237. ; the program.    If you set it too low, you will be in big trouble.  The
  1238. ; value must be set manually because most linkers cannot resolve an
  1239. ; "and", "shift", or "hi" byte extraction at link time to determine the
  1240. ; page boundary.
  1241. ;
  1242. ;=======================================================================
  1243.  
  1244. ; "MAXFLS" is  buffer size (in files) for wildcard expansions.    Room for
  1245. ; this many files will be allocated.
  1246.  
  1247. MAXFLS    EQU    256
  1248.  
  1249. FNBUFF    EQU    MEMPAG           ; (= beg of wildcard expansion buffer)
  1250. ENDFNB    EQU    FNBUFF+(12*MAXFLS) ; End of expansion buffer
  1251.  
  1252. IBUF    EQU    ENDFNB           ; (= beg of input buffer)
  1253. EIBUF    EQU    IBUF+(IBUFSZ*256)  ; End of input buffer
  1254.  
  1255. TABLE    EQU    EIBUF           ; (= beg of table)
  1256. EOTBL    EQU    TABLE+(3*1000H)       ; End of table
  1257. XLATBL    EQU    EOTBL
  1258. EXLATB    EQU    XLATBL+(2*1400H)
  1259. STAMP    EQU    EXLATB           ; 80h bytes for "stamp" buffer
  1260. ESTAMP    EQU    STAMP+80H
  1261.  
  1262. SAFETY    EQU    ESTAMP           ; Safety region- beyond legal bottom of stack
  1263. BOTSTK    EQU    SAFETY+80H       ; "Legal" stack limit
  1264. TOPSTK    EQU    EXLATB+(STKSZ*256) ; Top of stack
  1265.  
  1266. ENDALL    EQU    TOPSTK           ; End of everything, except output buffer
  1267. OBUF    EQU    ENDALL           ; Beginning of dynamically sized output buffer
  1268.  
  1269. ;.......................................................................
  1270.  
  1271. STKLIM    EQU    0-BOTSTK    ; Negation of "botstk", used as safety check
  1272.  
  1273. IBUFHI    EQU    HIGH IBUF    ; Input bfr addr, hi byte (lo byte = 0)
  1274. EIBFHI    EQU    HIGH EIBUF    ; End of input bfr addr, hi byte, likewise
  1275. TABLHI    EQU    HIGH TABLE    ; Beg of table, hi byte, likewise
  1276. ETBLHI    EQU    HIGH EOTBL    ; End of table, hi byte, likewise
  1277. XLATBH    EQU    HIGH XLATBL
  1278. EFNBHI    EQU    HIGH ENDFNB    ; End of expansion buffer, likewise
  1279. ENDHI    EQU    HIGH ENDALL    ; End of everything, likewise
  1280. OBUFHI    EQU    HIGH OBUF    ; Output buffer address, hi byte likewise
  1281.  
  1282.     END
  1283.