home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ZSYS / SIMTEL20 / SYSLIB / SLIB3.LBR / SPADC.Z80 < prev    next >
Text File  |  2000-06-30  |  1KB  |  71 lines
  1. ;
  2. ; SYSLIB Module Name:  SPADC
  3. ; Author:  Richard Conn
  4. ; SYSLIB Version Number:  3.6
  5. ; Module Version Number:  1.2
  6.  
  7.     public    pa3dc,padc
  8.  
  9.     EXT    COUT
  10.  
  11. ;
  12. ;  PA3DC --
  13. ;    PRINT REG A AS 3 DECIMAL CHARACTERS
  14. ;
  15. PA3DC:
  16.     PUSH    BC    ; SAVE REGS
  17.     PUSH    DE
  18.     PUSH    AF    ; SAVE A
  19.     LD    D,0    ; TURN OFF LEADING <SP> FLAG
  20.     JP    PADC1
  21. ;
  22. ;  PADC --
  23. ;    PRINT REG A AS DECIMAL CHARACTERS W/LEADING <SP> IN 3-CHAR FIELD
  24. ;
  25. PADC:
  26.     PUSH    BC    ; SAVE REGS
  27.     PUSH    DE
  28.     PUSH    AF    ; SAVE A
  29.     LD    D,1    ; TURN ON LEADING <SP> FLAG
  30. ;
  31. ;  PRINT ROUTINE
  32. ;
  33. PADC1:    LD    B,100    ; PRINT HUNDREDS
  34.     CALL    PAC    ; PRINT A CHAR
  35.     LD    B,10    ; PRINT TENS
  36.     CALL    PAC
  37.     ADD    '0'    ; CONVERT TO ASCII
  38.     CALL    COUT    ; PRINT
  39.     POP    AF    ; RESTORE A
  40.     POP    DE    ; RESTORE REGS
  41.     POP    BC
  42.     RET
  43.  
  44. ;
  45. ;  PRINT RESULT OF DIVISION OF A BY B W/LEADING <SP> (INTEGER DIVISION)
  46. ;
  47. PAC:    LD    C,0    ; SET COUNT
  48. PACL:    SUB    B    ; COMPUTE COUNT
  49.     JP    C,PACD
  50.     INC    C    ; INCR COUNT
  51.     JP    PACL
  52. PACD:    ADD    A,B    ; ADD B BACK IN
  53.     LD    E,A    ; SAVE A
  54.     LD    A,C    ; GET COUNT
  55.     OR    A    ; ZERO?
  56.     JP    NZ,PACD1
  57.     OR    D    ; 0 MEANS NO LEADING <SP> (A=0, SO A OR D = 0 IF D=0)
  58.     JP    Z,PACD1
  59.     LD    A,' '    ; PRINT <SP>
  60.     CALL    COUT
  61.     LD    A,E    ; RESTORE A
  62.     RET
  63. PACD1:    LD    D,0    ; D=0 FOR NO LEADING <SP>
  64.     LD    A,C    ; GET COUNT
  65.     ADD    '0'    ; CONVERT TO DECIMAL
  66.     CALL    COUT    ; PRINT IT
  67.     LD    A,E    ; RESTORE A
  68.     RET
  69.  
  70.     END
  71.