home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
ftp.barnyard.co.uk
/
2015.02.ftp.barnyard.co.uk.tar
/
ftp.barnyard.co.uk
/
cpm
/
walnut-creek-CDROM
/
SIMTEL
/
CPMUG
/
CPMUG033.ARK
/
RJCASP.BAS
< prev
next >
Wrap
BASIC Source File
|
1984-04-29
|
2KB
|
75 lines
10 REM THIS IS THE PROGRAM 'RJCASP.BAS' A SAR RESOURCE ALLOCATION PROGRAM
20 REM WRITTEN BY MJ BOB MATTSON USAF, DIR OF SAR, CIVIL AIR PATROL
30 REM
35 DIM D(50),C1$(50),C2(50),C5$(50),P1(50),P2(50)
40 LET P4=99
45 PRINT "ENTER PRIMARY CELL NAME,COMMA,SECONDARY CELL NAME,COMMA,AND THEN"
50 PRINT"PROBABILITY OF TARGET IN THE CELL USING THE RANGE 0-";P4
55 PRINT "FOR THE LAST ENTRY USE 'END,0,0'"
60 INPUT C3$,C6$,P3
70 FOR I=1 TO N
80 IF C3$="END" THEN 180
90 IF C3$<>C1$(I) THEN 120
100 LET P1(I)=P1(I)+P3
110 GOTO 60
120 NEXT I
130 LET N=N+1
140 LET C1$(N)=C3$
145 LET C5$(N)=C6$
150 LET P1(N)=P3
160 LET D(N)=N
170 GOTO 60
180 LET P4=0
190 FOR I=1 TO N
195 LET P4=P4+P1(I)
200 NEXT I
210 FOR I=1 TO N
220 LET P1(I)=P1(I)/P4
230 NEXT I
240 PRINT "ENTER CELL NAME,COMMA,AND POD FOR CELL (1-99)"
250 PRINT "FOR THE LAST ENTRY, ENTER 'END,0'"
260 INPUT C3$, Q1
270 FOR I=1 TO N
280 IF C3$=C1$(I) THEN 300
290 NEXT I
300 LET C2(I)=C2(I)-LOG(1-Q1/100)
310 IF C3$<>"END" THEN 260
320 LET C4=0
330 FOR I=1 TO N
340 LET C4=C4+P1(I)*EXP(-1*C2(I))
350 NEXT I
360 FOR I=1 TO N
370 LET P2(I)=P1(I)*EXP(-1*C2(I))/C4
380 NEXT I
390 FOR J=1 TO N-1
400 FOR I=J+1 TO N
410 IF P2(D(J))>P2(D(I)) THEN 450
420 LET T=D(J)
430 LET D(J)=D(I)
440 LET D(I)=T
450 NEXT I
460 NEXT J
470 PRINT "ENTER NUMBER OF CELLS YOU WISH TO SEE";
480 INPUT J
490 PRINT "CELL","CELL","INIT PROB", "CUMULATIVE","CURRENT PROB"
500 PRINT "NUMBER", "NAME","TGT IN CELL","POD","TARGET IN CELL"
510 FOR I=1 TO J
520 PRINT C5$(D(I)),C1$(D(I)),INT(100*P1(D(I))+.5);"%",
530 PRINT INT(100*(1-EXP(-1*C2(D(I))))+.5);"%",INT(100*P2(D(I))+.5);"%"
540 NEXT I
550 PRINT "SEARCH EFFECTIVENESS PROBABILITY =";INT(1000*(1-C4)+.5)/10;"%"
560 PRINT "DO YOU HAVE ANY NEW SEARCH POD'S TO REPORT? Y/N??";
570 INPUT K$
580 IF LEFT$(K$,1)="Y" THEN 240
590 PRINT "DO YOU HAVE ANY NEW AREAS OR REVISED POT'S TO REPORT? Y/N??";
600 INPUT K$
610 IF LEFT$(K$,1)<>"Y" THEN 660
620 FOR I=1 TO N
630 LET P1(I)=P4*P1(I)
640 NEXT I
650 GOTO 45
660 END
670 LTCOL MATTSON MAY BE CONTACTED BY WRITTING TO
671 NATIONAL HEADQUARTERS-CIVIL AIR PATROL
672 MAXWELL AIR FORCE BASE,ALABAMA 36112, U.S.A.