home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
SIMTEL
/
CPMUG
/
CPMUG080.ARK
/
MMENU.STB
< prev
next >
Wrap
Text File
|
1984-04-29
|
3KB
|
70 lines
9 Rem Copyright 1981 by David E. Trachtenbarg
10 Dim Today$(5),Last'edited$(5),Last'sorted$(5)
11 Dim Edit'file$(13),Data'file$(13),Sort'file$(13)
12 Dim File$(73),Name$(34)
20 Endcommon
25 If Today$="" Then Run"DATE.SAV"
30 Dim Command$(10)
40 Integer I
50 Set 0,-1
110 @ Chr$(7)
120 *Menu
130 Gosub Screen'erase
140 @ : @ : @"*********"
150 @ : @"Today: ";Today$(0,1);"/";Today$(2,3);"/";Today$(4,5)
160 @"Last Edited: ";Last'edited$(0,1);"/";Last'edited$(2,3);"/";Last'edited$(4,5)
170 @ : @ : @"Main Index" : @
180 @"1. Edit records"
190 @"2. Print records"
210 @"3. Change today's date"
211 @"4. Make a copy of the address file on drive B"
212 @"5. Quit"
220 @ : @
230 Input"Enter the number of your choice. ",Command$
240 If Command$="" Then Goto Menu
250 I=Val(Command$)
260 If I=1 Then Run"REC-EDIT.SAV"
270 If I=2 Then Run"REC-PRN.SAV"
280 If I=3 Then Goto Change'date
282 If I=4 Then Run"BACKUP.SAV"
285 If I=5 Then Bye
290 Goto Menu
300 *Screen'erase
310 Out 1,126 : Out 1,28 : Return
320 *Bottom'lines
330 Out 1,126 : Out 1,17 : Out 1,0 : Out 1,22
340 Out 1,126 : Out 1,24 : Return
350 *Enter'today
360 @ : Input"Enter the date in mo/da/yr format. ",Command$
370 If Command$="" Then Return
380 If Len(Command$)<>8 Then @"Please use mo/da/yr format." : Goto 360
390 I=Val(Command$(0,1))
400 If I<1 Or I>12 Then @"Then month must be between 01 and 12." : Goto 360
410 I=Val(Command$(3,4))
420 If I<1 Or I>31 Then @"The day must be between 01 and 31." : Goto 360
430 I=Val(Command$(6,7))
440 If I=0 And Command$(6,7)<>"00" Then @"The year must be a number." : Goto 360
450 If(Command$(2,2)<>"/") Or(Command$(5,5)<>"/") Then @"You must separate the date with /'s." : Goto 360
460 Today$=Command$(0,1)+Command$(3,4)+Command$(6,7)
470 Return
480 *Change'date
490 @ : @
500 Gosub Enter'today
510 Open\1,6\Edit'file$
520 Put\1,0\Today$(-1)
530 Close\1\
540 Goto Menu
550 *Create'file
560 If Sys(3)<>134 Then Goto Error'report
570 Create Edit'file$
580 Open\1,6\Edit'file$
590 Put\1,1\Today$(-1)
600 Close\1\
610 Retry
620 *Error'report
630 @ : @"Error ";Sys(3);" has occured."
640 Stop
650 @""