home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
robot-pd
/
19306.ZIP
/
19306B.DSK
/
#splitt.ras
< prev
next >
Wrap
Text File
|
1998-02-03
|
2KB
|
76 lines
org &4000
nolist
XOR A ; A l|schen => A=0
CALL &BC0E ; Mode 0
LD HL,&C9FB
LD (&38),HL
EI ; Interrupt abfangen
LD BC,&BC02 ; die folgenden OUTs dienen zum Verschieben
OUT (C),C ; und Strecken des Screens, zum vollen Genuss des Splitrasters!
LD BC,&BD32 ; f}r Bad CRTC &BD31 !
OUT (C),C
LD BC,&BC01
OUT (C),C
LD BC,&BD2F
OUT (C),C
frame LD B,&F5
IN A,(C)
RRA
JR NC,frame ; Frame Fly Back
HALT
HALT
HALT ; warten, bis Rasterstrahl im Bild
DEFS 30 ; auf Anfang der Zeile warten
LD HL,tab ; Adresse des Anfangs der Farbtabelle
LD B,10 ; 10 Zeilen sollen gerastert werden
splitloop DEFS 3 ; Zeilensynchronisation: warten
LD C,B ; Schleifenz{hler zwischenspeichern
LD B,&7F ; Portadresse Gate Array
XOR A ; A l|schen => A=0
OUT (C),A ; Ink 0
LD A,(HL) ; aktuellen Farbwert aus Tabelle lesen
OUT (C),A ; 1. Farbe ausgeben
INC HL ; Tabellenzeiger erh|hen
LD A,(HL)
OUT (C),A ; 2. Farbe ausgeben
INC HL
LD A,(HL)
OUT (C),A ; 3. Farbe
INC HL
LD A,(HL)
OUT (C),A ; 4. Farbe
INC HL
LD A,(HL)
OUT (C),A ; 5. Farbe
INC HL
LD A,(HL)
OUT (C),A ; 6. Farbe
INC HL
LD B,C ; Schleifenz{hler zur}ckholen
DJNZ splitloop ; n{chste der 10 Zeilen
LD B,&7F
LD C,84
OUT (C),C ; Farbe schwarz (84) ausgeben
JP frame ; und n{chster Screenaufbau
; Farbtabelle mit 10 x 6 Werten
tab defb 68,69,92,86,68,64
defb 85,69,76,82,85,84
defb 85,71,76,82,85,64
defb 87,71,78,74,87,64
defb 83,75,74,75,83,75
defb 83,75,74,75,83,75
defb 87,71,78,74,87,64
defb 85,71,76,82,85,64
defb 85,69,76,82,85,84
defb 68,69,92,86,68,64
; Interrupt abfangen
LD BC,&BC0