home *** CD-ROM | disk | FTP | other *** search
/ ftp.barnyard.co.uk / 2015.02.ftp.barnyard.co.uk.tar / ftp.barnyard.co.uk / cpm / walnut-creek-CDROM / SIMTEL / CPMUG / CPMUG042.ARK / BIDI.ASM < prev    next >
Assembly Source File  |  1984-04-29  |  9KB  |  328 lines
  1. ;
  2. ; TITLE        BI-DIRECTIONAL DIABLO PRINTER DRIVER
  3. ; FILENAME    BIDI.LIB
  4. ; AUTHOR    Robert A. Van Valzah   9/30/79
  5. ; LAST REVISOR    R.A.V.  11/10/79
  6. ; REASON    byte squeezing
  7. ; 
  8. ;
  9. ; plan of attack:
  10. ; ===============
  11. ; characters come in one at a time and are stored into
  12. ; a buffer until a line feed comes in.  at this point,
  13. ; the line in the buffer is analized and a decision is
  14. ; made to print it forward or backward so as to mininmize
  15. ; the head movement.
  16. ;
  17. ; the gory details:
  18. ; =================
  19. ; characters which are printable are just stored in the
  20. ; buffer.  blanks, on the other hand, are accumulated
  21. ; and the number of blanks to move is stored with a bias
  22. ; of 80h.  the first byte of the buffer is an exception:
  23. ; it is initialized to 0h and is used to accumulate the
  24. ; number of spaces between the left margin and the first
  25. ; printable character (this is the location leolpos).
  26. ; the position of the rightmost printable character is
  27. ; keep track of as characters come in the location reolpos.
  28. ;
  29. ; as the head is moved across the page, its position is
  30. ; recorded in hpos.  this information is used in
  31. ; conjunction with leolpos and reolpos to determine if
  32. ; printing forward or backward will cause the shortest
  33. ; printhead movement.  if the printhead is currently to
  34. ; the left of the centerpoint of the line, then it is
  35. ; shortest to move to the left end and start printing.
  36. ; otherwise, it is shortest to move to the right end
  37. ; and print backward.  if the printhead is exactly at
  38. ; the midpoint, the line is printed backward so as to
  39. ; leave the printhead as close to the left margin
  40. ; as possible.
  41. ;
  42. ;
  43. ;    port i/o number equates
  44. ;
  45. base    equ    0f4h
  46. datal    equ    base
  47. datah    equ    base+1
  48. cmand    equ    base+2
  49. stats    equ    base
  50. ;
  51. ;    print formatting equates
  52. ;
  53. ncols    equ    120    ;max number of cols/line (must be <=126)
  54. ;
  55. ;    command bits
  56. ;
  57. restr    equ    1    ;restore carriage
  58. chstb    equ    2    ;character strobe
  59. xstb    equ    4    ;carriage strobe
  60. ystb    equ    8    ;paper feed strobe
  61. selpr    equ    10h    ;select printer
  62. selry    equ    20h    ;select ready
  63. rblft    equ    40h    ;ribbon lift
  64. ;
  65. ;    status bits
  66. ;
  67. chrdy    equ    8    ;character ready
  68. xrdy    equ    10h    ;carriage ready
  69. yrdy    equ    20h    ;paper feed ready
  70. ;
  71. ;
  72. ; print character in reg c
  73. ;
  74. print:
  75.     mov    a,c    ;get char to print to reg a
  76.     ani    7fh    ;strip parity
  77.     mov    c,a
  78.     lhld    nbufad    ;and pointer to next buffer address
  79.     cpi    13    ;test for special characters
  80.     rz        ;ignore carriage return
  81.     cpi    10
  82.     jz    plf    ;line feed
  83.     cpi    12
  84.     jz    pff    ;form feed
  85.     inr    m    ;assume a space
  86.     cpi    ' '
  87.     rz        ;was a space, all done
  88.     dcr    m    ;un-do assumption
  89.     rc        ;was some other control char, ignore
  90.     ;must be a printable character
  91.     mov    a,l    ;see if buffer is about overflow
  92.     cpi    low(buf+ncols-2)
  93.     rz
  94.     cpi    low(buf) ;see if this is first character
  95.     mov    a,m    ;get amt to move before printing
  96.     jz    gotamt    ;jump if first character
  97.     cpi    81h
  98.     jz    noblank    ;no blanks between last & this char
  99.     sui    80h    ;subtract flag value
  100. gotamt:    ;amount to move in reg a
  101.     inx    h    ;move over number of blanks
  102.     db    11h    ;lxi trick to skip following mvi a
  103. noblank:
  104.     mvi    a,1    ;like one blank between character
  105.     mov    m,c    ;store the character comming in
  106.     inx    h    ;point to next buffer location
  107.     mvi    m,81h    ;init to one blank to next char
  108.     shld    nbufad    ;update buffer pointer
  109.     lxi    h,reolpos ;update right end of line position
  110.     add    m
  111.     mov    m,a
  112.     ret
  113. ;
  114. ; print line feed
  115. ;
  116. plf:
  117.     mov    a,l    ;see if nbufad = buf
  118.     cpi    low(buf) ;if = then blank line
  119.     jz    lfend    ;=, so don't print anything
  120.     lda    leolpos    ;get left end of line position
  121.     mov    b,a    ;save it in reg b
  122.     lda    reolpos    ;get right end of line position
  123.     add    b    ;add leolpos to reolpos
  124.     rar        ;divide by two to find midpoint
  125.     mov    b,a    ;save line center point in reg b
  126.     lda    hpos    ;get current head position
  127.     sub    b    ;hpos-(leolpos+reolpos)/2
  128.     jc    forward    ;middle > hpos
  129. ;
  130. ; print the buffer backward
  131. ;
  132. backward:
  133.     mvi    a,80h    ;put end of buffer marker at left end
  134.     sta    buf
  135.     lda    reolpos    ;get absolute position of right eol
  136.     lxi    h,hpos    ;compute amount to move to get there
  137.     sub    m    ;reolpos-hpos
  138.     lhld    nbufad    ;get right most character to print
  139.     dcx    h
  140. bkwd1:
  141.     ;signed distance to move is now in reg a
  142.     call    movprt    ;move as needed and print a character
  143.     dcx    h    ;point to movement amount
  144.     mov    a,m    ;amount to move to reg a
  145.     sui    80h    ;test for eob mark
  146.     jz    lfend    ;hit end of line
  147.     dcx    h    ;assume this is a movement
  148.     cma        ;two's comp for leftward movement
  149.     inr    a
  150.     jnc    bkwd1    ;it was, reg a has amount to move
  151.     inx    h    ;it wasn't, fix buffer pointer
  152.     mvi    a,0ffh    ;move one space to the left
  153.     jmp    bkwd1
  154. ;
  155. ; print buffer forwards
  156. ;
  157. forward:
  158.     mvi    m,80h    ;put in eob mark (also ignores trailing blanks)
  159.     lxi    h,buf    ;pointer into buffer
  160.     mov    a,m    ;absolute pos of leftmost char to reg a
  161.     inx    h    ;point to first printable character
  162.     push    h    ;save buffer pointer
  163.     lxi    h,hpos    ;compute amount to move to get to leolpos
  164.     sub    m    ;leolpos-hpos
  165.     pop    h    ;restore buffer pointer
  166. fwd1:
  167.     ;signed distance to move is now in reg a
  168.     call    movprt    ;move and print a character
  169.     inx    h    ;point to next character
  170.     mov    a,m    ;get it
  171.     sui    80h    ;test for end of line
  172.     jz    lfend    ;hit end of line
  173.     inx    h    ;point to character
  174.     jnc    fwd1    ;was a movement, reg a has distance
  175.     dcx    h    ;was a character, backup pointer
  176.     mvi    a,1    ;and set amount to move to 1
  177.     jmp    fwd1    ;go print next character
  178. ;
  179. ; common finish up routine for print line feed
  180. ;
  181. lfend:
  182.     lxi    h,lfstodo ;add one to line feeds to do before
  183.     inr    m    ;printing next line
  184.     jmp    init1    ;reset pointers
  185. ;
  186. ; print a form feed
  187. ;
  188. pff:
  189.     lda    lpp    ;get lines per page
  190.     lxi    h,lonp    ;subtract lines printed on this page
  191.     sub    m    ;leaving lines left on this page
  192.     sta    lfstodo    ;which is the number of lfs to do
  193.     ret
  194. ;
  195. ; move the number of character positions in reg a (taken as a
  196. ; signed number, + to the right, - to the left) and
  197. ; print the character pointed to by reg hl.
  198. ;
  199. movprt:
  200.     mov    c,m    ;get character to print
  201.     push    h    ;save while printing
  202.     mov    e,a    ;save amount to move in reg e
  203. movr:
  204.     in    stats    ;wait for all movement to stop
  205.     ani    chrdy+xrdy+yrdy
  206.     jnz    movr
  207.     lxi    h,hpos    ;update the head position byte
  208.     mov    a,e
  209.     add    m    ;add amount we are moving
  210.     mov    m,a
  211.     mvi    b,xstb    ;ready x strobe for movstb
  212.     lda    chwid    ;load up character muliplicaton factor
  213.     call    movstb    ;send necessary x movement
  214.     lda    lpp    ;lines per page to reg b
  215.     mov    b,a
  216.     lxi    h,lfstodo ;number of pending line feeds
  217.     mov    a,m    ;skip movement if zero
  218.     ora    a
  219.     jz    noymov    ;no y movement
  220.     mov    e,a    ;movement to reg e for movstb
  221.     mvi    m,0    ;there will be none to do now
  222.     lxi    h,lonp    ;keep track of line on page
  223.     add    m
  224.     mov    m,a
  225.     sub    b    ;see if started new page
  226.     jc    samepage ;nope
  227.     mov    m,a    ;yes - take lonp mod lpp
  228. samepage:
  229.     lda    linhgt    ;load up line multiplicaton factor
  230.     mvi    b,ystb    ;ready y strobe for movstb
  231.     call    movstb    ;send necessary y movement
  232. noymov:
  233.     mov    e,c    ;send character
  234.     mvi    b,chstb    ;send character strobe
  235.     mvi    a,1    ;dummy multiplication factor
  236.     call    movstb
  237.     pop    h
  238.     ret
  239. ;
  240. ; move the signed amount in reg e using value in reg a as
  241. ; a mulitplication factor to get the number of increments
  242. ; then send strobe in reg b.
  243. ;
  244. movstb:
  245.     push    psw    ;save multiplication factor
  246.     mov    a,e    ;form a 16 bit amount to move in reg de
  247.     ral        ;sign of movement into carry
  248.     sbb    a    ;generate sign extention
  249.     mov    d,a    ;16-bit signed movement now in reg de
  250.     pop    psw    ;get multiplication factor
  251.     lxi    h,0    ;initialize product
  252. mulbyw:            ;multiply
  253.     dad    d
  254.     dcr    a
  255.     jnz    mulbyw    ;keep multiplying
  256.     mov    a,h    ;is this leftward movement?
  257.     ora    a
  258.     jp    posmov    ;no - distance is ok
  259.     xra    a    ;yes - negate distance
  260.     sub    l    ;reg a = 0 - low order
  261.     mov    l,a    ;which is low order compliment
  262.     sbb    h    ;now subtract out high order and
  263.     sub    l    ;subtract out excess low order
  264.     ;complimented distance now in reg a and reg l
  265.     ori    4    ;and set negative motion bit
  266. posmov:
  267.     cma        ;high order data is active low
  268.     out    datah    ;send high order data
  269.     mov    a,l    ;get low order data
  270.     cma        ;it too is active low
  271.     out    datal    ;send low  order data
  272.             ;fall thru to strobe
  273. ;
  274. ; pulse strobe in reg b
  275. ;
  276. strobe:
  277.     xra    a    ;delay a while for data set-up time
  278. dlay:
  279.     dcr    a
  280.     jnz    dlay
  281.     mvi    a,0ffh-selpr-rblft-selry
  282.     push    psw    ;save bits which are allways high
  283.     sub    b    ;lower appropriate strobe bit
  284.     out    cmand    ;send strobe bit low
  285.     pop    psw    ;and send it high
  286.     out    cmand
  287.     ret
  288. ;
  289. ; init for printing
  290. ;
  291. init:
  292.     mvi    b,restr    ;pulse restore line to
  293.     call    strobe    ;reset printer
  294.     xra    a    ;set software head position to zero
  295.     sta    hpos
  296.     sta    lonp    ;reset line counter to top of page
  297.     sta    lfstodo    ;zero out number of line feeds to do
  298. init1:    ;empty buffer entry point
  299.     xra    a    ;reset right end of line position
  300.     sta    reolpos
  301.     lxi    h,buf    ;next buffer address pointer
  302.     shld    nbufad
  303.     mov    m,a    ;inits left end of line position
  304.     ret
  305. ;
  306. ;
  307. ;    ram parameter area
  308. ;
  309. linhgt    db    8    ;line height in increments
  310. chwid    db    6    ;character width in increments
  311. lpp    db    66    ;lines per page
  312. ;
  313. ;    ram areas
  314. ;
  315. lonp    ds    1    ;current line on page, 0 = first line
  316. lfstodo    ds    1    ;line feeds to do before printing
  317. hpos    ds    1
  318. reolpos    ds    1
  319. nbufad    ds    2
  320. buf:
  321. leolpos:        ;address of byte containing left eol
  322.     ds    1
  323. lmostch:        ;address of left most character
  324.     ds    ncols
  325. ;
  326.     end
  327.  
  328.