home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
SIMTEL
/
CPMUG
/
CPMUG042.ARK
/
TIME.BAS
< prev
next >
Wrap
BASIC Source File
|
1984-04-29
|
2KB
|
75 lines
10 REM ****** MICROSOFT DISK BASIC, RUNNING UNDER CP/M ******
20 REM *** REV. BY HARRY KAEMMERER 07/14/1979 ***
30 REM *** PGM TO DISPAY TIME AND DATE OF COMPU/TIME MODEL T102A CLOCK ***
40 REM *** SET DISPLAY SCREEN WIDTH ***
50 WIDTH 80
60 REM *** CLEAR SCREEN COMMAND ***
70 PRINT CHR$(12)
80 REM
90 REM *** CHANGE P1= TO DECIMAL ADDRESS OF YOUR STARTING PORT ***
100 REM *** 192=C0Hex ***
110 P1=192
120 H=23:V=0:GOSUB 680
130 PRINT" TIME ";
140 REM *** HOUR TENS ***
150 OUT P1,0
160 H1=INP(P1)
170 REM *** HOUR UNITS ***
180 OUT P1,1
190 H2=INP(P1)
200 REM *** MINUTE TENS ***
210 OUT P1,2
220 M1=INP(P1)
230 REM *** MINUTE UNITS ***
240 OUT P1,3
250 M2=INP(P1)
260 REM *** SECOND TENS ***
270 OUT P1,4
280 S1=INP(P1)
290 REM *** SECOND UNITS ***
300 OUT P1,5
310 S2=INP(P1)
320 REM *** ELIMINATE SPACES BETWEEN NUMBERS BY CONVERTING TO STRINGS ***
330 H1$=CHR$(H1+48)
340 H2$=CHR$(H2+48)
350 M1$=CHR$(M1+48)
360 M2$=CHR$(M2+48)
370 S1$=CHR$(S1+48)
380 S2$=CHR$(S2+48)
390 PRINT H1$;H2$;":";M1$;M2$;":";S1$;S2$;
400 PRINT" DATE ";
410 REM *** MONTH TENS ***
420 OUT P1,8
430 M1=INP(P1)
440 IF M1=15 THEN M1=0
450 REM *** MONTH UNITS ***
460 OUT P1,9
470 M2=INP(P1)
480 REM *** DAY TENS ***
490 OUT P1,10
500 D1=INP(P1)
510 REM *** DAY UNITS ***
520 OUT P1,11
530 D2=INP(P1)
540 REM *** ELIMINATE SPACES BETWEEN NUMBERS BY CONVERTING TO STRINGS ***
550 M1$=CHR$(M1+48)
560 M2$=CHR$(M2+48)
570 D1$=CHR$(D1+48)
580 D2$=CHR$(D2+48)
590 REM *** CHANGE NEXT LINE TO CURRENT YEAR ***
600 PRINT M1$;M2$;"/";D1$;D2$;"/1979"
610 PRINT:PRINT
620 END
630 REM ---------------------------
640 REM *** CURSOR CONTROL SUB. ***
650 REM ---------------------------
660 REM
670 REM H=HORZ V=VERTICAL
680 OUT 1,3
690 A=INP(0) AND 128:IF A<>0 THEN 690
700 OUT 1,H
710 A=INP(0) AND 128:IF A<>0 THEN 710
720 OUT 1,V
730 A=INP(0) AND 128:IF A<>0 THEN 730
740 RETURN