home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG084.ARK / XMODEM50.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  50KB  |  2,012 lines
  1. ;
  2. ;    XMODEM.ASM V5.0, by Keith Petersen, W8SDZ
  3. ;           (revised 6/8/82)
  4. ;
  5. ;    REMOTE CP/M - CP/M FILE TRANSFER PROGRAM
  6. ;
  7. ;Based on MODEM.ASM V2.0, by Ward Christensen.
  8. ;This program is intended for use on remote CP/M
  9. ;systems where it is important that the initialization
  10. ;of the modem not be changed, such as when using
  11. ;the PMMIBYE program. The baud rate and number of bits
  12. ;remains the same as whatever was set previously.
  13. ;There is no disconnect, terminal or echo option.
  14. ;
  15. ;Updates/fixes (in reverse order to minimize reading time):
  16. ;
  17. ;6/8/82    Added file transfer logging  feature. Enabled  with
  18. ;         the  equate  variable LOGCAL,  it uses  caller 
  19. ;        info   provided  by  the  RCPM  file   LASTCALR 
  20. ;        together with transferred file name,  size  and 
  21. ;        direction of transfer to append each successful 
  22. ;        transfer to new special file LOG.SYS.  The user 
  23. ;        area designation for LASTCALR must be specified 
  24. ;         by the variable LASTUSR and file is expected to 
  25. ;        reside on the DEFDRV drive. The support library 
  26. ;        SEQIO.LIB(vrs >=2.2) and the MAC assembler  are 
  27. ;        needed   ONLY if LOGCAL is true.  If logging is 
  28. ;        not desired,  or you don't have MAC then LOGCAL 
  29. ;        may  be  set false and the ASM  assembler  will 
  30. ;        work.  See  SEQIO.LIB for documentation on  the 
  31. ;        support  code.  Also made mods to  file  length 
  32. ;        printout  to  give  times for  600  baud  (PMMI 
  33. ;        only). This is optional with the LSPEED equate. 
  34. ;        If  used,  the baud rate of caller must be made 
  35. ;        available  thru  location  MSPEED(by  the   BYE 
  36. ;        program).             Jack Riley
  37. ;04/18/82 Corrected transfer time calculations. Added optional
  38. ;      equate, VOUT for sector count display to
  39. ;      console output. (Must be CRT type device)
  40. ;      Changed modem data port equates into 2 distinct
  41. ;      booleans to accomodate a wider variety of customized
  42. ;      EXTMOD equated modems.
  43. ;      Changed NOCOMR option on receive to  automatic
  44. ;      renaming of  .COM extents to .OBJ. (Howard Booker)
  45. ;
  46. ;04/01/82 Added routine to ERASE any file not properly received
  47. ;      (gets rid of all those damn 0K files) - thanks
  48. ;      to Skip Hansen for this one. - BHK
  49. ;
  50. ;03/28/82 Added cancel facility - if first char received 
  51. ;      when waiting for initial nak is control-X it will
  52. ;      cancel sending (useful for when the time estimate
  53. ;      is longer than you want to wait). - BHK
  54. ;
  55. ;03/22/82 Added calculation of estimated transmission time
  56. ;      when sending a file - divide # sectors by ~ 8 sectors
  57. ;      per minute transmission speed (at 300 baud) - BHK
  58. ;
  59. ;03/08/82 Added Bruce Wood's designated user and drive area
  60. ;         routines to the original ver. 46 which contained
  61. ;         the DCH modem updates which were first included
  62. ;         on 10/19/81.  Then renamed to ver. 48A to distinguish
  63. ;         from the first ver. 48.  (Bill Aten)
  64. ;
  65. ;01/06/82 Added code to implement designated user and drive
  66. ;       area to receive files on.  This was put in to
  67. ;      make it easier to locate new programs and for drives
  68. ;      that are write protected. This change will put the file
  69. ;      being sent into the designated area and when done return
  70. ;      to the orginal area.
  71. ;      SEE SETAREA LABEL IN THE CONDITIONAL SECTION  (Bruce Wood)
  72. ;
  73. ;10/19/81 Corrected numerous 'IN MODCTL2' errors for the DC
  74. ;      Hayes modem.  Added DC Hayes detection of framing
  75. ;      errors, overrun errors, and parity errors (if
  76. ;      parity is used) for the receive file routine.
  77. ;      (Bill Aten)
  78. ;
  79. ;10/12/81 Added code to implement Cyclic Redundancy
  80. ;      Checking for both receiving and sending files.
  81. ;      The CRC can only be specified by the operator
  82. ;      on the receive file option as a secondary
  83. ;      option of 'C' (XMODEM RC FN.FT).  When CRC is
  84. ;      in effect, an initial 'C' instead of a NAK will
  85. ;      be sent to the sender to start things off.
  86. ;      The 'C' will be the signal to the sender
  87. ;      (hopefully a version of MODEM that implements
  88. ;      this CRC convention) that CRC is in effect.
  89. ;      CRC will then take the place of the checksum
  90. ;      checking for data validity.  The CRC should
  91. ;      make file transfers as far as data integrity is
  92. ;      concerned better than 99.99% error free.  The
  93. ;      crc macro, CRC120, was used to implement CRC
  94. ;      in this program and its equivalent version of
  95. ;      MODEM.  Acknowledgements and thanks to Paul
  96. ;      Hansknecht who designed and wrote CRC120.
  97. ;
  98. ;07/01/81 REDID H8/H89 EQUATES TESTED PROGRAM USING BOTH
  99. ;      SYSTEMS AND CHANGED VER TO 4.4    (AL OLANDER)
  100. ;
  101. ;06/28/81 INSTALL H8/H89 EQUATES AND CHANGE EXTERNAL
  102. ;      MODEM EQUATES TO "EXTMOD". (L. SHIPINSKI)
  103. ;
  104. ;05/30/81 Added IF PMMI/ENDIF to RCVERR routine to eliminate
  105. ;      'undefined symbol' error when set for DCH modem.
  106. ;      (Dave Hardy)
  107. ;
  108. ;05/07/81 Changed signon revision number.
  109. ;      Cleaned up file. (KBP)
  110. ;
  111. ;05/01/81 Added detection of framing errors, overrun
  112. ;      errors, and parity errors (if parity is used)
  113. ;      for the receive file routine.  This feature
  114. ;      is only active for the PMMI modem, since I
  115. ;      do not know what the modem status bits are
  116. ;      for IDS and D.C. Hayes modems.  If there
  117. ;      is one of the above errors, the line will
  118. ;      be purged for that block and a NAK will be
  119. ;      sent to the sender for that block.  This was
  120. ;      added to help catch those transmission errors
  121. ;      that are not always caught by the checksum.
  122. ;      This error checking is in addition to the
  123. ;      checksum routine. (John Mahr)
  124. ;
  125. ;02/17/81 Added test for "f2" tagged files in OPENOK
  126. ;      for MP/M version 1.1 compatiblity, which
  127. ;      doesn't allow Ctl-C or Ctl-S in "f1" tagged
  128. ;      files. (Tim Nicholas)
  129. ;
  130. ;02/16/81 Added hex to file size display. Now reports
  131. ;      size in both decimal and (xxxxH) hex. Thanks
  132. ;      to Ben Bronson for the idea. (Tim Nicholas)
  133. ;
  134. ;02/15/81 Added a software timer to the carrier test
  135. ;      added in SEND and RECV routines. This will
  136. ;      now abort only if carrier is lost for a 
  137. ;      period of 15 seconds. This is only essential
  138. ;      for those using external modems with certain
  139. ;      SIO's, but will provide the PMMI/DCH user
  140. ;      faster recovery in a lost carrier situation
  141. ;      as well. Approx 15 seconds plus 15 seconds
  142. ;      in BYE.COM, compared to 3 minutes at 300
  143. ;      baud with earlier revisions. Thanks to Ben
  144. ;      Bronson for his aid in developing this
  145. ;      revision. (Tim Nicholas)
  146. ;
  147. ;02/14/81 Corrected error in last update which read
  148. ;      the incorrect port for PMMI in the added
  149. ;      carrier test. (Tim Nicholas)
  150. ;    
  151. ;01/31/81 Added equates and code for a carrier test.
  152. ;      Test performed in modem I/O routines. This
  153. ;      is required since loss of carrier will go
  154. ;      undetected by BYE.COM, if the loss occurs
  155. ;      after a sucessful XMODEM signon, when using
  156. ;      an external modem and SIO. (Tim Nicholas)
  157. ;
  158. ;01/17/81 Re-wrote routine to calculate file size so
  159. ;         that it works correctly on v2.X systems with
  160. ;         extent folding (non-zero extent mask). (BRR)
  161. ;
  162. ;12/06/80 Re-wrote routine to calculate file size,
  163. ;      added decimal print of file size. (KBP)
  164. ;
  165. ;12/05/80 Corrected error in use of ext byte that pre-
  166. ;      vented files greater than one extent from 
  167. ;      being sent.     Ron Fowler
  168. ;
  169. ;12/03/80 Corrected file extent length display. Now
  170. ;      reports correct number of records for files
  171. ;      longer than one extent. Display is now
  172. ;      double precision (xxxxH). Also made some
  173. ;      cosmetic changes by re-arranging the equates.
  174. ;      By Tim Nicholas
  175. ;
  176. ;10/28/80 Cleaned up file. (KBP)
  177. ;
  178. ;10/23/80 Expanded conditional assembly of NOCOM routines
  179. ;      into NOCOMS, NOLBS, and NOCOMR equates, to allow
  180. ;      separate conditional assembly of tests for sending
  181. ;      .COM files, sending .??# files, and receiving .COM
  182. ;      files, respectively.    (Dave Hardy)
  183. ;
  184. ;10/15/80 Added traps for ambiguous file name or
  185. ;      none at all. (KBP)
  186. ;
  187. ;09/09/80 Added conditional assembly to prevent filetypes
  188. ;      '.COM' or '.??#' from being sent to distant end
  189. ;      and added conditional assembly of test for '.COM'
  190. ;      filetype on receive as well. See 'NOCOM' below.
  191. ;      Any filetype ending in '#' will not be sent by
  192. ;      this program if 'NOCOM' is set to TRUE.  J.SEYMOUR
  193. ;
  194. ;NOTE: If you add improvements or otherwise update
  195. ;this program, please modem a copy of the new file
  196. ;to "TECHNICAL CBBS" in Dearborn, Michigan - phone
  197. ;313-846-6127 (110, 300, 450 or 600 baud).  Use the
  198. ;filename XMODEM.NEW.    (KBP)
  199. ;
  200. FALSE    EQU    0
  201. TRUE    EQU    NOT FALSE
  202. ;
  203. ;-----------------------------------------------------
  204. ;     --- Conditional Assembly Options ---          ;
  205. ;------------------------------------------------------
  206. ;
  207. STDCPM    EQU    TRUE    ;TRUE, IS STANDARD CP/M
  208. ALTCPM    EQU    FALSE    ;TRUE, IS TRS-80 OR H8 W/O 0-ORG
  209. ;
  210. PMMI    EQU    TRUE    ;TRUE, IS PMMI
  211. DCH    EQU    FALSE    ;TRUE, IS D.C. HAYES
  212. H8    EQU    FALSE    ;TRUE, IS H8/H89 W/INS8250 MODEM CHIP
  213. EXTMOD    EQU    FALSE    ;TRUE, IS NONE OF THE ABOVE!
  214. ;
  215. NOCOMS    EQU    TRUE    ;TRUE, NO .COM FILES SENT
  216. NOLBS    EQU    TRUE    ;TRUE, NO .??# FILES SENT
  217. NOCOMR    EQU    TRUE    ;TRUE, CHANGE.COM TO.OBJ ON RECEIVE
  218. ;
  219. FASTCLK EQU    TRUE    ;PUT TRUE HERE FOR 4 MHZ CLOCK
  220. ;
  221. FRNTPNL    EQU    FALSE    ;TO DISPLAY STATUS ON FRONT PANEL
  222. PANEL    EQU    0FFH    ;DEFAULT ADDRESS OF FRONT PANEL
  223. ;
  224. SETAREA    EQU    TRUE    ;TRUE, IF USING DESIGNATED AREA TO RECEIVE 
  225. RECU    EQU    0    ;USER AREA TO REC IN (NOT GREATER THAN 9)
  226. DEFDRV    EQU    'A'    ;DRIVE TO REC TO
  227. ;
  228. ;    FILE TRANSFER LOGGING OPTIONS    (J. Riley)
  229. LOGCAL    EQU    true     ;IF USING LOGGING OF XMODEM TRANSFERS
  230. LASTUSR    EQU    15    ;USER AREA OF 'LASTCALR' FILE (IF 'LOGCAL' ONLY)
  231. ;
  232. LSPEED    EQU    true     ;REPORT DIFFERENCES IN BAUD RATES IN PRINTOUT
  233. MSPEED    EQU    3EH    ;LOCATION OF CURRENT BAUD RATE FACTOR(set by BYE)
  234. ;
  235. VOUT    EQU    00000H    ;ADR OF VIDEO DRIVER IF OPTIONAL SECTOR
  236.             ;COUNT TO CONSOLE, ELSE LEAVE AS 0000H
  237. ;
  238. ;
  239. ;------------------------------------------------------
  240. ;         --- Modem Port Equates ---           ;
  241. ;------------------------------------------------------
  242. ;
  243.     IF    PMMI
  244. MODCTLP EQU    0C0H    ;PMMI VALUES(base port addr)
  245. MODSNDB EQU    1    ;BIT TO TEST FOR SEND
  246. MODSNDR EQU    1    ;VALUE WHEN READY
  247. MODRCVB EQU    2    ;BIT TO TEST FOR RECEIVE
  248. MODRCVR EQU    2    ;VALUE WHEN READY
  249. MODDCDB    EQU    4    ;CARRIER DETECT BIT
  250. MODDCDA    EQU    0    ;VALUE WHEN ACTIVE
  251. MODPARE    EQU    08H    ;VALUE FOR PARITY ERROR
  252. MODOVRE    EQU    10H    ;VALUE FOR OVERRUN ERROR
  253. MODFRME    EQU    20H    ;VALUE FOR FRAMING ERROR
  254. MODDATP EQU    MODCTLP+1;DATA PORT, RECEIVE
  255. MODDATO    EQU    MODCTLP+1;DATA PORT, SEND
  256. BAUDRP    EQU    MODCTLP+2;BAUD RATE OUTPUT/MODEM STATUS
  257. B600    EQU    1AH    ;FACTOR FOR B600 BAUD
  258. MODCTL2 EQU    MODCTLP+3;SECOND CTL PORT
  259.     ENDIF
  260. ;
  261.     IF    H8
  262. MODCTLP    EQU    0DDH    ;H8/H89 VALUES (LSR-LINE STATUS REG.)
  263. MODSNDB    EQU    20H    ;TEST FOR SEND (LSR-THRE)
  264. MODSNDR    EQU    20H    ;VALUE WHEN READY
  265. MODRCVB    EQU    01H    ;TEST FOR RECIEVE (LSR-DR)
  266. MODRCVR    EQU    01H    ;VALUE WHEN READY
  267. MODDCDB    EQU    20H    ;CARRIER DETECT BIT (MSR-CTS)
  268. MODDCDA    EQU    20H    ;VALUE WHEN ACTIVE
  269. MODPARE    EQU    04H    ;VALUE FOR PARITY ERROR (LSR-PE)
  270. MODOVRE    EQU    02H    ;VALUE FOR OVERRUN ERROR (LSR-OR)
  271. MODFRME    EQU    08H    ;VALUE FOR FRAMING ERROE (LSR-FE)
  272. MODDATP    EQU    0D8H    ;DATA PORT, RECIEVE
  273. MODDATO    EQU    0D8H    ;DATA PORT, SEND
  274. BAUDRP    EQU    0DDH    ;BAUD RATE PORT (DALB IN LCR MUST=1)
  275. MODCTL2    EQU    0DEH    ;MODEM STATUS REGISTER (MSR)
  276. MODCTL1    EQU    0DBH    ;LINE CONTROL REGISTER (LCR)
  277.     ENDIF
  278. ;
  279.     IF    DCH
  280. MODCTLP EQU    82H    ;D. C. HAYES VALUES
  281. MODSNDB EQU    2    ;BIT TO TEST FOR SEND
  282. MODSNDR EQU    2    ;VALUE WHEN READY
  283. MODRCVB EQU    1    ;BIT TO TEST FOR RECEIVE
  284. MODRCVR EQU    1    ;VALUE WHEN READY
  285. MODDCDB    EQU    40H    ;CARRIER DETECT BIT
  286. MODDCDA    EQU    40H    ;VALUE WHEN ACTIVE
  287. MODPARE    EQU    04H    ;VALUE FOR PARITY ERROR
  288. MODOVRE    EQU    10H    ;VALUE FOR OVERRUN ERROR
  289. MODFRME    EQU    08H    ;VALUE FOR FRAMING ERROR
  290. MODDATP EQU    80H    ;DATA PORT IN PORT
  291. MODDATO    EQU    80H    ;DATA OUT PORT
  292. MODCTL2 EQU    81H    ;SECOND CTL PORT
  293.     ENDIF
  294. ;
  295. ;If you are using an external modem (not S-100 plug-in)
  296. ;change these equates for your modem port requirements
  297. ;
  298.     IF    EXTMOD
  299. MODCTLP EQU    0C3H    ;PUT YOUR MODEM STATUS PORT HERE
  300. MODSNDB EQU    10H    ;YOUR BIT TO TEST FOR SEND
  301. MODSNDR EQU    10H    ;YOUR VALUE WHEN READY
  302. MODRCVB EQU    01H    ;YOUR BIT TO TEST FOR RECEIVE
  303. MODRCVR EQU    01H    ;YOUR VALUE WHEN READY
  304. MODDCDB    EQU    02H    ;CARRIER DETECT BIT
  305. MODDCDA    EQU    02H    ;VALUE WHEN ACTIVE
  306. MODDATP EQU    0C0H    ;YOUR MODEM DATA IN PORT
  307. MODDATO    EQU    0C2H    ;YOUR MODEM DATA OUT PORT
  308. MODCTL2    EQU    0C1H    ;SECOND CONTROL/STATUS PORT.
  309.     ENDIF        ;END OF EXTERNAL MODEM EQUATES
  310. ;
  311. ;        --- End of Options ---
  312. ;------------------------------------------------------
  313. ;
  314. ERRLIM    EQU    10    ;MAX ALLOWABLE ERRORS (10 STANDARD)
  315. ;
  316. ;Define ASCII characters used
  317. ;
  318. SOH    EQU    1    ;START OF HEADER
  319. EOT    EQU    4    ;END OF TRANSMISSION
  320. ACK    EQU    6    ;ACKNOWLEDGE
  321. NAK    EQU    15H    ;NEG ACKNOWLEDGE
  322. CRC    EQU    'C'    ;CRC REQUEST CHARACTER
  323. CAN    EQU    18H    ;CONTROL-X FOR CANCEL
  324. LF    EQU    10    ;LINEFEED
  325. CR    EQU    13    ;CARRIAGE RETURN
  326. ; 
  327.     IF    STDCPM
  328. BASE    EQU    0    ;CP/M BASE ADDRESS
  329.     ENDIF
  330. ;
  331.     IF    ALTCPM
  332. BASE    EQU    4200H    ;ALTERNATE CP/M BASE ADDRESS
  333.     ENDIF
  334. ;
  335.     ORG    BASE+100H
  336. ;
  337. ;
  338. ;Init private stack
  339. BEGIN    LXI    H,0    ;HL=0
  340.     DAD    SP    ;HL=STACK FROM CP/M
  341.     SHLD    STACK    ;..SAVE IT
  342.     LXI    SP,STACK ;SP=MY STACK
  343. ;
  344.     if    setarea
  345.     mvi    e,0ffh        ;get the current user area     a 01/06/82
  346.     mvi    c,user                        ;a 01/06/82
  347.     call    bdos                        ;a 01/06/82
  348.     sta    olduser        ;save user number here         a 01/06/82
  349.     mvi    c,curdrv    ;get the current drive         a 01/06/82
  350.     call    bdos                        ;a 01/06/82
  351.     sta    olddrv        ;save drive here         a 01/06/82
  352.     endif
  353. ;
  354.     CALL    ILPRT    ;PRINT:
  355.     DB    CR,LF
  356.     DB    'XMODEM ver 5.0V [CRC capable]',CR,LF,0
  357. ;
  358. ;GET OPTION
  359. ;
  360.     LDA    FCB+2    ;SECONDARY OPTION?
  361.     CPI    'C'    ;CRC CHECKING REQUESTED?
  362.     JNZ    CHKOPTN    ;NO, GO CHECK PRIMARY
  363.     LDA    FCB+1    ;GET PRIMARY OPTION
  364.     CPI    'R'    ;CRC VALID ONLY FOR RECEIVE
  365.     JNZ    OPTNERR    ;PRT MSG, ABORT
  366.     XRA    A    ;ZERO ACCUM
  367.     STA    CRCFLG    ;TURN ON CRC FLAG
  368. ;
  369. CHKOPTN    LDA    FCB+1    ;GET OPTION (S or R)
  370.     PUSH    PSW    ;SAVE OPTION
  371. ;
  372. ;Move the filename from FCB2 to FCB1
  373. ;
  374.     CALL    MOVEFCB
  375. ;
  376. ;Gobble up garbage chars from the line
  377. ;prior to receive or send
  378. ;
  379.     IN    MODDATP
  380.     IN    MODDATP
  381. ;
  382. ;Jump to appropriate function
  383. ;
  384.     POP    PSW    ;GET OPTION
  385.     IF    LOGCAL
  386.     PUSH    PSW    ;BUT SAVE IT
  387.     ENDIF
  388. ;
  389.     CPI    'S'    ;SEND..
  390.     JZ    SENDFIL ;..A FILE?
  391. ;
  392.     CPI    'R'    ;RECEIVE..
  393.     JZ    RCVFIL    ;..A FILE?
  394. ;
  395. ;Invalid option
  396. ;
  397. OPTNERR    CALL    ERXIT    ;EXIT W/ERROR
  398.     DB    '++INVALID OPTION ON XMODEM '
  399.     DB    'COMMAND++',CR,LF
  400.     DB    'Must be S for SEND; R or RC '
  401.     DB    'for RECEIVE',CR,LF,'$'
  402.  
  403.     IF    LOGCAL
  404.     MACLIB SEQIO22
  405.  
  406. BSIZE    EQU    80H
  407. FILERR    SET    EXIT
  408. BUFFERS    SET    DBUF
  409.  
  410. ;        THE FOLLOWING ALLOCATIONS ARE USED BY THE 'FILE' MACROS
  411. DEFAULT$USER:
  412.     DB    LASTUSR
  413. CUR$USER:
  414.     DB    0FFH
  415. DEFAULT$DISK:
  416.     DB    DEFDRV-'A'
  417. CUR$DISK:
  418.     DB    0FFH
  419. PGSIZE:    DW    0
  420.  
  421. LOGCALL    FILE    INFILE,CALLER,,LASTCALR,,BSIZE,,PUBLIC,TRUE
  422.     MVI    A,RECU
  423.     STA    DEFAULT$USER
  424.     FILE    APPEND,LOG,,LOG,SYS,BSIZE,,PUBLIC,TRUE
  425.  
  426.     POP    PSW    ; GET OPTION
  427.     PUT    LOG    ; PUT IT OUT TO LOG
  428.  
  429.     LDA    MSPEED    ; GET SPEED FACTOR
  430.     CMA
  431.     ADI    7EH    ; MAGIC NUMBER FOR PMMI MODEM SO WE CAN
  432.     PUT    LOG    ; PUT OUT A SINGLE LETTER CODE
  433.     LDA    PGSIZE    ; NOW THE PROGRAM SIZE(IN MINUTES TRANSFER TIME)
  434.     CALL    PNDEC
  435.     MVI    A,' '    ; BLANK
  436.     PUT    LOG
  437.  
  438. ;            LOG THE DRIVE AND USER AREA AS A PROMPT
  439.     LDA    FCB
  440.     ORA    A
  441.     JNZ    WDRV
  442.     MVI    C,25
  443.     CALL    @BDOS
  444.     INR    A
  445. WDRV:    ADI    'A'-1
  446.     PUT    LOG
  447.  
  448.     MVI    C,32        ; NOW THE USER AREA(AS DECIMAL NUMBER)
  449.     MVI    E,0FFH
  450.     CALL    @BDOS
  451.     CALL    PNDEC
  452.     MVI    A,'>'        ; MAKE IT LOOK LIKE A PROMPT
  453.     PUT    LOG
  454.  
  455.     LXI    H,FCB+1        ; NOW THE NAME OF THE FILE
  456.     MVI    B,11
  457.     CALL    PUTSTR
  458.  
  459.     MVI    A,' '        ; BLANK
  460.     PUT    LOG
  461.  
  462. CLOOP:    GET    CALLER        ; AND THE CALLER
  463.     CPI    EOF
  464.     JZ    QUIT
  465.     PUT    LOG
  466.     JMP    CLOOP
  467.  
  468. PNDEC:    CPI    10        ; TWO COLUMN DECIMAL FORMAT ROUTINE
  469.     JC    ONE        ; ONE OR TWO DIGITS TO AREA #?
  470.     JMP    TWO
  471. ONE:    PUSH    PSW
  472.     MVI    A,'0'
  473.     PUT    LOG
  474.     POP    PSW
  475. TWO:    MVI    H,0
  476.     MOV    L,A
  477.     CALL    DECOT
  478.     RET
  479.  
  480. DECOT:    PUSH    B
  481.     PUSH    D
  482.     PUSH    H
  483.     LXI    B,-10
  484.     LXI    D,-1
  485. ;
  486. DECOT2:    DAD    B
  487.     INX    D
  488.     JC    DECOT2
  489.     LXI    B,10
  490.     DAD    B
  491.     XCHG
  492.     MOV    A,H
  493.     ORA    L
  494.     CNZ    DECOT
  495.     MOV    A,E
  496.     ADI    '0'
  497.     PUT    LOG
  498.     POP    H
  499.     POP    D
  500.     POP    B
  501.     RET
  502.  
  503. PUTSTR:    MOV    A,M
  504.     PUSH    H
  505.     PUSH    B
  506.     PUT    LOG
  507.     POP    B
  508.     POP    H
  509.     INX    H
  510.     DCR    B
  511.     JNZ    PUTSTR
  512.     RET
  513.  
  514. QUIT:    FINIS    LOG
  515.     JMP    EXIT
  516.     ENDIF        ; LOGCAL
  517. ;
  518. * * * * * * * * * * * * * * * * * * * * *
  519. *                    *
  520. *    SENDFIL: SENDS A CP/M FILE    *
  521. *                    *
  522. * * * * * * * * * * * * * * * * * * * * *
  523. ;
  524. ;The CP/M file specified in the XMODEM command
  525. ;is transferred over the phone to another
  526. ;computer running MODEM with the "R" (receive)
  527. ;option.  The data is sent one sector at a
  528. ;time with headers and checksums, and re-
  529. ;transmission on errors.  
  530. ;
  531. SENDFIL CALL    TRAP    ;CHECK FOR NO NAME OR AMBIG. NAME
  532.     CALL    CNREC    ;COMPUTE # OF RECORDS.
  533.     CALL    OPENFIL ;OPEN THE FILE
  534.     MVI    E,80    ;WAIT 80 SEC..
  535.     CALL    WAITNAK ;..FOR INITIAL NAK
  536. ;
  537. SENDLP    CALL    RDSECT    ;READ A SECTOR
  538.     JC    SENDEOF ;SEND EOF IF DONE
  539.     CALL    INCRSNO ;BUMP SECTOR #
  540.     XRA    A    ;ZERO ERROR..
  541.     STA    ERRCT    ;..COUNT
  542. ;
  543. SENDRPT CALL    SENDHDR ;SEND A HEADER
  544.     CALL    SENDSEC ;SEND DATA SECTOR
  545.     LDA    CRCFLG    ;GET CRC FLAG
  546.     ORA    A    ;CRC IN EFFECT?
  547.     CZ    SENDCRC    ;YES, SEND CRC
  548.     CNZ    SENDCKS ;NO, SEND CKSUM
  549.     CALL    GETACK    ;GET THE ACK
  550.     JC    SENDRPT ;REPEAT IF NO ACK
  551.     JMP    SENDLP    ;LOOP UNTIL EOF
  552. ;
  553. ;File sent, send EOT's
  554. ;
  555. SENDEOF MVI    A,EOT    ;SEND..
  556.     CALL    SEND    ;..AN EOT
  557.     CALL    GETACK    ;GET THE ACK
  558.     JC    SENDEOF ;LOOP IF NO ACK
  559.     JMP    EXITLG    ;ALL DONE
  560. ;
  561. * * * * * * * * * * * * * * * * * * * * *
  562. *                    *
  563. *    RCVFIL: RECEIVE A FILE        *
  564. *                    *
  565. * * * * * * * * * * * * * * * * * * * * *
  566. ;
  567. ;Receives a file in block format as sent
  568. ;by another person doing "MODEM S FN.FT".
  569. ;Can be invoked by 'XMODEM R FN.FT' or
  570. ;by 'XMODEM RC FN.FT' if CRC is to be used.
  571. ;
  572. RCVFIL    CALL    TRAP    ;CHECK FOR NO NAME OR AMBIG. NAME
  573. ;
  574.     IF    NOCOMR
  575.     LXI    H,FCB+9 ;POINT TO FILETYPE
  576.     MVI    A,'C'    ;1ST LETTER
  577.     CMP    M    ;IS IT C ?
  578.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  579.     INX    H    ;GET 2ND LETTER
  580.     MVI    A,'O'    ;2ND LETTER
  581.     CMP    M    ;IS IT O ?
  582.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  583.     INX    H    ;GET 3RD LETTER
  584.     MVI    A,'M'    ;3RD LETTER
  585.     CMP    M    ;IS IT M ?
  586.     JNZ    CONTINU ;IF NOT, CONTINUE NORMALLY
  587.  
  588.     CALL    ILPRT    ; PRINT RENAMING MESSAGE
  589.     DB    'Auto Renaming Filetype To ".OBJ" '
  590.     DB    CR,LF,CR,LF,0
  591. ;
  592.     LXI    H,OBJEXT
  593.     LXI    D,FCB+9
  594.     MVI    B,3
  595. ALTEXT    MOV    A,M
  596.     STAX    D
  597.     INX    H
  598.     INX    D
  599.     DCR    B
  600.     JNZ    ALTEXT
  601.     JMP    CONTINU
  602.  
  603. OBJEXT    DB    'OBJ'
  604.     ENDIF
  605. ;
  606. CONTINU CALL    CHEKFIL ;SEE IF FILE EXISTS
  607.     CALL    MAKEFIL ;..THEN MAKE NEW
  608.     CALL    ILPRT    ;PRINT:
  609. ;
  610.     if    setarea
  611.     db    'NOTE: File Will Be Received On',cr,lf    ;         a 01/06/81
  612.     db    'Drive ',defdrv,' User ',recu+30H,cr,lf    ; tell this .a 01/06/81
  613.     endif
  614. ;
  615.     DB    'FILE OPEN - READY TO RECEIVE',CR,LF,0
  616. ;
  617. RCVLP    CALL    RCVSECT ;GET A SECTOR
  618.     JC    RCVEOT    ;GOT EOT
  619.     CALL    WRSECT    ;WRITE THE SECTOR
  620.     CALL    INCRSNO ;BUMP SECTOR #
  621.     CALL    SENDACK ;ACK THE SECTOR
  622.     JMP    RCVLP    ;LOOP UNTIL EOF
  623. ;
  624. ;Got EOT on sector - flush buffers, end
  625. ;
  626. RCVEOT    CALL    WRBLOCK ;WRITE THE LAST BLOCK
  627.     CALL    SENDACK ;ACK THE SECTOR
  628.     CALL    CLOSFIL ;CLOSE THE FILE
  629.     JMP    EXITLG    ;ALL DONE
  630. ;
  631. * * * * * * * * * * * * * * * * * * * * *
  632. *                    *
  633. *        SUBROUTINES        *
  634. *                    *
  635. * * * * * * * * * * * * * * * * * * * * *
  636. ;
  637. ;---->    TRAP: Check for no file name or ambiguous name
  638. ;
  639. TRAP    LXI    H,FCB+1 ;POINT TO FILE NAME
  640.     MOV    A,M    ;GET FIRST CHAR OF FILE NAME
  641.     CPI    ' '    ;ANY THERE?
  642.     JNZ    ATRAP    ;YES, CHECK FOR AMBIGOUS FILE NAME
  643.     CALL    ERXIT    ;PRINT MSG, EXIT
  644.     DB    '++NO FILE NAME SPECIFIED++',CR,LF,'$'
  645. ;
  646. ATRAP    MVI    B,11    ;11 CHARS TO CHECK
  647. ;
  648. TRLOOP    MOV    A,M    ;GET CHAR FROM FCB
  649.     CPI    '?'    ;AMBIGUOUS?
  650.     JZ    TRERR    ;YES, EXIT WITH ERROR MSG
  651.     INX    H    ;POINT TO NEXT CHAR
  652.     DCR    B    ;ONE LESS TO GO
  653.     JNZ    TRLOOP    ;NOT DONE, CHECK SOME MORE
  654.     RET        ;NO AMBIGUOUS NAME, RETURN
  655. ;
  656. TRERR    CALL    ERXIT    ;PRINT MSG, EXIT
  657.     DB    '++CAN''T USE WILD CARD OPTIONS++',CR,LF,'$'
  658. ;
  659. ;---->    RCVSECT: Receive a sector
  660. ;
  661. ;Returns with carry set if EOT received.
  662. ;
  663. RCVSECT XRA    A    ;GET 0
  664.     STA    ERRCT    ;INIT ERROR COUNT
  665. ;
  666. RCVRPT:
  667.     IF    PMMI OR H8 OR DCH
  668.     XRA    A    ;GET 0
  669.     STA    ERRCDE    ;CLEAR RECEIVE ERROR CODE
  670.     ENDIF
  671. ;
  672.     MVI    B,10    ;10 SEC TIMEOUT
  673.     CALL    RECV    ;GET SOH/EOT
  674.     JC    RCVSTOT ;TIMEOUT
  675. ;
  676.     IF    PMMI OR H8 OR DCH
  677.     CALL    RCVERR    ;TRANS ERROR?
  678.     JC    RCVSERR    ;CARRY SET IF ERROR
  679.     ENDIF
  680. ;
  681.     CPI    SOH    ;GET SOH?
  682.     JZ    RCVSOH    ;..YES
  683. ;
  684. ;Earlier versions of MODEM program send some nulls -
  685. ;ignore them
  686. ;
  687.     ORA    A    ;00 FROM SPEED CHECK?
  688.     JZ    RCVRPT    ;YES, IGNORE IT
  689.     CPI    EOT    ;END OF TRANSFER?
  690.     STC        ;RETURN WITH CARRY..
  691.     RZ        ;..SET IF EOT
  692. ;
  693. ;Didn't get SOH or EOT - 
  694. ;    -or-
  695. ;Didn't get valid header - purge the line,
  696. ;then send NAK.
  697. ;
  698. RCVSERR MVI    B,1    ;WAIT FOR 1 SEC..
  699.     CALL    RECV    ;..WITH NO CHARS
  700.     JNC    RCVSERR ;LOOP UNTIL SENDER DONE
  701.     LDA    CRCFLG    ;GET CRC FLAG
  702.     ORA    A    ;CRC IN EFFECT?
  703.     MVI    A,NAK    ;PUT NAK IN ACCUM
  704.     JNZ    RCVSER2    ;NO, SEND THE NAK
  705.     LDA    FIRSTIME;GET FIRST TIME SWITCH
  706.     ORA    A    ;HAS FIRST SOH BEEN RECEIVED?
  707.     MVI    A,NAK    ;PUT NAK IN ACCUM
  708.     JZ    RCVSER2    ;YES, THEN SEND NAK
  709.     MVI    A,CRC    ;TELL SENDER CRC IS IN EFFECT
  710. ;
  711. RCVSER2    CALL    SEND    ;..THE NAK or CRC request
  712.     LDA    ERRCT    ;ABORT IF..
  713.     INR    A    ;..WE HAVE REACHED..
  714.     STA    ERRCT    ;..THE ERROR..
  715.     CPI    ERRLIM    ;..LIMIT?
  716.     JC    RCVRPT    ;..NO, TRY AGAIN
  717. ;
  718. ;10 errors in a row -
  719. ;
  720. RCVSABT CALL    CLOSFIL ;KEEP WHATEVER WE GOT
  721.     CALL    ILPRT
  722.     DB    '++UNABLE TO RECEIVE BLOCK '
  723.     DB    '- ABORTING++',CR,LF,0
  724.     CALL    DELFILE    ;DELETE RECEIVED FILE            ; v48c smh
  725.     CALL    ILPRT    ;PRINT SECOND HALF OF MESSAGE
  726.     DB    '++INCOMPLETELY RECEIVED FILE '
  727.     DB    'DELETED++',CR,LF,0
  728.     JMP    EXIT    ;GIVE UP
  729. ;
  730. ;---->    DELFILE: Deletes the received file (used if receive aborts)
  731. ;                            ; v48c smh
  732. DELFILE LXI    D,FCB    ;POINT TO FILE            ; (whole routine)
  733.     MVI    C,ERASEF ;GET FUNCTION
  734.     CALL    BDOS    ;DELETE IT
  735.     INR    A    ;DELETE OK?
  736.     RNZ        ;..YES, RETURN
  737.     CALL    ERXIT    ;..NO, ABORT
  738.     DB    '++CAN''T DELETE RECEIVED FILE++',CR,LF,'$',0
  739. ;
  740. ;Timed out on receive
  741. ;
  742. RCVSTOT JMP    RCVSERR ;BUMP ERR CT, ETC.
  743. ;
  744. ;---->RCVERR: Checks to see if framing error, overrun, or
  745. ;        parity error occurred.
  746. ;    1. Error code (ERRCDE) was set in recv routine
  747. ;    2. ERRCDE=0 for no errors, ERRCDE<>0 for errors
  748. ;    3. If there has been an error, this routine sets
  749. ;        the carry bit on.
  750. ;
  751.     IF    PMMI OR H8 OR DCH
  752. RCVERR    PUSH    PSW    ;SAVE CHAR TRANSMITTED
  753.     LDA    ERRCDE    ;GET RECEIVE ERR CODE
  754.     ANA    A    ;IS IT ZERO?
  755.     JZ    RCVERR2    ;YES, NO ERROR
  756.     POP    PSW    ;RESTORE CHAR TRANSMITTED
  757.     STC        ;SET CARRY ON FOR ERROR
  758.     RET
  759. ;
  760. RCVERR2    POP    PSW    ;RESTORE CHAR TRANSMITTED
  761.     ORA    A    ;CLEAR CARRY BIT
  762.     RET
  763.     ENDIF
  764. ;
  765. ;Got SOH - get block #, block # complemented
  766. ;
  767. RCVSOH    XRA    A    ;ZERO ACCUM
  768.     STA    FIRSTIME;INDICATE FIRST SOH RECV'D
  769.     MVI    B,1    ;TIMEOUT = 1 SEC
  770.     CALL    RECV    ;GET SECTOR
  771.     JC    RCVSTOT ;GOT TIMEOUT
  772. ;
  773.     IF    PMMI OR H8 OR DCH
  774.     CALL    RCVERR    ;TRANS ERROR?
  775.     JC    RCVSERR    ;CARRY SET IF ERROR
  776.     ENDIF
  777. ;
  778.     MOV    D,A    ;D=BLK #
  779.     MVI    B,1    ;TIMEOUT = 1 SEC
  780.     CALL    RECV    ;GET CMA'D SECT #
  781.     JC    RCVSTOT ;TIMEOUT
  782. ;
  783.     IF    PMMI OR H8 OR DCH
  784.     CALL    RCVERR    ;TRANS ERROR?
  785.     JC    RCVSERR    ;CARRY SET IF ERROR
  786.     ENDIF
  787. ;
  788.     CMA        ;CALC COMPLEMENT
  789.     CMP    D    ;GOOD SECTOR #?
  790.     JZ    RCVDATA ;YES, GET DATA
  791. ;
  792. ;Got bad sector #
  793. ;
  794.     JMP    RCVSERR ;BUMP ERROR CT.
  795. ;
  796. RCVDATA MOV    A,D    ;GET SECTOR #
  797.     STA    RCVSNO    ;SAVE IT
  798.     MVI    C,0    ;INIT CKSUM
  799.     CALL    CLRCRC    ;CLEAR CRC COUNTER
  800.     LXI    H,BASE+80H ;POINT TO BUFFER
  801. ;
  802. RCVCHR    MVI    B,1    ;1 SEC TIMEOUT
  803.     CALL    RECV    ;GET CHAR
  804.     JC    RCVSTOT ;TIMEOUT
  805. ;
  806.     IF    PMMI OR H8 OR DCH
  807.     CALL    RCVERR    ;TRANS ERROR?
  808.     JC    RCVSERR    ;CARRY SET IF ERROR
  809.     ENDIF
  810. ;
  811.     MOV    M,A    ;STORE CHAR
  812.     INR    L    ;DONE?
  813.     JNZ    RCVCHR    ;NO, LOOP
  814.     LDA     CRCFLG    ;GET CRC FLAG
  815.     ORA    A    ;CRC IN EFFECT?
  816.     JZ    RCVCRC    ;YES, TO RECEIVE CRC
  817. ;
  818. ;Verify checksum
  819. ;
  820.     MOV    D,C    ;SAVE CHECKSUM
  821.     MVI    B,1    ;TIMEOUT LEN.
  822.     CALL    RECV    ;GET CHECKSUM
  823.     JC    RCVSTOT ;TIMEOUT
  824. ;
  825.     IF    PMMI OR H8 OR DCH
  826.     CALL    RCVERR    ;TRANS ERROR?
  827.     JC    RCVSERR    ;CARRY SET IF ERROR
  828.     ENDIF
  829. ;
  830.     CMP    D    ;CHECKSUM OK?
  831.     JNZ    RCVSERR ;NO, ERROR
  832. ;
  833. ;Got a sector, it's a duplicate if = previous,
  834. ;    or OK if = 1 + previous sector
  835. ;
  836. CHKSNUM    LDA    RCVSNO    ;GET RECEIVED
  837.     MOV    B,A    ;SAVE IT
  838.     LDA    SECTNO    ;GET PREV
  839.     CMP    B    ;PREV REPEATED?
  840.     JZ    RECVACK ;ACK TO CATCH UP
  841.     INR    A    ;CALC NEXT SECTOR #
  842.     CMP    B    ;MATCH?
  843.     JNZ    ABORT    ;NO MATCH - STOP SENDER, EXIT
  844.     RET        ;CARRY OFF - NO ERRORS
  845. ;
  846. ;---->    RCVCRC:    Receive the cyclic redundancy check
  847. ;        characters (2 bytes), and see if the crc
  848. ;        received matches the one calculated.
  849. ;        If they match, get next sector, else
  850. ;        send a NAK requesting the sector be
  851. ;        resent.
  852. ;
  853. RCVCRC    MVI    E,2    ;NUMBER OF BYTES TO RECEIVE
  854. ;
  855. RCVCRC2    MVI    B,1    ;1 SEC TIMEOUT
  856.     CALL    RECV    ;GET CRC BYTE
  857.     JC    RCVSTOT    ;TIMEOUT
  858. ;
  859.     IF    PMMI OR H8 OR DCH
  860.     CALL    RCVERR    ;TRANSMISSION ERROR?
  861.     JC    RCVSERR    ;YES, IF CARRY IS ON
  862.     ENDIF
  863. ;
  864.     DCR    E    ;DECREMENT NUM OF BYTES
  865.     JNZ    RCVCRC2    ;GET BOTH BYTES
  866.     CALL    CHKCRC    ;CHECK RCVD CRC AGAINST CALC'D CRC
  867.     ORA    A    ;IS CRC OKAY?
  868.     JZ    CHKSNUM    ;YES, GO CHECK SECTOR NUMBERS
  869.     JMP    RCVSERR    ;GO CHECK ERROR LIMIT AND SEND NAK
  870. ;
  871. ;Previous sector repeated, due to the last ACK
  872. ;being garbaged.  ACK it so sender will catch up 
  873. ;
  874. RECVACK CALL    SENDACK ;SEND THE ACK,
  875.     JMP    RCVSECT ;GET NEXT BLOCK
  876. ;
  877. ;Send an ACK for the sector
  878. ;
  879. SENDACK MVI    A,ACK    ;GET ACK
  880.     CALL    SEND    ;..AND SEND IT
  881.     RET
  882. ;
  883. ;---->    SENDHDR: Send the sector header
  884. ;
  885. ;SEND: (SOH) (block #) (complemented block #)
  886. ;
  887. SENDHDR MVI    A,SOH    ;SEND..
  888.     CALL    SEND    ;..SOH,
  889.     LDA    SECTNO    ;THEN SEND..
  890.     CALL    SEND    ;..SECTOR #
  891.     LDA    SECTNO    ;THEN SECTOR #
  892.     CMA        ;..COMPLEMENTED..
  893.     CALL    SEND    ;..SECTOR #
  894.     RET        ;FROM SENDHDR
  895. ;
  896. ;---->    SENDSEC: Send the data sector
  897. ;
  898. SENDSEC MVI    C,0    ;INIT CKSUM
  899.     CALL    CLRCRC    ;CLEAR THE CRC COUNTER
  900.     LXI    H,BASE+80H ;POINT TO BUFFER
  901. ;
  902. SENDC    MOV    A,M    ;GET A CHAR
  903.     CALL    SEND    ;SEND IT
  904.     INR    L    ;POINT TO NEXT CHAR
  905.     JNZ    SENDC    ;LOOP IF <100H
  906.     RET        ;FROM SENDSEC
  907. ;
  908. ;---->    SENDCKS: Send the checksum
  909. ;
  910. SENDCKS MOV    A,C    ;SEND THE..
  911.     CALL    SEND    ;..CHECKSUM
  912.     RET        ;FROM SENDCKS
  913. ;
  914. ;---->    SENDCRC: Send the two Cyclic Redundancy
  915. ;         Check characters.  Call FINCRC
  916. ;         to calc the CRC which will be in
  917. ;         d,e regs upon return.
  918. ;
  919. SENDCRC    CALL    FINCRC    ;CALC THE CRC FOR THIS SECTOR
  920.     MOV    A,D    ;PUT FIRST CRC BYTE IN ACCUM
  921.     CALL    SEND    ;SEND IT
  922.     MOV    A,E    ;PUT SECOND CRC BYTE IN ACCUM
  923.     CALL    SEND    ;SEND IT
  924.     XRA    A    ;SET ZERO RETURN CODE
  925.     RET
  926. ;
  927. ;---->    GETACK: Get the ACK on the sector
  928. ;
  929. ;Returns with carry clear if ACK received.
  930. ;If an ACK is not received, the error count
  931. ;is incremented, and if less than "ERRLIM",
  932. ;carry is set and control returns.  If the
  933. ;error count is at "ERRLIM", the program
  934. ;aborts.
  935. ;
  936. GETACK    MVI    B,10    ;WAIT 10 SECONDS MAX
  937.     CALL    RECVDG    ;RECV W/GARBAGE COLLECT
  938.     JC    GETATOT ;TIMED OUT
  939.     CPI    ACK    ;OK? (CARRY OFF IF =)
  940.     RZ        ;YES, RET FROM GETACK
  941. ;
  942. ;Timeout or error on ACK - bump error count
  943. ;
  944. ACKERR    LDA    ERRCT    ;GET COUNT
  945.     INR    A    ;BUMP IT
  946.     STA    ERRCT    ;SAVE BACK
  947.     CPI    ERRLIM    ;AT LIMIT?
  948.     RC        ;NOT AT LIMIT
  949. ;
  950. ;Reached error limit
  951. ;
  952. CSABORT CALL    ERXIT
  953.     DB    '++CAN''T SEND SECTOR '
  954.     DB    '- ABORTING++',CR,LF,'$'
  955. ;
  956. ;Timeout getting ACK
  957. ;
  958. GETATOT JMP    ACKERR    ;NO MSG
  959. ; 
  960. ABORT    LXI    SP,STACK
  961. ;
  962. ABORTL    MVI    B,1    ;1 SEC. W/O CHARS.
  963.     CALL    RECV
  964.     JNC    ABORTL    ;LOOP UNTIL SENDER DONE
  965.     MVI    A,CAN    ;CONTROL X
  966.     CALL    SEND    ;STOP SENDING END
  967. ;
  968. ABORTW    MVI    B,1    ;1 SEC W/O CHARS.
  969.     CALL    RECV
  970.     JNC    ABORTW    ;LOOP UNTIL SENDER DONE
  971.     MVI    A,' '    ;GET A SPACE...
  972.     CALL    SEND    ;TO CLEAR OUT CONTROL X
  973.     CALL    ERXIT    ;EXIT WITH ABORT MSG
  974.     DB    'XMODEM PROGRAM CANCELLED',CR,LF,'$'
  975. ;
  976. ;---->    INCRSNO: Increment sector #
  977. ;
  978. INCRSNO LDA    SECTNO    ;INCR..
  979.     INR    A    ;..SECT..
  980.     STA    SECTNO    ;..NUMBER
  981.     PUSH    H
  982.     LXI    H,VOUT    ;CK FOR OPTIONAL COUNT TO CONSOLE
  983.     MOV    A,H
  984.     ORA    L
  985.     JNZ    CONSEC
  986.     POP    H
  987.     RET
  988. ;
  989. CONSEC:    MVI    A,CR
  990.     CALL    VOUT
  991.     LHLD    SECCNT    ;UPDATE TOTAL SECTOR COUNT
  992.     INX    H
  993.     SHLD    SECCNT
  994.     CALL    DECOUTX    ;DISPLAY COUNT
  995.     POP    H
  996.     RET
  997. ;
  998. DECOUTX    PUSH    B
  999.     PUSH    D
  1000.     PUSH    H
  1001.     LXI    B,-10
  1002.     LXI    D,-1
  1003. ;
  1004. DECOU2X    DAD    B
  1005.     INX    D
  1006.     JC    DECOU2X
  1007.     LXI    B,10
  1008.     DAD    B
  1009.     XCHG
  1010.     MOV    A,H
  1011.     ORA    L
  1012.     CNZ    DECOUTX
  1013.     MOV    A,E
  1014.     ADI    '0'
  1015.     CALL    VOUT
  1016.     POP    H
  1017.     POP    D
  1018.     POP    B
  1019.     RET
  1020. ;
  1021. ;---->    CHEKFIL: See if file exists
  1022. ;
  1023. ;If it exists, say use a different name.
  1024. ;
  1025. CHEKFIL
  1026.     if    setarea        
  1027.     call    recarea        ;set the designated area up     a 01/06/81
  1028.     endif
  1029. ;
  1030.     LXI    D,FCB    ;POINT TO CTL BLOCK
  1031.     MVI    C,SRCHF ;SEE IF IT..
  1032.     CALL    BDOS    ;..EXISTS
  1033.     INR    A    ;FOUND?
  1034.     RZ        ;..NO, RETURN
  1035.     CALL    ERXIT    ;EXIT, PRINT ERROR MESSAGE
  1036.     DB    '++FILE EXISTS - USE A DIFFERENT NAME++'
  1037.     DB    CR,LF,'$'
  1038. ;
  1039. ;---->    MAKEFIL: Makes the file to be received
  1040. ;
  1041. MAKEFIL    XRA    A    ;SET EXT & REC # TO 0
  1042.     STA    FCBEXT
  1043.     STA    FCBSNO
  1044.     LXI    D,FCB    ;POINT TO FCB
  1045.     MVI    C,MAKE    ;GET BDOS FNC
  1046.     CALL    BDOS    ;TO THE MAKE
  1047.     INR    A    ;FF=BAD?
  1048.     RNZ        ;OPEN OK
  1049. ;Directory full - can't make file
  1050.     CALL    ERXIT
  1051.     DB    '++ERROR - CAN''T MAKE FILE++',CR,LF
  1052.     DB    'Directory must be full',CR,LF,'$'
  1053. ;
  1054. ;---->    CNREC: Computes record count, and saves it
  1055. ;           until successful file OPEN.
  1056. ;
  1057. ;LOOK UP THE FCB IN THE DIRECTORY
  1058. CNREC    MVI    A,'?'    ;MATCH ALL EXTENTS
  1059.     STA    FCBEXT
  1060.     MVI    A,0FFH
  1061.     STA    MAXEXT    ;INIT MAX EXT NO.
  1062.     MVI    C,SRCHF ;GET 'SEARCH FIRST' FNC
  1063.     LXI    D,FCB
  1064.     CALL    BDOS    ;READ FIRST
  1065.     INR    A    ;WERE THERE ANY?
  1066.     JNZ    SOME    ;GOT SOME
  1067.     CALL    ERXIT
  1068.     DB    '++FILE NOT FOUND++$'
  1069. ;
  1070. ;READ MORE DIRECTORY ENTRIES
  1071. MOREDIR    MVI    C,SRCHN ;SEARCH NEXT
  1072.     LXI    D,FCB
  1073.     CALL    BDOS    ;READ DIR ENTRY
  1074.     INR    A    ;CHECK FOR END (0FFH)
  1075.     JNZ    SOME    ;NOT END OF DIR...PROCESS EXTENT
  1076.     LDA    MAXEXT    ;HIT END...GET HIGHEST EXTENT NO. SEEN
  1077.     MOV    L,A    ;WHICH GIVES EXTENT COUNT - 1
  1078.     MVI    H,0
  1079.     MOV    D,H
  1080.     LDA    RCNT    ;GET RECORD COUNT OF MAX EXTENT SEEN
  1081.     MOV    E,A    ;SAVE IT IN DE
  1082.     DAD    H
  1083.     DAD    H    ;MULTIPLY # OF EXTENTS - 1
  1084.     DAD    H    ; TIMES 128
  1085.     DAD    H
  1086.     DAD    H
  1087.     DAD    H
  1088.     DAD    H
  1089.     DAD    D    ;ADD IN SIZE OF LAST EXTENT
  1090.     SHLD    RCNT    ;SAVE TOTAL RECORD COUNT
  1091.     RET        ;AND EXIT
  1092. ;
  1093. ;POINT TO DIRECTORY ENTRY 
  1094. SOME    DCR    A    ;UNDO PREV 'INR A'
  1095.     ANI    3    ;MAKE MODULUS 4
  1096.     ADD    A    ;MULTIPLY...
  1097.     ADD    A    ;..BY 32 BECAUSE
  1098.     ADD    A    ;..EACH DIRECTORY
  1099.     ADD    A    ;..ENTRY IS 32
  1100.     ADD    A    ;..BYTES LONG
  1101.     LXI    H,BASE+80H ;POINT TO BUFFER
  1102.     ADD    L    ;POINT TO ENTRY
  1103.     ADI    15    ;OFFSET TO RECORD COUNT
  1104.     MOV    L,A    ;HL NOW POINTS TO REC COUNT
  1105.     MOV    B,M    ;GET RECORD COUNT
  1106.     DCX    H
  1107.     DCX    H    ;BACK DOWN TO EXTENT NUMBER
  1108.     DCX    H
  1109.     LDA    MAXEXT    ;COMPARE WITH CURRENT MAX.
  1110.     ORA    A    ;IF NO MAX YET
  1111.     JM    BIGGER    ;THEN SAVE RECORD COUNT ANYWAY
  1112.     CMP    M
  1113.     JNC    MOREDIR
  1114. ;
  1115. BIGGER:    MOV    A,B    ;SAVE NEW RECORD COUNT
  1116.     STA    RCNT
  1117.     MOV    A,M    ;SAVE NEW MAX. EXTENT NO.
  1118.     STA    MAXEXT
  1119.     JMP    MOREDIR    ;GO FIND MORE EXTENTS
  1120. ;
  1121. ;---->    OPENFIL: Opens the file to be sent
  1122. ;
  1123. OPENFIL    XRA    A    ;SET EXT & REC # TO 0 FOR PROPER OPEN
  1124.     STA    FCBEXT
  1125.     STA    FCBSNO
  1126.     LXI    D,FCB    ;POINT TO FILE
  1127.     MVI    C,OPEN    ;GET FUNCTION
  1128.     CALL    BDOS    ;OPEN IT
  1129.     INR    A    ;OPEN OK?
  1130.     JNZ    OPENOK    ;..YES
  1131.     CALL    ERXIT    ;..NO, ABORT
  1132.     DB    '++OPEN ERROR++',CR,LF,'$'
  1133. ;
  1134. ;Check for distribution-protected file
  1135. ;
  1136. OPENOK    LDA    FCB+1    ;FIRST CHAR OF FILE NAME
  1137.     ANI    80H    ;CHECK BIT 7
  1138.     JNZ    OPENOT    ;If on, file can't be sent.
  1139.     LDA    FCB+2    ;Also check "f2" for tag.
  1140.     ANI    80H    ;Is it set?
  1141.     JZ    OPENOK2    ;If not, ok to send file.
  1142. ;
  1143. OPENOT    CALL    ERXIT    ;EXIT W/MESSAGE
  1144.     DB    '++THIS FILE IS NOT FOR DISTRIBUTION, SORRY++'
  1145.     DB    CR,LF,'$'
  1146. ;
  1147. OPENOK2 EQU    $
  1148. ;
  1149.     IF    NOLBS OR NOCOMS ;CHECK FOR SEND RESTRICTIONS
  1150.     LXI    H,FCB+11
  1151.     MOV    A,M    ;CHECK FOR PROTECT ATTR
  1152.     ANI    7FH    ;REMOVE CP/M 2.x ATTRS
  1153.     ENDIF        ;NOLBS OR NOCOMS
  1154. ;
  1155.     IF    NOLBS    ;DON'T ALLOW '#' TO BE SENT.
  1156.     CPI    '#'    ;CHK FOR '#' AS LAST FIRST
  1157.     JZ    OPENOT    ;IF '#', CAN'T SEND, SHOW WHY
  1158.     ENDIF        ;NOLBS
  1159. ;
  1160.     IF    NOCOMS    ;DON'T ALLOW .COM TO BE SENT
  1161.     CPI    'M'    ;IF NOT, CHK FOR '.COM'
  1162.     JNZ    OPENOK3 ;IF NOT, OK TO SEND
  1163.     DCX    H
  1164.     MOV    A,M    ;CHK NEXT CHAR
  1165.     ANI    7FH    ;STRIP ATTRIBUTES
  1166.     CPI    'O'    ; 'O'?
  1167.     JNZ    OPENOK3 ;IF NOT, OK TO SEND
  1168.     DCX    H
  1169.     MOV    A,M    ;NOW CHK FIRST CHAR
  1170.     ANI    7FH    ;STRIP ATTRIBUTES
  1171.     CPI    'C'    ; 'C' AS IN '.COM'?
  1172.     JNZ    OPENOK3 ;IF NOT, CONTINUE
  1173.     CALL    ERXIT    ;EXIT W/MESSAGE
  1174.     DB    '++CAN''T SEND A .COM FILE++'
  1175.     DB    CR,LF,'$'
  1176.     ENDIF        ;NOCOMS
  1177. ;
  1178. OPENOK3 CALL    ILPRT    ;PRINT:
  1179.     DB    'File Open -  ',0            ; v48b bhk
  1180.     LHLD    RCNT    ; Get record count.
  1181.     CALL    DECOUT    ;PRINT DECIMAL NUMBER OF SECTORS
  1182.     CALL    ILPRT
  1183.     DB    ' (',0
  1184.     CALL    DHXOUT    ;Now print size in hex.
  1185.     CALL    ILPRT
  1186.     DB    ' Hex) Sectors',CR,LF            ; v48b bhk
  1187.     db    '(approximately ',0            ; v48b bhk
  1188.     lhld    rcnt    ; get # of sectors        ; v48b bhk
  1189.     IF    LSPEED
  1190.     LDA    MSPEED                    ; V50  JPR
  1191.     CPI    B600                    ;  "
  1192.     PUSH    PSW                    ;  "
  1193.     JNZ    S300                    ;  "
  1194.     XRA    A    ; DIVIDE HL BY 2           "
  1195.     MOV    A,H                    ;  "
  1196.     RAR                        ;  "
  1197.     MOV    H,A                    ;  "
  1198.     MOV    A,L                    ;  "
  1199.     RAR                        ;  "
  1200.     MOV    L,A                    ;  "
  1201.  
  1202. S300
  1203.     ENDIF
  1204.     call    divhl14    ; divide HL by 14 (sectors/min)    ; v48b bhk
  1205.     PUSH    H
  1206.     IF    LOGCAL
  1207.     SHLD    PGSIZE                    ; V50  JPR
  1208.     ENDIF
  1209.     MVI    H,0
  1210.     call    decout    ; print decimal # of minutes    ; v48b bhk
  1211.     call    ilprt                    ; v48b bhk
  1212.     db    ' mins, ',0
  1213.  
  1214.     POP    H
  1215.     MOV    A,H        ;REMAINDER X 4 = SECONDS
  1216.     RLC
  1217.     RLC
  1218.     MOV    L,A
  1219.     MVI    H,0
  1220.     CALL    DECOUT
  1221.     IF    LSPEED
  1222.     POP    PSW                    ; V50 JPR
  1223.     JNZ    MS300
  1224.     CALL    ILPRT
  1225.     DB    ' secs to send at 600 baud).',cr,lf        ; v48b bhk
  1226.     db    '[Control-X to cancel.]',cr,lf,0    ; v48c bhk
  1227.     RET
  1228. MS300
  1229.     ENDIF
  1230.     CALL    ILPRT
  1231.     DB    ' secs to send at 300 baud).',cr,lf        ; v48b bhk
  1232.     db    '[Control-X to cancel.]',cr,lf,0    ; v48c bhk
  1233.     RET
  1234. ;
  1235. ;---->  DIVHL14: Divides HL by 14, 
  1236. ;    UPON EXIT: L=QUOTIENT,H=REMAINDER
  1237. ;
  1238. divhl14    push    b
  1239.     MVI    B,8    ;SHIFT FACTOR TO B
  1240.     MVI    C,14    ;DIVISOR TO C
  1241. div2    xra    a    ; clear carry flag and accumulator
  1242.     DAD    H
  1243.     MOV    A,H
  1244.     SUB    C
  1245.     JM    DIV3    ;DONT BORROW ON NEG RESULTS
  1246.     MOV    H,A
  1247.     MOV    A,L
  1248.     ORI    1    ;BORROW 1
  1249.     MOV    L,A
  1250. DIV3    dcr    b
  1251.     jnz    div2
  1252.     pop    b
  1253.     ret
  1254. ;
  1255. ;---->    CLOSFIL: Closes the received file
  1256. ;
  1257. CLOSFIL LXI    D,FCB    ;POINT TO FILE
  1258.     MVI    C,CLOSE ;GET FUNCTION
  1259.     CALL    BDOS    ;CLOSE IT
  1260.     INR    A    ;CLOSE OK?
  1261.     RNZ        ;..YES, RETURN
  1262.     CALL    ERXIT    ;..NO, ABORT
  1263.     DB    '++CAN''T CLOSE FILE++',CR,LF,'$'
  1264. ;
  1265. ;
  1266. ;----> DECOUT: Decimal output routine
  1267. ;
  1268. DECOUT:    PUSH    B
  1269.     PUSH    D
  1270.     PUSH    H
  1271.     LXI    B,-10
  1272.     LXI    D,-1
  1273. ;
  1274. DECOU2:    DAD    B
  1275.     INX    D
  1276.     JC    DECOU2
  1277.     LXI    B,10
  1278.     DAD    B
  1279.     XCHG
  1280.     MOV    A,H
  1281.     ORA    L
  1282.     CNZ    DECOUT
  1283.     MOV    A,E
  1284.     ADI    '0'
  1285.     CALL    CTYPE
  1286.     POP    H
  1287.     POP    D
  1288.     POP    B
  1289.     RET
  1290. ;
  1291. ;---->    DHXOUT: - double precision hex output routine.
  1292. ;    Call with hex value in HL.
  1293. ;
  1294. DHXOUT    PUSH    H    ;Save H,L
  1295.     PUSH    PSW    ;Save A
  1296.     MOV    A,H    ;Get MS byte.
  1297.     CALL    HEXO    ;Output hi order byte.
  1298.     MOV    A,L    ;Get LS byte.
  1299.     CALL    HEXO    ;Output lo order byte.
  1300.     POP    PSW    ;Restore A
  1301.     POP    H    ;Restore H,L
  1302.     RET        ;Return to caller.
  1303. ;
  1304. ;
  1305. ;---->    RDSECT: Reads a sector
  1306. ;
  1307. ;For speed, this routine buffers up 16
  1308. ;sectors at a time.
  1309. ;
  1310. RDSECT    LDA    SECINBF ;GET # SECT IN BUFF.
  1311.     DCR    A    ;DECREMENT..
  1312.     STA    SECINBF ;..IT
  1313.     JM    RDBLOCK ;EXHAUSTED?  NEED MORE.
  1314.     LHLD    SECPTR    ;GET POINTER
  1315.     LXI    D,BASE+80H ;TO DATA
  1316.     CALL    MOVE128 ;MOVE TO BUFFER
  1317.     SHLD    SECPTR    ;SAVE BUFFER POINTER
  1318.     RET        ;FROM "READSEC"
  1319. ;
  1320. ;Buffer is empty - read in another block of 16
  1321. ;
  1322. RDBLOCK LDA    EOFLG    ;GED EOF FLAG
  1323.     CPI    1    ;IS IT SET?
  1324.     STC        ;TO SHOW EOF
  1325.     RZ        ;GOT EOF
  1326.     MVI    C,0    ;SECTORS IN BLOCK
  1327.     LXI    D,DBUF    ;TO DISK BUFFER
  1328. ;
  1329. RDSECLP PUSH    B
  1330.     PUSH    D
  1331.     MVI    C,STDMA ;SET DMA..
  1332.     CALL    BDOS    ;..ADDR
  1333.     LXI    D,FCB
  1334.     MVI    C,READ
  1335.     CALL    BDOS
  1336.     POP    D
  1337.     POP    B
  1338.     ORA    A    ;READ OK?
  1339.     JZ    RDSECOK ;YES
  1340.     DCR    A    ;EOF?
  1341.     JZ    REOF    ;GOT EOF
  1342. ;
  1343. ;Read error
  1344. ;
  1345.     CALL    ERXIT
  1346.     DB    '++FILE READ ERROR++',CR,LF,'$'
  1347. ;
  1348. RDSECOK LXI    H,80H    ;ADD LENGTH OF ONE SECTOR...
  1349.     DAD    D    ;...TO NEXT BUFF
  1350.     XCHG        ;BUFF TO DE
  1351.     INR    C    ;MORE SECTORS?
  1352.     MOV    A,C    ;GET COUNT
  1353.     CPI    16    ;DONE?
  1354.     JZ    RDBFULL ;..YES, BUFF IS FULL
  1355.     JMP    RDSECLP ;READ MORE
  1356. ;
  1357. REOF    MVI    A,1
  1358.     STA    EOFLG    ;SET EOF FLAG
  1359.     MOV    A,C
  1360. ;
  1361. ;Buffer is full, or got EOF
  1362. ;
  1363. RDBFULL STA    SECINBF ;STORE SECTOR COUNT
  1364.     LXI    H,DBUF    ;INIT BUFFER..
  1365.     SHLD    SECPTR    ;..POINTER
  1366.     LXI    D,BASE+80H ;RESET..
  1367.     MVI    C,STDMA ;..DMA..
  1368.     CALL    BDOS    ;..ADDR
  1369.     JMP    RDSECT    ;PASS SECT TO CALLER
  1370. ;
  1371. ;---->    WRSECT: Write a sector
  1372. ;
  1373. ;Writes the sector into a buffer.  When 16
  1374. ;have been written, writes the block to disk.
  1375. ;
  1376. ;Entry point "WRBLOCK" flushes the buffer at EOF.
  1377. ;
  1378. WRSECT    LHLD    SECPTR    ;GET BUFF ADDR
  1379.     XCHG        ;TO DE FOR MOVE
  1380.     LXI    H,BASE+80H    ;FROM HERE
  1381.     CALL    MOVE128 ;MOVE TO BUFFER
  1382.     XCHG        ;SAVE NEXT..
  1383.     SHLD    SECPTR    ;..BLOCK POINTER
  1384.     LDA    SECINBF ;BUMP THE..
  1385.     INR    A    ;..SECTOR #..
  1386.     STA    SECINBF ;..IN THE BUFF
  1387.     CPI    16    ;HAVE WE 16?
  1388.     RNZ        ;NO, RETURN
  1389. ;
  1390. ;---->    WRBLOCK: Writes a block to disk
  1391. ;
  1392. WRBLOCK LDA    SECINBF ;# SECT IN BUFFER
  1393.     ORA    A    ;0 MEANS END OF FILE
  1394.     RZ        ;NONE TO WRITE
  1395.     MOV    C,A    ;SAVE COUNT
  1396.     LXI    D,DBUF    ;POINT TO DISK BUFF
  1397. ;
  1398. DKWRLP    PUSH    H
  1399.     PUSH    D
  1400.     PUSH    B
  1401.     MVI    C,STDMA ;SET DMA
  1402.     CALL    BDOS    ;TO BUFFER
  1403.     LXI    D,FCB    ;THEN WRITE
  1404.     MVI    C,WRITE ;..THE..
  1405.     CALL    BDOS    ;..BLOCK
  1406.     POP    B
  1407.     POP    D
  1408.     POP    H
  1409.     ORA    A
  1410.     JNZ    WRERR    ;OOPS, ERROR
  1411.     LXI    H,80H    ;LENGTH OF 1 SECT
  1412.     DAD    D    ;HL= NEXT BUFF
  1413.     XCHG        ;TO DE FOR SETDMA
  1414.     DCR    C    ;MORE SECTORS?
  1415.     JNZ    DKWRLP    ;..YES, LOOP
  1416.     XRA    A    ;GET A ZERO
  1417.     STA    SECINBF ;RESET # OF SECTORS
  1418.     LXI    H,DBUF    ;RESET BUFFER..
  1419.     SHLD    SECPTR    ;..POINTER
  1420. ;
  1421. RSDMA    LXI    D,BASE+80H ;RESET..
  1422.     MVI    C,STDMA ;..DMA..
  1423.     CALL    BDOS    ;..ADDR
  1424.     RET
  1425. ;
  1426. WRERR    CALL    RSDMA    ;RESET DMA TO NORM.
  1427.     MVI    C,CAN    ;CANCEL..
  1428.     CALL    SEND    ;..SENDER
  1429.     CALL    ERXIT    ;EXIT W/MSG:
  1430.     DB    '++ERROR WRITING FILE++',CR,LF,'$'
  1431. ;
  1432. ;---->    RECV: Receive a character
  1433. ;
  1434. ;Timeout time is in B, in seconds.  Entry via
  1435. ;"RECVDG" deletes garbage characters on the
  1436. ;line.    For example, having just sent a sector,
  1437. ;calling RECVDG will delete any line-noise-induced
  1438. ;characters "long" before the ACK/NAK would
  1439. ;be received.
  1440. ;
  1441. RECVDG    EQU    $    ;RECEIVE W/GARBAGE DELETE
  1442.     IN    MODDATP ;GET A CHAR
  1443.     IN    MODDATP ;..TOTALLY PURGE UART
  1444. ;
  1445. RECV    PUSH    D    ;SAVE
  1446. ;
  1447.     IF    FASTCLK ;4MHZ?
  1448.     MOV    A,B    ;GET TIME REQUEST
  1449.     ADD    A    ;DOUBLE IT
  1450.     MOV    B,A    ;NEW TIME IN B
  1451.     ENDIF
  1452. ;
  1453. MSEC    LXI    D,50000 ;1 SEC DCR COUNT
  1454. ;
  1455.     IF    NOT DCH
  1456. MWTI    IN    MODCTLP ;CHECK STATUS
  1457.     ENDIF
  1458. ;
  1459.     IF    DCH
  1460. MWTI    IN    MODCTL2 ;CHECK STATUS
  1461.     ENDIF
  1462. ;
  1463.     IF    PMMI AND FRNTPNL
  1464.     OUT    PANEL    ;DISPLAY STATUS ON PANEL LIGHTS
  1465.     ENDIF
  1466. ;
  1467.     ANI    MODRCVB ;ISOLATE BIT
  1468.     CPI    MODRCVR ;READY?
  1469.     JZ    MCHAR    ;GOT CHAR
  1470.     DCR    E    ;COUNT..
  1471.     JNZ    MWTI    ;..DOWN..
  1472.     DCR    D    ;..FOR..
  1473.     JNZ    MWTI    ;..TIMEOUT
  1474.     DCR    B    ;MORE SECONDS?
  1475.     JNZ    MSEC    ;YES, WAIT
  1476. ;
  1477. ;Test for the presence of carrier - if none, go to 
  1478. ;CARCK and continue testing for 15 seconds. If carrier
  1479. ;returns, continue. If is doesn't return, exit.
  1480. ;
  1481.     IF    EXTMOD OR H8 OR DCH
  1482.     IN    MODCTL2    ;READ MODEM STATUS
  1483.     ENDIF
  1484. ;
  1485.     IF    PMMI
  1486.     IN    BAUDRP    ;READ MODEM STATUS
  1487.     ENDIF
  1488. ;
  1489.     IF    PMMI AND FRNTPNL
  1490.     OUT    PANEL    ;DISPLAY STATUS ON PANEL LIGHTS
  1491.     ENDIF
  1492. ;
  1493.     ANI    MODDCDB    ;CARRIER DETECT MASK
  1494.     CPI    MODDCDA    ;IS IT STILL ON?
  1495.     CNZ    CARCK    ;IF NOT, TEST FOR 15 SECONDS
  1496. ;
  1497. ;Modem timed out receiving - but carrier still on.
  1498. ;
  1499.     POP    D    ;RESTORE D,E
  1500.     STC        ;CARRY SHOWS TIMEOUT
  1501.     RET
  1502. ;
  1503. ;Got character from modem
  1504. ;
  1505. MCHAR:
  1506. ;Check to see if there was a framing error,
  1507. ;overrun, or parity error.
  1508. ;
  1509.     IF    PMMI OR H8
  1510.     IN    MODCTLP    ;GET MODEM STATUS
  1511.     ENDIF
  1512. ;
  1513.     IF    DCH
  1514.     IN    MODCTL2    ;GET MODEM STATUS
  1515.     ENDIF
  1516. ;
  1517.     IF    PMMI OR H8 OR DCH
  1518.     MOV    D,A    ;SAVE STATUS
  1519.     ANI    MODFRME    ;FRAMING ERROR?
  1520.     CPI    MODFRME
  1521.     JNZ    MCHAR2    ;NO, CHECK FOR OVERRUN
  1522.     LDA    ERRCDE    ;GET RECV ERR CODE
  1523.     ORI    MODFRME    ;TURN ON RECV ERR CODE
  1524.     STA    ERRCDE    ;PUT IT BACK
  1525. ;
  1526. MCHAR2:    MOV    A,D    ;RESTORE MODEM STATUS
  1527.     ANI    MODOVRE    ;OVERRUN?
  1528.     CPI    MODOVRE
  1529.     JNZ    MCHAR3    ;NO, CHECK FOR PARITY ERROR
  1530.     LDA    ERRCDE
  1531.     ORI    MODOVRE    ;TURN ON RECV ERR CODE
  1532.     STA    ERRCDE
  1533. ;
  1534. MCHAR3:    MOV    A,D    ;RESTORE MODEM STATUS
  1535.     ANI    MODPARE    ;PARITY ERROR?
  1536.     CPI    MODPARE
  1537.     JNZ    MCHAR4    ;NO, GET DATA CHAR
  1538.     LDA    ERRCDE
  1539.     ORI    MODPARE
  1540.     STA    ERRCDE
  1541. ;
  1542. MCHAR4:
  1543.     ENDIF        ;PMMI OR H8 OR DCH
  1544. ;
  1545. ;Get data char
  1546. ;
  1547.     IN    MODDATP ;READ THE CHAR
  1548.     POP    D    ;RESTORE DE
  1549. ;
  1550. ;Calc checksum and CRC
  1551. ;
  1552.     PUSH    PSW    ;SAVE THE CHAR
  1553.     CALL    UPDCRC    ;CALC CRC
  1554.     ADD    C    ;ADD TO CHECKSUM
  1555.     MOV    C,A    ;SAVE CHECKSUM
  1556.     POP    PSW    ;RESTORE CHAR
  1557.     ORA    A    ;CARRY OFF: NO ERROR
  1558.     RET        ;FROM "RECV"
  1559. ;
  1560. ;CARCK - common 15 second carrier test for RECV and
  1561. ;SEND. If carrier returns within 15 seconds, normal
  1562. ;program execution continues. Else, it will abort
  1563. ;to CP/M via EXIT.
  1564. ;
  1565. CARCK    MVI    E,150    ;VALUE FOR 15 SECOND DELAY
  1566. ;
  1567. CARCK1    CALL    DELAY    ;KILL .1 SECONDS
  1568. ;
  1569.     IF    EXTMOD OR H8 OR DCH
  1570.     IN    MODCTL2    ;READ MODEM STATUS
  1571.     ENDIF
  1572. ;
  1573.     IF    PMMI
  1574.     IN    BAUDRP    ;READ MODEM STATUS
  1575.     ENDIF
  1576. ;
  1577.     IF    PMMI AND FRNTPNL
  1578.     OUT    PANEL    ;DISPLAY STATUS
  1579.     ENDIF
  1580. ;
  1581.     ANI    MODDCDB    ;CARRIER DETECT MASK
  1582.     CPI    MODDCDA    ;IS IT STILL ON?
  1583.     RZ        ;RETURN IF CARRIER ON
  1584.     DCR    E    ;HAS 15 SECONDS EXPIRED?
  1585.     JNZ    CARCK1    ;IF NOT, CONTINUE TESTING
  1586.     JMP    EXIT    ;ELSE, ABORT TO CP/M.
  1587. ;
  1588. ;DELAY - 100 millisecond delay.
  1589. ;
  1590. DELAY    PUSH    B    ;SAVE B,C
  1591. ;
  1592.     IF    FASTCLK    ;IF 4MHZ CLOCK
  1593.     LXI    B,16667    ;VALUE FOR 100MS DELAY
  1594.     ENDIF
  1595. ;
  1596.     IF    NOT FASTCLK
  1597.     LXI    B,8334    ;VALUE FOR 100MS DELAY
  1598.     ENDIF
  1599. ;
  1600. DELAY2    DCX    B    ;UPDATE COUNT
  1601.     MOV    A,B    ;GET MS BYTE
  1602.     ORA    C    ;COUNT = ZERO?
  1603.     JNZ    DELAY2    ;IF NOT, CONTINUE
  1604.     POP    B    ;RESTORE B,C
  1605.     RET        ;RETURN TO CARCK1.
  1606. ;
  1607. ;---->    SEND: Send a character to the modem
  1608. ;
  1609. SEND    PUSH    PSW    ;SAVE THE CHARACTER
  1610.     CALL    UPDCRC    ;calc the crc
  1611.     ADD    C    ;CALC CKSUM
  1612.     MOV    C,A    ;SAVE CKSUM
  1613. ;
  1614.     IF    NOT DCH
  1615. SENDW    IN    MODCTLP ;GET STATUS
  1616.     ENDIF
  1617. ;
  1618.     IF    DCH
  1619. SENDW    IN    MODCTL2 ;GET STATUS
  1620.     ENDIF
  1621. ;
  1622.     IF    PMMI AND FRNTPNL
  1623.     OUT    PANEL    ;DISPLAY STATUS
  1624.     ENDIF
  1625. ;
  1626.     ANI    MODSNDB ;ISOLATE READY BIT
  1627.     CPI    MODSNDR ;READY?
  1628.     JZ    SENDR    ;..YES, GO SEND
  1629. ;
  1630. ;Xmit status not ready, so test for carrier before
  1631. ;looping - if lost, go to CARCK and give it up to 15
  1632. ;seconds to return. If it doesn't return abort via
  1633. ;EXIT.
  1634. ;
  1635.     PUSH    D    ;Save D,E
  1636. ;
  1637.     IF    EXTMOD OR H8 OR DCH
  1638.     IN    MODCTL2    ;READ MODEM STATUS
  1639.     ENDIF
  1640. ;
  1641.     IF    PMMI
  1642.     IN    BAUDRP    ;READ MODEM STATUS
  1643.     ENDIF
  1644. ;
  1645.     IF    PMMI AND FRNTPNL
  1646.     OUT    PANEL    ;DISPLAY STATUS
  1647.     ENDIF
  1648. ;
  1649.     ANI    MODDCDB    ;CARRIER DETECT MASK
  1650.     CPI    MODDCDA    ;IS IT STILL ON?
  1651.     CNZ    CARCK    ;IF NOT, CONTINUE TESTING IT
  1652.     POP    D    ;RESTORE D,E
  1653.     JMP    SENDW    ;ELSE, WAIT FOR XMIT READY.
  1654. ;
  1655. ;Xmit status ready, carrier still on - send the data.
  1656. ;
  1657. SENDR    POP    PSW    ;GET CHAR
  1658.     OUT    MODDATP ;OUTPUT IT
  1659.     RET        ;FROM "SEND"
  1660. ;
  1661. ;---->    WAITNAK: Waits for initial NAK
  1662. ;
  1663. ;To ensure no data is sent until the receiving
  1664. ;program is ready, this routine waits for the
  1665. ;first timeout-NAK or the letter 'C' for CRC
  1666. ;from the receiver.  If CRC is in effect, then
  1667. ;Cyclic Redundancy Checks are used instead of
  1668. ;checksums.
  1669. ;(E) contains the # of seconds to wait.
  1670. ;
  1671. ; If the first character received is a CAN (control-X)
  1672. ; then the send will be aborted as though it had timed out.
  1673. ; 04/01/82 BHK 
  1674. ;
  1675. WAITNAK MVI    B,1    ;TIMEOUT DELAY
  1676.     CALL    RECV    ;DID WE GET..
  1677.     CPI    NAK    ;..A NAK?
  1678.     RZ        ;YES, SEND BLOCK
  1679.     CPI    CRC    ;CRC INDICATED?
  1680.     JZ    WAITCRC    ;YES, GO PUT CRC IN EFFECT
  1681.     CPI    CAN    ;WAS IT A CANCEL (CONTROL-X)?        ; v48c bhk
  1682.     JZ    ABORT    ;YES, ABORT                ; v48c bhk
  1683.     DCR    E    ;80 TRIES?
  1684.     JZ    ABORT    ;YES, ABORT
  1685.     JMP    WAITNAK ;NO, LOOP
  1686. ;
  1687. ;----> WAITCRC: Turn on CRC Flag
  1688. ;
  1689. WAITCRC    XRA    A    ;ZERO ACCUM
  1690.     STA    CRCFLG    ;TURN ON CRC OPT
  1691.     RET
  1692. ;
  1693. ;---->    MOVEFCB: Moves FCB(2) to FCB
  1694. ;
  1695. ;In order to make the XMODEM command 'natural',
  1696. ;i.e. XMODEM SEND FILENAME (MODEM S FN.FT) rather
  1697. ;than XMODEM FILENAME SEND (MODEM FN.FT S), this
  1698. ;routine moves the filename from the second FCB
  1699. ;to the first.
  1700. ;
  1701. MOVEFCB LXI    H,FCB+16 ;FROM
  1702.     LXI    D,FCB    ;TO
  1703.     MVI    B,16    ;LEN
  1704.     CALL    MOVE    ;DO THE MOVE
  1705.     XRA    A    ;GET 0
  1706.     STA    FCBSNO    ;ZERO SECTOR #
  1707.     STA    FCBEXT    ;..AND EXTENT
  1708.     RET
  1709. ;
  1710. CTYPE    PUSH    B    ;SAVE..
  1711.     PUSH    D    ;..ALL..
  1712.     PUSH    H    ;..REGS
  1713.     MOV    E,A    ;CHAR TO E
  1714.     MVI    C,WRCON ;GET BDOS FNC
  1715.     CALL    BDOS    ;PRIN THE CHR
  1716.     POP    H    ;RESTORE..
  1717.     POP    D    ;..ALL..
  1718.     POP    B    ;..REGS
  1719.     RET        ;FROM "CTYPE"
  1720. ;
  1721. HEXO    PUSH    PSW    ;SAVE FOR RIGHT DIGIT
  1722.     RAR        ;RIGHT..
  1723.     RAR        ;..JUSTIFY..
  1724.     RAR        ;..LEFT..
  1725.     RAR        ;..DIGIT..
  1726.     CALL    NIBBL    ;PRINT LEFT DIGIT
  1727.     POP    PSW    ;RESTORE RIGHT
  1728. ;
  1729. NIBBL    ANI    0FH    ;ISOLATE DIGIT
  1730.     CPI    10    ;IS IT <10?
  1731.     JC    ISNUM    ;YES, NOT ALPHA
  1732.     ADI    7    ;ADD ALPHA BIAS
  1733. ;
  1734. ISNUM    ADI    '0'    ;MAKE PRINTABLE
  1735.     JMP    CTYPE    ;..THEN TYPE IT
  1736. ;
  1737. ;---->    ILPRT: Inline print of message
  1738. ;
  1739. ;The call to ILPRT is followed by a message,
  1740. ;binary 0 as the end.
  1741. ;
  1742. ILPRT    XTHL        ;SAVE HL, GET HL=MSG
  1743. ;
  1744. ILPLP    MOV    A,M    ;GET CHAR
  1745.     ORA    A    ;END OF MSG?
  1746.     JZ    ILPRET    ;..YES, RETURN
  1747.     CALL    CTYPE    ;TYPE THE MSG
  1748.     INX    H    ;TO NEXT CHAR
  1749.     JMP    ILPLP    ;LOOP
  1750. ;
  1751. ILPRET    XTHL        ;RESTORE HL
  1752.     RET        ;PAST MSG
  1753. ;
  1754. EXITLG                ; SPECIAL LOG CALLER EXIT
  1755.     IF    LOGCAL
  1756.     JMP    LOGCALL
  1757.     ENDIF
  1758.     JMP    EXIT
  1759. ;
  1760. ;---->    ERXIT: Exit printing message following call
  1761. ;
  1762. ERXIT    POP    D    ;GET MESSAGE
  1763.     MVI    C,PRINT ;GET BDOS FNC
  1764.     CALL    BDOS    ;PRINT MESSAGE
  1765. ;
  1766. EXIT    LHLD    STACK    ;GET ORIGINAL STACK
  1767.     SPHL        ;RESTORE IT
  1768. ;
  1769.     if    setarea
  1770.     call    restu        ; restore old area user & drive ..a 01/06/81
  1771.     endif
  1772. ;
  1773.     RET        ;--EXIT-- TO CP/M
  1774. ;
  1775.     if    setarea
  1776. ;
  1777. ;------> RESTORE THE OLD USER AREA AND DRIVE FROM A RECEIVED FILE
  1778. ;
  1779. RESTU    lda    olddrv        ;RESTORE THE OLD DRIVE        ;a 01/06/81
  1780.     mov    e,a                        ;a 01/06/81
  1781.     call    recdrx                        ;a 01/06/81
  1782.     lda    olduser        ;RESTORE THE OLD USER NUMBER    ;a 01/06/81
  1783.     mov    e,a                        ;a 01/06/81
  1784.     jmp    recare                        ;a 01/06/81
  1785. ;
  1786. ;--------> SET USER AREA TO RECEIVE FILE
  1787. RECAREA    call    recdrv        ;ok set the drive to its place    ;a 01/06/81
  1788.     mvi    e,recu        ;ok now set the user area    ;a 01/06/81
  1789. RECARE    mvi    c,user        ;tell bdos what we want to do    ;a 01/06/81
  1790.     call    bdos        ;do it                ;a 01/06/81
  1791.     RET
  1792. ;
  1793. RECDRV    mvi    e,defdrv-41h    ;make drive cp/m number        ;a 01/06/81
  1794. RECDRX    mvi    c,seldrv    ;tell bdos            ;a 01/06/81
  1795.     call    bdos        ;do it                ;a 01/06/81
  1796.     ret            ;back                ;a 01/06/81
  1797.     endif
  1798. ;
  1799. ;Move 128 characters
  1800. ;
  1801. MOVE128 MVI    B,128    ;SET MOVE COUNT
  1802. ;
  1803. ;Move from (HL) to (DE) length in (B)
  1804. ;
  1805. MOVE    MOV    A,M    ;GET A CHAR
  1806.     STAX    D    ;STORE IT
  1807.     INX    H    ;TO NEXT "FROM"
  1808.     INX    D    ;TO NEXT "TO"
  1809.     DCR    B    ;MORE?
  1810.     JNZ    MOVE    ;..YES, LOOP
  1811.     RET        ;..NO, RETURN
  1812. ;
  1813. ;************************************************************************
  1814. ;* CRCSUBS (Cyclic Redundancy Code Subroutines) version 1.20        *
  1815. ;* 8080 Mnemonics                            *
  1816. ;*                                    *
  1817. ;*         These subroutines will compute and check a true 16-bit        *
  1818. ;*    Cyclic Redundancy Code for a message of arbitrary length.    *
  1819. ;*                                    *
  1820. ;*    The  use  of this scheme will guarantee detection of all    *
  1821. ;*    single and double bit errors, all  errors  with  an  odd    *
  1822. ;*    number  of  error bits, all burst errors of length 16 or    *
  1823. ;*    less, 99.9969% of all 17-bit error bursts, and  99.9984%    *
  1824. ;*    of  all  possible  longer  error bursts.  (Ref: Computer    *
  1825. ;*    Networks, Andrew S.  Tanenbaum, Prentiss-Hall, 1981)        *
  1826. ;*                                    *
  1827. ;*                                    *
  1828. ;*    There are four entry points, which are used as follows:        *
  1829. ;*                                    *
  1830. ;*    CLRCRC - A call to this entry resets the CRC accumulator.    *
  1831. ;*         It must be called at the start of each message.    *
  1832. ;*                                    *
  1833. ;*         Entry Parameters: None.                *
  1834. ;*                                    *
  1835. ;*         Exit Conditions:  CRC accumulator cleared.        *
  1836. ;*                   All registers preserved.        *
  1837. ;*                                    *
  1838. ;*                                    *
  1839. ;*    UPDCRC - A call to this entry updates the CRC accumulator.    *
  1840. ;*         It must be called once for each byte in the        *
  1841. ;*         message for which the CRC is being calculated.        *
  1842. ;*                                    *
  1843. ;*         Entry Parameters: (A) = a byte to be included        *
  1844. ;*                     in the CRC calculation.    *
  1845. ;*                                    *
  1846. ;*         Exit Conditions:  CRC accumulator updated.        *
  1847. ;*                   All registers preserved.        *
  1848. ;*                                    *
  1849. ;*                                    *
  1850. ;*    FINCRC - A call to this entry finishes the CRC calculation    *
  1851. ;*         for a message which is to be TRANSMITTED. It must    *
  1852. ;*         be called after the last byte of the message has    *
  1853. ;*         been passed thru UPDCRC. It returns the calculated    *
  1854. ;*         CRC bytes, which must be transmitted as the final    *
  1855. ;*         two bytes of the message (first D, then E).        *
  1856. ;*                                    *
  1857. ;*         Entry Parameters: None.                *
  1858. ;*                                    *
  1859. ;*         Exit Conditions:  (DE) = calculated CRC bytes.        *
  1860. ;*                   All other registers preserved.    *
  1861. ;*                                    *
  1862. ;*                                    *
  1863. ;*    CHKCRC - A call to this routine checks the CRC bytes of        *
  1864. ;*         a RECEIVED message and returns a code to indicate    *
  1865. ;*         whether the message was received correctly. It must    *
  1866. ;*         be called after the message AND the two CRC bytes    *
  1867. ;*         have been received AND passed thru UPDCRC.        *
  1868. ;*                                    *
  1869. ;*         Entry Parameters: None.                *
  1870. ;*                                    *
  1871. ;*         Exit Conditions:  (A) =  0 if message ok.        *
  1872. ;*                   (A) = -1 if message garbled.        *
  1873. ;*                   All other registers preserved.    *
  1874. ;*                                    *
  1875. ;************************************************************************
  1876. ;*                                    *
  1877. ;*    Designed & coded by Paul Hansknecht, June 13, 1981        *
  1878. ;*                                    *
  1879. ;*                                    *
  1880. ;*    Copyright (c) 1981, Carpenter Associates            *
  1881. ;*                Box 451                    *
  1882. ;*                Bloomfield Hills, MI 48013            *
  1883. ;*                313/855-3074                *
  1884. ;*                                    *
  1885. ;*    This program may be freely reproduced for non-profit use.    *
  1886. ;*                                    *
  1887. ;************************************************************************
  1888. ;
  1889. ;    ENTRY    CLRCRC,UPDCRC,FINCRC,CHKCRC
  1890. ;
  1891. CLRCRC:    EQU    $        ; Reset CRC Accumulator for a new message.
  1892.     PUSH    H
  1893.     LXI    H,0
  1894.     SHLD    CRCVAL
  1895.     POP    H
  1896.     RET
  1897. ;
  1898. UPDCRC:    EQU    $        ; Update CRC Accumulator using byte in (A).
  1899.     PUSH    PSW
  1900.     PUSH    B
  1901.     PUSH    H
  1902.     MVI    B,8
  1903.     MOV    C,A
  1904.     LHLD    CRCVAL
  1905. UPDLOOP:MOV    A,C
  1906.     RLC
  1907.     MOV    C,A
  1908.     MOV    A,L
  1909.     RAL
  1910.     MOV    L,A
  1911.     MOV    A,H
  1912.     RAL
  1913.     MOV    H,A
  1914.     JNC    SKIPIT
  1915.     MOV    A,H        ; The generator is X^16 + X^12 + X^5 + 1
  1916.     XRI    10H        ; as recommended by CCITT.
  1917.     MOV    H,A        ; An alternate generator which is often
  1918.     MOV    A,L        ; used in synchronous transmission protocols
  1919.     XRI    21H        ; is X^16 + X^15 + X^2 + 1. This may be
  1920.     MOV    L,A        ; used by substituting XOR 80H for XOR 10H
  1921. SKIPIT:    DCR    B        ; and XOR 05H for XOR 21H in the adjacent code.
  1922.     JNZ    UPDLOOP
  1923.     SHLD    CRCVAL
  1924.     POP    H
  1925.     POP    B
  1926.     POP    PSW
  1927.     RET
  1928. ;
  1929. FINCRC:    EQU    $        ; Finish CRC calc for outbound message.
  1930.     PUSH    PSW
  1931.     XRA    A
  1932.     CALL    UPDCRC
  1933.     CALL    UPDCRC
  1934.     PUSH    H
  1935.     LHLD    CRCVAL
  1936.     MOV    D,H
  1937.     MOV    E,L
  1938.     POP    H
  1939.     POP    PSW
  1940.     RET
  1941. ;
  1942. CHKCRC:    EQU    $        ; Check CRC bytes of received message.
  1943.     PUSH    H
  1944.     LHLD    CRCVAL
  1945.     MOV    A,H
  1946.     ORA    L
  1947.     POP    H
  1948.     RZ
  1949.     MVI    A,0FFh
  1950.     RET
  1951. ;
  1952. ;
  1953. CRCVAL    DW    0
  1954. ;
  1955. ;
  1956. ;
  1957. ;Temporary storage area
  1958. ;
  1959. MAXEXT    DB    0    ;HIGHEST EXTENT NO. SEEN IN FILE SIZE CALC.
  1960. RCNT    DW    0    ;RECORD COUNT
  1961. RCVSNO    DB    0    ;SECT # RECEIVED
  1962. SECTNO    DB    0    ;CURRENT SECTOR NUMBER 
  1963. SECCNT    DW    0    ;TOTAL SECTOR COUNT
  1964. ERRCT    DB    0    ;ERROR COUNT
  1965. olduser db    0    ;save the org user number
  1966. olddrv    db    0    ;save the org drive number
  1967. ;
  1968.     IF    PMMI OR H8 OR DCH
  1969. ERRCDE    DB    0    ;RECEIVE ERROR CODE
  1970.     ENDIF
  1971. ;
  1972. CRCFLG    DB    'C'    ;SET TO NULL IF CRC USED
  1973. FIRSTIME DB    1    ;TURNED OFF AFTER FIRST SOH RECEIVED
  1974. ;
  1975. ;Following 3 used by disk buffering routines
  1976. EOFLG    DB    0    ;EOF FLAG (1=TRUE)
  1977. SECPTR    DW    DBUF
  1978. SECINBF DB    0    ;# OF SECTORS IN BUFFER
  1979.     DS    60    ;STACK AREA
  1980. STACK    DS    2    ;STACK POINTER
  1981. ;
  1982. ;16 sector disk buffer
  1983. ;
  1984. DBUF    EQU    $    ;16 SECTOR DISK BUFFER
  1985. ;
  1986. ;BDOS equates
  1987. ;
  1988. RDCON    EQU    1
  1989. WRCON    EQU    2
  1990. PRINT    EQU    9
  1991. CONST    EQU    11    ;CONSOLE STAT
  1992. SELDRV    EQU    14    ;SELECT DRIVE
  1993. OPEN    EQU    15    ;0FFH = NOT FOUND
  1994. CLOSE    EQU    16    ;    "       "
  1995. SRCHF    EQU    17    ;    "       "
  1996. SRCHN    EQU    18    ;    "       "
  1997. ERASEF    EQU    19    ;NO RET CODE
  1998. READ    EQU    20    ;0=OK, 1=EOF
  1999. WRITE    EQU    21    ;0=OK, 1=ERR, 2=?, 0FFH=NO DIR SPC
  2000. MAKE    EQU    22    ;0FFH=BAD
  2001. REN    EQU    23    ;0FFH=BAD
  2002. CURDRV    EQU    25    ;GET CURRENT DRIVE
  2003. STDMA    EQU    26    ;SET DMA
  2004. USER    EQU    32    ;SET USER AREA TO RECEIVE FILE
  2005. BDOS    EQU    BASE+5
  2006. FCB    EQU    BASE+5CH ;SYSTEM FCB
  2007. FCBEXT    EQU    FCB+12    ;FILE EXTENT
  2008. FCBSNO    EQU    FCB+32    ;SECTOR #
  2009. FCB2    EQU    BASE+6CH ;SECOND FCB
  2010. ;
  2011.     END
  2012.