home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / ZSYS / SIMTEL20 / SYSLIB / SLIB1.LBR / SACAS2.Z80 < prev    next >
Text File  |  2000-06-30  |  2KB  |  81 lines
  1. ;
  2. ; SYSLIB Module Name: ACASE2
  3. ; Author: Richard Conn
  4. ; SYSLIB Version Number: 3.6
  5. ; Module Version Number: 1.1
  6.  
  7.     public    acase2
  8.  
  9. ;
  10. ; ACASE2 is a acase2 statement processor.  On input, register A contains a
  11. ; value to test against and DE contains the address of the case table:
  12. ;
  13. ;    MVI    A,TEST    ; test value
  14. ;    LXI    D,TABLE    ; case table
  15. ;    CALL    ACASE2
  16. ;    ...
  17. ; TABLE:
  18. ;    DB    NUM$ENT    ; number of entries in CASE table
  19. ;    DW    DEFAULT    ; address to goto if no match in acase2
  20. ;    DB    VAL1    ; entry value 1 to test for
  21. ;    DW    ADDR1    ; address to goto if entry 1 matches
  22. ;    DB    VAL2    ; entry value 2 to test for
  23. ;    DW    ADDR2    ; address to goto if entry 2 matches
  24. ;    ...
  25. ;    DB    VALN    ; entry value N to test for (N = NUM$ENT)
  26. ;    DW    ADDRN    ; address to goto if entry N matches
  27. ;
  28. ; NUM$ENT is the number of values (VAL1 .. VALN) in the case table
  29. ;
  30. acase2:
  31.     ex    (sp),hl        ; return address in HL
  32.     ld    h,d    ; HL=DE=case table address
  33.     ld    l,e
  34.     push    af    ; save regs
  35.     push    bc
  36.     ld    b,(hl)    ; number of entries
  37.     inc    hl    ; pt to default
  38.     ld    (default),hl    ; save it
  39.     inc    hl    ; pt to first entry
  40.     inc    hl
  41. ;
  42. ; Loop through case table entries, looking for a match
  43. ;
  44. loop:
  45.     cp    (hl)    ; compare
  46.     jp    z,match
  47.     inc    hl    ; pt to next
  48.     inc    hl
  49.     inc    hl
  50.     dec    b    ; count down
  51.     jp    nz,loop
  52. ;
  53. ; No match found - use default
  54. ;
  55.     ld    hl,(default)    ; get default
  56.     jp    goto
  57. ;
  58. ; Match - use HL+1
  59. ;
  60. match:
  61.     inc    hl    ; point to address
  62. ;
  63. ; Get address in HL and return
  64. ;
  65. goto:
  66.     ld    a,(hl)    ; get low
  67.     inc    hl
  68.     ld    h,(hl)    ; get high
  69.     ld    l,a    ; HL = address
  70.     pop    bc    ; restore regs
  71.     pop    af
  72.     ex    (sp),hl        ; return address on stack, HL restored
  73.     ret
  74. ;
  75. ; Storage for default address
  76. ;
  77. default:
  78.     ds    2
  79.  
  80.     end
  81.